Simplify get_flag() and get_flag_list()

The get_flag/3 function which returns a default value if the
flag doesn't exist, is implemented in terms of get_flag/2
which throws an exception if the flag doesn't exist.

get_flag/3 is frequently used for the flags that don't exist,
which means that means that an exception will be generated and
catched for no good reason.

Reimplement get_flag/3 so that it doesn't have to call get_flag/2
and catch an exception. Eliminate the get_flag/2 function by
writing a special purpose function for the only time it's used,
that is for retrieving the value for the -root flag. As a
side-effect, we will get a nicer error message if there is
something wrong with the -root flag.

Similarly, simplify get_flag_list/3 and remove get_flag_list/2.

We can also eliminate search/3 and use the lists:keyfind/3
BIF instead.

1 files changed, 19 insertions, 34 deletions

diff --git a/erts/preloaded/src/init.erl b/erts/preloaded/src/init.erl
index b166aba81d..a85b41fddb 100644
--- a/erts/preloaded/src/init.erl
+++ b/erts/preloaded/src/init.erl
@@ -724,7 +724,7 @@ do_boot(Flags,Start) ->
 do_boot(Init,Flags,Start) ->
     process_flag(trap_exit,true),
     {Pgm0,Nodes,Id,Path} = prim_load_flags(Flags),
-    Root = b2s(get_flag(root, Flags)),
+    Root = get_root(Flags),
     PathFls = path_flags(Flags),
     Pgm = b2s(Pgm0),
     _Pid = start_prim_loader(Init,b2a(Id),Pgm,bs2as(Nodes),
@@ -748,6 +748,14 @@ do_boot(Init,Flags,Start) ->
 
     start_em(Start).
 
+get_root(Flags) ->
+    case get_argument(root, Flags) of
+	{ok,[[Root]]} ->
+	    Root;
+	_ ->
+	    exit(no_or_multiple_root_variables)
+    end.
+
 bootfile(Flags,Root) ->
     b2s(get_flag(boot, Flags, concat([Root,"/bin/start"]))).
 
@@ -1180,44 +1188,28 @@ get_args([], As) -> {reverse(As),[]}.
 %%         atom() if a single arg was given.
 %%         list(atom()) if several args were given.
 %%
-get_flag(F,Flags,Default) ->
-    case catch get_flag(F,Flags) of
-	{'EXIT',_} ->
-	    Default;
-	Value ->
-	    Value
-    end.
-
-get_flag(F,Flags) ->
-    case search(F,Flags) of
-	{value,{F,[]}} ->
+get_flag(F, Flags, Default) ->
+    case lists:keyfind(F, 1, Flags) of
+	{F,[]} ->
 	    true;
-	{value,{F,[V]}} ->
+	{F,[V]} ->
 	    V;
-	{value,{F,V}} ->
+	{F,V} ->
 	    V;
 	_ ->
-	    exit(list_to_atom(concat(["no ",F," flag"])))
+	    Default
     end.
 
 %%
 %% Internal get_flag function, with default value.
 %% Return: list(atom()) 
 %%
-get_flag_list(F,Flags,Default) ->
-    case catch get_flag_list(F,Flags) of
-	{'EXIT',_} ->
-	    Default;
-	Value ->
-	    Value
-    end.
-
-get_flag_list(F,Flags) ->
-    case search(F,Flags) of
-	{value,{F,V}} ->
+get_flag_list(F, Flags, Default) ->
+    case lists:keyfind(F, 1, Flags) of
+	{F,[_|_]=V} ->
 	    V;
 	_ ->
-	    exit(list_to_atom(concat(["no ",F," flag"])))
+	    Default
     end.
 
 %%
@@ -1290,13 +1282,6 @@ reverse([A, B]) ->
 reverse([A, B | L]) ->
     lists:reverse(L, [B, A]). % BIF
 			
-search(Key, [H|_T]) when is_tuple(H), element(1, H) =:= Key ->
-    {value, H};
-search(Key, [_|T]) ->
-    search(Key, T);
-search(_Key, []) ->
-    false.
-
 -spec objfile_extension() -> nonempty_string().
 objfile_extension() ->
     ".beam".