Merge branch 'legoscia/tls_dist_options' into maint

* legoscia/tls_dist_options:
  Test interface listen option for TLS distribution
  Test socket listen options for TLS distribution
  Test port options for TLS distribution
  TLS Dist: Use inet_dist_ options

Conflicts:
	lib/ssl/src/ssl_tls_dist_proxy.erl
	lib/ssl/test/ssl_dist_SUITE.erl

OTP-12838

2 files changed, 179 insertions, 2 deletions

diff --git a/lib/ssl/src/ssl_tls_dist_proxy.erl b/lib/ssl/src/ssl_tls_dist_proxy.erl
index fda08cb87f..d384264b53 100644
--- a/lib/ssl/src/ssl_tls_dist_proxy.erl
+++ b/lib/ssl/src/ssl_tls_dist_proxy.erl
@@ -48,6 +48,47 @@ accept(Listen) ->
 connect(Ip, Port) ->
     gen_server:call(?MODULE, {connect, Ip, Port}, infinity).
 
+
+do_listen(Options) ->
+    {First,Last} = case application:get_env(kernel,inet_dist_listen_min) of
+                        {ok,N} when is_integer(N) ->
+                            case application:get_env(kernel,
+                                                    inet_dist_listen_max) of
+                               {ok,M} when is_integer(M) ->
+                                   {N,M};
+                               _ ->
+                                   {N,N}
+                            end;
+                        _ ->
+                            {0,0}
+                   end,
+    do_listen(First, Last, listen_options([{backlog,128}|Options])).
+
+do_listen(First,Last,_) when First > Last ->
+    {error,eaddrinuse};
+do_listen(First,Last,Options) ->
+    case gen_tcp:listen(First, Options) of
+        {error, eaddrinuse} ->
+            do_listen(First+1,Last,Options);
+        Other ->
+            Other
+    end.
+
+listen_options(Opts0) ->
+    Opts1 =
+        case application:get_env(kernel, inet_dist_use_interface) of
+            {ok, Ip} ->
+                [{ip, Ip} | Opts0];
+            _ ->
+                Opts0
+        end,
+    case application:get_env(kernel, inet_dist_listen_options) of
+        {ok,ListenOpts} ->
+            ListenOpts ++ Opts1;
+        _ ->
+            Opts1
+    end.
+
 %%====================================================================
 %% gen_server callbacks
 %%====================================================================
@@ -62,7 +103,7 @@ init([]) ->
 handle_call({listen, Name}, _From, State) ->
     case gen_tcp:listen(0, [{active, false}, {packet,?PPRE}]) of
 	{ok, Socket} ->
-	    {ok, World} = gen_tcp:listen(0, [{active, false}, binary, {packet,?PPRE}]),
+	    {ok, World} = do_listen([{active, false}, binary, {packet,?PPRE}, {reuseaddr, true}]),
 	    {ok, TcpAddress} = get_tcp_address(Socket),
 	    {ok, WorldTcpAddress} = get_tcp_address(World),
 	    {_,Port} = WorldTcpAddress#net_address.address,
diff --git a/lib/ssl/test/ssl_dist_SUITE.erl b/lib/ssl/test/ssl_dist_SUITE.erl
index 19ed4e1299..092015d3d8 100644
--- a/lib/ssl/test/ssl_dist_SUITE.erl
+++ b/lib/ssl/test/ssl_dist_SUITE.erl
@@ -40,7 +40,8 @@
 %% Common Test interface functions -----------------------------------
 %%--------------------------------------------------------------------
 all() ->
-    [basic, payload, plain_options, plain_verify_options, nodelay_option].
+    [basic, payload, plain_options, plain_verify_options, nodelay_option, 
+     listen_port_options, listen_options, use_interface].
 
 groups() ->
     [].
@@ -262,6 +263,135 @@ nodelay_option(Config) ->
 	application:unset_env(kernel, dist_nodelay)
     end.
 
