Allow mixed IPv4 and IPv6 addresses to sctp_bindx

Also allow mixed address families to bind, since the first address on
a multihomed sctp socket must be bound with bind, while the rest are
to be bound using sctp_bindx.

At least Linux supports adding address of mixing families.

Make inet_set_faddress function available also when HAVE_SCTP is not
defined, since we use it to find an address for bind to be able to mix
ipv4 and ipv6 addresses.

4 files changed, 162 insertions, 56 deletions

diff --git a/erts/emulator/drivers/common/inet_drv.c b/erts/emulator/drivers/common/inet_drv.c
index 7f3b3323f5..8f4fff0f40 100644
--- a/erts/emulator/drivers/common/inet_drv.c
+++ b/erts/emulator/drivers/common/inet_drv.c
@@ -3753,7 +3753,7 @@ static char* inet_set_address(int family, inet_address* dst,
 #endif
     return NULL;
 }
-#ifdef HAVE_SCTP
+
 /*
 ** Set an inaddr structure, address family comes from source data,
 ** or from argument if source data specifies constant address.
@@ -3839,7 +3839,7 @@ static char *inet_set_faddress(int family, inet_address* dst,
     }
     return inet_set_address(family, dst, src, len);
 }
-#endif /* HAVE_SCTP */
+
 
 /* Get a inaddr structure
 ** src = inaddr structure
@@ -7804,7 +7804,7 @@ static ErlDrvSSizeT inet_ctl(inet_descriptor* desc, int cmd, char* buf,
 	if (desc->state != INET_STATE_OPEN)
 	    return ctl_xerror(EXBADPORT, rbuf, rsize);
 
-	if (inet_set_address(desc->sfamily, &local, buf, &len) == NULL)
+	if (inet_set_faddress(desc->sfamily, &local, buf, &len) == NULL)
 	    return ctl_error(EINVAL, rbuf, rsize);
 
 	if (IS_SOCKET_ERROR(sock_bind(desc->s,(struct sockaddr*) &local, len)))
@@ -10189,10 +10189,9 @@ static ErlDrvSSizeT packet_inet_ctl(ErlDrvData e, unsigned int cmd, char* buf,
 
 	    while (curr < buf+len)
 		{
-		    /* List item format: Port(2), IP(4|16) -- compatible with
-		       "inet_set_address": */
+		    /* List item format: see "inet_set_faddress": */
 		    ErlDrvSizeT alen  = buf + len - curr;
-		    curr = inet_set_address(desc->sfamily, &addr, curr, &alen);
+		    curr = inet_set_faddress(desc->sfamily, &addr, curr, &alen);
 		    if (curr == NULL)
 			return ctl_error(EINVAL, rbuf, rsize);
 
diff --git a/erts/preloaded/ebin/prim_inet.beam b/erts/preloaded/ebin/prim_inet.beam
index b2f3ab6c5b..ad49f5e892 100644
--- a/erts/preloaded/ebin/prim_inet.beam
+++ b/erts/preloaded/ebin/prim_inet.beam
diff --git a/erts/preloaded/src/prim_inet.erl b/erts/preloaded/src/prim_inet.erl
index 846ae97ed2..91fcd3ac82 100644
--- a/erts/preloaded/src/prim_inet.erl
+++ b/erts/preloaded/src/prim_inet.erl
@@ -184,7 +184,7 @@ close_pend_loop(S, N) ->
 %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 
 bind(S,IP,Port) when is_port(S), is_integer(Port), Port >= 0, Port =< 65535 ->
-    case ctl_cmd(S,?INET_REQ_BIND,[?int16(Port),ip_to_bytes(IP)]) of
+    case ctl_cmd(S,?INET_REQ_BIND,enc_value(set, addr, {IP,Port})) of
 	{ok, [P1,P0]} -> {ok, ?u16(P1, P0)};
 	{error,_}=Error -> Error
     end;
@@ -206,10 +206,10 @@ bindx(S, AddFlag, Addrs) ->
     case getprotocol(S) of
 	sctp ->
 	    %% Really multi-homed "bindx". Stringified args:
-	    %% [AddFlag, (Port, IP)+]:
+	    %% [AddFlag, (AddrBytes see enc_value_2(addr,X))+]:
 	    Args =
 		[?int8(AddFlag)|
-		 [[?int16(Port)|ip_to_bytes(IP)] ||
+		 [enc_value(set, addr, {IP,Port}) ||
 		     {IP, Port} <- Addrs]],
 	    case ctl_cmd(S, ?SCTP_REQ_BINDX, Args) of
 		{ok,_} -> {ok, S};
diff --git a/lib/kernel/test/gen_sctp_SUITE.erl b/lib/kernel/test/gen_sctp_SUITE.erl
index 209b95a99f..f4bf6e719e 100644
--- a/lib/kernel/test/gen_sctp_SUITE.erl
+++ b/lib/kernel/test/gen_sctp_SUITE.erl
@@ -32,7 +32,10 @@
     api_open_close/1,api_listen/1,api_connect_init/1,api_opts/1,
     xfer_min/1,xfer_active/1,def_sndrcvinfo/1,implicit_inet6/1,
     basic_stream/1, xfer_stream_min/1, peeloff/1, buffers/1,
-    open_multihoming_ipv4_socket/1, open_multihoming_ipv6_socket/1]).
+    open_multihoming_ipv4_socket/1,
+    open_unihoming_ipv6_socket/1,
+    open_multihoming_ipv6_socket/1,
+    open_multihoming_ipv4_and_ipv6_socket/1]).
 
 suite() -> [{ct_hooks,[ts_install_cth]}].
 
@@ -40,7 +43,10 @@ all() ->
     [basic, api_open_close, api_listen, api_connect_init,
      api_opts, xfer_min, xfer_active, def_sndrcvinfo, implicit_inet6,
      basic_stream, xfer_stream_min, peeloff, buffers,
-     open_multihoming_ipv4_socket, open_multihoming_ipv6_socket].
+     open_multihoming_ipv4_socket,
+     open_unihoming_ipv6_socket,
+     open_multihoming_ipv6_socket,
+     open_multihoming_ipv4_and_ipv6_socket].
 
 groups() -> 
     [].
@@ -1114,45 +1120,119 @@ open_multihoming_ipv4_socket(doc) ->
 open_multihoming_ipv4_socket(suite) ->
     [];
 open_multihoming_ipv4_socket(Config) when is_list(Config) ->
-    ?line IfAddrs = ok(inet:getifaddrs()),
-    ?line
-	case filter_addrs_by_family(IfAddrs, inet) of
-	    [Addr1, Addr2 | _] ->
-		?line io:format("using ipv4 addresses ~p and ~p~n",
-				[Addr1, Addr2]),
-		?line S = ok(gen_sctp:open(0, [{ip,Addr1},{ip,Addr2},inet])),
-		?line ok = gen_sctp:listen(S, true),
-		?line setup_connection(S, Addr1, inet),
-		?line ok = gen_sctp:close(S);
-	    X ->
-		{skip, f("Need 2 IPv4 addresses, found only ~p", [X])}
-	end.
+    ?line case get_addrs_by_family(inet, 2) of
+	      {ok, [Addr1, Addr2]} ->
+		  ?line do_open_and_connect([Addr1, Addr2], Addr1);
+	      {error, Reason} ->
+		  {skip, Reason}
+	  end.
+
+open_unihoming_ipv6_socket(doc) ->
+    %% This test is mostly aimed to indicate
+    %% whether host has a non-working ipv6 setup
+    "Test opening a unihoming (non-multihoming) ipv6 socket";
+open_unihoming_ipv6_socket(suite) ->
+    [];
+open_unihoming_ipv6_socket(Config) when is_list(Config) ->
+    ?line case get_addrs_by_family(inet6, 1) of
+	      {ok, [Addr]} ->
+		  ?line do_open_and_connect([Addr], Addr);
+	      {error, Reason} ->
+		  {skip, Reason}
+	  end.
+
 
 open_multihoming_ipv6_socket(doc) ->
     "Test opening a multihoming ipv6 socket";
 open_multihoming_ipv6_socket(suite) ->
     [];
 open_multihoming_ipv6_socket(Config) when is_list(Config) ->
