Added sasl_report:format_report/3 to return a string rather than send an io

sasl_report:write_report/3 calls io:format to output the report
message, but does not provide an option to generate a formatted string
rather than sending the message.  sasl_report:format_report/3 is added
to allow the replacement of sasl_report with a different handler but
still generate reports in the same format.  It returns the string
generated by io_lib:format.  sasl_report:write_report/3 retains its
original behavior.

This patch was submitted in 2008 (see
http://www.erlang.org/cgi-bin/ezmlm-cgi/4/35061) but was never
incorporated into the source.

1 files changed, 26 insertions, 14 deletions

diff --git a/lib/sasl/src/sasl_report.erl b/lib/sasl/src/sasl_report.erl
index bad3a75151..338a8239cb 100644
--- a/lib/sasl/src/sasl_report.erl
+++ b/lib/sasl/src/sasl_report.erl
@@ -18,23 +18,29 @@
 %%
 -module(sasl_report).
 
--export([write_report/3]).
+-export([write_report/3, format_report/3]).
 
-write_report(Fd, What, {Time, {error_report, _GL, {Pid, Type, Report}}}) ->
+format_report(Fd, What, Report) ->
+    io_report(io_lib, Fd, What, Report).
+
+write_report(Fd, What, Report) ->
+    io_report(io, Fd, What, Report).
+
+io_report(IO, Fd, What, {Time, {error_report, _GL, {Pid, Type, Report}}}) ->
     case is_my_error_report(What, Type) of
 	true ->
 	    Head = write_head(Type, Time, Pid),
-	    write_report2(Fd, Head, Type, Report);
+	    write_report2(IO, Fd, Head, Type, Report);
 	_ -> true
     end;
-write_report(Fd, What, {Time, {info_report, _GL, {Pid, Type, Report}}}) ->
+io_report(IO, Fd, What, {Time, {info_report, _GL, {Pid, Type, Report}}}) ->
     case is_my_info_report(What, Type) of
 	true ->
 	    Head = write_head(Type, Time, Pid),
-	    write_report2(Fd, Head, Type, Report);
+	    write_report2(IO, Fd, Head, Type, Report);
 	_ -> true
     end;
-write_report(_Fd, _, _) ->
+io_report(_IO, _Fd, _, _) ->
     false.
 
 is_my_error_report(all, Type)   ->  is_my_error_report(Type);
@@ -50,20 +56,26 @@ is_my_info_report(_, _Type)       -> false.
 is_my_info_report(progress)  -> true;
 is_my_info_report(_)                    -> false.
 
-write_report2(Fd, Head, supervisor_report, Report) ->
+write_report2(IO, Fd, Head, supervisor_report, Report) ->
     Name = sup_get(supervisor, Report),
     Context = sup_get(errorContext, Report),
     Reason = sup_get(reason, Report),
     Offender = sup_get(offender, Report),
-    io:format(Fd, Head ++ "     Supervisor: ~p~n     Context:    ~p~n     Reason:     "
-	      "~80.18p~n     Offender:   ~80.18p~n~n",
-	      [Name,Context,Reason,Offender]);
-write_report2(Fd, Head, progress, Report) ->
+    FmtString = "     Supervisor: ~p~n     Context:    ~p~n     Reason:     "
+	"~80.18p~n     Offender:   ~80.18p~n~n",
+    write_report_action(IO, Fd, Head ++ FmtString,
+			[Name,Context,Reason,Offender]);
+write_report2(IO, Fd, Head, progress, Report) ->
     Format = format_key_val(Report),
-    io:format(Fd, Head ++ "~s", [Format]);
-write_report2(Fd, Head, crash_report, Report) ->
+    write_report_action(IO, Fd, Head ++ "~s", [Format]);
+write_report2(IO, Fd, Head, crash_report, Report) ->
     Format = proc_lib:format(Report),
-    io:format(Fd, Head ++ "~s", [Format]).
+    write_report_action(IO, Fd, Head ++ "~s", [Format]).
+
+write_report_action(io, Fd, Format, Args) ->
+    io:format(Fd, Format, Args);
+write_report_action(io_lib, _Fd, Format, Args) ->
+    io_lib:format(Format, Args).
 
 format_key_val([{Tag,Data}|Rep]) ->
     io_lib:format("    ~16w: ~p~n",[Tag,Data]) ++ format_key_val(Rep);