erts: Extend process and port tracing

This commit completes the tracing for processes so that
all messages sent by a process (via nifs or otherwise) will
be traced.

The commit also adds tracing of all types of events from ports.

When enabling tracing using erlang:trace, the 'all' flag now also
enables tracing on all ports.

OTP-13496

6 files changed, 882 insertions, 27 deletions

diff --git a/erts/emulator/test/Makefile b/erts/emulator/test/Makefile
index 92182e3890..de395dfb97 100644
--- a/erts/emulator/test/Makefile
+++ b/erts/emulator/test/Makefile
@@ -114,6 +114,7 @@ MODULES= \
 	tracer_test \
 	scheduler_SUITE \
 	old_scheduler_SUITE \
+	port_trace_SUITE \
 	unique_SUITE \
 	z_SUITE \
 	old_mod \
diff --git a/erts/emulator/test/call_trace_SUITE.erl b/erts/emulator/test/call_trace_SUITE.erl
index 2159546054..6ba6301c7c 100644
--- a/erts/emulator/test/call_trace_SUITE.erl
+++ b/erts/emulator/test/call_trace_SUITE.erl
@@ -84,32 +84,46 @@ process_specs(Config) when is_list(Config) ->
     {tracer,Tracer} = trace_info(self(), tracer),
     trace_func({?MODULE,worker_foo,1}, []),
 
-    %% Test the 'new' flag.
-
-    {Work1A,Work1B} = start_and_trace(new, [1,2,3], A1B={3,2,1}),
-    {flags,[]} = trace_info(Work1A, flags),
-    {tracer,[]} = trace_info(Work1A, tracer),
-    {tracer,Tracer} = trace_info(Work1B, tracer),
-    {flags,[call]} = trace_info(Work1B, flags),
-    expect({trace,Work1B,call,{?MODULE,worker_foo,[A1B]}}),
-    unlink(Work1B),
-    Mref = erlang:monitor(process, Work1B),
-    exit(Work1B, kill),
-    receive
-        {'DOWN',Mref,_,_,_} -> ok
-    end,
-    undefined = trace_info(Work1B, flags),
-    {flags,[]} = trace_info(new, flags),
-    {tracer,[]} = trace_info(new, tracer),
-
-    %% Test the 'existing' flag.
-    {Work2A,_Work2B} = start_and_trace(existing, A2A=[5,6,7], [7,6,5]),
-    expect({trace,Work2A,call,{?MODULE,worker_foo,[A2A]}}),
-
-    %% Test the 'all' flag.
-    {Work3A,Work3B} = start_and_trace(all, A3A=[12,13], A3B=[13,12]),
-    expect({trace,Work3A,call,{?MODULE,worker_foo,[A3A]}}),
-    expect({trace,Work3B,call,{?MODULE,worker_foo,[A3B]}}),
+    %% Test the 'new' and 'new_processes' flags.
+
+    New = fun(Flag) ->
+                  {Work1A,Work1B} = start_and_trace(Flag, [1,2,3], A1B={3,2,1}),
+                  {flags,[]} = trace_info(Work1A, flags),
+                  {tracer,[]} = trace_info(Work1A, tracer),
+                  {tracer,Tracer} = trace_info(Work1B, tracer),
+                  {flags,[call]} = trace_info(Work1B, flags),
+                  expect({trace,Work1B,call,{?MODULE,worker_foo,[A1B]}}),
+                  unlink(Work1B),
+                  Mref = erlang:monitor(process, Work1B),
+                  exit(Work1B, kill),
+                  receive
+                      {'DOWN',Mref,_,_,_} -> ok
+                  end,
+                  undefined = trace_info(Work1B, flags),
+                  {flags,[]} = trace_info(Flag, flags),
+                  {tracer,[]} = trace_info(Flag, tracer)
+          end,
+    New(new),
+    New(new_processes),
+
+    %% Test the 'existing' and 'existing_processes' flags.
+    Existing =
+        fun(Flag) ->
+                {Work2A,_Work2B} = start_and_trace(Flag, A2A=[5,6,7], [7,6,5]),
+                expect({trace,Work2A,call,{?MODULE,worker_foo,[A2A]}})
+        end,
+    Existing(existing),
+    Existing(existing_processes),
+
+    %% Test the 'all' and 'processes' flags.
+    All =
+        fun(Flag) ->
+                   {Work3A,Work3B} = start_and_trace(Flag, A3A=[12,13], A3B=[13,12]),
+                   expect({trace,Work3A,call,{?MODULE,worker_foo,[A3A]}}),
+                   expect({trace,Work3B,call,{?MODULE,worker_foo,[A3B]}})
+        end,
+    All(all),
+    All(processes),
 
     ok.
 