-    ?line IfAddrs = ok(inet:getifaddrs()),
+    ?line case get_addrs_by_family(inet6, 2) of
+	      {ok, [Addr1, Addr2]} ->
+		  ?line do_open_and_connect([Addr1, Addr2], Addr1);
+	      {error, Reason} ->
+		  {skip, Reason}
+	  end.
+
+open_multihoming_ipv4_and_ipv6_socket(doc) ->
+    "Test opening a multihoming ipv6 socket with ipv4 and ipv6 addresses";
+open_multihoming_ipv4_and_ipv6_socket(suite) ->
+    [];
+open_multihoming_ipv4_and_ipv6_socket(Config) when is_list(Config) ->
+    ?line case get_addrs_by_family(inet_and_inet6, 2) of
+	      {ok, [[InetAddr1, InetAddr2], [Inet6Addr1, Inet6Addr2]]} ->
+		  %% Connect to the first address to test bind
+		  ?line do_open_and_connect([InetAddr1, Inet6Addr1, InetAddr2],
+					    InetAddr1),
+		  ?line do_open_and_connect([Inet6Addr1, InetAddr1],
+					    Inet6Addr1),
+
+		  %% Connect an address, not the first,
+		  %% to test sctp_bindx
+		  ?line do_open_and_connect([Inet6Addr1, Inet6Addr2, InetAddr1],
+					    Inet6Addr2),
+		  ?line do_open_and_connect([Inet6Addr1, Inet6Addr2, InetAddr1],
+					    InetAddr1);
+	      {error, Reason} ->
+		  {skip, Reason}
+	  end.
+
+
+get_addrs_by_family(Family, NumAddrs) ->
+    case os:type() of
+	{unix,linux} ->
+	    get_addrs_by_family_aux(Family, NumAddrs);
+	{unix,freebsd} ->
+	    get_addrs_by_family_aux(Family, NumAddrs);
+	{unix,sunos} ->
+	    case get_addrs_by_family_aux(Family, NumAddrs) of
+		{ok, [InetAddrs, Inet6Addrs]} when Family =:= inet_and_inet6 ->
+		    %% Man page for sctp_bindx on Solaris says: "If sock is an
+		    %% Internet Protocol Version 6 (IPv6) socket, addrs should
+		    %% be an array of sockaddr_in6 structures containing IPv6
+		    %% or IPv4-mapped IPv6 addresses."
+		    {ok, [ipv4_map_addrs(InetAddrs), Inet6Addrs]};
+		{ok, Addrs} ->
+		    {ok, Addrs};
+		{error, Reason} ->
+		    {error, Reason}
+	    end;
+	Os ->
+	    Reason = if Family =:= inet_and_inet6 ->
+			     f("Mixing ipv4 and ipv6 addresses for multihoming "
+			       " has not been verified on ~p", [Os]);
+			true ->
+			     f("Multihoming for ~p has not been verified on ~p",
+			       [Family, Os])
+		     end,
+	    {error, Reason}
+    end.
+
+get_addrs_by_family_aux(Family, NumAddrs) when Family =:= inet;
+					       Family =:= inet6 ->
     ?line
-	case inet:getaddr(localhost, inet6) of
+	case inet:getaddr(localhost, Family) of
 	    {error,eafnosupport} ->
-		{skip, "No IPv6 support"};
+		{skip, f("No support for ~p", Family)};
 	    {ok, _} ->
