BER: Inline testing of constraints when decoding

Calling library routines for validation of constraints may cause
dialyzer warnings if some type of constraints handled by the library
routine are not used in a specific ASN.1 module. To avoid those
warnings (and slightly speed up the decoding), inline the constraint
checking.

2 files changed, 134 insertions, 125 deletions

diff --git a/lib/asn1/src/asn1ct_gen_ber_bin_v2.erl b/lib/asn1/src/asn1ct_gen_ber_bin_v2.erl
index 09cb7c0628..6db31c5ea2 100644
--- a/lib/asn1/src/asn1ct_gen_ber_bin_v2.erl
+++ b/lib/asn1/src/asn1ct_gen_ber_bin_v2.erl
@@ -492,6 +492,11 @@ gen_dec_prim(Att, BytesVar, DoTag) ->
 		      'ObjectDescriptor'-> restricted_string;
 		      'UTCTime'         -> restricted_string;
 		      'GeneralizedTime' -> restricted_string;
+		      'OCTET STRING'    ->
+			  case asn1ct:use_legacy_types() of
+			      true -> restricted_string;
+			      false -> Typename
+			  end;
 		      _                 -> Typename
 		  end,
     TagStr = case DoTag of
@@ -502,26 +507,23 @@ gen_dec_prim(Att, BytesVar, DoTag) ->
 	'BOOLEAN'->
 	    call(decode_boolean, [BytesVar,TagStr]);
 	'INTEGER' ->
-	    case IntConstr of
-		[] ->
-		    call(decode_integer, [BytesVar,TagStr]);
-		{_,_} ->
-		    call(decode_integer, [BytesVar,{asis,IntConstr},TagStr])
-	    end;
-	{'INTEGER',NamedNumberList} ->
-	    case IntConstr of
-		[] ->
-		    call(decode_named_integer,
-			 [BytesVar,
-			  {asis,NamedNumberList},
-			  TagStr]);
-		{_,_} ->
-		    call(decode_named_integer,
-			 [BytesVar,
-			  {asis,IntConstr},
-			  {asis,NamedNumberList},
-			  TagStr])
-	    end;
+	    check_constraint(decode_integer, [BytesVar,TagStr],
+			     IntConstr,
+			     identity,
+			     identity);
+	{'INTEGER',NNL} ->
+	    check_constraint(decode_integer,
+			     [BytesVar,TagStr],
+			     IntConstr,
+			     identity,
+			     fun(Val) ->
+				     asn1ct_name:new(val),
+				     emit([{curr,val}," = "]),
+				     Val(),
+				     emit([com,nl,
+					   {call,ber,number2name,
+					    [{curr,val},{asis,NNL}]}])
+			     end);
 	{'ENUMERATED',NNL} ->
 	    call(decode_enumerated, [BytesVar,{asis,NNL},TagStr]);
 	'REAL' ->
@@ -540,32 +542,25 @@ gen_dec_prim(Att, BytesVar, DoTag) ->
 	'RELATIVE-OID' ->
 	    call(decode_relative_oid, [BytesVar,TagStr]);
 	'OCTET STRING' ->
-	    F = case asn1ct:use_legacy_types() of
-		    false -> decode_octet_string;
-		    true -> decode_restricted_string
-		end,
-	    case Constraint of
-		[] ->
-		    call(F, [BytesVar,TagStr]);
-		_ ->
-		    call(F, [BytesVar,{asis,Constraint},TagStr])
-	    end;
+	    check_constraint(decode_octet_string, [BytesVar,TagStr],
+			     Constraint, {erlang,byte_size}, identity);
 	restricted_string ->
-	    case Constraint of
-		[] ->
-		    call(decode_restricted_string,
-			 [BytesVar,TagStr]);
-		_ ->
-		    call(decode_restricted_string,
-			 [BytesVar,{asis,Constraint},TagStr])
-	    end;
+	    check_constraint(decode_restricted_string, [BytesVar,TagStr],
+			     Constraint,
+			     {erlang,byte_size},
+			     fun(Val) ->
+				     emit("binary_to_list("),
+				     Val(),
+				     emit(")")
+			     end);
 	'UniversalString' ->
-	    call(decode_universal_string,
-		 [BytesVar,{asis,Constraint},TagStr]);
+	    check_constraint(decode_universal_string, [BytesVar,TagStr],
+			     Constraint, {erlang,length}, identity);
 	'UTF8String' ->
 	    call(decode_UTF8_string, [BytesVar,TagStr]);
 	'BMPString' ->
