Add cow_http:parse_{status_line,headers}/1

Imported from Cowboy and then optimized.

1 files changed, 178 insertions, 0 deletions

diff --git a/src/cow_http.erl b/src/cow_http.erl
index ed7b447..ac8f556 100644
--- a/src/cow_http.erl
+++ b/src/cow_http.erl
@@ -14,12 +14,189 @@
 
 -module(cow_http).
 
+%% @todo parse_request_line
+-export([parse_status_line/1]).
+-export([parse_headers/1]).
+
 -export([parse_fullhost/1]).
 -export([parse_fullpath/1]).
 -export([parse_version/1]).
 
+-type version() :: 'HTTP/1.0' | 'HTTP/1.1'.
+-type status() :: 100..999.
+-type headers() :: [{binary(), binary()}].
+
 -include("cow_inline.hrl").
 
+%% @doc Parse the status line.
+
+-spec parse_status_line(binary()) -> {version(), status(), binary(), binary()}.
+parse_status_line(<< "HTTP/1.1 200 OK\r\n", Rest/bits >>) ->
+	{'HTTP/1.1', 200, <<"OK">>, Rest};
+parse_status_line(<< "HTTP/1.1 404 Not Found\r\n", Rest/bits >>) ->
+	{'HTTP/1.1', 404, <<"Not Found">>, Rest};
+parse_status_line(<< "HTTP/1.1 500 Internal Server Error\r\n", Rest/bits >>) ->
+	{'HTTP/1.1', 500, <<"Internal Server Error">>, Rest};
+parse_status_line(<< "HTTP/1.1 ", Status/bits >>) ->
+	parse_status_line(Status, 'HTTP/1.1');
+parse_status_line(<< "HTTP/1.0 ", Status/bits >>) ->
+	parse_status_line(Status, 'HTTP/1.0').
+
+parse_status_line(<< H, T, U, " ", Rest/bits >>, Version)
+		when $0 =< H, H =< $9, $0 =< T, T =< $9, $0 =< U, U =< $9 ->
+	Status = (H - $0) * 100 + (T - $0) * 10 + (U - $0),
+	{Pos, _} = binary:match(Rest, <<"\r">>),
+	<< StatusStr:Pos/binary, "\r\n", Rest2/bits >> = Rest,
+	{Version, Status, StatusStr, Rest2}.
+
+-ifdef(TEST).
+parse_status_line_test_() ->
+	Tests = [
+		{<<"HTTP/1.1 200 OK\r\nRest">>,
+			{'HTTP/1.1', 200, <<"OK">>, <<"Rest">>}},
+		{<<"HTTP/1.0 404 Not Found\r\nRest">>,
+			{'HTTP/1.0', 404, <<"Not Found">>, <<"Rest">>}},
+		{<<"HTTP/1.1 500 Something very funny here\r\nRest">>,
+			{'HTTP/1.1', 500, <<"Something very funny here">>, <<"Rest">>}},
+		{<<"HTTP/1.1 200 \r\nRest">>,
+			{'HTTP/1.1', 200, <<>>, <<"Rest">>}}
+	],
+	[{V, fun() -> R = parse_status_line(V) end}
+		|| {V, R} <- Tests].
+
+parse_status_line_error_test_() ->
+	Tests = [
+		<<>>,
+		<<"HTTP/1.1">>,
+		<<"HTTP/1.1 200\r\n">>,
+		<<"HTTP/1.1 200 OK">>,
+		<<"HTTP/1.1 200 OK\r">>,
+		<<"HTTP/1.1 200 OK\n">>,
+		<<"HTTP/0.9 200 OK\r\n">>,
+		<<"HTTP/1.1 42 Answer\r\n">>,
+		<<"HTTP/1.1 999999999 More than OK\r\n">>,
+		<<"content-type: text/plain\r\n">>,
+		<<0:80, "\r\n">>
+	],
+	[{V, fun() -> {'EXIT', _} = (catch parse_status_line(V)) end}
+		|| V <- Tests].
+-endif.
+
+-ifdef(PERF).
+horse_parse_status_line_200() ->
+	horse:repeat(200000,
+		parse_status_line(<<"HTTP/1.1 200 OK\r\n">>)
+	).
+
+horse_parse_status_line_404() ->
+	horse:repeat(200000,
+		parse_status_line(<<"HTTP/1.1 404 Not Found\r\n">>)
+	).
+
+horse_parse_status_line_500() ->
+	horse:repeat(200000,
+		parse_status_line(<<"HTTP/1.1 500 Internal Server Error\r\n">>)
+	).
+
+horse_parse_status_line_other() ->
+	horse:repeat(200000,
+		parse_status_line(<<"HTTP/1.1 416 Requested range not satisfiable\r\n">>)
+	).
+-endif.
+
+%% @doc Parse the list of headers.
+
+-spec parse_headers(binary()) -> {headers(), binary()}.
+parse_headers(Data) ->
+	parse_header(Data, []).
+
+parse_header(<< $\r, $\n, Rest/bits >>, Acc) ->
+	{lists:reverse(Acc), Rest};
+parse_header(Data, Acc) ->
+	parse_hd_name(Data, Acc, <<>>).
+
+parse_hd_name(<< C, Rest/bits >>, Acc, SoFar) ->
+	case C of
+		$: -> parse_hd_before_value(Rest, Acc, SoFar);
+		$\s -> parse_hd_name_ws(Rest, Acc, SoFar);
+		$\t -> parse_hd_name_ws(Rest, Acc, SoFar);
+		?INLINE_LOWERCASE(parse_hd_name, Rest, Acc, SoFar)
+	end.
+
+parse_hd_name_ws(<< C, Rest/bits >>, Acc, Name) ->
+	case C of
+		$: -> parse_hd_before_value(Rest, Acc, Name);
+		$\s -> parse_hd_name_ws(Rest, Acc, Name);
+		$\t -> parse_hd_name_ws(Rest, Acc, Name)
+	end.
+
+parse_hd_before_value(<< $\s, Rest/bits >>, Acc, Name) ->
+	parse_hd_before_value(Rest, Acc, Name);
+parse_hd_before_value(<< $\t, Rest/bits >>, Acc, Name) ->
+	parse_hd_before_value(Rest, Acc, Name);
+parse_hd_before_value(Data, Acc, Name) ->
+	parse_hd_value(Data, Acc, Name, <<>>).
+
+parse_hd_value(<< $\r, Rest/bits >>, Acc, Name, SoFar) ->
+	case Rest of
+		<< $\n, C, Rest2/bits >> when C =:= $\s; C =:= $\t ->
+			parse_hd_value(Rest2, Acc, Name, << SoFar/binary, C >>);
+		<< $\n, Rest2/bits >> ->
+			parse_header(Rest2, [{Name, SoFar}|Acc])
+	end;
+parse_hd_value(<< C, Rest/bits >>, Acc, Name, SoFar) ->
+	parse_hd_value(Rest, Acc, Name, << SoFar/binary, C >>).
+
+-ifdef(TEST).
+parse_headers_test_() ->
+	Tests = [
+		{<<"\r\nRest">>,
+			{[], <<"Rest">>}},
+		{<<"Server: Erlang/R17\r\n"
+			"Date: Sun, 23 Feb 2014 09:30:39 GMT\r\n"
+			"Multiline-Header: why hello!\r\n"
+				" I didn't see you all the way over there!\r\n"
+			"Content-Length: 12\r\n"
+			"Content-Type: text/plain\r\n"
+			"\r\nRest">>,
+			{[{<<"server">>, <<"Erlang/R17">>},
+				{<<"date">>, <<"Sun, 23 Feb 2014 09:30:39 GMT">>},
+				{<<"multiline-header">>,
+					<<"why hello! I didn't see you all the way over there!">>},
+				{<<"content-length">>, <<"12">>},
+				{<<"content-type">>, <<"text/plain">>}],
+				<<"Rest">>}}
+	],
+	[{V, fun() -> R = parse_headers(V) end}
+		|| {V, R} <- Tests].
+
+parse_headers_error_test_() ->
+	Tests = [
+		<<>>,
+		<<"\r">>,
+		<<"Malformed\r\n\r\n">>,
+		<<"content-type: text/plain\r\nMalformed\r\n\r\n">>,
+		<<"HTTP/1.1 200 OK\r\n\r\n">>,
+		<<0:80, "\r\n\r\n">>,
+		<<"content-type: text/plain\r\ncontent-length: 12\r\n">>
+	],
+	[{V, fun() -> {'EXIT', _} = (catch parse_headers(V)) end}
+		|| V <- Tests].
+-endif.
+
+-ifdef(PERF).
+horse_parse_headers() ->
+	horse:repeat(50000,
+		parse_headers(<<"Server: Erlang/R17\r\n"
+			"Date: Sun, 23 Feb 2014 09:30:39 GMT\r\n"
+			"Multiline-Header: why hello!\r\n"
+				" I didn't see you all the way over there!\r\n"
+			"Content-Length: 12\r\n"
+			"Content-Type: text/plain\r\n"
+			"\r\nRest">>)
+	).
+-endif.
+
 %% @doc Extract host and port from a binary.
 %%
 %% Because the hostname is case insensitive it is converted
@@ -33,6 +210,7 @@ parse_fullhost(<< $[, Rest/bits >>, false, <<>>) ->
 	parse_fullhost(Rest, true, << $[ >>);
 parse_fullhost(<<>>, false, Acc) ->
 	{Acc, undefined};
+%% @todo Optimize.
 parse_fullhost(<< $:, Rest/bits >>, false, Acc) ->
 	{Acc, list_to_integer(binary_to_list(Rest))};
 parse_fullhost(<< $], Rest/bits >>, true, Acc) ->