From 73c07376bb1371afd3a10c4dc135912cfe16a247 Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Lo=C3=AFc=20Hoguin?= <essen@ninenines.eu>
Date: Sat, 21 Jul 2012 22:19:13 +0200
Subject: Add a POST echo example

---
 examples/echo_post/src/echo_post.app.src   | 15 +++++++++++++
 examples/echo_post/src/echo_post.erl       | 12 ++++++++++
 examples/echo_post/src/echo_post_app.erl   | 26 +++++++++++++++++++++
 examples/echo_post/src/echo_post_sup.erl   | 23 +++++++++++++++++++
 examples/echo_post/src/toppage_handler.erl | 36 ++++++++++++++++++++++++++++++
 5 files changed, 112 insertions(+)
 create mode 100644 examples/echo_post/src/echo_post.app.src
 create mode 100644 examples/echo_post/src/echo_post.erl
 create mode 100644 examples/echo_post/src/echo_post_app.erl
 create mode 100644 examples/echo_post/src/echo_post_sup.erl
 create mode 100644 examples/echo_post/src/toppage_handler.erl

(limited to 'examples/echo_post/src')

diff --git a/examples/echo_post/src/echo_post.app.src b/examples/echo_post/src/echo_post.app.src
new file mode 100644
index 0000000..74ff7f3
--- /dev/null
+++ b/examples/echo_post/src/echo_post.app.src
@@ -0,0 +1,15 @@
+%% Feel free to use, reuse and abuse the code in this file.
+
+{application, echo_post, [
+	{description, "Cowboy POST echo example."},
+	{vsn, "1"},
+	{modules, []},
+	{registered, []},
+	{applications, [
+		kernel,
+		stdlib,
+		cowboy
+	]},
+	{mod, {echo_post_app, []}},
+	{env, []}
+]}.
diff --git a/examples/echo_post/src/echo_post.erl b/examples/echo_post/src/echo_post.erl
new file mode 100644
index 0000000..0073a80
--- /dev/null
+++ b/examples/echo_post/src/echo_post.erl
@@ -0,0 +1,12 @@
+%% Feel free to use, reuse and abuse the code in this file.
+
+-module(echo_post).
+
+%% API.
+-export([start/0]).
+
+%% API.
+
+start() ->
+	ok = application:start(cowboy),
+	ok = application:start(echo_post).
diff --git a/examples/echo_post/src/echo_post_app.erl b/examples/echo_post/src/echo_post_app.erl
new file mode 100644
index 0000000..bb74d4a
--- /dev/null
+++ b/examples/echo_post/src/echo_post_app.erl
@@ -0,0 +1,26 @@
+%% Feel free to use, reuse and abuse the code in this file.
+
+%% @private
+-module(echo_post_app).
+-behaviour(application).
+
+%% API.
+-export([start/2]).
+-export([stop/1]).
+
+%% API.
+
+start(_Type, _Args) ->
+	Dispatch = [
+		{'_', [
+			{[], toppage_handler, []}
+		]}
+	],
+	{ok, _} = cowboy:start_listener(http, 100,
+		cowboy_tcp_transport, [{port, 8080}],
+		cowboy_http_protocol, [{dispatch, Dispatch}]
+	),
+	echo_post_sup:start_link().
+
+stop(_State) ->
+	ok.
diff --git a/examples/echo_post/src/echo_post_sup.erl b/examples/echo_post/src/echo_post_sup.erl
new file mode 100644
index 0000000..6f973c0
--- /dev/null
+++ b/examples/echo_post/src/echo_post_sup.erl
@@ -0,0 +1,23 @@
+%% Feel free to use, reuse and abuse the code in this file.
+
+%% @private
+-module(echo_post_sup).
+-behaviour(supervisor).
+
+%% API.
+-export([start_link/0]).
+
+%% supervisor.
+-export([init/1]).
+
+%% API.
+
+-spec start_link() -> {ok, pid()}.
+start_link() ->
+	supervisor:start_link({local, ?MODULE}, ?MODULE, []).
+
+%% supervisor.
+
+init([]) ->
+	Procs = [],
+	{ok, {{one_for_one, 10, 10}, Procs}}.
diff --git a/examples/echo_post/src/toppage_handler.erl b/examples/echo_post/src/toppage_handler.erl
new file mode 100644
index 0000000..aed26e6
--- /dev/null
+++ b/examples/echo_post/src/toppage_handler.erl
@@ -0,0 +1,36 @@
+%% Feel free to use, reuse and abuse the code in this file.
+
+%% @doc POST echo handler.
+-module(toppage_handler).
+
+-export([init/3]).
+-export([handle/2]).
+-export([terminate/2]).
+
+init(_Transport, Req, []) ->
+	{ok, Req, undefined}.
+
+handle(Req, State) ->
+	{Method, Req2} = cowboy_http_req:method(Req),
+	{HasBody, Req3} = cowboy_http_req:has_body(Req2),
+	{ok, Req4} = maybe_echo(Method, HasBody, Req3),
+	{ok, Req4, State}.
+
+maybe_echo('POST', true, Req) ->
+	{PostVals, Req2} = cowboy_http_req:body_qs(Req),
+	Echo = proplists:get_value(<<"echo">>, PostVals),
+	echo(Echo, Req2);
+maybe_echo('POST', false, Req) ->
+	cowboy_http_req:reply(400, [], <<"Missing body.">>, Req);
+maybe_echo(_, _, Req) ->
+	%% Method not allowed.
+	cowboy_http_req:reply(405, Req).
+
+echo(undefined, Req) ->
+	cowboy_http_req:reply(400, [], <<"Missing echo parameter.">>, Req);
+echo(Echo, Req) ->
+	cowboy_http_req:reply(200,
+		[{<<"Content-Encoding">>, <<"utf-8">>}], Echo, Req).
+
+terminate(_Req, _State) ->
+	ok.
-- 
cgit v1.2.3