Readline-style line edit history

Change the shell's line buffer mechanism to more
closely match readline-based shells. New behavior:

  1. Blank lines are not added to the line buffer.

  2. Pressing the down arrow on the last line causes no change.

     The previous behavior erased the line.

  3. The new line is temporarily added to the line buffer
     so the user can move to previous lines with up arrows
     and then back to the new line with down arrows.

     The previous behavior discarded the partially written
     new line.

  4. Changes made to previous lines while exploring the line
     buffer history are preserved.

     The previous behavior discarded changes made to older lines.

2 files changed, 35 insertions, 8 deletions

diff --git a/lib/kernel/src/group.erl b/lib/kernel/src/group.erl
index a45ba34eae..b770ab8386 100644
--- a/lib/kernel/src/group.erl
+++ b/lib/kernel/src/group.erl
@@ -477,15 +477,15 @@ get_line(Chars, Pbs, Drv, Encoding) ->
     get_line1(edlin:edit_line(Chars, Cont), Drv, new_stack(get(line_buffer)), 
 	      Encoding).
 
-get_line1({done,Line,Rest,Rs}, Drv, _Ls, _Encoding) ->
+get_line1({done,Line,Rest,Rs}, Drv, Ls, _Encoding) ->
     send_drv_reqs(Drv, Rs),
-    put(line_buffer, [Line|lists:delete(Line, get(line_buffer))]),
+    save_line_buffer(Line, get_lines(Ls)),
     {done,Line,Rest};
 get_line1({undefined,{_A,Mode,Char},Cs,Cont,Rs}, Drv, Ls0, Encoding) 
   when ((Mode =:= none) and (Char =:= $\^P))
        or ((Mode =:= meta_left_sq_bracket) and (Char =:= $A)) ->
     send_drv_reqs(Drv, Rs),
-    case up_stack(Ls0) of
+    case up_stack(save_line(Ls0, edlin:current_line(Cont))) of
 	{none,_Ls} ->
 	    send_drv(Drv, beep),
 	    get_line1(edlin:edit_line(Cs, Cont), Drv, Ls0, Encoding);
@@ -498,14 +498,14 @@ get_line1({undefined,{_A,Mode,Char},Cs,Cont,Rs}, Drv, Ls0, Encoding)
 		      Drv,
 		      Ls, Encoding)
     end;
-get_line1({undefined,{_A,Mode,Char},_Cs,Cont,Rs}, Drv, Ls0, Encoding) 
+get_line1({undefined,{_A,Mode,Char},Cs,Cont,Rs}, Drv, Ls0, Encoding)
   when ((Mode =:= none) and (Char =:= $\^N))
        or ((Mode =:= meta_left_sq_bracket) and (Char =:= $B)) ->
     send_drv_reqs(Drv, Rs),
-    case down_stack(Ls0) of
-	{none,Ls} ->
-	    send_drv_reqs(Drv, edlin:erase_line(Cont)),
-	    get_line1(edlin:start(edlin:prompt(Cont)), Drv, Ls, Encoding);
+    case down_stack(save_line(Ls0, edlin:current_line(Cont))) of
+	{none,_Ls} ->
+	    send_drv(Drv, beep),
+	    get_line1(edlin:edit_line(Cs, Cont), Drv, Ls0, Encoding);
 	{Lcs,Ls} ->
 	    send_drv_reqs(Drv, edlin:erase_line(Cont)),
 	    {more_chars,Ncont,Nrs} = edlin:start(edlin:prompt(Cont)),
@@ -627,6 +627,28 @@ down_stack({stack,U,{},[]}) ->
 down_stack({stack,U,C,D}) ->
     down_stack({stack,[C|U],{},D}).
 
+save_line({stack, U, {}, []}, Line) ->
+    {stack, U, {}, [Line]};
+save_line({stack, U, _L, D}, Line) ->
+    {stack, U, Line, D}.
+
+get_lines({stack, U, {}, []}) ->
+    U;
+get_lines({stack, U, {}, D}) ->
+    tl(lists:reverse(D, U));
+get_lines({stack, U, L, D}) ->
+    get_lines({stack, U, {}, [L|D]}).
+
+save_line_buffer("\n", Lines) ->
+    save_line_buffer(Lines);
+save_line_buffer(Line, [Line|_Lines]=Lines) ->
+    save_line_buffer(Lines);
+save_line_buffer(Line, Lines) ->
+    save_line_buffer([Line|Lines]).
+
+save_line_buffer(Lines) ->
+    put(line_buffer, Lines).
+
 %% This is get_line without line editing (except for backspace) and
 %% without echo.
 get_password_line(Chars, Drv) ->
diff --git a/lib/stdlib/src/edlin.erl b/lib/stdlib/src/edlin.erl
index 6cb441dbed..026bd9038f 100644
--- a/lib/stdlib/src/edlin.erl
+++ b/lib/stdlib/src/edlin.erl
@@ -24,6 +24,7 @@
 -export([init/0,start/1,edit_line/2,prefix_arg/1]).
 -export([erase_line/1,erase_inp/1,redraw_line/1]).
 -export([length_before/1,length_after/1,prompt/1]).
+-export([current_line/1]).
 %%-export([expand/1]).
 
 -export([edit_line1/2]).
@@ -421,6 +422,7 @@ over_paren_auto([], _, _, _) ->
 %% length_before(Line)
 %% length_after(Line)
 %% prompt(Line)
+%% current_line(Line)
 %%  Various functions for accessing bits of a line.
 
 erase_line({line,Pbs,{Bef,Aft},_}) ->
@@ -447,6 +449,9 @@ length_after({line,_,{_Bef,Aft},_}) ->
 prompt({line,Pbs,_,_}) ->
     Pbs.
 
+current_line({line,_,{Bef, Aft},_}) ->
+    reverse(Bef, Aft ++ "\n").
+
 %% %% expand(CurrentBefore) ->
 %% %%	{yes,Expansion} | no
 %% %%  Try to expand the word before as either a module name or a function