+listen_port_options() ->
+    [{doc, "Test specifying listening ports"}].
+listen_port_options(Config) when is_list(Config) ->
+    %% Start a node, and get the port number it's listening on.
+    NH1 = start_ssl_node(Config),
+    Node1 = NH1#node_handle.nodename,
+    Name1 = lists:takewhile(fun(C) -> C =/= $@ end, atom_to_list(Node1)),
+    {ok, NodesPorts} = apply_on_ssl_node(NH1, fun net_adm:names/0),
+    {Name1, Port1} = lists:keyfind(Name1, 1, NodesPorts),
+    
+    %% Now start a second node, configuring it to use the same port
+    %% number.
+    PortOpt1 = "-kernel inet_dist_listen_min " ++ integer_to_list(Port1) ++
+        " inet_dist_listen_max " ++ integer_to_list(Port1),
+    
+    try start_ssl_node([{additional_dist_opts, PortOpt1} | Config]) of
+	#node_handle{} ->
+	    %% If the node was able to start, it didn't take the port
+	    %% option into account.
+	    exit(unexpected_success)
+    catch
+	exit:{accept_failed, timeout} ->
+	    %% The node failed to start, as expected.
+	    ok
+    end,
+
+    %% Try again, now specifying a high max port.
+    PortOpt2 = "-kernel inet_dist_listen_min " ++ integer_to_list(Port1) ++
+        " inet_dist_listen_max 65535",
+    NH2 = start_ssl_node([{additional_dist_opts, PortOpt2} | Config]),
+    Node2 = NH2#node_handle.nodename,
+    Name2 = lists:takewhile(fun(C) -> C =/= $@ end, atom_to_list(Node2)),
+    {ok, NodesPorts2} = apply_on_ssl_node(NH2, fun net_adm:names/0),
+    {Name2, Port2} = lists:keyfind(Name2, 1, NodesPorts2),
+
+    %% The new port should be higher:
+    if Port2 > Port1 ->
+	    ok;
+       true ->
+	    error({port, Port2, not_higher_than, Port1})
+    end,
+
+    stop_ssl_node(NH1),
+    stop_ssl_node(NH2),
+    success(Config).
+%%--------------------------------------------------------------------
+listen_options() ->
+    [{doc, "Test inet_dist_listen_options"}].
+listen_options(Config) when is_list(Config) ->
+    Prio = 1,
+    case gen_udp:open(0, [{priority,Prio}]) of
+	{ok,Socket} ->
+	    case inet:getopts(Socket, [priority]) of
+		{ok,[{priority,Prio}]} ->
+		    ok = gen_udp:close(Socket),
+		    do_listen_options(Prio, Config);
+		_ ->
+		    ok = gen_udp:close(Socket),
+		    {skip,
+		     "Can not set priority "++integer_to_list(Prio)++
+			 " on socket"}
+	    end;
+	{error,_} ->
+	    {skip, "Can not set priority on socket"}
+    end.
+
+do_listen_options(Prio, Config) ->
+    PriorityString0 = "[{priority,"++integer_to_list(Prio)++"}]",
+    PriorityString =
+	case os:cmd("echo [{a,1}]") of
+	    "[{a,1}]"++_ ->
+		PriorityString0;
+	    _ ->
+		%% Some shells need quoting of [{}]
+		"'"++PriorityString0++"'"
+	end,
+
+    Options = "-kernel inet_dist_listen_options " ++ PriorityString,
+
+    NH1 = start_ssl_node([{additional_dist_opts, Options} | Config]),
+    NH2 = start_ssl_node([{additional_dist_opts, Options} | Config]),
+    Node2 = NH2#node_handle.nodename,
+    
+    pong = apply_on_ssl_node(NH1, fun () -> net_adm:ping(Node2) end),
+
+    PrioritiesNode1 =
+	apply_on_ssl_node(NH1, fun get_socket_priorities/0),
+    PrioritiesNode2 =
+	apply_on_ssl_node(NH2, fun get_socket_priorities/0),
+
+    Elevated1 = [P || P <- PrioritiesNode1, P =:= Prio],
+    ?t:format("Elevated1: ~p~n", [Elevated1]),
+    Elevated2 = [P || P <- PrioritiesNode2, P =:= Prio],
+    ?t:format("Elevated2: ~p~n", [Elevated2]),
+    [_|_] = Elevated1,
+    [_|_] = Elevated2,
+
+    stop_ssl_node(NH1),
+    stop_ssl_node(NH2),
+    success(Config).
+%%--------------------------------------------------------------------
+use_interface() ->
+    [{doc, "Test inet_dist_use_interface"}].
+use_interface(Config) when is_list(Config) ->
+    %% Force the node to listen only on the loopback interface.
+    IpString = "'{127,0,0,1}'",
+    Options = "-kernel inet_dist_use_interface " ++ IpString,
+
+    %% Start a node, and get the port number it's listening on.
+    NH1 = start_ssl_node([{additional_dist_opts, Options} | Config]),
+    Node1 = NH1#node_handle.nodename,
+    Name = lists:takewhile(fun(C) -> C =/= $@ end, atom_to_list(Node1)),
+    {ok, NodesPorts} = apply_on_ssl_node(NH1, fun net_adm:names/0),
+    {Name, Port} = lists:keyfind(Name, 1, NodesPorts),
+    
+    %% Now find the socket listening on that port, and check its sockname.
+    Sockets = apply_on_ssl_node(
+		NH1,
+		fun() ->
+			[inet:sockname(P) ||
+			    P <- erlang:ports(),
+			    {ok, Port} =:= (catch inet:port(P))]
+		end),
+    %% And check that it's actually listening on localhost.
+    [{ok,{{127,0,0,1},Port}}] = Sockets,
+
+    stop_ssl_node(NH1),
+    success(Config).
+
 %%--------------------------------------------------------------------
 %%% Internal functions -----------------------------------------------
 %%--------------------------------------------------------------------
@@ -275,6 +405,12 @@ tstsrvr_format(Fmt, ArgList) ->
 send_to_tstcntrl(Message) ->
     send_to_tstsrvr({message, Message}).
 
+get_socket_priorities() ->
+    [Priority ||
+	{ok,[{priority,Priority}]} <-
+	    [inet:getopts(Port, [priority]) ||
+		Port <- erlang:ports(),
+		element(2, erlang:port_info(Port, name)) =:= "tcp_inet"]].
 
 %%
 %% test_server side api