Merge branch 'hasse/kernel/limit_crash_reports/OTP-14417'

* hasse/kernel/limit_crash_reports/OTP-14417:
  stdlib: Limit the size of gen_statem's error events
  kernel: Introcude error_logger:get_format_depth()
  stdlib: Limit the size of proc_lib's crash reports
  stdlib: Limit the size of gen_server's error events
  kernel: Add error_logger:limit_term/1
  stdlib: Add io_lib:limit_term/2

10 files changed, 307 insertions, 72 deletions

diff --git a/lib/kernel/doc/src/error_logger.xml b/lib/kernel/doc/src/error_logger.xml
index 814e8eac46..27db00819f 100644
--- a/lib/kernel/doc/src/error_logger.xml
+++ b/lib/kernel/doc/src/error_logger.xml
@@ -4,7 +4,7 @@
 <erlref>
   <header>
     <copyright>
-      <year>1996</year><year>2016</year>
+      <year>1996</year><year>2017</year>
       <holder>Ericsson AB. All Rights Reserved.</holder>
     </copyright>
     <legalnotice>
@@ -163,6 +163,19 @@ ok</pre>
       </desc>
     </func>
     <func>
+      <name name="get_format_depth" arity="0"/>
+      <fsummary>Get the value of the Kernel application variable
+                <c>error_logger_format_depth</c>.</fsummary>
+      <desc>
+	<p>Returns <c>max(10, Depth)</c>, where <c>Depth</c> is the
+	value of
+	<seealso marker="kernel:kernel_app#error_logger_format_depth">
+	error_logger_format_depth</seealso>
+	in the Kernel application, if Depth is an integer. Otherwise,
+	<c>unlimited</c> is returned.</p>
+      </desc>
+    </func>
+    <func>
       <name name="info_msg" arity="1"/>
       <name name="info_msg" arity="2"/>
       <fsummary>Send a standard information event to the error logger.</fsummary>
diff --git a/lib/kernel/src/error_logger.erl b/lib/kernel/src/error_logger.erl
index 81f1bf8d97..9bf8547745 100644
--- a/lib/kernel/src/error_logger.erl
+++ b/lib/kernel/src/error_logger.erl
@@ -31,6 +31,8 @@
 	 handle_event/2, handle_call/2, handle_info/2,
 	 terminate/2]).
 
+-export([get_format_depth/0, limit_term/1]).
+
 -define(buffer_size, 10).
 
 %%-----------------------------------------------------------------
@@ -518,3 +520,21 @@ string_p1([H|T]) when is_list(H) ->
     end;
 string_p1([]) -> true;
 string_p1(_) ->  false.
+
+-spec limit_term(term()) -> term().
+
+limit_term(Term) ->
+    case get_format_depth() of
+        unlimited -> Term;
+        D -> io_lib:limit_term(Term, D)
+    end.
+
+-spec get_format_depth() -> 'unlimited' | pos_integer().
+
+get_format_depth() ->
+    case application:get_env(kernel, error_logger_format_depth) of
+	{ok, Depth} when is_integer(Depth) ->
+	    max(10, Depth);
+	undefined ->
+	    unlimited
+    end.
diff --git a/lib/sasl/src/sasl_report.erl b/lib/sasl/src/sasl_report.erl
index 14702b0ad2..eb454155d5 100644
--- a/lib/sasl/src/sasl_report.erl
+++ b/lib/sasl/src/sasl_report.erl
@@ -1,7 +1,7 @@
 %%
 %% %CopyrightBegin%
 %%
-%% Copyright Ericsson AB 1996-2016. All Rights Reserved.
+%% Copyright Ericsson AB 1996-2017. All Rights Reserved.
 %%
 %% Licensed under the Apache License, Version 2.0 (the "License");
 %% you may not use this file except in compliance with the License.
@@ -68,12 +68,12 @@ write_report2(IO, Fd, Head, progress, Report) ->
     Format = format_key_val(Report),
     write_report_action(IO, Fd, Head, "~s", [Format]);
 write_report2(IO, Fd, Head, crash_report, Report) ->
