6 files changed, 170 insertions, 0 deletions
diff --git a/examples/web_server/src/directory_handler.erl b/examples/web_server/src/directory_handler.erl
new file mode 100644
index 0000000..ed342b5
--- /dev/null
+++ b/examples/web_server/src/directory_handler.erl
@@ -0,0 +1,51 @@
+%% Feel free to use, reuse and abuse the code in this file.
+
+%% @doc Directory handler.
+-module(directory_handler).
+
+%% REST Callbacks
+-export([init/3]).
+-export([rest_init/2]).
+-export([allowed_methods/2]).
+-export([resource_exists/2]).
+-export([content_types_provided/2]).
+
+%% Callback Callbacks
+-export([list_json/2]).
+-export([list_html/2]).
+
+init(_Transport, _Req, _Paths) ->
+	{upgrade, protocol, cowboy_rest}.
+
+rest_init(Req, Paths) ->
+	{ok, Req, Paths}.
+
+allowed_methods(Req, State) ->
+	{[<<"GET">>], Req, State}.
+
+resource_exists(Req, {ReqPath, FilePath}) ->
+	case file:list_dir(FilePath) of
+		{ok, Fs} -> {true, Req, {ReqPath, lists:sort(Fs)}};
+		_Err -> {false, Req, {ReqPath, FilePath}}
+	end.
+
+content_types_provided(Req, State) ->
+	{[
+		{{<<"application">>, <<"json">>, []}, list_json},
+		{{<<"text">>, <<"html">>, []}, list_html}
+	], Req, State}.
+
+list_json(Req, {Path, Fs}) ->
+	Files = [[ <<(list_to_binary(F))/binary>> || F <- Fs ]],
+	{jsx:encode(Files), Req, Path}.
+
+list_html(Req, {Path, Fs}) ->
+	Body = [[ links(Path, F) || F <- [".."|Fs] ]],
+	HTML = [<<"<!DOCTYPE html><html><head><title>Index</title></head>",
+		"<body>">>, Body, <<"</body></html>\n">>],
+	{HTML, Req, Path}.
+
+links(<<>>, File) ->
+	["<a href='/", File, "'>", File, "</a><br>\n"];
+links(Prefix, File) ->
+	["<a href='/", Prefix, $/, File, "'>", File, "</a><br>\n"].
diff --git a/examples/web_server/src/directory_lister.erl b/examples/web_server/src/directory_lister.erl
new file mode 100644
index 0000000..a59f957
--- /dev/null
+++ b/examples/web_server/src/directory_lister.erl
@@ -0,0 +1,37 @@
+%% Feel free to use, reuse and abuse the code in this file.
+
+-module(directory_lister).
+-behaviour(cowboy_middleware).
+
+-export([execute/2]).
+
+execute(Req, Env) ->
+	case lists:keyfind(handler, 1, Env) of
+		{handler, cowboy_static} -> redirect_directory(Req, Env);
+		_H -> {ok, Req, Env}
+	end.
+
+redirect_directory(Req, Env) ->
+	{Path, Req1} = cowboy_req:path_info(Req),
+	Path1 = << <<S/binary, $/>> || S <- Path >>,
+	{handler_opts, StaticOpts} = lists:keyfind(handler_opts, 1, Env),
+	{dir_handler, DirHandler} = lists:keyfind(dir_handler, 1, StaticOpts),
+	FullPath = resource_path(Path1),
+	case valid_path(Path) and filelib:is_dir(FullPath) of
+		true -> handle_directory(Req1, Env, Path1, FullPath, DirHandler);
+		false -> {ok, Req1, Env}
+	end.
+
+handle_directory(Req, Env, Prefix, Path, DirHandler) ->
+	Env1 = lists:keydelete(handler, 1,
+		lists:keydelete(handler_opts, 1, Env)),
+	{ok, Req, [{handler, DirHandler}, {handler_opts, {Prefix, Path}} | Env1]}.
+
+valid_path([]) -> true;
+valid_path([<<"..">> | _T]) -> false;
+valid_path([<<"/", _/binary>> | _T]) -> false;
+valid_path([_H | Rest]) -> valid_path(Rest).
+
+resource_path(Path) ->
+	{ok, Cwd} = file:get_cwd(),
+	filename:join([Cwd, "priv", Path]).
diff --git a/examples/web_server/src/web_server.app.src b/examples/web_server/src/web_server.app.src
new file mode 100644
index 0000000..b4326d7
--- /dev/null
+++ b/examples/web_server/src/web_server.app.src
@@ -0,0 +1,15 @@
+%% Feel free to use, reuse and abuse the code in this file.
+
+{application, web_server, [
+	{description, "Cowboy static file handler with directory indexes."},
+	{vsn, "1"},
+	{modules, []},
+	{registered, []},
+	{applications, [
+		kernel,
+		stdlib,
+		cowboy
+	]},
+	{mod, {web_server_app, []}},
+	{env, []}
+]}.
diff --git a/examples/web_server/src/web_server.erl b/examples/web_server/src/web_server.erl
new file mode 100644
index 0000000..ae75c3a
--- /dev/null
+++ b/examples/web_server/src/web_server.erl
@@ -0,0 +1,14 @@
+%% Feel free to use, reuse and abuse the code in this file.
+
+-module(web_server).
+
+%% API.
+-export([start/0]).
+
+%% API.
+
+start() ->
+	ok = application:start(crypto),
+	ok = application:start(ranch),
+	ok = application:start(cowboy),
+	ok = application:start(web_server).
diff --git a/examples/web_server/src/web_server_app.erl b/examples/web_server/src/web_server_app.erl
new file mode 100644
index 0000000..43dc078
--- /dev/null
+++ b/examples/web_server/src/web_server_app.erl
@@ -0,0 +1,30 @@
+%% Feel free to use, reuse and abuse the code in this file.
+
+%% @private
+-module(web_server_app).
+-behaviour(application).
+
+%% API.
+-export([start/2]).
+-export([stop/1]).
+
+%% API.
+
+start(_Type, _Args) ->
+	Dispatch = cowboy_router:compile([
+		{'_', [
+			{"/[...]", cowboy_static, [
+				{directory, {priv_dir, web_server, []}},
+				{dir_handler, directory_handler},
+				{mimetypes, {fun mimetypes:path_to_mimes/2, default}}
+			]}
+		]}
+	]),
+	{ok, _} = cowboy:start_http(http, 100, [{port, 8080}], [
+		{env, [{dispatch, Dispatch}]},
+		{middlewares, [cowboy_router, directory_lister, cowboy_handler]}
+	]),
+	web_server_sup:start_link().
+
+stop(_State) ->
+	ok.
diff --git a/examples/web_server/src/web_server_sup.erl b/examples/web_server/src/web_server_sup.erl
new file mode 100644
index 0000000..03f9f67
--- /dev/null
+++ b/examples/web_server/src/web_server_sup.erl
@@ -0,0 +1,23 @@
+%% Feel free to use, reuse and abuse the code in this file.
+
+%% @private
+-module(web_server_sup).
+-behaviour(supervisor).
+
+%% API.
+-export([start_link/0]).
+
+%% supervisor.
+-export([init/1]).
+
+%% API.
+
+-spec start_link() -> {ok, pid()}.
+start_link() ->
+	supervisor:start_link({local, ?MODULE}, ?MODULE, []).
+
+%% supervisor.
+
+init([]) ->
+	Procs = [],
+	{ok, {{one_for_one, 10, 10}, Procs}}.