diff --git a/erts/emulator/test/port_trace_SUITE.erl b/erts/emulator/test/port_trace_SUITE.erl
new file mode 100644
index 0000000000..41e8a316c4
--- /dev/null
+++ b/erts/emulator/test/port_trace_SUITE.erl
@@ -0,0 +1,600 @@
+%%
+%% %CopyrightBegin%
+%%
+%% Copyright Ericsson AB 1999-2012. All Rights Reserved.
+%%
+%% Licensed under the Apache License, Version 2.0 (the "License");
+%% you may not use this file except in compliance with the License.
+%% You may obtain a copy of the License at
+%%
+%%     http://www.apache.org/licenses/LICENSE-2.0
+%%
+%% Unless required by applicable law or agreed to in writing, software
+%% distributed under the License is distributed on an "AS IS" BASIS,
+%% WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+%% See the License for the specific language governing permissions and
+%% limitations under the License.
+%%
+%% %CopyrightEnd%
+%%
+
+
+-module(port_trace_SUITE).
+
+-export([all/0, suite/0,init_per_suite/1, end_per_suite/1,
+	 init_per_group/2,end_per_group/2,
+	 init_per_testcase/2,end_per_testcase/2]).
+-export([port_specs/1, ports/1, open_close/1,
+         command/1, control/1, connect/1, call/1,
+         output/1, output2/1, output_binary/1,
+         outputv/1, set_timer/1, failure_eof/1,
+         failure_atom/1, failure_posix/1,
+         failure/1, output_term/1,
+         driver_output_term/1,
+         send_term/1, driver_send_term/1]).
+
+-define(ECHO_DRV_NOOP, 0).
+-define(ECHO_DRV_OUTPUT, 1).
+-define(ECHO_DRV_OUTPUT2, 2).
+-define(ECHO_DRV_OUTPUT_BINARY, 3).
+-define(ECHO_DRV_OUTPUTV, 4).
+-define(ECHO_DRV_SET_TIMER, 5).
+-define(ECHO_DRV_FAILURE_EOF, 6).
+-define(ECHO_DRV_FAILURE_ATOM, 7).
+-define(ECHO_DRV_FAILURE_POSIX, 8).
+-define(ECHO_DRV_FAILURE, 9).
+-define(ECHO_DRV_OUTPUT_TERM, 10).
+-define(ECHO_DRV_DRIVER_OUTPUT_TERM, 11).
+-define(ECHO_DRV_SEND_TERM, 12).
+-define(ECHO_DRV_DRIVER_SEND_TERM, 13).
+-define(ECHO_DRV_SAVE_CALLER, 14).
+
+suite() -> [{ct_hooks,[ts_install_cth]},
+            {timetrap, {seconds, 30}}].
+
+all() ->
+    [port_specs, ports, open_close,
+     command, control, connect, call,
+     output, output2, output_binary,
+     outputv, set_timer, failure_eof,
+     failure_atom, failure_posix,
+     failure, output_term,
+     driver_output_term,
+     send_term, driver_send_term].
+
+init_per_suite(Config) ->
+    Config.
+
+end_per_suite(_Config) ->
+    ok.
+
+init_per_group(_GroupName, Config) ->
+    Config.
+
+end_per_group(_GroupName, Config) ->
+    Config.
+
+
+init_per_testcase(Func, Config) when is_atom(Func), is_list(Config) ->
+    erlang:trace(all, false, [all]),
+    os:unsetenv("OUTPUTV"),
+    reload_drv(Config),
+    Config.
+
+end_per_testcase(_Func, _Config) ->
+    erlang:trace(all, false, [all]),
+    ok.
+
+%% Test the first argument of trace/3
+port_specs(_Config) ->
+
+    S = self(),
+
+    Tracer = fun F() ->
+                     receive
+                         stop ->
+                             ok;
+                         M ->
+                             S ! M,
+                             F()
+                     end
+             end,
+
+    Test = fun(TraceSpec, Info1, Info2) ->
+                   {TracerPid,Ref} = spawn_monitor(Tracer),
+                   Prt1 = erlang:open_port({spawn, echo_drv}, [binary]),
+                   erlang:trace(TraceSpec, true, ['receive', {tracer, TracerPid}]),
+                   %% We disable trace messages from the testcase process
+                   erlang:trace(self(), false, ['receive']),
+                   Prt2 = erlang:open_port({spawn, echo_drv}, [binary]),
+
+                   InfoCheck =
+                       fun(Info, Prt) ->
+                               if
+                                   Info ->
+                                       {tracer, TracerPid} = erlang:trace_info(Prt, tracer),
+                                       {flags,['receive']} = erlang:trace_info(Prt, flags);
+                                   not Info ->
+                                       {tracer,[]} = erlang:trace_info(Prt, tracer),
+                                       {flags,[]} = erlang:trace_info(Prt, flags)
+                               end
+                       end,
+                   InfoCheck(Info1, Prt1),
+                   InfoCheck(Info2, Prt2),
+
+                   %% These may create trace messages
+                   erlang:port_command(Prt1, <<?ECHO_DRV_NOOP>>),
+                   erlang:port_command(Prt2, <<?ECHO_DRV_NOOP>>),
+
+                   %% Test what happens when the tracer dies
+                   trace_delivered(),
+                   TracerPid ! stop,
+                   receive {'DOWN', Ref, process, TracerPid, normal} -> ok end,
+
+                   %% These should not generate any trace messages
+                   erlang:port_command(Prt1, <<?ECHO_DRV_NOOP>>),
+                   erlang:port_command(Prt2, <<?ECHO_DRV_NOOP>>),
+
+                   InfoCheck(false, Prt1),
+                   InfoCheck(false, Prt2),
+
+                   erlang:port_close(Prt1),
+                   erlang:port_close(Prt2),
+                   erlang:trace(all, false, [all]),
+                   {Prt1, Prt2}
+           end,
+
+    {_Prt11, Prt12} = Test(new, false, true),
+    [{trace, Prt12, 'receive', {S, {command,<<?ECHO_DRV_NOOP>>}}}]
+        = flush(Prt12),
+
+    {_Prt21, Prt22} = Test(new_ports, false, true),
+    [{trace, Prt22, 'receive', {S, {command,<<?ECHO_DRV_NOOP>>}}}]
+        = flush(Prt22),
+
+    {Prt31, _Prt32} = Test(existing, true, false),
+    [{trace, Prt31, 'receive', {S, {command,<<?ECHO_DRV_NOOP>>}}}]
+        = flush(Prt31),
+
+    {Prt41, _Prt42} = Test(existing_ports, true, false),
+    [{trace, Prt41, 'receive', {S, {command,<<?ECHO_DRV_NOOP>>}}}]
+        = flush(Prt41),
+
+    {Prt51, Prt52} = Test(all, true, true),
+    [{trace, Prt51, 'receive', {S, {command,<<?ECHO_DRV_NOOP>>}}}]
+        = flush(Prt51),
+    [{trace, Prt52, 'receive', {S, {command,<<?ECHO_DRV_NOOP>>}}}]
+        = flush(Prt52),
+
+    {Prt61, Prt62} = Test(ports, true, true),
+    [{trace, Prt61, 'receive', {S, {command,<<?ECHO_DRV_NOOP>>}}}]
+        = flush(Prt61),
+    [{trace, Prt62, 'receive', {S, {command,<<?ECHO_DRV_NOOP>>}}}]
+        = flush(Prt62),
+
+    ok.
+
+%% Test that the 'ports' trace flag works
+ports(_Config) ->
+
+    {Prt, S} = trace_and_open([ports],[binary]),
+
+    [{trace, Prt, open, S, echo_drv},
+     {trace, Prt, getting_linked, S}] = flush(),
+
+    register(?MODULE, Prt),
+    unregister(?MODULE),
+    register(?MODULE, Prt),
+
+    [{trace,Prt,register,port_trace_SUITE},
+     {trace,Prt,unregister,port_trace_SUITE},
+     {trace,Prt,register,port_trace_SUITE}] = flush(),
+
+    unlink(Prt),
+    link(Prt),
+
+    [{trace,Prt,getting_unlinked,S},
+     {trace,Prt,getting_linked,S}] = flush(),
+
+    erlang:port_close(Prt),
+
+    [{trace,Prt,closed,normal},
+     {trace,Prt,unregister,port_trace_SUITE},
+     {trace,Prt,unlink,S}] = flush(),
+
+    ok.
+
+%% Test that port_close and ! close generate correct trace messages
+open_close(_Config) ->
+
+    S = trace_ports([send,'receive']),
+
+    Prt = erlang:open_port({spawn, echo_drv}, [binary]),
+    erlang:port_close(Prt),
+    [{trace, Prt, 'receive', {S, close}}] = flush(),
+
+    Prt2 = erlang:open_port({spawn, echo_drv}, [binary]),
+    Prt2 ! {S, close},
+    recv({Prt2, closed}),
+    [{trace, Prt2, 'receive', {S, close}},
+     {trace, Prt2, send, closed, S}] = flush(),
+
+    catch erlang:port_close(Prt2),
+    [] = flush(),
+
+    ok.
+
+%% Test that port_command and ! command generate correct trace messages
+command(Config) ->
+
+    Flags = [send,'receive'],
+    S = trace_ports(Flags),
+    Prt = erlang:open_port({spawn, echo_drv}, [binary]),
+
+    erlang:port_command(Prt, <<?ECHO_DRV_NOOP:8>>),
+    [{trace, Prt, 'receive', {S, {command, <<?ECHO_DRV_NOOP:8>>}}}] = flush(),
+
+    erlang:port_command(Prt, [?ECHO_DRV_NOOP, <<0:8>>]),
+    [{trace, Prt, 'receive', {S, {command, <<?ECHO_DRV_NOOP:8,0:8>>}}}] = flush(),
+
+    Prt ! {S, {command, <<?ECHO_DRV_NOOP:8>>}},
+    [{trace, Prt, 'receive', {S, {command, <<?ECHO_DRV_NOOP:8>>}}}] = flush(),
+
+    close(Prt, Flags),
+
+    os:putenv("OUTPUTV","true"),
+    reload_drv(Config),
+
+    Prt2 = erlang:open_port({spawn, echo_drv}, [binary]),
+    Msg = [<<0:8>>,<<0:(8*512)>>,<<0:(8*256)>>,<<0:8>>],
+
+    erlang:port_command(Prt2, Msg),
+    [{trace, Prt2, 'receive', {S, {command, Msg}}}] = flush(),
+
+    Prt2 ! {S, {command, Msg}},
+    [{trace, Prt2, 'receive', {S, {command, Msg}}}] = flush(),
+
+    close(Prt2, Flags),
+
+    os:unsetenv("OUTPUTV"),
+
+    ok.
+
+%% Test that port_control generate correct trace messages
+control(_Config) ->
+
+    Flags = [send,'receive'],
+    {Prt, S} = trace_and_open(Flags,[binary]),
+
+    [0] = erlang:port_control(Prt, 1, <<?ECHO_DRV_NOOP:8, 0:8>>),
+    [{trace, Prt, 'receive', {S, {control, {1, <<?ECHO_DRV_NOOP:8, 0:8>>}}}},
+     {trace, Prt, send, {Prt, {control, <<0:8>>}}, S}] = flush(),
+
+    [0] = erlang:port_control(Prt, (1 bsl 32) - 1, <<?ECHO_DRV_NOOP:8, 0:8>>),
+    [{trace, Prt, 'receive', {S, {control, {(1 bsl 32) - 1, <<?ECHO_DRV_NOOP:8, 0:8>>}}}},
+     {trace, Prt, send, {Prt, {control, <<0:8>>}}, S}] = flush(),
+
+    close(Prt, Flags),
+
+    ok.
+
+%% Test that port_connect and ! connect generate correct trace messages
+%% This includes that the proper getting_linked messages are sent
+connect(_Config) ->
+
+
+    {Prt, S} = trace_and_open([send, 'receive', ports],[binary]),
+
+    flush(),
+
+    {Pid,Ref} = spawn_monitor(
+                  fun() ->
+                          receive
+                              go ->
+                                  Prt ! {self(), {connect, S}},
+                                  receive {Prt, connected} -> unlink(Prt) end
+                          end
+                  end),
+    erlang:trace(Pid, true, [send, 'receive', procs]),
+
+    erlang:port_connect(Prt, Pid),
+    unlink(Prt),
+
+    [{trace,Prt,getting_linked,Pid},
+     {trace,Prt,'receive',{S,{connect,Pid}}},
+     {trace,Prt,send,{Prt,connected},S},
+     {trace,Prt,getting_unlinked, S}] = flush(Prt),
+
+    [{trace,Pid,getting_linked,Prt}] = flush(),
+
+    Pid ! go,
+    recv({'DOWN',Ref,process,Pid,normal}),
+
+    [{trace,Prt,'receive',{Pid,{connect,S}}},
+     {trace,Prt,send,{Prt,connected},Pid},
+     {trace,Prt,getting_unlinked,Pid}] = flush(Prt),
+
+    [{trace,Pid,'receive',go},
+     {trace,Pid,send,{Pid,{connect,S}}, Prt},
+     {trace,Pid,'receive',{Prt,connected}},
+     {trace,Pid,unlink,Prt},
+     {trace,Pid,exit,normal}] = flush(),
+
+    erlang:port_close(Prt),
+    [{trace, Prt, 'receive', {S, close}},
+     {trace, Prt, closed, normal}] = flush(),
+    ok.
+
+%% Test that port_call generate correct trace messages
+call(_Config) ->
+
+    Flags = [send,'receive'],
+    {Prt, S} = trace_and_open(Flags,[binary]),
+
+    Msg = {hello, world, make_ref()},
+    BinMsg = term_to_binary(Msg),
+
+    Msg = erlang:port_call(Prt, 0, Msg),
+    [{trace, Prt, 'receive', {S, {call, {0, BinMsg}}}},
+     {trace, Prt, send, {Prt, {call, BinMsg}}, S}] = flush(),
+
+    close(Prt, Flags),
+
+    ok.
+
+%% Test that driver_output generate correct trace messages
+output(_Config) ->
+
+    Flags = [send],
+    {Prt, S} = trace_and_open(Flags,[binary]),
+
+    erlang:port_command(Prt, <<?ECHO_DRV_OUTPUT, 123456:32>>),
+    recv({Prt,{data,<<123456:32>>}}),
+
+    [{trace, Prt, send, {Prt, {data, <<123456:32>>}}, S}] = flush(),
+
+    close(Prt, Flags),
+
+    ok.
+
+%% Test that driver_output2 generate correct trace messages
+output2(_Config) ->
+
+    Flags = [send],
+    {Prt, S} = trace_and_open(Flags,[binary]),
+
+    erlang:port_command(Prt, <<?ECHO_DRV_OUTPUT2, 123456:32>>),
+    recv({Prt,{data,[$a|<<123456:32>>]}}),
+    [{trace, Prt, send, {Prt, {data, [$a|<<123456:32>>]}}, S}] = flush(),
+
+    close(Prt, Flags),
+
+    ok.
+
+%% Test that driver_output_binary generate correct trace messages
+output_binary(_Config) ->
+
+    Flags = [send],
+    {Prt, S} = trace_and_open(Flags,[binary]),
+
+    erlang:port_command(Prt, <<?ECHO_DRV_OUTPUT_BINARY, 0, 123456:32>>),
+    recv({Prt,{data,[$a|<<123456:32>>]}}),
+    [{trace, Prt, send, {Prt, {data, [$a|<<123456:32>>]}}, S}] = flush(),
+
+    close(Prt, Flags),
+
+    ok.
+
+%% Test that driver_outputv generate correct trace messages
+outputv(_Config) ->
+
+    Flags = [send],
+    {Prt, S} = trace_and_open(Flags,[binary]),
+
+    erlang:port_command(Prt, <<?ECHO_DRV_OUTPUTV, 123456:32>>),
+    recv({Prt,{data,[$a|<<123456:32>>]}}),
+
+    [{trace, Prt, send, {Prt, {data, [$a|<<123456:32>>]}}, S}] = flush(),
+
+    erlang:port_close(Prt),
+    [] = flush(),
+
+    ok.
+
+%% Test that driver_set_timer generate correct trace messages
+set_timer(_Config) ->
+
+    Flags = [send,'receive'],
+    {Prt, S} = trace_and_open(Flags,[binary]),
+
+    erlang:port_command(Prt, <<?ECHO_DRV_SET_TIMER>>),
+    timer:sleep(100),
+    [{trace, Prt, 'receive', {S, {command, <<?ECHO_DRV_SET_TIMER>>}}},
+     {trace, Prt, 'receive', timeout}] = flush(),
+
+    close(Prt, Flags),
+
+    ok.
+
+%% Test that driver_failure* generate correct trace messages
+failure_eof(_Config) ->
+
+    Flags = [send,'receive', ports],
+    S = trace_ports(Flags),
+
+    Prt = erlang:open_port({spawn, echo_drv}, [eof, binary]),
+    [{trace, Prt, open, S, echo_drv},
+     {trace, Prt, getting_linked, S}] = flush(),
+
+    erlang:port_command(Prt, <<?ECHO_DRV_FAILURE_EOF>>),
+    recv({Prt,eof}),
+    [{trace, Prt, 'receive', {S, {command, <<?ECHO_DRV_FAILURE_EOF>>}}},
+     {trace, Prt, send, {Prt, eof}, S}] = flush(),
+
+    close(Prt, Flags),
+
+    %% Run same test without eof option
+    failure_test(<<?ECHO_DRV_FAILURE_EOF>>, normal).
+
+failure_atom(_Config) ->
+    failure_test(<<?ECHO_DRV_FAILURE_ATOM, "failure\0">>, failure).
+failure_posix(_Config) ->
+    failure_test(<<?ECHO_DRV_FAILURE_POSIX>>, eagain).
+failure(_Config) ->
+    failure_test(<<?ECHO_DRV_FAILURE, 1>>, 1).
+
+failure_test(Failure, Reason) ->
+
+    {Prt, S} = trace_and_open([send, 'receive', ports],[binary]),
+
+    [{trace, Prt, open, S, echo_drv},
+     {trace, Prt, getting_linked, S}] = flush(),
+
+    process_flag(trap_exit, true),
+    erlang:port_command(Prt, Failure),
+    try
+        recv({'EXIT',Prt,Reason})
+    after
+        process_flag(trap_exit, false)
+    end,
+    [{trace, Prt, 'receive', {S, {command, Failure}}},
+     {trace, Prt, closed, Reason},
+     {trace, Prt, unlink, S}] = flush(),
+
+    ok.
+
+%% Test that erl_drv_output_term generate correct trace messages
+output_term(_Config) ->
+
+    Flags = [send],
+    {Prt, S} = trace_and_open(Flags,[binary]),
+
+    erlang:port_command(Prt, <<?ECHO_DRV_OUTPUT_TERM, 123456:32>>),
+    recv({echo, Prt, <<123456:32>>}),
+    [{trace, Prt, send, {echo, Prt, <<123456:32>>}, S}] = flush(),
+
+    close(Prt, Flags),
+
+    ok.
+
+%% Test that driver_output_term generate correct trace messages
+driver_output_term(_Config) ->
+
+    Flags = [send],
+    {Prt, S} = trace_and_open(Flags,[binary]),
+
+    erlang:port_command(Prt, <<?ECHO_DRV_DRIVER_OUTPUT_TERM, 123456:32>>),
+    recv({echo, Prt, <<123456:32>>}),
+    [{trace, Prt, send, {echo, Prt, <<123456:32>>}, S}] = flush(),
+
+    close(Prt, Flags),
+
+    ok.
+
+%% Test that erl_drv_send_term generate correct trace messages
+send_term(_Config) ->
+
+    Flags = [send],
+    {Prt, S} = trace_and_open(Flags,[binary]),
+
+    erlang:port_command(Prt, <<?ECHO_DRV_SEND_TERM, 123456:32>>),
+    recv({echo, Prt, <<123456:32>>}),
+    [{trace, Prt, send, {echo, Prt, <<123456:32>>}, S}] = flush(),
+
+    {Pid, Ref} = spawn_monitor(fun() -> erlang:port_command(Prt, <<?ECHO_DRV_SAVE_CALLER>>) end),
+    recv({'DOWN',Ref,process,Pid,normal}),
+    erlang:port_command(Prt, <<?ECHO_DRV_SEND_TERM, 123456:32>>),
+    [{trace, Prt, send_to_non_existing_process, {echo, Prt, <<123456:32>>}, Pid}] = flush(),
+
+    close(Prt, Flags),
+
+    ok.
+
+%% Test that driver_send_term generate correct trace messages
+driver_send_term(_Config) ->
+
+    Flags = [send],
+    {Prt, S} = trace_and_open(Flags,[binary]),
+
+    erlang:port_command(Prt, <<?ECHO_DRV_DRIVER_SEND_TERM, 123456:32>>),
+    recv({echo, Prt, <<123456:32>>}),
+    [{trace, Prt, send, {echo, Prt, <<123456:32>>}, S}] = flush(),
+
+    {Pid, Ref} = spawn_monitor(fun() -> erlang:port_command(Prt, <<?ECHO_DRV_SAVE_CALLER>>) end),
+    recv({'DOWN',Ref,process,Pid,normal}),
+    erlang:port_command(Prt, <<?ECHO_DRV_SEND_TERM, 123456:32>>),
+    [{trace, Prt, send_to_non_existing_process, {echo, Prt, <<123456:32>>}, Pid}] = flush(),
+
+    close(Prt, Flags),
+
+    ok.
+
+%%%%%%%%%%%%%%%%%%%
+%% Helper functions
+%%%%%%%%%%%%%%%%%%%
+
+trace_ports(TraceFlags) ->
+    erlang:trace(new_ports, true, TraceFlags),
+    self().
+
+trace_and_open(TraceFlags, OpenFlags) ->
+    S = self(),
+    Ports = proplists:get_value(ports, TraceFlags),
+    [trace_ports(TraceFlags) || Ports],
+    Prt = erlang:open_port({spawn, echo_drv}, OpenFlags),
+    [erlang:trace(Prt, true, TraceFlags) || Ports == undefined],
+    {Prt, S}.
+
+close(Prt, Flags) ->
+    Recv = proplists:get_value('receive', Flags),
+    Ports = proplists:get_value(ports, Flags),
+    S = self(),
+
+    erlang:port_close(Prt),
+
+    if Recv, Ports ->
+            [{trace, Prt, 'receive', {S, close}},
+             {trace, Prt, closed, normal},
+             {trace, Prt, unlink, S}] = flush();
+       Recv ->
+            [{trace, Prt, 'receive', {S, close}}] = flush();
+       Ports ->
+            [{trace, Prt, closed, normal},
+             {trace, Prt, unlink, S}] = flush();
+       true ->
+            [] = flush()
+    end.
+
+trace_delivered() ->
+    Ref = erlang:trace_delivered(all),
+    receive {trace_delivered, all, Ref} -> ok end.
+
+flush() ->
+    flush(all).
+flush(From) ->
+    trace_delivered(),
+    f(From).
+
+f(From) ->
+    receive
+        M when From =:= all; element(2, M) == From ->
+            [M | f(From)]
+    after 0 ->
+            []
+    end.
+
+recv(Msg) ->
+    receive Msg -> ok after 100 -> ct:fail({did_not_get_data,Msg,flush()}) end.
+
+load_drv(Config) ->
+    Path = proplists:get_value(data_dir, Config),
+    case erl_ddll:load_driver(Path, echo_drv) of
+        ok -> ok;
+        {error, Error} = Res ->
+            io:format("~s\n", [erl_ddll:format_error(Error)]),
+	    ct:fail(Res)
+    end.
+
+reload_drv(Config) ->
+    erl_ddll:unload_driver(echo_drv),
+    load_drv(Config).
diff --git a/erts/emulator/test/port_trace_SUITE_data/Makefile.src b/erts/emulator/test/port_trace_SUITE_data/Makefile.src
new file mode 100644
index 0000000000..c1bf142ccf
--- /dev/null
+++ b/erts/emulator/test/port_trace_SUITE_data/Makefile.src
@@ -0,0 +1,3 @@
+all: echo_drv@dll@
+
+@SHLIB_RULES@
diff --git a/erts/emulator/test/port_trace_SUITE_data/echo_drv.c b/erts/emulator/test/port_trace_SUITE_data/echo_drv.c
new file mode 100644
index 0000000000..b5728bc170
--- /dev/null
+++ b/erts/emulator/test/port_trace_SUITE_data/echo_drv.c
@@ -0,0 +1,237 @@
+#include <stdio.h>
+#include "erl_driver.h"
+#include <errno.h>
+#include <string.h>
+
+
+/* -------------------------------------------------------------------------
+** Data types
+**/
+
+
+typedef struct _erl_drv_data {
+    ErlDrvPort   erlang_port;
+    ErlDrvTermData caller;
+} EchoDrvData;
+
+#define ECHO_DRV_NOOP                 0
+#define ECHO_DRV_OUTPUT               1
+#define ECHO_DRV_OUTPUT2              2
+#define ECHO_DRV_OUTPUT_BINARY        3
+#define ECHO_DRV_OUTPUTV              4
+#define ECHO_DRV_SET_TIMER            5
+#define ECHO_DRV_FAILURE_EOF          6
+#define ECHO_DRV_FAILURE_ATOM         7
+#define ECHO_DRV_FAILURE_POSIX        8
+#define ECHO_DRV_FAILURE              9
+#define ECHO_DRV_OUTPUT_TERM         10
+#define ECHO_DRV_DRIVER_OUTPUT_TERM  11
+#define ECHO_DRV_SEND_TERM           12
+#define ECHO_DRV_DRIVER_SEND_TERM    13
+#define ECHO_DRV_SAVE_CALLER         14
+
+
+/* -------------------------------------------------------------------------
+** Entry struct
+**/
+
+static EchoDrvData *echo_drv_start(ErlDrvPort port, char *command);
+static void         echo_drv_stop(ErlDrvData drv_data);
+static void         echo_drv_output(ErlDrvData drv_data, char *buf,
+				    ErlDrvSizeT len);
+static void         echo_drv_outputv(ErlDrvData drv_data, ErlIOVec *iov);
+static void         echo_drv_finish(void);
+static ErlDrvSSizeT echo_drv_control(ErlDrvData drv_data,
+				     unsigned int command,
+				     char *buf,  ErlDrvSizeT len,
+				     char **rbuf, ErlDrvSizeT rlen);
+static void echo_drv_timeout(ErlDrvData drv_data);
+static ErlDrvSSizeT echo_drv_call(ErlDrvData drv_data,
+                                  unsigned int command,
+                                  char *buf, ErlDrvSizeT len,
+                                  char **rbuf, ErlDrvSizeT rlen,
+                                  unsigned int *flags);
+
+static ErlDrvEntry echo_drv_entry = {
+    NULL, /* init */
+    echo_drv_start,
+    echo_drv_stop,
+    echo_drv_output,
+    NULL, /* ready_input */
+    NULL, /* ready_output */
+    "echo_drv",
+    echo_drv_finish,
+    NULL, /* handle */
+    echo_drv_control,
+    echo_drv_timeout, /* timeout */
+    NULL, /* outputv */
+    NULL, /* ready_async */
+    NULL, /* flush */
+    echo_drv_call, /* call */
+    NULL, /* event */
+    ERL_DRV_EXTENDED_MARKER,
+    ERL_DRV_EXTENDED_MAJOR_VERSION,
+    ERL_DRV_EXTENDED_MINOR_VERSION,
+    0,
+    NULL,
+    NULL,
+    NULL
+};
+
+/* -------------------------------------------------------------------------
+** Entry functions
+**/
+
+DRIVER_INIT(echo_drv)
+{
+    char buff[5];
+    size_t size = sizeof(buff);
+
+    if (erl_drv_getenv("OUTPUTV", buff, &size) == -1) {
+        echo_drv_entry.outputv = NULL;
+    } else {
+        echo_drv_entry.outputv = echo_drv_outputv;
+    }
+
+    return &echo_drv_entry;
+}
+
+static EchoDrvData *echo_drv_start(ErlDrvPort port, char *command)
+{
+    EchoDrvData *echo_drv_data_p = driver_alloc(sizeof(EchoDrvData));
+    echo_drv_data_p->erlang_port = port;
+    echo_drv_data_p->caller = driver_caller(port);
+    return echo_drv_data_p;
+}
+
+static void echo_drv_stop(EchoDrvData *data_p) {
+    driver_free(data_p);
+}
+
+static void echo_drv_outputv(ErlDrvData drv_data, ErlIOVec *iov)
+{
+    return;
+}
+
+static void echo_drv_output(ErlDrvData drv_data, char *buf, ErlDrvSizeT len) {
+    EchoDrvData* data_p = (EchoDrvData *) drv_data;
+    ErlDrvPort port = data_p->erlang_port;
+
+    switch (buf[0]) {
+    case ECHO_DRV_OUTPUT:
+    {
+        driver_output(port, buf+1, len-1);
+        break;
+    }
+    case ECHO_DRV_OUTPUT2:
+    {
+         driver_output2(port, "a", 1, buf+1, len-1);
+         break;
+    }
+    case ECHO_DRV_OUTPUT_BINARY:
+    {
+        ErlDrvBinary *bin = driver_alloc_binary(len-1);
+        memcpy(&bin->orig_bytes, buf+1, len-1);
+        driver_output_binary(port, "a", 1, bin, 1, len - 2);
+        driver_free_binary(bin);
+        break;
+    }
+    case ECHO_DRV_OUTPUTV:
+    {
+        ErlIOVec iov;
+        ErlDrvSizeT sz;
+        driver_enq(port, buf + 1, len - 1);
+        sz = driver_peekqv(port, &iov);
+        driver_outputv(port, "a", 1, &iov, 0);
+        driver_deq(port, sz);
+        break;
+    }
+    case ECHO_DRV_SET_TIMER:
+    {
+        driver_set_timer(port, 10);
+        break;
+    }
+    case ECHO_DRV_FAILURE_EOF:
+    {
+        driver_failure_eof(port);
+        break;
+    }
+    case ECHO_DRV_FAILURE_ATOM:
+    {
+        driver_failure_atom(port, buf+1);
+        break;
+    }
+    case ECHO_DRV_FAILURE_POSIX:
+    {
+        driver_failure_posix(port, EAGAIN);
+        break;
+    }
+    case ECHO_DRV_FAILURE:
+    {
+        driver_failure(port, buf[1]);
+        break;
+    }
+    case ECHO_DRV_OUTPUT_TERM:
+    case ECHO_DRV_DRIVER_OUTPUT_TERM:
+    case ECHO_DRV_SEND_TERM:
+    case ECHO_DRV_DRIVER_SEND_TERM:
+    {
+        ErlDrvTermData term[] = {
+            ERL_DRV_ATOM, driver_mk_atom("echo"),
+            ERL_DRV_PORT, driver_mk_port(port),
+            ERL_DRV_BUF2BINARY, (ErlDrvTermData)(buf+1),
+                                (ErlDrvTermData)(len - 1),
+            ERL_DRV_TUPLE, 3};
+        switch (buf[0]) {
+        case ECHO_DRV_OUTPUT_TERM:
+            erl_drv_output_term(driver_mk_port(port), term, sizeof(term) / sizeof(ErlDrvTermData));
+            break;
+        case ECHO_DRV_DRIVER_OUTPUT_TERM:
+            driver_output_term(port, term, sizeof(term) / sizeof(ErlDrvTermData));
+            break;
+        case ECHO_DRV_SEND_TERM:
+            driver_send_term(port, data_p->caller,
+                             term, sizeof(term) / sizeof(ErlDrvTermData));
+            break;
+        case ECHO_DRV_DRIVER_SEND_TERM:
+            erl_drv_send_term(driver_mk_port(port), data_p->caller,
+                              term, sizeof(term) / sizeof(ErlDrvTermData));
+            break;
+        }
+        break;
+    }
+    case ECHO_DRV_SAVE_CALLER:
+        data_p->caller = driver_caller(port);
+        break;
+    default:
+        break;
+    }
+}
+
+static void echo_drv_finish() {
+
+}
+
+static ErlDrvSSizeT echo_drv_control(ErlDrvData drv_data,
+				     unsigned int command,
+				     char *buf, ErlDrvSizeT len,
+				     char **rbuf, ErlDrvSizeT rlen)
+{
+    memcpy(*rbuf, buf+1, len-1);
+    return len-1;
+}
+
+static void echo_drv_timeout(ErlDrvData drv_data)
+{
+
+}
+
+static ErlDrvSSizeT echo_drv_call(ErlDrvData drv_data,
+                                  unsigned int command,
+                                  char *buf, ErlDrvSizeT len,
+                                  char **rbuf, ErlDrvSizeT rlen,
+                                  unsigned int *flags)
+{
+    memcpy(*rbuf, buf+command, len-command);
+    return len-command;
+}
diff --git a/erts/emulator/test/trace_port_SUITE.erl b/erts/emulator/test/trace_port_SUITE.erl
index 98dc96bfa7..838b5093f4 100644
--- a/erts/emulator/test/trace_port_SUITE.erl
+++ b/erts/emulator/test/trace_port_SUITE.erl
@@ -440,7 +440,7 @@ default_tracer(Config) when is_list(Config) ->
     {tracer, []} = erlang:trace_info(G1, tracer),
     G1 ! {apply,{erlang,exit,[normal]}},
     io:format("~p = ~p.~n", [M, N]),
-    M = N,
+    M = N - 1, % G1 has been started, but Tracer and Port have died
     ok.
 
 tracer_port_crash(Config) when is_list(Config) ->