-    Depth = get_depth(),
+    Depth = error_logger:get_format_depth(),
     Format = proc_lib:format(Report, latin1, Depth),
     write_report_action(IO, Fd, Head, "~s", [Format]).
 
 supervisor_format(Args0) ->
-    case get_depth() of
+    case error_logger:get_format_depth() of
 	unlimited ->
 	    {"     Supervisor: ~p~n"
 	     "     Context:    ~p~n"
@@ -102,14 +102,6 @@ format_key_val([{Tag,Data}|Rep]) ->
 format_key_val(_) ->
     [].
 
-get_depth() ->
-    case application:get_env(kernel, error_logger_format_depth) of
-	{ok, Depth} when is_integer(Depth) ->
-	    max(10, Depth);
-	undefined ->
-	    unlimited
-    end.
-
 sup_get(Tag, Report) ->
     case lists:keysearch(Tag, 1, Report) of
 	{value, {_, Value}} ->
diff --git a/lib/stdlib/src/error_logger_file_h.erl b/lib/stdlib/src/error_logger_file_h.erl
index 0b262de3ab..76f89841b9 100644
--- a/lib/stdlib/src/error_logger_file_h.erl
+++ b/lib/stdlib/src/error_logger_file_h.erl
@@ -1,7 +1,7 @@
 %%
 %% %CopyrightBegin%
 %% 
-%% Copyright Ericsson AB 1996-2016. All Rights Reserved.
+%% Copyright Ericsson AB 1996-2017. All Rights Reserved.
 %% 
 %% Licensed under the Apache License, Version 2.0 (the "License");
 %% you may not use this file except in compliance with the License.
@@ -57,7 +57,7 @@ init(File, PrevHandler) ->
     process_flag(trap_exit, true),
     case file:open(File, [write]) of
 	{ok,Fd} ->
-	    Depth = get_depth(),
+            Depth = error_logger:get_format_depth(),
 	    State = #st{fd=Fd,filename=File,prev_handler=PrevHandler,
 			depth=Depth},
 	    {ok, State};
@@ -65,14 +65,6 @@ init(File, PrevHandler) ->
 	    Error
     end.
 
-get_depth() ->
-    case application:get_env(kernel, error_logger_format_depth) of
-	{ok, Depth} when is_integer(Depth) ->
-	    max(10, Depth);
-	undefined ->
-	    unlimited
-    end.
-
 handle_event({_Type, GL, _Msg}, State) when node(GL) =/= node() ->
     {ok, State};
 handle_event(Event, State) ->
diff --git a/lib/stdlib/src/error_logger_tty_h.erl b/lib/stdlib/src/error_logger_tty_h.erl
index 2f2fd65252..8f0d7b0362 100644
--- a/lib/stdlib/src/error_logger_tty_h.erl
+++ b/lib/stdlib/src/error_logger_tty_h.erl
@@ -1,7 +1,7 @@
 %%
 %% %CopyrightBegin%
 %% 
-%% Copyright Ericsson AB 1996-2016. All Rights Reserved.
+%% Copyright Ericsson AB 1996-2017. All Rights Reserved.
 %% 
 %% Licensed under the Apache License, Version 2.0 (the "License");
 %% you may not use this file except in compliance with the License.
@@ -44,7 +44,7 @@
 %% This one is used when we takeover from the simple error_logger.
 init({[], {error_logger, Buf}}) ->
     User = set_group_leader(),
-    Depth = get_depth(),
+    Depth = error_logger:get_format_depth(),
     State = #st{user=User,prev_handler=error_logger,depth=Depth},
     write_events(State, Buf),
     {ok, State};
@@ -56,17 +56,9 @@ init({[], {error_logger_tty_h, PrevHandler}}) ->
 %% This one is used when we are started directly.
 init([]) ->
     User = set_group_leader(),
