Move optimizations of bs_put* instruction to beam_ssa_opt

Do the optimizations of bs_put* instructions in beam_ssa_opt
and remove the beam_bs pass. This can lead to a slight improvement
of compilation times.

8 files changed, 175 insertions, 190 deletions

diff --git a/lib/compiler/src/Makefile b/lib/compiler/src/Makefile
index 961dacc6c9..074d9b881b 100644
--- a/lib/compiler/src/Makefile
+++ b/lib/compiler/src/Makefile
@@ -49,7 +49,6 @@ MODULES =  \
 	beam_a \
 	beam_asm \
 	beam_block \
-	beam_bs \
 	beam_clean \
 	beam_dict \
 	beam_disasm \
diff --git a/lib/compiler/src/beam_bs.erl b/lib/compiler/src/beam_bs.erl
deleted file mode 100644
index 9cf12be1b6..0000000000
--- a/lib/compiler/src/beam_bs.erl
+++ /dev/null
@@ -1,180 +0,0 @@
-%%
-%% %CopyrightBegin%
-%%
-%% Copyright Ericsson AB 1999-2018. All Rights Reserved.
-%%
-%% Licensed under the Apache License, Version 2.0 (the "License");
-%% you may not use this file except in compliance with the License.
-%% You may obtain a copy of the License at
-%%
-%%     http://www.apache.org/licenses/LICENSE-2.0
-%%
-%% Unless required by applicable law or agreed to in writing, software
-%% distributed under the License is distributed on an "AS IS" BASIS,
-%% WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
-%% See the License for the specific language governing permissions and
-%% limitations under the License.
-%%
-%% %CopyrightEnd%
-%%
-%% Purpose: Peephole optimization of binary syntax instructions.
-
--module(beam_bs).
-
--export([module/2]).
--import(lists, [reverse/1]).
-
--spec module(beam_utils:module_code(), [compile:option()]) ->
-                    {'ok',beam_utils:module_code()}.
-
-module({Mod,Exp,Attr,Fs0,Lc}, _Opt) ->
-    Fs = [function(F) || F <- Fs0],
-    {ok,{Mod,Exp,Attr,Fs,Lc}}.
-
-function({function,Name,Arity,CLabel,Is0}) ->
-    try
-	Is = bs_opt(Is0),
-	{function,Name,Arity,CLabel,Is}
-    catch
-        Class:Error:Stack ->
-	    io:fwrite("Function: ~w/~w\n", [Name,Arity]),
-	    erlang:raise(Class, Error, Stack)
-    end.
-
-%%%
-%%% Evaluate construction of constant bit fields.
-%%%
-
-bs_opt([{bs_put,_,_,_}=I|Is0]) ->
-    {BsPuts0,Is} = collect_bs_puts(Is0, [I]),
-    BsPuts = opt_bs_puts(BsPuts0),
-    BsPuts ++ bs_opt(Is);
-bs_opt([I|Is]) ->
-    [I|bs_opt(Is)];
-bs_opt([]) -> [].
-
-collect_bs_puts([{bs_put,_,_,_}=I|Is], Acc) ->
-    collect_bs_puts(Is, [I|Acc]);
-collect_bs_puts([_|_]=Is, Acc) ->
-    {reverse(Acc),Is}.
-
-opt_bs_puts(Is) ->
-    opt_bs_1(Is, []).
-
-opt_bs_1([{bs_put,Fail,
-	   {bs_put_float,1,Flags0},[{integer,Sz},Src]}=I0|Is], Acc) ->
-    try eval_put_float(Src, Sz, Flags0) of
-	<<Int:Sz>> ->
-	    Flags = force_big(Flags0),
-	    I = {bs_put,Fail,{bs_put_integer,1,Flags},
-		 [{integer,Sz},{integer,Int}]},
-	    opt_bs_1([I|Is], Acc)
-    catch
-	error:_ ->
-	    opt_bs_1(Is, [I0|Acc])
-    end;
-opt_bs_1([{bs_put,_,{bs_put_integer,1,_},[{integer,8},{integer,_}]}|_]=IsAll,
-	 Acc0) ->
-    {Is,Acc} = bs_collect_string(IsAll, Acc0),
-    opt_bs_1(Is, Acc);
-opt_bs_1([{bs_put,Fail,{bs_put_integer,1,F},[{integer,Sz},{integer,N}]}=I|Is0],
-	 Acc) when Sz > 8 ->
-    case field_endian(F) of
-	big ->
-	    %% We can do this optimization for any field size without
-	    %% risk for code explosion.
-	    case bs_split_int(N, Sz, Fail, Is0) of
-		no_split -> opt_bs_1(Is0, [I|Acc]);
-		Is -> opt_bs_1(Is, Acc)
-	    end;
-	little when Sz < 128 ->
-	    %% We only try to optimize relatively small fields, to
-	    %% avoid an explosion in code size.
-	    <<Int:Sz>> = <<N:Sz/little>>,
-	    Flags = force_big(F),
-	    Is = [{bs_put,Fail,{bs_put_integer,1,Flags},
-		   [{integer,Sz},{integer,Int}]}|Is0],
-	    opt_bs_1(Is, Acc);
-	_ ->			      %native or too wide little field
-	    opt_bs_1(Is0, [I|Acc])
-    end;
-opt_bs_1([{bs_put,Fail,{Op,U,F},[{integer,Sz},Src]}|Is], Acc) when U > 1 ->
-    opt_bs_1([{bs_put,Fail,{Op,1,F},[{integer,U*Sz},Src]}|Is], Acc);
-opt_bs_1([I|Is], Acc) ->
-    opt_bs_1(Is, [I|Acc]);
-opt_bs_1([], Acc) -> reverse(Acc).
-
-eval_put_float(Src, Sz, Flags) when Sz =< 256 ->
-    %%Only evaluate if Sz is reasonable.
-    Val = value(Src),
-    case field_endian(Flags) of
-	little -> <<Val:Sz/little-float-unit:1>>;
-	big -> <<Val:Sz/big-float-unit:1>>
-        %% native intentionally not handled here - we can't optimize
-        %% it.
-    end.
-
-value({integer,I}) -> I;
-value({float,F}) -> F.
-
-bs_collect_string(Is, [{bs_put,_,{bs_put_binary,1,_},
-                        [{atom,all},{literal,BinString}]}|Acc]) ->
-    bs_coll_str_1(Is, BinString, Acc);
-bs_collect_string(Is, Acc) ->
-    bs_coll_str_1(Is, <<>>, Acc).
-
-bs_coll_str_1([{bs_put,_,{bs_put_binary,1,_},
-                [{atom,all},{literal,BinString}]}|Is],
-              StrAcc, IsAcc) when is_binary(BinString) ->
-    bs_coll_str_1(Is, <<StrAcc/binary,BinString/binary>>, IsAcc);
-bs_coll_str_1([{bs_put,_,{bs_put_integer,U,_},[{integer,Sz},{integer,V}]}|Is],
-	      StrAcc, IsAcc) when U*Sz =:= 8 ->
-    Byte = V band 16#FF,
-    bs_coll_str_1(Is, <<StrAcc/binary,Byte>>, IsAcc);
-bs_coll_str_1(Is, StrAcc, IsAcc) ->
-    {Is,[{bs_put,{f,0},{bs_put_binary,1,{field_flags,[unsigned,big]}},
-          [{atom,all},{literal,StrAcc}]}|IsAcc]}.
-
-field_endian({field_flags,F}) -> field_endian_1(F).
-
-field_endian_1([big=E|_]) -> E;
-field_endian_1([little=E|_]) -> E;
-field_endian_1([native=E|_]) -> E;
-field_endian_1([_|Fs]) -> field_endian_1(Fs).
-
-force_big({field_flags,F}) ->
-    {field_flags,force_big_1(F)}.
-
-force_big_1([big|_]=Fs) -> Fs;
-force_big_1([little|Fs]) -> [big|Fs];
-force_big_1([F|Fs]) -> [F|force_big_1(Fs)].
-
-bs_split_int(0, Sz, _, _) when Sz > 64 ->
-    %% We don't want to split in this case because the
-    %% string will consist of only zeroes.
-    no_split;
-bs_split_int(-1, Sz, _, _) when Sz > 64 ->
-    %% We don't want to split in this case because the
-    %% string will consist of only 255 bytes.
-    no_split;
-bs_split_int(N, Sz, Fail, Acc) ->
-    FirstByteSz = case Sz rem 8 of
-		      0 -> 8;
-		      Rem -> Rem
-		  end,
-    bs_split_int_1(N, FirstByteSz, Sz, Fail, Acc).
-
-bs_split_int_1(-1, _, Sz, Fail, Acc) when Sz > 64 ->
-    I = {bs_put,Fail,{bs_put_integer,1,{field_flags,[big]}},
-	 [{integer,Sz},{integer,-1}]},
-    [I|Acc];
-bs_split_int_1(0, _, Sz, Fail, Acc) when Sz > 64 ->
-    I = {bs_put,Fail,{bs_put_integer,1,{field_flags,[big]}},
-	 [{integer,Sz},{integer,0}]},
-    [I|Acc];
-bs_split_int_1(N, ByteSz, Sz, Fail, Acc) when Sz > 0 ->
-    Mask = (1 bsl ByteSz) - 1,
-    I = {bs_put,Fail,{bs_put_integer,1,{field_flags,[big]}},
-	 [{integer,ByteSz},{integer,N band Mask}]},
-    bs_split_int_1(N bsr ByteSz, 8, Sz-ByteSz, Fail, [I|Acc]);
-bs_split_int_1(_, _, _, _, Acc) -> Acc.
diff --git a/lib/compiler/src/beam_ssa_opt.erl b/lib/compiler/src/beam_ssa_opt.erl
index a6f1dd434e..6bba47b4ac 100644
--- a/lib/compiler/src/beam_ssa_opt.erl
+++ b/lib/compiler/src/beam_ssa_opt.erl
@@ -61,6 +61,7 @@ passes(Opts0) ->
           ?PASS(ssa_opt_cse),
           ?PASS(ssa_opt_type),
           ?PASS(ssa_opt_live),
