Merge branch 'maint'

* maint:
  Bumped version nr
  ssl & public_key: Workaround that some certificates encode countryname as utf8 and close down gracefully if other ASN-1 errors occur.
  Add more cross reference links to ct docs
  Remove config option from common_test args
  Update user config to use nested tuple keys
  Allow mixed IPv4 and IPv6 addresses to sctp_bindx
  Add checks for in6addr_any and in6addr_loopback
  Fix SCTP multihoming
  observer: fix app file (Noticed-by: Motiejus Jakstys)
  Fix lib/src/test/ssh_basic_SUITE.erl to fix IPv6 option typos
  Prevent index from being corrupted if a nonexistent item is deleted
  Add tests showing that trying to delete non-existing object may corrupt the table index
  Fix Table Viewer search crash on new|changed|deleted rows
  Escape control characters in Table Viewer
  Fix Table Viewer crash after a 'Found' -> 'Not found' search sequence
  inet_drv.c: Set sockaddr lengths in inet_set_[f]address

Conflicts:
	erts/preloaded/ebin/prim_inet.beam

1 files changed, 58 insertions, 0 deletions

diff --git a/erts/configure.in b/erts/configure.in
index e576bd7755..281f61f86e 100644
--- a/erts/configure.in
+++ b/erts/configure.in
@@ -1944,6 +1944,64 @@ AC_CHECK_FUNCS([openpty])
 AC_CHECK_HEADERS(net/if_dl.h ifaddrs.h netpacket/packet.h)
 AC_CHECK_FUNCS([getifaddrs])
 
+dnl Checks for variables in6addr_any and in6addr_loopback,
+dnl
+dnl They normally declared by netinet/in.h, according to POSIX,
+dnl but not on Windows 7 (Windows SDK 7.1).  I would have liked
+dnl to just write AC_CHECK_DECL([in6addr_any], ...) but if doing so,
+dnl the configure check fails erroneously on Linux with the error
+dnl "cannot convert to a pointer type", on a line looking like
+dnl "char *p = (char *) in6addr_any;", so work around that
+dnl with some more code. 
+AC_CACHE_CHECK(
+    [whether in6addr_any is declared],
+    [erts_cv_have_in6addr_any],
+    [AC_LINK_IFELSE(
+	[AC_LANG_PROGRAM(
+	    [[
+		#include <sys/types.h>
+		#include <sys/socket.h>
+		#include <netinet/in.h>
+	    ]],
+	    [[printf("%d", in6addr_any.s6_addr[16]);]]
+	)],
+	[erts_cv_have_in6addr_any=yes],
+	[erts_cv_have_in6addr_any=no]
+    )]
+)
+
+case "$erts_cv_have_in6addr_any" in
+ yes)
+   AC_DEFINE([HAVE_IN6ADDR_ANY], [1],
+             [Define to 1 if you have the variable in6addr_any declared.])
+esac
+
+AC_CACHE_CHECK(
+    [whether in6addr_loopback is declared],
+    [erts_cv_have_in6addr_loopback],
+    [AC_LINK_IFELSE(
+	[AC_LANG_PROGRAM(
+	    [[
+		#include <sys/types.h>
+		#include <sys/socket.h>
+		#include <netinet/in.h>
+	    ]],
+	    [[printf("%d", in6addr_loopback.s6_addr[16]);]]
+	)],
+	[erts_cv_have_in6addr_loopback=yes],
+	[erts_cv_have_in6addr_loopback=no]
+    )]
+)
+
+case "$erts_cv_have_in6addr_loopback" in
+ yes)
+   AC_DEFINE([HAVE_IN6ADDR_LOOPBACK], [1],
+             [Define to 1 if you have the variable in6addr_loopback declared.])
+esac
+
+AC_CHECK_DECLS([IN6ADDR_ANY_INIT, IN6ADDR_LOOPBACK_INIT], [], [],
+	       [#include <netinet/in.h>])
+
 dnl ----------------------------------------------------------------------
 dnl Checks for features/quirks in the system that affects Erlang.
 dnl ----------------------------------------------------------------------