-    Depth = get_depth(),
+    Depth = error_logger:get_format_depth(),
     {ok, #st{user=User,prev_handler=[],depth=Depth}}.
 
-get_depth() ->
-    case application:get_env(kernel, error_logger_format_depth) of
-	{ok, Depth} when is_integer(Depth) ->
-	    max(10, Depth);
-	undefined ->
-	    unlimited
-    end.
-    
 handle_event({_Type, GL, _Msg}, State) when node(GL) =/= node() ->
     {ok, State};
 handle_event(Event, State) ->
diff --git a/lib/stdlib/src/gen_server.erl b/lib/stdlib/src/gen_server.erl
index ba0a7ae8e5..9f6568473d 100644
--- a/lib/stdlib/src/gen_server.erl
+++ b/lib/stdlib/src/gen_server.erl
@@ -107,8 +107,6 @@
 %% Internal exports
 -export([init_it/6]).
 
--import(error_logger, [format/2]).
-
 %%%=========================================================================
 %%%  API
 %%%=========================================================================
@@ -861,14 +859,15 @@ error_info(Reason, Name, From, Msg, State, Debug) ->
 			end
 		end;
 	    _ ->
-		Reason
+		error_logger:limit_term(Reason)
 	end,    
     {ClientFmt, ClientArgs} = client_stacktrace(From),
-    format("** Generic server ~p terminating \n"
-           "** Last message in was ~p~n"
-           "** When Server state == ~p~n"
-           "** Reason for termination == ~n** ~p~n" ++ ClientFmt,
-	   [Name, Msg, State, Reason1] ++ ClientArgs),
+    LimitedState = error_logger:limit_term(State),
+    error_logger:format("** Generic server ~p terminating \n"
+                        "** Last message in was ~p~n"
+                        "** When Server state == ~p~n"
+                        "** Reason for termination == ~n** ~p~n" ++ ClientFmt,
+                        [Name, Msg, LimitedState, Reason1] ++ ClientArgs),
     sys:print_log(Debug),
     ok.
 client_stacktrace(undefined) ->
diff --git a/lib/stdlib/src/gen_statem.erl b/lib/stdlib/src/gen_statem.erl
index 86109f04b4..b5e9da1e66 100644
--- a/lib/stdlib/src/gen_statem.erl
+++ b/lib/stdlib/src/gen_statem.erl
@@ -1722,6 +1722,8 @@ error_info(
 		end;
 	    _ -> {Reason,Stacktrace}
 	end,
+    [LimitedP, LimitedFmtData, LimitedFixedReason] =
+        [error_logger:limit_term(D) || D <- [P, FmtData, FixedReason]],
     CBMode =
 	 case StateEnter of
 	     true ->
@@ -1755,8 +1757,8 @@ error_info(
 	   [] -> [];
 	   [Event|_] -> [Event]
        end] ++
-	  [FmtData,
-	   Class,FixedReason,
+	  [LimitedFmtData,
+	   Class,LimitedFixedReason,
 	   CBMode] ++
 	  case Q of
 	      [_|[_|_] = Events] -> [Events];
@@ -1764,7 +1766,7 @@ error_info(
 	  end ++
 	  case P of
 	      [] -> [];
-	      _ -> [P]
+	      _ -> [LimitedP]
 	  end ++
 	  case FixedStacktrace of
 	      [] -> [];
diff --git a/lib/stdlib/src/io_lib.erl b/lib/stdlib/src/io_lib.erl
index 5ed2f4d888..9d447418f8 100644
--- a/lib/stdlib/src/io_lib.erl
+++ b/lib/stdlib/src/io_lib.erl
@@ -84,6 +84,8 @@
 -export([write_unicode_string/1, write_unicode_char/1,
          deep_unicode_char_list/1]).
 
+-export([limit_term/2]).
+
 -export_type([chars/0, latin1_string/0, continuation/0,
               fread_error/0, fread_item/0, format_spec/0]).
 
@@ -911,3 +913,116 @@ binrev(L) ->
 
 binrev(L, T) ->
     list_to_binary(lists:reverse(L, T)).
+
+-spec limit_term(term(), non_neg_integer()) -> term().
+
+%% The intention is to mimic the depth limitation of io_lib:write()
+%% and io_lib_pretty:print(). The leaves ('...') should never be
+%% seen when printed with the same depth. Bitstrings are never
+%% truncated, which is OK as long as they are not sent to other nodes.
+limit_term(Term, Depth) ->
+    try test_limit(Term, Depth) of
+        ok -> Term
+    catch
+        throw:limit ->
+            limit(Term, Depth)
+    end.
+
+limit(_, 0) -> '...';
+limit([H|T]=L, D) ->
+    if
+	D =:= 1 -> '...';
+	true ->
+            case printable_list(L) of
+                true -> L;
+                false ->
+                    [limit(H, D-1)|limit_tail(T, D-1)]
+            end
+    end;
+limit(Term, D) when is_map(Term) ->
+    limit_map(Term, D);
+limit({}=T, _D) -> T;
+limit(T, D) when is_tuple(T) ->
+    if
+	D =:= 1 -> '...';
+	true ->
+            list_to_tuple([limit(element(1, T), D-1)|
+                           limit_tail(tl(tuple_to_list(T)), D-1)])
+    end;
+limit(<<_/bitstring>>=Term, D) -> limit_bitstring(Term, D);
+limit(Term, _D) -> Term.
+
+limit_tail([], _D) -> [];
+limit_tail(_, 1) -> ['...'];
+limit_tail([H|T], D) ->
+    [limit(H, D-1)|limit_tail(T, D-1)];
+limit_tail(Other, D) ->
+    limit(Other, D-1).
+
+%% Cannot limit maps properly since there is no guarantee that
+%% maps:from_list() creates a map with the same internal ordering of
+%% the selected associations as in Map.
+limit_map(Map, D) ->
+    maps:from_list(erts_internal:maps_to_list(Map, D)).
+%%     maps:from_list(limit_map_body(erts_internal:maps_to_list(Map, D), D)).
+
+%% limit_map_body(_, 0) -> [{'...', '...'}];
+%% limit_map_body([], _) -> [];
+%% limit_map_body([{K,V}], D) -> [limit_map_assoc(K, V, D)];
+%% limit_map_body([{K,V}|KVs], D) ->
+%%     [limit_map_assoc(K, V, D) | limit_map_body(KVs, D-1)].
+
+%% limit_map_assoc(K, V, D) ->
+%%     {limit(K, D-1), limit(V, D-1)}.
+
+limit_bitstring(B, _D) -> B. %% Keeps all printable binaries.
+
+test_limit(_, 0) -> throw(limit);
+test_limit([H|T]=L, D) when is_integer(D) ->
+    if
+	D =:= 1 -> throw(limit);
+	true ->
+            case printable_list(L) of
+                true -> ok;
+                false ->
+                    test_limit(H, D-1),
+                    test_limit_tail(T, D-1)
+            end
+    end;
+test_limit(Term, D) when is_map(Term) ->
+    test_limit_map(Term, D);
+test_limit({}, _D) -> ok;
+test_limit(T, D) when is_tuple(T) ->
+    test_limit_tuple(T, 1, tuple_size(T), D);
+test_limit(<<_/bitstring>>=Term, D) -> test_limit_bitstring(Term, D);
+test_limit(_Term, _D) -> ok.
+
+test_limit_tail([], _D) -> ok;
+test_limit_tail(_, 1) -> throw(limit);
+test_limit_tail([H|T], D) ->
+    test_limit(H, D-1),
+    test_limit_tail(T, D-1);
+test_limit_tail(Other, D) ->
+    test_limit(Other, D-1).
+
+test_limit_tuple(_T, I, Sz, _D) when I > Sz -> ok;
+test_limit_tuple(_, _, _, 1) -> throw(limit);
+test_limit_tuple(T, I, Sz, D) ->
+    test_limit(element(I, T), D-1),
+    test_limit_tuple(T, I+1, Sz, D-1).
+
+test_limit_map(_Map, _D) -> ok.
+%%     test_limit_map_body(erts_internal:maps_to_list(Map, D), D).
+
+%% test_limit_map_body(_, 0) -> throw(limit);
+%% test_limit_map_body([], _) -> ok;
+%% test_limit_map_body([{K,V}], D) -> test_limit_map_assoc(K, V, D);
+%% test_limit_map_body([{K,V}|KVs], D) ->
+%%     test_limit_map_assoc(K, V, D),
+%%     test_limit_map_body(KVs, D-1).
+
+%% test_limit_map_assoc(K, V, D) ->
+%%     test_limit(K, D-1),
+%%     test_limit(V, D-1).
+
+test_limit_bitstring(_, _) -> ok.
diff --git a/lib/stdlib/src/proc_lib.erl b/lib/stdlib/src/proc_lib.erl
index 2219467a8d..3fa54cd0d5 100644
--- a/lib/stdlib/src/proc_lib.erl
+++ b/lib/stdlib/src/proc_lib.erl
@@ -1,7 +1,7 @@
 %%
 %% %CopyrightBegin%
 %%
-%% Copyright Ericsson AB 1996-2016. All Rights Reserved.
+%% Copyright Ericsson AB 1996-2017. All Rights Reserved.
 %%
 %% Licensed under the Apache License, Version 2.0 (the "License");
 %% you may not use this file except in compliance with the License.
@@ -519,7 +519,8 @@ my_info_1(Class, Reason, Stacktrace) ->
      get_process_info(self(), registered_name),         
      {error_info, {Class,Reason,Stacktrace}},
      get_ancestors(self()),        
-     get_process_info(self(), messages),
+     get_process_info(self(), message_queue_len),
+     get_messages(self()),
      get_process_info(self(), links),
      get_cleaned_dictionary(self()),
      get_process_info(self(), trap_exit),
@@ -539,12 +540,49 @@ get_ancestors(Pid) ->
 	    {ancestors,[]}
     end.
 
+%% The messages and the dictionary are possibly limited too much if
+%% some error handles output the messages or the dictionary using ~P
+%% or ~W with depth greater than the depth used here (the depth of
+%% control characters P and W takes precedence over the depth set by
+%% application variable error_logger_format_depth). However, it is
+%% assumed that all report handlers call proc_lib:format().
+get_messages(Pid) ->
+    Messages = get_process_messages(Pid),
+    {messages, error_logger:limit_term(Messages)}.
+
+get_process_messages(Pid) ->
+    Depth = error_logger:get_format_depth(),
+    case Pid =/= self() orelse Depth =:= unlimited of
+        true ->
+            {messages, Messages} = get_process_info(Pid, messages),
+            Messages;
+        false ->
+            %% If there are more messages than Depth, garbage
+            %% collection can sometimes be avoided by collecting just
+            %% enough messages for the crash report. It is assumed the
+            %% process is about to die anyway.
+            receive_messages(Depth)
+    end.
+
+receive_messages(0) -> [];
+receive_messages(N) ->
+    receive
+        M ->
+            [M|receive_messages(N - 1)]
+    after 0 ->
+            []
+    end.
+
 get_cleaned_dictionary(Pid) ->
     case get_process_info(Pid,dictionary) of
-	{dictionary,Dict} -> {dictionary,clean_dict(Dict)};
+	{dictionary,Dict} -> {dictionary,cleaned_dict(Dict)};
 	_                 -> {dictionary,[]}
     end.
 
+cleaned_dict(Dict) ->
+    CleanDict = clean_dict(Dict),
+    error_logger:limit_term(CleanDict).
+
 clean_dict([{'$ancestors',_}|Dict]) ->
     clean_dict(Dict);
 clean_dict([{'$initial_call',_}|Dict]) ->
@@ -582,20 +620,24 @@ make_neighbour_reports1([P|Ps]) ->
 make_neighbour_reports1([]) ->
   [].
   
+%% Do not include messages or process dictionary, even if
+%% error_logger_format_depth is unlimited.
 make_neighbour_report(Pid) ->
   [{pid, Pid},
    get_process_info(Pid, registered_name),          
    get_initial_call(Pid),
    get_process_info(Pid, current_function),
    get_ancestors(Pid),
-   get_process_info(Pid, messages),
+   get_process_info(Pid, message_queue_len),
+   %% get_messages(Pid),
    get_process_info(Pid, links),
-   get_cleaned_dictionary(Pid),
+   %% get_cleaned_dictionary(Pid),
    get_process_info(Pid, trap_exit),
    get_process_info(Pid, status),
    get_process_info(Pid, heap_size),
    get_process_info(Pid, stack_size),
-   get_process_info(Pid, reductions)
+   get_process_info(Pid, reductions),
+   get_process_info(Pid, current_stacktrace)
   ].
  
 get_initial_call(Pid) ->
@@ -722,24 +764,37 @@ format(CrashReport, Encoding) ->
 
 format([OwnReport,LinkReport], Encoding, Depth) ->
     Extra = {Encoding,Depth},
-    OwnFormat = format_report(OwnReport, Extra),
-    LinkFormat = format_report(LinkReport, Extra),
+    MyIndent = "    ",
+    OwnFormat = format_report(OwnReport, MyIndent, Extra),
+    LinkFormat = format_link_report(LinkReport, MyIndent, Extra),
     Str = io_lib:format("  crasher:~n~ts  neighbours:~n~ts",
                         [OwnFormat, LinkFormat]),
     lists:flatten(Str).
 
-format_report(Rep, Extra) when is_list(Rep) ->
-    format_rep(Rep, Extra);
-format_report(Rep, {Enc,_}) ->
-    io_lib:format("~"++modifier(Enc)++"p~n", [Rep]).
-
-format_rep([{initial_call,InitialCall}|Rep], {_Enc,Depth}=Extra) ->
-    [format_mfa(InitialCall, Depth)|format_rep(Rep, Extra)];
-format_rep([{error_info,{Class,Reason,StackTrace}}|Rep], Extra) ->
-    [format_exception(Class, Reason, StackTrace, Extra)|format_rep(Rep, Extra)];
-format_rep([{Tag,Data}|Rep], Extra) ->
-    [format_tag(Tag, Data, Extra)|format_rep(Rep, Extra)];
-format_rep(_, _Extra) ->
+format_link_report([Link|Reps], Indent, Extra) ->
+    Rep = case Link of
+              {neighbour,Rep0} -> Rep0;
+              _ -> Link
+          end,
+    LinkIndent = ["  ",Indent],
+    [Indent,"neighbour:\n",format_report(Rep, LinkIndent, Extra)|
+     format_link_report(Reps, Indent, Extra)];
+format_link_report([], _, _) ->
+    [].
+
+format_report(Rep, Indent, Extra) when is_list(Rep) ->
+    format_rep(Rep, Indent, Extra);
+format_report(Rep, Indent, {Enc,Depth}) ->
+    io_lib:format("~s~"++modifier(Enc)++"P~n", [Indent, Rep, Depth]).
+
+format_rep([{initial_call,InitialCall}|Rep], Indent, Extra) ->
+    [format_mfa(Indent, InitialCall, Extra)|format_rep(Rep, Indent, Extra)];
+format_rep([{error_info,{Class,Reason,StackTrace}}|Rep], Indent, Extra) ->
+    [format_exception(Class, Reason, StackTrace, Extra)|
+     format_rep(Rep, Indent, Extra)];
+format_rep([{Tag,Data}|Rep], Indent, Extra) ->
+    [format_tag(Indent, Tag, Data, Extra)|format_rep(Rep, Indent, Extra)];
+format_rep(_, _, _Extra) ->
     [].
 
 format_exception(Class, Reason, StackTrace, {Enc,_}=Extra) ->
@@ -750,14 +805,14 @@ format_exception(Class, Reason, StackTrace, {Enc,_}=Extra) ->
     [EI, lib:format_exception(1+length(EI), Class, Reason, 
                               StackTrace, StackFun, PF, Enc), "\n"].
 
-format_mfa({M,F,Args}=StartF, Depth) ->
+format_mfa(Indent, {M,F,Args}=StartF, Extra) ->
     try
 	A = length(Args),
-	["    initial call: ",atom_to_list(M),$:,atom_to_list(F),$/,
+	[Indent,"initial call: ",atom_to_list(M),$:,atom_to_list(F),$/,
 	 integer_to_list(A),"\n"]
     catch
 	error:_ ->
-	    format_tag(initial_call, StartF, Depth)
+	    format_tag(Indent, initial_call, StartF, Extra)
     end.
 
 pp_fun({Enc,Depth}) ->
@@ -770,12 +825,12 @@ pp_fun({Enc,Depth}) ->
             io_lib:format("~." ++ integer_to_list(I) ++ P, [Term|Tl])
     end.
 
-format_tag(Tag, Data, {_Enc,Depth}) ->
+format_tag(Indent, Tag, Data, {_Enc,Depth}) ->
     case Depth of
 	unlimited ->
-	    io_lib:format("    ~p: ~80.18p~n", [Tag, Data]);
+	    io_lib:format("~s~p: ~80.18p~n", [Indent, Tag, Data]);
 	_ ->
-	    io_lib:format("    ~p: ~80.18P~n", [Tag, Data, Depth])
+            io_lib:format("~s~p: ~80.18P~n", [Indent, Tag, Data, Depth])
     end.
 
 modifier(latin1) -> "";
diff --git a/lib/stdlib/test/io_SUITE.erl b/lib/stdlib/test/io_SUITE.erl
index ef3f0be5d7..e2c73371cd 100644
--- a/lib/stdlib/test/io_SUITE.erl
+++ b/lib/stdlib/test/io_SUITE.erl
@@ -31,7 +31,7 @@
          otp_10836/1, io_lib_width_too_small/1,
          io_with_huge_message_queue/1, format_string/1,
 	 maps/1, coverage/1, otp_14178_unicode_atoms/1, otp_14175/1,
-         otp_14285/1]).
+         otp_14285/1, limit_term/1]).
 
 -export([pretty/2]).
 
@@ -63,7 +63,7 @@ all() ->
      io_lib_print_binary_depth_one, otp_10302, otp_10755, otp_10836,
      io_lib_width_too_small, io_with_huge_message_queue,
      format_string, maps, coverage, otp_14178_unicode_atoms, otp_14175,
-     otp_14285].
+     otp_14285, limit_term].
 
 %% Error cases for output.
 error_1(Config) when is_list(Config) ->