+          ?PASS(ssa_opt_bs_puts),
           ?PASS(ssa_opt_dead),
           ?PASS(ssa_opt_cse),                   %Second time.
           ?PASS(ssa_opt_float),
@@ -1181,6 +1182,175 @@ bsm_units_join_1([], _MapA, Right) ->
     Right.
 
 %%%
+%%% Optimize binary construction.
+%%%
+%%% If an integer segment or a float segment has a literal size and
+%%% a literal value, convert to a binary segment. Coalesce adjacent
+%%% literal binary segments. Literal binary segments will be converted
+%%% to bs_put_string instructions in later pass.
+%%%
+
+ssa_opt_bs_puts(#st{ssa=Linear0,cnt=Count0}=St) ->
+    {Linear,Count} = opt_bs_puts(Linear0, Count0, []),
+    St#st{ssa=Linear,cnt=Count}.
+
+opt_bs_puts([{L,#b_blk{is=Is}=Blk0}|Bs], Count0, Acc0) ->
+    case Is of
+        [#b_set{op=bs_put}=I0] ->
+            case opt_bs_put(L, I0, Blk0, Count0, Acc0) of
+                not_possible ->
+                    opt_bs_puts(Bs, Count0, [{L,Blk0}|Acc0]);
+                {Count,Acc1} ->
+                    Acc = opt_bs_puts_merge(Acc1),
+                    opt_bs_puts(Bs, Count, Acc)
+            end;
+        _ ->
+            opt_bs_puts(Bs, Count0, [{L,Blk0}|Acc0])
+    end;
+opt_bs_puts([], Count, Acc) ->
+    {reverse(Acc),Count}.
+
+opt_bs_puts_merge([{L1,#b_blk{is=Is}=Blk0},{L2,#b_blk{is=AccIs}}=BAcc|Acc]) ->
+    case {AccIs,Is} of
+        {[#b_set{op=bs_put,
+                 args=[#b_literal{val=binary},
+                       #b_literal{},
+                       #b_literal{val=Bin0},
+                       #b_literal{val=all},
+                       #b_literal{val=1}]}],
+         [#b_set{op=bs_put,
+                 args=[#b_literal{val=binary},
+                       #b_literal{},
+                       #b_literal{val=Bin1},
+                       #b_literal{val=all},
+                       #b_literal{val=1}]}=I0]} ->
+            %% Coalesce the two segments to one.
+            Bin = <<Bin0/bitstring,Bin1/bitstring>>,
+            I = I0#b_set{args=bs_put_args(binary, Bin, all)},
+            Blk = Blk0#b_blk{is=[I]},
+            [{L2,Blk}|Acc];
+        {_,_} ->
+            [{L1,Blk0},BAcc|Acc]
+    end.
+
+opt_bs_put(L, I0, #b_blk{last=Br0}=Blk0, Count0, Acc) ->
+    case opt_bs_put(I0) of
+        [Bin] when is_bitstring(Bin) ->
+            Args = bs_put_args(binary, Bin, all),
+            I = I0#b_set{args=Args},
+            Blk = Blk0#b_blk{is=[I]},
+            {Count0,[{L,Blk}|Acc]};
+        [{int,Int,Size},Bin] when is_bitstring(Bin) ->
+            %% Construct a bs_put_integer instruction following
+            %% by a bs_put_binary instruction.
+            IntArgs = bs_put_args(integer, Int, Size),
+            BinArgs = bs_put_args(binary, Bin, all),
+            {BinL,BinVarNum} = {Count0,Count0+1},
+            Count = Count0 + 2,
+            BinVar = #b_var{name={'@ssa_bool',BinVarNum}},
+            BinI = I0#b_set{dst=BinVar,args=BinArgs},
+            BinBlk = Blk0#b_blk{is=[BinI],last=Br0#b_br{bool=BinVar}},
+            IntI = I0#b_set{args=IntArgs},
+            IntBlk = Blk0#b_blk{is=[IntI],last=Br0#b_br{succ=BinL}},
+            {Count,[{BinL,BinBlk},{L,IntBlk}|Acc]};
+        not_possible ->
+            not_possible
+    end.
+
+opt_bs_put(#b_set{args=[#b_literal{val=binary},_,#b_literal{val=Val},
+                        #b_literal{val=all},#b_literal{val=Unit}]})
+  when is_bitstring(Val) ->
+    if
+        bit_size(Val) rem Unit =:= 0 ->
+            [Val];
+        true ->
+            not_possible
+    end;
+opt_bs_put(#b_set{args=[#b_literal{val=Type},#b_literal{val=Flags},
+                        #b_literal{val=Val},#b_literal{val=Size},
+                        #b_literal{val=Unit}]}=I0) when is_integer(Size) ->
+    EffectiveSize = Size * Unit,
+    if
+        EffectiveSize > 0 ->
+            case {Type,opt_bs_put_endian(Flags)} of
+                {integer,big} when is_integer(Val) ->
+                    if
+                        EffectiveSize < 64 ->
+                            [<<Val:EffectiveSize>>];
+                        true ->
+                            opt_bs_put_split_int(Val, EffectiveSize)
+                    end;
+                {integer,little} when is_integer(Val), EffectiveSize < 128 ->
+                    %% To avoid an explosion in code size, we only try
+                    %% to optimize relatively small fields.
+                    <<Int:EffectiveSize>> = <<Val:EffectiveSize/little>>,
+                    Args = bs_put_args(Type, Int, EffectiveSize),
+                    I = I0#b_set{args=Args},
+                    opt_bs_put(I);
+                {binary,_} when is_bitstring(Val) ->
+                    <<Bitstring:EffectiveSize/bits,_/bits>> = Val,
+                    [Bitstring];
+                {float,Endian} ->
+                    try
+                        [opt_bs_put_float(Val, EffectiveSize, Endian)]
+                    catch error:_ ->
+                            not_possible
+                    end;
+                {_,_} ->
+                    not_possible
+            end;
+        true ->
+            not_possible
+    end;
+opt_bs_put(#b_set{}) -> not_possible.
+
+opt_bs_put_float(N, Sz, Endian) ->
+    case Endian of
+        big -> <<N:Sz/big-float-unit:1>>;
+        little -> <<N:Sz/little-float-unit:1>>
+    end.
+
+bs_put_args(Type, Val, Size) ->
+    [#b_literal{val=Type},
+     #b_literal{val=[unsigned,big]},
+     #b_literal{val=Val},
+     #b_literal{val=Size},
+     #b_literal{val=1}].
+
+opt_bs_put_endian([big=E|_]) -> E;
+opt_bs_put_endian([little=E|_]) -> E;
+opt_bs_put_endian([native=E|_]) -> E;
+opt_bs_put_endian([_|Fs]) -> opt_bs_put_endian(Fs).
+
+opt_bs_put_split_int(Int, Size) ->
+    Pos = opt_bs_put_split_int_1(Int, 0, Size - 1),
+    UpperSize = Size - Pos,
+    if
+        Pos =:= 0 ->
+            %% Value is 0 or -1 -- keep the original instruction.
+            not_possible;
+        UpperSize < 64 ->
+            %% No or few leading zeroes or ones.
+            [<<Int:Size>>];
+        true ->
+            %% There are 64 or more leading ones or zeroes in
+            %% the resulting binary. Split into two separate
+            %% segments to avoid an explosion in code size.
+            [{int,Int bsr Pos,UpperSize},<<Int:Pos>>]
+    end.
+
+opt_bs_put_split_int_1(_Int, L, R) when L > R ->
+    8 * ((L + 7) div 8);
+opt_bs_put_split_int_1(Int, L, R) ->
+    Mid = (L + R) div 2,
+    case Int bsr Mid of
+        Upper when Upper =:= 0; Upper =:= -1 ->
+            opt_bs_put_split_int_1(Int, L, Mid - 1);
+        _ ->
+            opt_bs_put_split_int_1(Int, Mid + 1, R)
+    end.
+
+%%%
 %%% Miscellanous optimizations in execution order.
 %%%
 
diff --git a/lib/compiler/src/compile.erl b/lib/compiler/src/compile.erl
index 14c8c5b4ab..73c66e6efc 100644
--- a/lib/compiler/src/compile.erl
+++ b/lib/compiler/src/compile.erl
@@ -855,8 +855,6 @@ asm_passes() ->
 	 {iff,dblk,{listing,"block"}},
 	 {unless,no_except,{pass,beam_except}},
 	 {iff,dexcept,{listing,"except"}},
-	 {unless,no_bs_opt,{pass,beam_bs}},
-	 {iff,dbs,{listing,"bs"}},
 	 {unless,no_jopt,{pass,beam_jump}},
 	 {iff,djmp,{listing,"jump"}},
 	 {unless,no_peep_opt,{pass,beam_peep}},
@@ -2084,7 +2082,6 @@ pre_load() ->
     L = [beam_a,
 	 beam_asm,
 	 beam_block,
-	 beam_bs,
 	 beam_clean,
 	 beam_dict,
 	 beam_except,
diff --git a/lib/compiler/src/compiler.app.src b/lib/compiler/src/compiler.app.src
index 1472e3fde1..108a0ca100 100644
--- a/lib/compiler/src/compiler.app.src
+++ b/lib/compiler/src/compiler.app.src
@@ -24,7 +24,6 @@
 	     beam_a,
 	     beam_asm,
 	     beam_block,
-	     beam_bs,
 	     beam_clean,
 	     beam_dict,
 	     beam_disasm,
diff --git a/lib/compiler/test/bs_construct_SUITE.erl b/lib/compiler/test/bs_construct_SUITE.erl
index ccc49df005..69017d87e7 100644
--- a/lib/compiler/test/bs_construct_SUITE.erl
+++ b/lib/compiler/test/bs_construct_SUITE.erl
@@ -153,6 +153,8 @@ l(I_13, I_big1, I_16, Bin) ->
 	[0,0,0,0, 0,0,0,0, 0,0,0,0, 0,0,0,0,
 	 16#77,16#FF,16#FF,16#FF,16#FF,16#FF,16#FF,16#FF,16#FF,16#FF,16#FF,
 	 16#FF,16#FF,16#FF,16#FF,16#FF,16#FF]),
+     ?T(<< (<<"abc",7:3>>):3/binary >>,
+        [$a,$b,$c]),
 
      %% Mix different units.
      ?T(<<37558955:(I_16-12)/unit:8,1:1>>,
@@ -311,6 +313,9 @@ fail(Config) when is_list(Config) ->
     {'EXIT',{badarg,_}} = (catch <<0:(-(1 bsl 100))>>),
     {'EXIT',{badarg,_}} = (catch <<Bin/binary,0:(-(1 bsl 100))>>),
 
+    %% Unaligned sizes with literal binaries.
+    {'EXIT',{badarg,_}} = (catch <<0,(<<7777:17>>)/binary>>),
+
     ok.
 
 float_bin(Config) when is_list(Config) ->
diff --git a/lib/compiler/test/compile_SUITE.erl b/lib/compiler/test/compile_SUITE.erl
index 6eae7b1404..c17d63cd60 100644
--- a/lib/compiler/test/compile_SUITE.erl
+++ b/lib/compiler/test/compile_SUITE.erl
@@ -391,7 +391,6 @@ do_file_listings(DataDir, PrivDir, [File|Files]) ->
     do_listing(Simple, TargetDir, dcg, ".codegen"),
     do_listing(Simple, TargetDir, dblk, ".block"),
     do_listing(Simple, TargetDir, dexcept, ".except"),
-    do_listing(Simple, TargetDir, dbs, ".bs"),
     do_listing(Simple, TargetDir, djmp, ".jump"),
     do_listing(Simple, TargetDir, dclean, ".clean"),
     do_listing(Simple, TargetDir, dpeep, ".peep"),
diff --git a/lib/compiler/test/misc_SUITE.erl b/lib/compiler/test/misc_SUITE.erl
index 2a6303ece8..e999c8ffae 100644
--- a/lib/compiler/test/misc_SUITE.erl
+++ b/lib/compiler/test/misc_SUITE.erl
@@ -223,10 +223,6 @@ silly_coverage(Config) when is_list(Config) ->
 		     {label,2}|non_proper_list]}],99},
     expect_error(fun() -> beam_block:module(BlockInput, []) end),
 
-    %% beam_bs
-    BsInput = BlockInput,
-    expect_error(fun() -> beam_bs:module(BsInput, []) end),
-
     %% beam_except
     ExceptInput = {?MODULE,[{foo,0}],[],
 		   [{function,foo,0,2,