From e06dc58a9db38ad349143629f4ba7411275183ab Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Bj=C3=B6rn=20Gustavsson?= <bjorn@erlang.org>
Date: Mon, 27 Feb 2017 16:12:41 +0100
Subject: zip: Eliminate leak of open file after crash

Make sure that zip:extract() and zip:create() closes the zip
file if there is an error.

ERL-349
---
 lib/stdlib/src/zip.erl        | 28 ++++++++++++++++++++--------
 lib/stdlib/test/zip_SUITE.erl | 36 ++++++++++++++++++++++++++++++++++--
 2 files changed, 54 insertions(+), 10 deletions(-)

(limited to 'lib')

diff --git a/lib/stdlib/src/zip.erl b/lib/stdlib/src/zip.erl
index 31438ae36b..fadf96146e 100644
--- a/lib/stdlib/src/zip.erl
+++ b/lib/stdlib/src/zip.erl
@@ -368,9 +368,12 @@ do_unzip(F, Options) ->
     {Info, In1} = get_central_dir(In0, RawIterator, Input),
     %% get rid of zip-comment
     Z = zlib:open(),
-    Files = get_z_files(Info, Z, In1, Opts, []),
-    zlib:close(Z),
-    Input(close, In1),
+    Files = try
+                get_z_files(Info, Z, In1, Opts, [])
+            after
+                zlib:close(Z),
+                Input(close, In1)
+            end,
     {ok, Files}.
 
 %% Iterate over all files in a zip archive
@@ -447,11 +450,20 @@ do_zip(F, Files, Options) ->
     #zip_opts{output = Output, open_opts = OpO} = Opts,
     Out0 = Output({open, F, OpO}, []),
     Z = zlib:open(),
-    {Out1, LHS, Pos} = put_z_files(Files, Z, Out0, 0, Opts, []),
-    zlib:close(Z),
-    Out2 = put_central_dir(LHS, Pos, Out1, Opts),
-    Out3 = Output({close, F}, Out2),
-    {ok, Out3}.
+    try
+        {Out1, LHS, Pos} = put_z_files(Files, Z, Out0, 0, Opts, []),
+        zlib:close(Z),
+        Out2 = put_central_dir(LHS, Pos, Out1, Opts),
+        Out3 = Output({close, F}, Out2),
+        {ok, Out3}
+    catch
+        C:R ->
+            Stk = erlang:get_stacktrace(),
+            zlib:close(Z),
+            Output({close, F}, Out0),
+            erlang:raise(C, R, Stk)
+    end.
+
 
 %% List zip directory contents
 %%
diff --git a/lib/stdlib/test/zip_SUITE.erl b/lib/stdlib/test/zip_SUITE.erl
index 7d90795c9e..f0feda217a 100644
--- a/lib/stdlib/test/zip_SUITE.erl
+++ b/lib/stdlib/test/zip_SUITE.erl
@@ -27,7 +27,7 @@
          openzip_api/1, zip_api/1, open_leak/1, unzip_jar/1,
 	 unzip_traversal_exploit/1,
          compress_control/1,
-	 foldl/1]).
+	 foldl/1,fd_leak/1]).
 
 -include_lib("common_test/include/ct.hrl").
 -include_lib("kernel/include/file.hrl").
@@ -40,7 +40,7 @@ all() ->
      unzip_to_binary, zip_to_binary, unzip_options,
      zip_options, list_dir_options, aliases, openzip_api,
      zip_api, open_leak, unzip_jar, compress_control, foldl,
-     unzip_traversal_exploit].
+     unzip_traversal_exploit,fd_leak].
 
 groups() -> 
     [].
@@ -882,3 +882,35 @@ foldl(Config) ->
     {error, enoent} = zip:foldl(ZipFun, [], File),
 
     ok.
+
+fd_leak(Config) ->
+    ok = file:set_cwd(proplists:get_value(priv_dir, Config)),
+    DataDir = proplists:get_value(data_dir, Config),
+    Name = filename:join(DataDir, "bad_file_header.zip"),
+    BadExtract = fun() ->
+                         {error,bad_file_header} = zip:extract(Name),
+                         ok
+                 end,
+    do_fd_leak(BadExtract, 1),
+
+    BadCreate = fun() ->
+                        {error,enoent} = zip:zip("failed.zip",
+                                                 ["none"]),
+                        ok
+                end,
+    do_fd_leak(BadCreate, 1),
+
+    ok.
+
+do_fd_leak(_Bad, 10000) ->
+    ok;
+do_fd_leak(Bad, N) ->
+    try Bad() of
+        ok ->
+            do_fd_leak(Bad, N + 1)
+    catch
+        C:R ->
+            Stk = erlang:get_stacktrace(),
+            io:format("Bad error after ~p attempts\n", [N]),
+            erlang:raise(C, R, Stk)
+    end.
-- 
cgit v1.2.3