@@ -2373,3 +2373,58 @@ otp_14285(_Config) ->
 latin1_fmt(Fmt, Args) ->
     L = fmt(Fmt, Args),
     true = lists:all(fun is_latin1/1, L).
+
+limit_term(_Config) ->
+    {_, 2} = limt([a,b,c], 2),
+    {_, 2} = limt([a,b,c], 3),
+    {_, 2} = limt([a,b|c], 2),
+    {_, 2} = limt([a,b|c], 3),
+    {_, 2} = limt({a,b,c,[d,e]}, 2),
+    {_, 2} = limt({a,b,c,[d,e]}, 3),
+    {_, 2} = limt({a,b,c,[d,e]}, 4),
+    {_, 1} = limt(<<"foo">>, 18),
+    ok = blimt(<<"123456789012345678901234567890">>),
+    {_, 1} = limt(<<7:3>>, 2),
+    {_, 1} = limt(<<7:21>>, 2),
+    {_, 1} = limt([], 2),
+    {_, 1} = limt({}, 2),
+    {_, 1} = limt(#{}, 2),
+    {_, 1} = limt(#{[] => {}}, 2),
+    {_, 1} = limt(#{[] => {}}, 3),
+    T = #{[] => {},[a] => [b]},
+    {_, 1} = limt(T, 2),
+    {_, 1} = limt(T, 3),
+    {_, 1} = limt(T, 4),
+    ok.
+
+blimt(Binary) ->
+    blimt(Binary, byte_size(Binary)).
+
+blimt(_B, 1) -> ok;
+blimt(B, D) ->
+    {_, 1} = limt(B, D),
+    blimt(B, D - 1).
+
+limt(Term, Depth) when is_integer(Depth) ->
+    T1 = io_lib:limit_term(Term, Depth),
+    S = form(Term, Depth),
+    S1 = form(T1, Depth),
+    OK1 = S1 =:= S,
+
+    T2 = io_lib:limit_term(Term, Depth+1),
+    S2 = form(T2, Depth),
+    OK2 = S2 =:= S,
+
+    T3 = io_lib:limit_term(Term, Depth-1),
+    S3 = form(T3, Depth),
+    OK3 = S3 =/= S,
+
+    R = case {OK1, OK2, OK3} of
+            {true, true, true} -> 2;
+            {true, true, false} -> 1;
+            _ -> 0
+        end,
+    {{S, S1, S2}, R}.
+
+form(Term, Depth) ->
+    lists:flatten(io_lib:format("~W", [Term, Depth])).