Use compile options when dialyzing beam files

Fetch the compile options from beam files, and use them when creating
core from the abstract code. Previously the options were ignored.

Test by Henrik Nordh

3 files changed, 89 insertions, 4 deletions

diff --git a/lib/dialyzer/src/dialyzer_analysis_callgraph.erl b/lib/dialyzer/src/dialyzer_analysis_callgraph.erl
index 6a33a2acb3..af1c2b7e3a 100644
--- a/lib/dialyzer/src/dialyzer_analysis_callgraph.erl
+++ b/lib/dialyzer/src/dialyzer_analysis_callgraph.erl
@@ -373,7 +373,16 @@ compile_byte(File, Callgraph, CServer, UseContracts) ->
       {error, "  Could not get abstract code for: " ++ File ++ "\n" ++
 	 "  Recompile with +debug_info or analyze starting from source code"};
     {ok, AbstrCode} ->
-      compile_common(File, AbstrCode, [], Callgraph, CServer, UseContracts)
+      compile_byte(File, AbstrCode, Callgraph, CServer, UseContracts)
+  end.
+
+compile_byte(File, AbstrCode, Callgraph, CServer, UseContracts) ->
+  case dialyzer_utils:get_compile_options_from_beam(File) of
+    error ->
+      {error, "  Could not get compile options for: " ++ File ++ "\n" ++
+	 "  Recompile or analyze starting from source code"};
+    {ok, CompOpts} ->
+      compile_common(File, AbstrCode, CompOpts, Callgraph, CServer, UseContracts)
   end.
 
 compile_common(File, AbstrCode, CompOpts, Callgraph, CServer, UseContracts) ->
diff --git a/lib/dialyzer/src/dialyzer_utils.erl b/lib/dialyzer/src/dialyzer_utils.erl
index 21183e3459..b7d7ab4812 100644
--- a/lib/dialyzer/src/dialyzer_utils.erl
+++ b/lib/dialyzer/src/dialyzer_utils.erl
@@ -31,6 +31,7 @@
 	 format_sig/1,
 	 format_sig/2,
 	 get_abstract_code_from_beam/1,
+ 	 get_compile_options_from_beam/1,
 	 get_abstract_code_from_src/1,
 	 get_abstract_code_from_src/2,
 	 get_core_from_abstract_code/1,
@@ -136,6 +137,26 @@ get_abstract_code_from_beam(File) ->
       error
   end.
 
+-spec get_compile_options_from_beam(file:filename()) -> 'error' | {'ok', [compile:option()]}.
+
+get_compile_options_from_beam(File) ->
+  case beam_lib:chunks(File, [compile_info]) of
+    {ok, {_, List}} ->
+      case lists:keyfind(compile_info, 1, List) of
+	{compile_info, CompInfo} -> compile_info_to_options(CompInfo);
+	_ -> error
+      end;
+    _ ->
+      %% No or unsuitable compile info.
+      error
+  end.
+
+compile_info_to_options(CompInfo) ->
+  case lists:keyfind(options, 1, CompInfo) of
+    {options, CompOpts} -> {ok, CompOpts};
+    _ -> error
+  end.
+
 -type get_core_from_abs_ret() :: {'ok', cerl:c_module()} | 'error'.
 
 -spec get_core_from_abstract_code(abstract_code()) -> get_core_from_abs_ret().
@@ -150,7 +171,9 @@ get_core_from_abstract_code(AbstrCode, Opts) ->
   %% performed them. In some cases we end up in trouble when
   %% performing them again.
   AbstrCode1 = cleanup_parse_transforms(AbstrCode),
-  try compile:forms(AbstrCode1, Opts ++ src_compiler_opts()) of
+  %% Remove parse_transforms (and other options) from compile options.
+  Opts2 = cleanup_compile_options(Opts),
+  try compile:forms(AbstrCode1, Opts2 ++ src_compiler_opts()) of
       {ok, _, Core} -> {ok, Core};
       _What -> error
   catch
@@ -419,6 +442,24 @@ cleanup_parse_transforms([Other|Left]) ->
 cleanup_parse_transforms([]) ->
   [].
 
+-spec cleanup_compile_options([compile:option()]) -> [compile:option()].
+
+%% Using abstract, not asm or core.
+cleanup_compile_options([from_asm|Opts]) ->
+  Opts;
+cleanup_compile_options([asm|Opts]) ->
+  Opts;
+cleanup_compile_options([from_core|Opts]) ->
+  Opts;
+%% The parse transform will already have been applied, may cause problems if it
+%% is re-applied.
+cleanup_compile_options([{parse_transform, _}|Opts]) ->
+  Opts;
+cleanup_compile_options([Other|Opts]) ->
+  [Other|cleanup_compile_options(Opts)];
+cleanup_compile_options([]) ->
+  [].
+
 -spec format_errors([{module(), string()}]) -> [string()].
 
 format_errors([{Mod, Errors}|Left]) ->
diff --git a/lib/dialyzer/test/dialyzer_SUITE.erl b/lib/dialyzer/test/dialyzer_SUITE.erl
index 1b62291a00..8507525597 100644
--- a/lib/dialyzer/test/dialyzer_SUITE.erl
+++ b/lib/dialyzer/test/dialyzer_SUITE.erl
@@ -30,12 +30,12 @@
 -export([init_per_testcase/2, end_per_testcase/2]).
 
 %% Test cases must be exported.
--export([app_test/1, appup_test/1]).
+-export([app_test/1, appup_test/1, beam_tests/1]).
 
 suite() -> [{ct_hooks,[ts_install_cth]}].
 
 all() ->
-    [app_test, appup_test].
+    [app_test, appup_test, beam_tests].
 
 groups() ->
     [].
@@ -75,3 +75,38 @@ app_test(Config) when is_list(Config) ->
 %% Test that the .appup file does not contain any `basic' errors
 appup_test(Config) when is_list(Config) ->
     ok = ?t:appup_test(dialyzer).
+
+beam_tests(Config) when is_list(Config) ->
+    Prog = <<"
+              -module(no_auto_import).
+
+              %% Copied from erl_lint_SUITE.erl, clash6
+
+              -export([size/1]).
+
+              size([]) ->
+                  0;
+              size({N,_}) ->
+                  N;
+              size([_|T]) ->
+                  1+size(T).
+             ">>,
+    Opts = [no_auto_import],
+    {ok, BeamFile} = compile(Config, Prog, no_auto_import, Opts),
+    [] = run_dialyzer([BeamFile]),
+    ok.
+
+compile(Config, Prog, Module, CompileOpts) ->
+    Source = lists:concat([Module, ".erl"]),
+    PrivDir = ?config(priv_dir,Config),
+    Filename = filename:join([PrivDir, Source]),
+    ok = file:write_file(Filename, Prog),
+    Opts = [{outdir, PrivDir}, debug_info | CompileOpts],
+    {ok, Module} = compile:file(Filename, Opts),
+    {ok, filename:join([PrivDir, lists:concat([Module, ".beam"])])}.
+
+run_dialyzer(Files) ->
+    dialyzer:run([{analysis_type, plt_build},
+                  {files, Files},
+                  {from, byte_code},
+                  {check_plt, false}]).