From ae0dd616737d8e1116de4a04be0bc84188997eb0 Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Lo=C3=AFc=20Hoguin?= <essen@ninenines.eu>
Date: Wed, 10 Aug 2016 11:49:31 +0200
Subject: Add tests for responses and request body reading

This is a large commit. The cowboy_req interface has largely
changed, and will change a little more. It's possible that
some examples or tests have not been converted to the new
interface yet. The documentation has not yet been updated.
All of this will be fixed in smaller subsequent commits.

Gotta start somewhere...
---
 test/handlers/multipart_h.erl | 65 +++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 65 insertions(+)
 create mode 100644 test/handlers/multipart_h.erl

(limited to 'test/handlers/multipart_h.erl')

diff --git a/test/handlers/multipart_h.erl b/test/handlers/multipart_h.erl
new file mode 100644
index 0000000..289d2ed
--- /dev/null
+++ b/test/handlers/multipart_h.erl
@@ -0,0 +1,65 @@
+%% This module reads a multipart body and echoes it back as an Erlang term.
+
+-module(multipart_h).
+
+-export([init/2]).
+
+init(Req0, State) ->
+	{Result, Req} = case cowboy_req:binding(key, Req0) of
+		undefined -> acc_multipart(Req0, []);
+		<<"skip_body">> -> skip_body_multipart(Req0, []);
+		<<"read_part2">> -> read_part2_multipart(Req0, []);
+		<<"read_part_body2">> -> read_part_body2_multipart(Req0, [])
+	end,
+	{ok, cowboy_req:reply(200, #{}, term_to_binary(Result), Req), State}.
+
+acc_multipart(Req0, Acc) ->
+	case cowboy_req:part(Req0) of
+		{ok, Headers, Req1} ->
+			{ok, Body, Req} = stream_body(Req1, <<>>),
+			acc_multipart(Req, [{Headers, Body}|Acc]);
+		{done, Req} ->
+			{lists:reverse(Acc), Req}
+	end.
+
+stream_body(Req0, Acc) ->
+	case cowboy_req:part_body(Req0) of
+		{more, Data, Req} ->
+			stream_body(Req, << Acc/binary, Data/binary >>);
+		{ok, Data, Req} ->
+			{ok, << Acc/binary, Data/binary >>, Req}
+	end.
+
+skip_body_multipart(Req0, Acc) ->
+	case cowboy_req:part(Req0) of
+		{ok, Headers, Req} ->
+			skip_body_multipart(Req, [Headers|Acc]);
+		{done, Req} ->
+			{lists:reverse(Acc), Req}
+	end.
+
+read_part2_multipart(Req0, Acc) ->
+	case cowboy_req:part(Req0, #{length => 1, period => 1}) of
+		{ok, Headers, Req1} ->
+			{ok, Body, Req} = stream_body(Req1, <<>>),
+			acc_multipart(Req, [{Headers, Body}|Acc]);
+		{done, Req} ->
+			{lists:reverse(Acc), Req}
+	end.
+
+read_part_body2_multipart(Req0, Acc) ->
+	case cowboy_req:part(Req0) of
+		{ok, Headers, Req1} ->
+			{ok, Body, Req} = stream_body2(Req1, <<>>),
+			acc_multipart(Req, [{Headers, Body}|Acc]);
+		{done, Req} ->
+			{lists:reverse(Acc), Req}
+	end.
+
+stream_body2(Req0, Acc) ->
+	case cowboy_req:part_body(Req0, #{length => 1, period => 1}) of
+		{more, Data, Req} ->
+			stream_body(Req, << Acc/binary, Data/binary >>);
+		{ok, Data, Req} ->
+			{ok, << Acc/binary, Data/binary >>, Req}
+	end.
-- 
cgit v1.2.3