Add restart_new_emulator instruction to kernel, stdlib and sasl appups

The appup files for kernel, stdlib and sasl did not contain any
UpFromVsn and DownToVsn. This means that it was not possible to create
a relup file with systool:make_relup if any of these applications had
changed.

This commit adds entries in the appup files for a maximum of two major
releases back - all with only one upgrade instruction:
restart_new_emulator. The point is to allow relups to be generated,
but ensure that no soft upgrade is done for these three applications -
i.e. they will always cause a restart of the emulator prior to all
other upgrade instructions from other applications.

Test cases (appup_test) are added to kernel_SUITE, stdlib_SUITE and
sasl_SUITE. These all check that expected versions are matched in the
appups, and illegal versions (older than two major releases, or in any
other way illegal) do not match. The test is written in a general way
where it is assumed that the version of these applications are stepped
according the the rule that major releases step the second number,
maintenance releases step the third number and patches step the fourth
number.

1 files changed, 60 insertions, 3 deletions

diff --git a/lib/stdlib/test/stdlib_SUITE.erl b/lib/stdlib/test/stdlib_SUITE.erl
index 0cca030b3d..8a2cb5ea6b 100644
--- a/lib/stdlib/test/stdlib_SUITE.erl
+++ b/lib/stdlib/test/stdlib_SUITE.erl
@@ -33,8 +33,7 @@
 -export([init_per_testcase/2, end_per_testcase/2]).
 
 % Test cases must be exported.
--export([app_test/1]).
--define(cases, [app_test]).
+-export([app_test/1, appup_test/1]).
 
 %%
 %% all/1
@@ -42,7 +41,7 @@
 suite() -> [{ct_hooks,[ts_install_cth]}].
 
 all() -> 
-    [app_test].
+    [app_test, appup_test].
 
 groups() -> 
     [].
@@ -79,3 +78,61 @@ app_test(Config) when is_list(Config) ->
     ?t:app_test(stdlib),
     ok.
 
+%% Test that appup allows upgrade from/downgrade to a maximum of two
+%% major releases back.
+appup_test(_Config) ->
+    application:load(stdlib),
+    {_,_,Vsn} = lists:keyfind(stdlib,1,application:loaded_applications()),
+    AppupFile = filename:join([code:lib_dir(stdlib),ebin,"stdlib.appup"]),
+    {ok,[{Vsn,UpFrom,DownTo}=AppupScript]} = file:consult(AppupFile),
+    ct:log("~p~n",[AppupScript]),
+    {OkVsns,NokVsns} = create_test_vsns(Vsn),
+    check_appup(OkVsns,UpFrom,{ok,[restart_new_emulator]}),
+    check_appup(OkVsns,DownTo,{ok,[restart_new_emulator]}),
+    check_appup(NokVsns,UpFrom,error),
+    check_appup(NokVsns,DownTo,error),
+    ok.
+
+create_test_vsns(Current) ->
+    [XStr,YStr|Rest] = string:tokens(Current,"."),
+    X = list_to_integer(XStr),
+    Y = list_to_integer(YStr),
+    SecondMajor = vsn(X,Y-2),
+    SecondMinor = SecondMajor ++ ".1.3",
+    FirstMajor = vsn(X,Y-1),
+    FirstMinor = FirstMajor ++ ".57",
+    ThisMajor = vsn(X,Y),
+    This =
+	case Rest of
+	    [] ->
+		[];
+	    ["1"] ->
+		[ThisMajor];
+	    _ ->
+		ThisMinor = ThisMajor ++ ".1",
+		[ThisMajor,ThisMinor]
+	end,
+    OkVsns = This ++ [FirstMajor, FirstMinor, SecondMajor, SecondMinor],
+
+    ThirdMajor = vsn(X,Y-3),
+    ThirdMinor = ThirdMajor ++ ".10.12",
+    Illegal = ThisMajor ++ ",1",
+    Newer1Major = vsn(X,Y+1),
+    Newer1Minor = Newer1Major ++ ".1",
+    Newer2Major = ThisMajor ++ "1",
+    NokVsns = [ThirdMajor,ThirdMinor,
+	       Illegal,
+	       Newer1Major,Newer1Minor,
+	       Newer2Major],
+    {OkVsns,NokVsns}.
+
+vsn(X,Y) ->
+    integer_to_list(X) ++ "." ++ integer_to_list(Y).
+
+check_appup([Vsn|Vsns],Instrs,Expected) ->
+    case systools_relup:appup_search_for_version(Vsn, Instrs) of
+	Expected -> check_appup(Vsns,Instrs,Expected);
+	Other -> ct:fail({unexpected_result_for_vsn,Vsn,Other})
+    end;
+check_appup([],_,_) ->
+    ok.