v3_core: Eliminate double processing of patterns

Internally in the v3_core pass, an #imatch{} record represents
a match expression:

  Pattern = Expression

If Pattern is a single, unbound variable, #imatch{} will be
rewritten to #iset{}; otherwise it will be rewritten to #icase{}.

To determine how #imatch{} should be translated, the pattern is
processed using upattern/3. The return value from upattern/3 is thrown
away (after having been used for determing how the #imatch{} record
should be translated).

That means that every pattern in an #imatch{} is processed twice,
which is wasteful.

We can easily avoid the double processing of patterns by
introducing a new helper function that determines whether the
pattern is a new variable.

1 files changed, 24 insertions, 20 deletions

diff --git a/lib/compiler/src/v3_core.erl b/lib/compiler/src/v3_core.erl
index 8074456be2..72649e5c9f 100644
--- a/lib/compiler/src/v3_core.erl
+++ b/lib/compiler/src/v3_core.erl
@@ -1853,27 +1853,22 @@ uguard(Pg, Gs0, Ks, St0) ->
 %% uexprs([Kexpr], [KnownVar], State) -> {[Kexpr],State}.
 
 uexprs([#imatch{anno=A,pat=P0,arg=Arg,fc=Fc}|Les], Ks, St0) ->
-    %% Optimise for simple set of unbound variable.
-    case upattern(P0, Ks, St0) of
-	{#c_var{},[],_Pvs,_Pus,_} ->
-	    %% Throw our work away and just set to iset.
+    case upat_is_new_var(P0, Ks) of
+	true ->
+	    %% Assignment to a new variable.
 	    uexprs([#iset{var=P0,arg=Arg}|Les], Ks, St0);
-	_Other ->
-	    %% Throw our work away and set to icase.
-	    if
-		Les =:= [] ->
-		    %% Need to explicitly return match "value", make
-		    %% safe for efficiency.
-		    {La0,Lps,St1} = force_safe(Arg, St0),
-		    La = mark_compiler_generated(La0),
-		    Mc = #iclause{anno=A,pats=[P0],guard=[],body=[La]},
-		    uexprs(Lps ++ [#icase{anno=A,
-					  args=[La0],clauses=[Mc],fc=Fc}], Ks, St1);
-		true ->
-		    Mc = #iclause{anno=A,pats=[P0],guard=[],body=Les},
-		    uexprs([#icase{anno=A,args=[Arg],
-				   clauses=[Mc],fc=Fc}], Ks, St0)
-	    end
+	false when Les =:= [] ->
+	    %% Need to explicitly return match "value", make
+	    %% safe for efficiency.
+	    {La0,Lps,St1} = force_safe(Arg, St0),
+	    La = mark_compiler_generated(La0),
+	    Mc = #iclause{anno=A,pats=[P0],guard=[],body=[La]},
+	    uexprs(Lps ++ [#icase{anno=A,
+				  args=[La0],clauses=[Mc],fc=Fc}], Ks, St1);
+	false ->
+	    Mc = #iclause{anno=A,pats=[P0],guard=[],body=Les},
+	    uexprs([#icase{anno=A,args=[Arg],
+			   clauses=[Mc],fc=Fc}], Ks, St0)
     end;
 uexprs([Le0|Les0], Ks, St0) ->
     {Le1,St1} = uexpr(Le0, Ks, St0),
@@ -1881,6 +1876,15 @@ uexprs([Le0|Les0], Ks, St0) ->
     {[Le1|Les1],St2};
 uexprs([], _, St) -> {[],St}.
 
+%% upat_is_new_var(Pattern, [KnownVar]) -> true|false.
+%%  Test whether the pattern is a single, previously unknown
+%%  variable.
+
+upat_is_new_var(#c_var{name=V}, Ks) ->
+    not is_element(V, Ks);
+upat_is_new_var(_, _) ->
+    false.
+
 %% Mark a "safe" as compiler-generated.
 mark_compiler_generated(#c_cons{anno=A,hd=H,tl=T}) ->
     ann_c_cons([compiler_generated|A], mark_compiler_generated(H),