Fix broken handling of default values for BIT STRINGs

For DER/PER/UPER, a value equal to the DEFAULT is not supposed to
be encoded.

BIT STRINGs values can be represented as Erlang terms in four
different ways: as an integer, as a list of zeroes and ones,
as a {Unused,Binary} tuple, or as an Erlang bitstring.

When encoding a BIT STRING, only certain representations of
BIT STRINGs values were recognized. All representations must
be recognized.

When decoding a DEFAULT value for a BIT STRING, the actual value
given in the decoding would be either an integer or a list
of zeroes and one (depending on how the literal was written in
the specification). We expect that the default value should be
in the same representation as any other BIT STRING value (i.e.
by default an Erlang bitstring, or a list if the 'legacy_bitstring'
option has been given, or as compact bitstring if 'compact_bitstring'
has been given).

1 files changed, 41 insertions, 0 deletions

diff --git a/lib/asn1/src/asn1rtt_per_common.erl b/lib/asn1/src/asn1rtt_per_common.erl
index 9e9fd87ec3..3309e6a4ca 100644
--- a/lib/asn1/src/asn1rtt_per_common.erl
+++ b/lib/asn1/src/asn1rtt_per_common.erl
@@ -37,6 +37,7 @@
 	 bitstring_from_positions/1,bitstring_from_positions/2,
 	 to_bitstring/1,to_bitstring/2,
 	 to_named_bitstring/1,to_named_bitstring/2,
+	 is_default_bitstring/5,
 	 extension_bitmap/3]).
 
 -define('16K',16384).
@@ -271,6 +272,36 @@ to_named_bitstring(Val, Lb) ->
     %% for correctness, not speed.
     adjust_trailing_zeroes(to_bitstring(Val), Lb).
 
+is_default_bitstring(asn1_DEFAULT, _, _, _, _) ->
+    true;
+is_default_bitstring({Unused,Bin}, V0, V1, V2, V3) when is_integer(Unused) ->
+    %% Convert compact bitstring to a bitstring.
+    Sz = bit_size(Bin) - Unused,
+    <<Bs:Sz/bitstring,_:Unused>> = Bin,
+    is_default_bitstring(Bs, V0, V1, V2, V3);
+is_default_bitstring(Named, Named, _, _, _) ->
+    true;
+is_default_bitstring(Bs, _, Bs, _, _) ->
+    true;
+is_default_bitstring(List, _, _, List, _) ->
+    true;
+is_default_bitstring(Int, _, _, _, Int) ->
+    true;
+is_default_bitstring(Val, _, Def, _, _) when is_bitstring(Val) ->
+    Sz = bit_size(Def),
+    case Val of
+	<<Def:Sz/bitstring,T/bitstring>> ->
+	    NumZeroes = bit_size(T),
+	    case T of
+		<<0:NumZeroes>> -> true;
+		_ -> false
+	    end;
+	_ ->
+	    false
+    end;
+is_default_bitstring(Val, _, _, List, _) when is_list(Val) ->
+    is_default_bitstring_list(List, Val);
+is_default_bitstring(_, _, _, _, _) -> false.
 
 extension_bitmap(Val, Pos, Limit) ->
     extension_bitmap(Val, Pos, Limit, 0).
@@ -447,6 +478,16 @@ ntz(Byte) ->
 	 4,0,1,0,2,0,1,0,3,0,1,0,2,0,1,0},
     element(Byte+1, T).
 
+is_default_bitstring_list([H|Def], [H|Val]) ->
+    is_default_bitstring_list(Def, Val);
+is_default_bitstring_list([], []) ->
+    true;
+is_default_bitstring_list([], [_|_]=Val) ->
+    lists:all(fun(0) -> true;
+		 (_) -> false
+	      end, Val);
+is_default_bitstring_list(_, _) -> false.
+
 extension_bitmap(_Val, Pos, Limit, Acc) when Pos >= Limit ->
     Acc;
 extension_bitmap(Val, Pos, Limit, Acc) ->