-		?line
-		    case filter_addrs_by_family(IfAddrs, inet6) of
-			[Addr1, Addr2 | _] ->
-			    ?line io:format("using ipv6 addresses ~p and ~p~n",
-					    [Addr1, Addr2]),
-			    ?line S = ok(gen_sctp:open(
-					   0, [{ip,Addr1},{ip,Addr2}, inet6])),
-			    ?line ok = gen_sctp:listen(S, true),
-			    ?line setup_connection(S, Addr1, inet6),
-			    ?line ok = gen_sctp:close(S);
-			X ->
-			    {skip, f("Need 2 IPv6 addresses, found ~p", [X])}
-		    end
-	end.
+		?line IfAddrs = ok(inet:getifaddrs()),
+		?line case filter_addrs_by_family(IfAddrs, Family) of
+			  Addrs when length(Addrs) >= NumAddrs ->
+			      {ok, lists:sublist(Addrs, NumAddrs)};
+			  [] ->
+			      {error, f("Need ~p ~p address(es) found none~n",
+					[NumAddrs, Family])};
+			  Addrs ->
+			      {error,
+			       f("Need ~p ~p address(es) found only ~p: ~p~n",
+				 [NumAddrs, Family, length(Addrs), Addrs])}
+		      end
+	end;
+get_addrs_by_family_aux(inet_and_inet6, NumAddrs) ->
+    ?line catch {ok, [case get_addrs_by_family_aux(Family, NumAddrs) of
+			  {ok, Addrs}     -> Addrs;
+			  {error, Reason} -> throw({error, Reason})
+		      end || Family <- [inet, inet6]]}.
 
 filter_addrs_by_family(IfAddrs, Family) ->
     lists:flatten([[Addr || {addr, Addr} <- Info,
@@ -1170,27 +1250,54 @@ is_good_addr(Addr, inet6) when tuple_size(Addr) =:= 8 ->
 is_good_addr(_Addr, _Family) ->
     false.
 
+ipv4_map_addrs(InetAddrs) ->
+    [begin
+	 <<AB:16>> = <<A,B>>,
+	 <<CD:16>> = <<C,D>>,
+	 {0, 0, 0, 0, 0, 16#ffff, AB, CD}
+     end || {A,B,C,D} <- InetAddrs].
+
 f(F, A) ->
     lists:flatten(io_lib:format(F, A)).
 
-setup_connection(S1, Addr, IpFamily) ->
+do_open_and_connect(ServerAddresses, AddressToConnectTo) ->
+    ?line ServerFamily = get_family_by_addrs(ServerAddresses),
+    ?line io:format("Serving ~p addresses: ~p~n",
+		    [ServerFamily, ServerAddresses]),
+    ?line S1 = ok(gen_sctp:open(0, [{ip,Addr} || Addr <- ServerAddresses] ++
+				    [ServerFamily])),
+    ?line ok = gen_sctp:listen(S1, true),
     ?line P1 = ok(inet:port(S1)),
-    ?line S2 = ok(gen_sctp:open(0, [IpFamily])),
-    ?line P2 = ok(inet:port(S2)),
+    ?line ClientFamily = get_family_by_addr(AddressToConnectTo),
+    ?line io:format("Connecting to ~p ~p~n",
+		    [ClientFamily, AddressToConnectTo]),
+    ?line S2 = ok(gen_sctp:open(0, [ClientFamily])),
+    %% Verify client can connect
     ?line #sctp_assoc_change{state=comm_up} =
-	ok(gen_sctp:connect(S2, Addr, P1, [])),
-    ?line case ok(gen_sctp:recv(S1)) of
-	      {Addr,P2,_,#sctp_assoc_change{state=comm_up}} ->
-		  ok;
-	      {Addr,P2,_,#sctp_paddr_change{state=addr_confirmed,
-					    addr={Addr,P2}}} ->
-		  ?line case ok(gen_sctp:recv(S1)) of
-			    {Addr,P2,_,#sctp_assoc_change{state=comm_up}} ->
-				ok
-			end
-	  end,
-    ?line ok = gen_sctp:close(S2).
+	ok(gen_sctp:connect(S2, AddressToConnectTo, P1, [])),
+    %% verify server side also receives comm_up from client
+    ?line recv_comm_up_eventually(S1),
+    ?line ok = gen_sctp:close(S2),
+    ?line ok = gen_sctp:close(S1).
+
+%% If at least one of the addresses is an ipv6 address, return inet6, else inet.
+get_family_by_addrs(Addresses) ->
+    ?line case lists:usort([get_family_by_addr(Addr) || Addr <- Addresses]) of
+	      [inet, inet6] -> inet6;
+	      [inet]        -> inet;
+	      [inet6]       -> inet6
+	  end.
 
+get_family_by_addr(Addr) when tuple_size(Addr) =:= 4 -> inet;
+get_family_by_addr(Addr) when tuple_size(Addr) =:= 8 -> inet6.
+
+recv_comm_up_eventually(S) ->
+    ?line case ok(gen_sctp:recv(S)) of
+	      {_Addr, _Port, _Info, #sctp_assoc_change{state=comm_up}} ->
+		  ok;
+	      {_Addr, _Port, _Info, _OtherSctpMsg} ->
+		  ?line recv_comm_up_eventually(S)
+	  end.
 
 %%% %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 %%% socket gen_server ultra light