From d6dc673a00f6244b03e1e9c849e3267b141c23c7 Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Bj=C3=B6rn=20Gustavsson?= <bjorn@erlang.org>
Date: Thu, 31 Mar 2011 08:40:36 +0200
Subject: Don't include tail-recursive calls in stacktraces

The stacktrace in debugger-generated exceptions should be
as similar to stacktraces in BEAM-generated exceptions as
possible.
---
 lib/debugger/test/int_eval_SUITE.erl               |  35 +++++-
 .../test/int_eval_SUITE_data/stacktrace.erl        | 130 +++++++++++++++++++++
 2 files changed, 163 insertions(+), 2 deletions(-)
 create mode 100644 lib/debugger/test/int_eval_SUITE_data/stacktrace.erl

(limited to 'lib/debugger/test')

diff --git a/lib/debugger/test/int_eval_SUITE.erl b/lib/debugger/test/int_eval_SUITE.erl
index f36ed213d1..99af1a8a2e 100644
--- a/lib/debugger/test/int_eval_SUITE.erl
+++ b/lib/debugger/test/int_eval_SUITE.erl
@@ -28,7 +28,7 @@
 	 bifs_outside_erlang/1, spawning/1, applying/1,
 	 catch_and_throw/1, external_call/1, test_module_info/1,
 	 apply_interpreted_fun/1, apply_uninterpreted_fun/1,
-	 interpreted_exit/1, otp_8310/1]).
+	 interpreted_exit/1, otp_8310/1, stacktrace/1]).
 
 %% Helpers.
 -export([applier/3]).
@@ -44,7 +44,7 @@ all() ->
     [bifs_outside_erlang, spawning, applying,
      catch_and_throw, external_call, test_module_info,
      apply_interpreted_fun, apply_uninterpreted_fun,
-     interpreted_exit, otp_8310].
+     interpreted_exit, otp_8310, stacktrace].
 
 groups() -> 
     [].
@@ -277,6 +277,37 @@ applier(M, F, A) ->
     io:format("~p:~p(~p) => ~p\n", [M,F,A,Res]),
     Res.
 
+stacktrace(Config) when is_list(Config) ->
+    ?line {done,Stk} = do_eval(Config, stacktrace),
+    ?line 13 = length(Stk),
+    ?line OldStackTraceFlag = int:stack_trace(),
+    ?line int:stack_trace(no_tail),
+    try
+	?line Res = spawn_eval(fun() -> stacktrace:stacktrace() end),
+	?line io:format("\nInterpreted (no_tail):\n~p", [Res]),
+	?line {done,Stk} = Res
+	after
+	    ?line int:stack_trace(OldStackTraceFlag)
+	end,
+    ok.
+
+
+do_eval(Config, Mod) ->
+    ?line DataDir = ?config(data_dir, Config),
+    ?line ok = file:set_cwd(DataDir),
+
+    ?line {ok,Mod} = compile:file(Mod, [report,debug_info]),
+    ?line {module,Mod} = code:load_file(Mod),
+    ?line CompiledRes = Mod:Mod(),
+    ?line ok = io:format("Compiled:\n~p", [CompiledRes]),
+    io:nl(),
+
+    ?line {module,Mod} = int:i(Mod),
+    ?line IntRes = Mod:Mod(),
+    ?line ok = io:format("Interpreted:\n~p", [IntRes]),
+
+    ?line CompiledRes = IntRes.
+
 %%
 %% Evaluate in another process, to prevent the test_case process to become
 %% interpreted.
diff --git a/lib/debugger/test/int_eval_SUITE_data/stacktrace.erl b/lib/debugger/test/int_eval_SUITE_data/stacktrace.erl
new file mode 100644
index 0000000000..a42dfca433
--- /dev/null
+++ b/lib/debugger/test/int_eval_SUITE_data/stacktrace.erl
@@ -0,0 +1,130 @@
+-module(stacktrace).
+-export([?MODULE/0]).
+
+?MODULE() ->
+    OldDepth = erlang:system_flag(backtrace_depth, 32),
+    done = (catch do_try()),
+    Stk = trim(erlang:get_stacktrace()),
+    erlang:system_flag(backtrace_depth, OldDepth),
+    {done,Stk}.
+
+trim([{int_eval_SUITE,_,_}|_]) ->
+    [];
+trim([H|T]) ->
+    [H|trim(T)];
+trim([]) -> [].
+
+do_try() ->
+    try
+	0 = id(42)
+    catch
+	error:{badmatch,42} ->
+	    do_try2()				%Tail-recursive
+    end.
+
+do_try2() ->
+    try
+	0 = id(42)
+    catch
+	error:{badmatch,42} ->
+	    do_try3()				%Not tail-recursive
+    end,
+    ?LINE.
+
+do_try3() ->
+    try id(42) of
+	42 -> do_try4()				%Tail-recursive
+    catch
+	error:ignore ->				%Should never catch
+	    ?LINE
+    end.
+
+do_try4() ->
+    try
+	do_recv()				%Not tail-recursive
+    catch
+	error:ignore ->				%Should never catch
+	    ?LINE
+    end.
+
+do_recv() ->
+    self() ! x,
+    receive
+	x -> do_recv2()				%Not tail-recursive
+    end,
+    ?LINE.
+
+do_recv2() ->
+    self() ! y,
+    receive
+	y -> do_recv3()				%Tail-recursive
+    end.
+
+do_recv3() ->
+    receive
+	after 0 -> do_recv4()			%Tail-recursive
+    end.
+
+do_recv4() ->
+    receive
+	after 0 -> do_if(true)			%Not tail-recursive
+    end,
+    ?LINE.
+
+do_if(Bool) ->
+    if
+	Bool -> do_if2(Bool)			%Tail-recursive
+    end.
+
+do_if2(Bool) ->
+    if
+	Bool -> do_case(Bool)			%Not tail-recursive
+    end,
+    ?LINE.
+
+
+do_case(Bool) ->
+    case Bool of
+	true -> do_case2(Bool)			%Tail-recursive
+    end.
+
+do_case2(Bool) ->
+    case Bool of
+	true -> do_fun(Bool)			%Not tail-recursive
+    end,
+    ?LINE.
+
+do_fun(Bool) ->
+    F = fun(true) ->
+		do_fun2(Bool)			%Tail-recursive
+	end,
+    F(Bool).					%Tail-recursive
+
+do_fun2(Bool) ->
+    F = fun(true) ->
+		cons(Bool)			%Tail-recursive
+	end,
+    F(Bool),					%Not tail-recursive
+    ?LINE.
+
+cons(Bool) ->
+    [Bool|tuple()].
+
+tuple() ->
+    {ok,op()}.
+
+op() ->
+    1 + lc().
+
+lc() ->
+    [done() || true].
+
+done() ->
+    tail(100),
+    throw(done).
+
+tail(0) -> ok;
+tail(N) -> tail(N-1).
+
+id(I) ->
+    I.
-- 
cgit v1.2.3