-	    call(decode_BMP_string, [BytesVar,{asis,Constraint},TagStr]);
+	    check_constraint(decode_BMP_string, [BytesVar,TagStr],
+			     Constraint, {erlang,length}, identity);
 	'ASN1_OPEN_TYPE' ->
 	    call(decode_open_type_as_binary, [BytesVar,TagStr])
     end.
@@ -583,7 +578,7 @@ int_constr(C) ->
 	[{'ValueRange',{_,_}=Range}] ->
 	    Range;
 	[{'SingleValue',Sv}] ->
-	    {Sv,Sv};
+	    Sv;
 	[] ->
 	    []
     end.
@@ -594,16 +589,82 @@ gen_dec_bit_string(BytesVar, _Constraint, [_|_]=NNL, TagStr) ->
 gen_dec_bit_string(BytesVar, Constraint, [], TagStr) ->
     case asn1ct:get_bit_string_format() of
 	compact ->
-	    call(decode_compact_bit_string,
-		 [BytesVar,{asis,Constraint},TagStr]);
+	    check_constraint(decode_compact_bit_string,
+			     [BytesVar,TagStr],
+			     Constraint,
+			     {ber,compact_bit_string_size},
+			     identity);
 	legacy ->
-	    call(decode_legacy_bit_string,
-		 [BytesVar,{asis,Constraint},TagStr]);
+	    check_constraint(decode_native_bit_string,
+			     [BytesVar,TagStr],
+			     Constraint,
+			     {erlang,bit_size},
+			     fun(Val) ->
+				     asn1ct_name:new(val),
+				     emit([{curr,val}," = "]),
+				     Val(),
+				     emit([com,nl,
+					   {call,ber,native_to_legacy_bit_string,
+					    [{curr,val}]}])
+			     end);
 	bitstring ->
-	    call(decode_native_bit_string,
-		 [BytesVar,{asis,Constraint},TagStr])
+	    check_constraint(decode_native_bit_string,
+			     [BytesVar,TagStr],
+			     Constraint,
+			     {erlang,bit_size},
+			     identity)
     end.
 
+check_constraint(F, Args, Constr, PreConstr0, ReturnVal0) ->
+    PreConstr = case PreConstr0 of
+		    identity ->
+			fun(V) -> V end;
+		    {Mod,Name} ->
+			fun(V) ->
+				asn1ct_name:new(c),
+				emit([{curr,c}," = ",
+				      {call,Mod,Name,[V]},com,nl]),
+				{curr,c}
+			end
+		end,
+    ReturnVal = case ReturnVal0 of
+		    identity ->	fun(Val) -> Val() end;
+		    _ -> ReturnVal0
+		end,
+    case Constr of
+	[] when ReturnVal0 =:= identity ->
+	    %% No constraint, no complications.
+	    call(F, Args);
+	[] ->
+	    %% No constraint, but the return value could consist
+	    %% of more than one statement.
+	    emit(["begin",nl]),
+	    ReturnVal(fun() -> call(F, Args) end),
+	    emit([nl,
+		  "end",nl]);
+	_ ->
+	    %% There is a constraint.
+	    asn1ct_name:new(val),
+	    emit(["begin",nl,
+		  {curr,val}," = ",{call,ber,F,Args},com,nl]),
+	    PreVal0 = asn1ct_gen:mk_var(asn1ct_name:curr(val)),
+	    PreVal = PreConstr(PreVal0),
+	    emit("if "),
+	    case Constr of
+		{Min,Max} ->
+		    emit([{asis,Min}," =< ",PreVal,", ",
+			  PreVal," =< ",{asis,Max}]);
+		Sv when is_integer(Sv) ->
+		    emit([PreVal," =:= ",{asis,Sv}])
+	    end,
+	    emit([" ->",nl]),
+	    ReturnVal(fun() -> emit(PreVal0) end),
+	    emit([";",nl,
+		  "true ->",nl,
+		  "exit({error,{asn1,bad_range}})",nl,
+		  "end",nl,
+		 "end"])
+    end.
     
 %% Object code generating for encoding and decoding
 %% ------------------------------------------------
