Handle map fields in their own function in erl_eval

Map fields (K := V, K => V) are not expressions and shouldn't be clauses of
erl_eval:expr/5.

2 files changed, 37 insertions, 12 deletions

diff --git a/lib/stdlib/src/erl_eval.erl b/lib/stdlib/src/erl_eval.erl
index 5f96795d92..63e7be4b74 100644
--- a/lib/stdlib/src/erl_eval.erl
+++ b/lib/stdlib/src/erl_eval.erl
@@ -241,23 +241,15 @@ expr({record,_,_,Name,_}, _Bs, _Lf, _Ef, _RBs) ->
     erlang:raise(error, {undef_record,Name}, stacktrace());
 
 %% map
-expr({map_field_assoc,_,EK, EV}, Bs0, Lf, Ef, RBs) ->
-    {value,K,Bs1} = expr(EK, Bs0, Lf, Ef, none),
-    {value,V,Bs2} = expr(EV, Bs0, Lf, Ef, none),
-    ret_expr({map_assoc,K,V}, merge_bindings(Bs1,Bs2), RBs);
-expr({map_field_exact,_,EK, EV}, Bs0, Lf, Ef, RBs) ->
-    {value,K,Bs1} = expr(EK, Bs0, Lf, Ef, none),
-    {value,V,Bs2} = expr(EV, Bs0, Lf, Ef, none),
-    ret_expr({map_exact,K,V}, merge_bindings(Bs1,Bs2), RBs);
 expr({map,_, Binding,Es}, Bs0, Lf, Ef, RBs) ->
     {value, Map0, Bs1} = expr(Binding, Bs0, Lf, Ef, RBs),
-    {Vs,Bs} = expr_list(Es, Bs1, Lf, Ef),
+    {Vs,Bs} = eval_map_fields(Es, Bs1, Lf, Ef),
     ret_expr(lists:foldl(fun
 		({map_assoc,K,V}, Mi) -> maps:put(K,V,Mi);
 		({map_exact,K,V}, Mi) -> maps:update(K,V,Mi)
 	end, Map0, Vs), Bs, RBs);
 expr({map,_,Es}, Bs0, Lf, Ef, RBs) ->
-    {Vs,Bs} = expr_list(Es, Bs0, Lf, Ef),
+    {Vs,Bs} = eval_map_fields(Es, Bs0, Lf, Ef),
     ret_expr(lists:foldl(fun
 		({map_assoc,K,V}, Mi) -> maps:put(K,V,Mi)
 	    end, maps:new(), Vs), Bs, RBs);
@@ -749,6 +741,24 @@ eval_filter(F, Bs0, Lf, Ef, CompFun, Acc) ->
 	    end
     end.
 
+%% eval_map_fields([Field], Bindings, LocalFunctionHandler,
+%%                 ExternalFuncHandler) ->
+%%  {[{map_assoc | map_exact,Key,Value}],Bindings}
+
+eval_map_fields(Fs, Bs, Lf, Ef) ->
+    eval_map_fields(Fs, Bs, Lf, Ef, []).
+
+eval_map_fields([{map_field_assoc,_,K0,V0}|Fs], Bs0, Lf, Ef, Acc) ->
+    {value,K1,Bs1} = expr(K0, Bs0, Lf, Ef, none),
+    {value,V1,Bs2} = expr(V0, Bs1, Lf, Ef, none),
+    eval_map_fields(Fs, Bs2, Lf, Ef, [{map_assoc,K1,V1}|Acc]);
+eval_map_fields([{map_field_exact,_,K0,V0}|Fs], Bs0, Lf, Ef, Acc) ->
+    {value,K1,Bs1} = expr(K0, Bs0, Lf, Ef, none),
+    {value,V1,Bs2} = expr(V0, Bs1, Lf, Ef, none),
+    eval_map_fields(Fs, Bs2, Lf, Ef, [{map_exact,K1,V1}|Acc]);
+eval_map_fields([], Bs, _Lf, _Ef, Acc) ->
+    {lists:reverse(Acc),Bs}.
+
 
 %% RBs is the bindings to return when the evalution of a function
 %% (fun) has finished. If RBs =:= none, then the evalution took place
diff --git a/lib/stdlib/test/erl_eval_SUITE.erl b/lib/stdlib/test/erl_eval_SUITE.erl
index c4b6b35e72..b194c7cb41 100644
--- a/lib/stdlib/test/erl_eval_SUITE.erl
+++ b/lib/stdlib/test/erl_eval_SUITE.erl
@@ -42,7 +42,8 @@
 	 try_catch/1,
 	 eval_expr_5/1,
 	 zero_width/1,
-         eep37/1]).
+         eep37/1,
+         eep43/1]).
 
 %%
 %% Define to run outside of test server
@@ -82,7 +83,7 @@ all() ->
      simple_cases, unary_plus, apply_atom, otp_5269,
      otp_6539, otp_6543, otp_6787, otp_6977, otp_7550,
      otp_8133, otp_10622, funs, try_catch, eval_expr_5, zero_width,
-     eep37].
+     eep37, eep43].
 
 groups() -> 
     [].
@@ -1424,6 +1425,20 @@ eep37(Config) when is_list(Config) ->
           720),
     ok.
 
+eep43(Config) when is_list(Config) ->
+    check(fun () -> #{} end, " #{}.", #{}),
+    check(fun () -> #{a => b} end, "#{a => b}.", #{a => b}),
+    check(fun () ->
+                  Map = #{a => b},
+                  {Map#{a := b},Map#{a => c},Map#{d => e}}
+          end,
+          "begin "
+          "    Map = #{a => B=b}, "
+          "    {Map#{a := B},Map#{a => c},Map#{d => e}} "
+          "end.",
+          {#{a => b},#{a => c},#{a => b,d => e}}),
+    ok.
+
 %% Check the string in different contexts: as is; in fun; from compiled code.
 check(F, String, Result) ->
     check1(F, String, Result),