diff --git a/lib/asn1/src/asn1rtt_ber.erl b/lib/asn1/src/asn1rtt_ber.erl
index 4bd814769f..c65e7dea11 100644
--- a/lib/asn1/src/asn1rtt_ber.erl
+++ b/lib/asn1/src/asn1rtt_ber.erl
@@ -26,25 +26,25 @@
 	 skip_ExtensionAdditions/2]).
 -export([encode_boolean/2,decode_boolean/2,
 	 encode_integer/2,encode_integer/3,
-	 decode_integer/2,decode_integer/3,
-	 decode_named_integer/3,decode_named_integer/4,
+	 decode_integer/2,
+	 number2name/2,
 	 encode_enumerated/2,decode_enumerated/3,
 	 encode_unnamed_bit_string/2,encode_unnamed_bit_string/3,
 	 encode_named_bit_string/3,encode_named_bit_string/4,
 	 encode_bit_string/4,
 	 decode_named_bit_string/3,
-	 decode_compact_bit_string/3,
-	 decode_legacy_bit_string/3,
-	 decode_native_bit_string/3,
+	 decode_compact_bit_string/2,compact_bit_string_size/1,
+	 decode_native_bit_string/2,
+	 native_to_legacy_bit_string/1,
 	 encode_null/2,decode_null/2,
 	 encode_relative_oid/2,decode_relative_oid/2,
 	 encode_object_identifier/2,decode_object_identifier/2,
 	 encode_restricted_string/2,
-	 decode_octet_string/2,decode_octet_string/3,
-	 decode_restricted_string/2,decode_restricted_string/3,
-	 encode_universal_string/2,decode_universal_string/3,
+	 decode_octet_string/2,
+	 decode_restricted_string/2,
+	 encode_universal_string/2,decode_universal_string/2,
 	 encode_UTF8_string/2,decode_UTF8_string/2,
-	 encode_BMP_string/2,decode_BMP_string/3]).
+	 encode_BMP_string/2,decode_BMP_string/2]).
 
 -export([encode_open_type/2,decode_open_type/2,
 	 decode_open_type_as_binary/2]).
@@ -697,41 +697,17 @@ encode_integer_neg(N, Acc) ->
 
 %%===============================================================================
 %% decode integer
-%%    (Buffer, Range, HasTag, TotalLen) -> {Integer, Remain, RemovedBytes}
-%%    (Buffer, Range, NamedNumberList, HasTag, TotalLen) -> {Integer, Remain, RemovedBytes}
 %%===============================================================================
 
-decode_named_integer(Tlv, NamedNumberList, TagIn) ->
-    V = match_tags(Tlv, TagIn),
-    Int = decode_integer(V),
-    number2name(Int, NamedNumberList).
-
-decode_named_integer(Tlv, Range, NamedNumberList, TagIn) ->
-    V = match_tags(Tlv, TagIn),
-    Int = range_check_integer(decode_integer(V), Range),
-    number2name(Int, NamedNumberList).
-
 decode_integer(Tlv, TagIn) ->
     V = match_tags(Tlv, TagIn),
     decode_integer(V).
 
-decode_integer(Tlv, Range, TagIn) ->
-    V = match_tags(Tlv, TagIn),
-    Int = decode_integer(V),
-    range_check_integer(Int, Range).
-
 decode_integer(Bin) ->
     Len = byte_size(Bin),
     <<Int:Len/signed-unit:8>> = Bin,
     Int.
 
-range_check_integer(Int, {Lb,Ub}) when Lb =< Int, Int =< Ub ->
-    Int;
-range_check_integer(Int, Range) ->
-    exit({error,{asn1,{integer_range,Range,Int}}}).
-
-number2name(Int, []) ->
-    Int;
 number2name(Int, NamedNumberList) ->
     case lists:keyfind(Int, 2, NamedNumberList) of
 	{NamedVal,_} ->
@@ -1098,33 +1074,23 @@ unused_bitlist([Bit | Rest], Trail, Ack) ->
 %% decode bitstring value
 %%============================================================================
 
-decode_compact_bit_string(Buffer, Range, Tags) ->
+decode_compact_bit_string(Buffer, Tags) ->
     case match_and_collect(Buffer, Tags) of
-	<<0>> ->
-	    check_restricted_string({0,<<>>}, 0, Range);
-	<<Unused,Bits/binary>> ->
-	    Val = {Unused,Bits},
-	    Len = bit_size(Bits) - Unused,
-	    check_restricted_string(Val, Len, Range)
+	<<0>> -> {0,<<>>};
+	<<Unused,Bits/binary>> -> {Unused,Bits}
     end.
 
-decode_legacy_bit_string(Buffer, Range, Tags) ->
-    Val = case match_and_collect(Buffer, Tags) of
-	      <<0>> ->
-		  [];
-	      <<Unused,Bits/binary>> ->
-		  decode_bitstring2(byte_size(Bits), Unused, Bits)
-	  end,
-    check_restricted_string(Val, length(Val), Range).
+compact_bit_string_size({Unused,Bits}) ->
+    bit_size(Bits) - Unused.
 
-decode_native_bit_string(Buffer, Range, Tags) ->
+decode_native_bit_string(Buffer, Tags) ->
     case match_and_collect(Buffer, Tags) of
 	<<0>> ->
-	    check_restricted_string(<<>>, 0, Range);
+	    <<>>;
 	<<Unused,Bits/binary>> ->
 	    Size = bit_size(Bits) - Unused,
 	    <<Val:Size/bitstring,_:Unused/bitstring>> = Bits,
-	    check_restricted_string(Val, Size, Range)
+	    Val
     end.
 
 decode_named_bit_string(Buffer, NamedNumberList, Tags) ->
@@ -1147,6 +1113,9 @@ decode_bitstring2(Len, Unused,
     [B7,B6,B5,B4,B3,B2,B1,B0|
      decode_bitstring2(Len - 1, Unused, Buffer)].
 
+native_to_legacy_bit_string(Bits) ->
+    [B || <<B:1>> <= Bits].
+
 %%----------------------------------------
 %% Decode the bitlist to names
 %%----------------------------------------
@@ -1310,31 +1279,12 @@ decode_octet_string(Tlv, TagsIn) ->
     Bin = match_and_collect(Tlv, TagsIn),
     binary:copy(Bin).
 
-decode_octet_string(Tlv, Range, TagsIn) ->
-    Bin0 = match_and_collect(Tlv, TagsIn),
-    Bin = binary:copy(Bin0),
-    check_restricted_string(Bin, byte_size(Bin), Range).
-
 %%============================================================================
 %% decode Numeric Printable Teletex Videotex Visible IA5 Graphic General strings
 %%============================================================================
 
 decode_restricted_string(Tlv, TagsIn) ->
-    Bin = match_and_collect(Tlv, TagsIn),
-    binary_to_list(Bin).
-
-decode_restricted_string(Tlv, Range, TagsIn) ->
-    Bin = match_and_collect(Tlv, TagsIn),
-    check_restricted_string(binary_to_list(Bin), byte_size(Bin), Range).
-
-check_restricted_string(Val, _Len, []) ->
-    Val;
-check_restricted_string(Val, Len, {Lb,Ub}) when Lb =< Len, Len =< Ub ->
-    Val;
-check_restricted_string(Val, Len, Len) ->
-    Val;
-check_restricted_string(Val, _Len, Range) ->
-    exit({error,{asn1,{length,Range,Val}}}).
+    match_and_collect(Tlv, TagsIn).
 
 %%============================================================================
 %% encode Universal string
@@ -1360,10 +1310,9 @@ mk_uni_list([H|T],List) ->
 %%                           {String, Remain, RemovedBytes}
 %%===========================================================================
 
-decode_universal_string(Buffer, Range, Tags) ->
+decode_universal_string(Buffer, Tags) ->
     Bin = match_and_collect(Buffer, Tags),
-    Val = mk_universal_string(binary_to_list(Bin)),
-    check_restricted_string(Val, length(Val), Range).
+    mk_universal_string(binary_to_list(Bin)).
 
 mk_universal_string(In) ->
     mk_universal_string(In, []).
@@ -1423,10 +1372,9 @@ mk_BMP_list([H|T], List) ->
 %%    (Buffer, Range, StringType, HasTag, TotalLen) ->
 %%                               {String, Remain, RemovedBytes}
 %%============================================================================
-decode_BMP_string(Buffer, Range, Tags) ->
+decode_BMP_string(Buffer, Tags) ->
     Bin = match_and_collect(Buffer, Tags),
-    Val = mk_BMP_string(binary_to_list(Bin)),
-    check_restricted_string(Val, length(Val), Range).
+    mk_BMP_string(binary_to_list(Bin)).
 
 mk_BMP_string(In) ->
     mk_BMP_string(In,[]).