Clean up and correct validation of OBJECT IDENTIFIER/RELATIVE-OID

Besides simplifying the code and doing better error checking
and error reporting, fix the following bugs:

Support retrieving an OBJECT IDENTIFIER/RELATIVE-OID from an
object. Example:

  oid OBJECT IDENTIFIER ::= some-object.&some-field

Allow an integer constant first in an OBJECT IDENTIFIER:

  integer INTEGER ::= 0
  oid OBJECT IDENTIFIER ::= {integer 1}

7 files changed, 263 insertions, 146 deletions

diff --git a/lib/asn1/src/asn1ct_check.erl b/lib/asn1/src/asn1ct_check.erl
index e883ee28bd..996c040373 100644
--- a/lib/asn1/src/asn1ct_check.erl
+++ b/lib/asn1/src/asn1ct_check.erl
@@ -2128,135 +2128,97 @@ is_contextswitchtype(#typedef{name='CHARACTER STRING'}) ->
 is_contextswitchtype(_) ->
     false.
 
-%%------------
-%% This can be removed when the old parser is removed
-%% The function removes 'space' atoms from the list
-
-is_space_list([H],Acc) ->
-    lists:reverse([H|Acc]);
-is_space_list([H,space|T],Acc) ->
-    is_space_list(T,[H|Acc]);
-is_space_list([],Acc) ->
-    lists:reverse(Acc);
-is_space_list([H|T],Acc) ->
-    is_space_list(T,[H|Acc]).
-
-validate_objectidentifier(S,OID,ERef,C) 
-  when is_record(ERef,'Externalvaluereference') ->
-    validate_objectidentifier(S,OID,[ERef],C);
-validate_objectidentifier(S,OID,Tup,C) when is_tuple(Tup) ->
-    validate_objectidentifier(S,OID,tuple_to_list(Tup),C);
-validate_objectidentifier(S,OID,L,_) ->
-    NewL = is_space_list(L,[]),
-    case validate_objectidentifier1(S,OID,NewL) of
-	NewL2 when is_list(NewL2) ->{ok,list_to_tuple(NewL2)};
-	Other -> {ok,Other}
-    end.
+%%%
+%%% Start of OBJECT IDENTFIER/RELATIVE-OID validation.
+%%%
 
-validate_objectidentifier1(S, OID, [Id|T])
-  when is_record(Id,'Externalvaluereference') ->
-    case catch get_referenced_type(S,Id) of
-	{M,V} when is_record(V,valuedef) -> 
-	    NewS = update_state(S,M),
-	    case check_value(NewS,V) of
-		#valuedef{type=#type{def=ERef},checked=true,
-			  value=Value} when is_tuple(Value) ->
-		    case is_object_id(OID,NewS,ERef) of 
-			true ->
-			    %% T must be a RELATIVE-OID
-			    validate_oid(true,NewS, rel_oid, T, lists:reverse(tuple_to_list(Value)));
-			_ ->
-			    error({value, {"illegal "++to_string(OID),[Id|T]}, S})
-		    end;
-		_ -> 
-		    error({value, {"illegal "++to_string(OID),[Id|T]}, S})
-	    end;
+validate_objectidentifier(S, OidType, #'Externalvaluereference'{}=Id) ->
+    %% Must be an OBJECT IDENTIFIER or RELATIVE-OID depending on OidType.
+    get_oid_value(S, OidType, false, Id);
+validate_objectidentifier(S, OidType, {'ValueFromObject',{object,Obj},Fields}) ->
+    %% Must be an OBJECT IDENTIFIER/RELATIVE-OID depending on OidType.
+    case extract_field(S, Obj, Fields) of
+	#valuedef{checked=true,value=Value,type=Type} when is_tuple(Value) ->
+	    _ = get_oid_type(S, OidType, Type),
+	    Value;
 	_ ->
-	    validate_oid(true,S, OID, [Id|T], [])
+	    asn1_error(S, {illegal_oid,OidType})
     end;
-validate_objectidentifier1(S,OID,V) ->
-    validate_oid(true,S,OID,V,[]).
-
-validate_oid(false, S, OID, V, Acc) ->
-    error({value, {"illegal "++to_string(OID), V,Acc}, S});
-validate_oid(_,_, _, [], Acc) ->
-    lists:reverse(Acc);
-validate_oid(_, S, OID, [Value|Vrest], Acc) when is_integer(Value) ->
-    validate_oid(valid_objectid(OID,Value,Acc),S, OID, Vrest, [Value|Acc]);
-validate_oid(_, S, OID, [{'NamedNumber',_Name,Value}|Vrest], Acc) 
-  when is_integer(Value) ->
-    validate_oid(valid_objectid(OID,Value,Acc), S, OID, Vrest, [Value|Acc]);
-validate_oid(_, S, OID, [Id|Vrest], Acc) 
-  when is_record(Id,'Externalvaluereference') ->
-    case catch get_referenced_type(S, Id) of
-	{M,V} when is_record(V,valuedef) ->
-	    NewS = update_state(S,M),
-	    NewVal = case check_value(NewS, V) of
-			 #valuedef{checked=true,value=Value} ->
-			     fun(Int) when is_integer(Int) ->  [Int];
-				(L) when is_list(L) -> L;
-				(T) when is_tuple(T) -> tuple_to_list(T)
-			     end (Value);
-			 _ ->
-			     error({value, {"illegal "++to_string(OID),
-					    [Id|Vrest],Acc}, S})
-		     end,
-	    case NewVal of
-		List when is_list(List) ->
-		    validate_oid(valid_objectid(OID,NewVal,Acc), NewS, 
-				 OID, Vrest,lists:reverse(NewVal)++Acc);
+validate_objectidentifier(S, OidType,
+			  [{#seqtag{module=Mod,pos=Pos,val=Atom},Val}]) ->
+    %% This case is when an OBJECT IDENTIFIER value has been parsed as a
+    %% SEQUENCE value.
+    Rec = #'Externalvaluereference'{pos=Pos,
+				    module=Mod,
+				    value=Atom},
+    validate_oid(S, OidType, [Rec,Val], []);
+validate_objectidentifier(S, OidType, [_|_]=L0) ->
+    validate_oid(S, OidType, L0, []);
+validate_objectidentifier(S, OidType, _) ->
+    asn1_error(S, {illegal_oid,OidType}).
+
+get_oid_value(S, OidType, AllowInteger, #'Externalvaluereference'{}=Id) ->
+    case get_referenced_type(S, Id) of
+	{_,#valuedef{checked=Checked,type=Type,value=V}} ->
+	    case get_oid_type(S, OidType, Type) of
+		'INTEGER' when not AllowInteger ->
+		    asn1_error(S, {illegal_oid,OidType});
+		_ when Checked ->
+		    V;
+		'INTEGER' ->
+		    V;
 		_ ->
-		    NewVal
+		    validate_objectidentifier(S, OidType, V)
 	    end;
 	_ ->
+	    asn1_error(S, {illegal_oid,OidType})
+    end.
+
+validate_oid(S, OidType, [], Acc) ->
+    Oid = lists:reverse(Acc),
+    validate_oid_path(S, OidType, Oid),
+    list_to_tuple(Oid);
+validate_oid(S, OidType, [Value|Vrest], Acc) when is_integer(Value) ->
+    validate_oid(S, OidType, Vrest, [Value|Acc]);
+validate_oid(S, OidType, [{'NamedNumber',_Name,Value}|Vrest], Acc)
+  when is_integer(Value) ->
+    validate_oid(S, OidType, Vrest, [Value|Acc]);
+validate_oid(S, OidType, [#'Externalvaluereference'{}=Id|Vrest], Acc) ->
+    NeededOidType = case Acc of
+			[] -> o_id;
+			[_|_] -> rel_oid
+		    end,
+    try get_oid_value(S, NeededOidType, true, Id) of
+	Val when is_integer(Val) ->
+	    validate_oid(S, OidType, Vrest, [Val|Acc]);
+	Val when is_tuple(Val) ->
+	    L = tuple_to_list(Val),
+	    validate_oid(S, OidType, Vrest, lists:reverse(L, Acc))
+    catch
+	_:_ ->
 	    case reserved_objectid(Id#'Externalvaluereference'.value, Acc) of
 		Value when is_integer(Value) ->
-		    validate_oid(valid_objectid(OID,Value,Acc),
-				 S, OID,Vrest, [Value|Acc]);
+		    validate_oid(S, OidType,Vrest, [Value|Acc]);
 		false ->
-		    error({value, {"illegal "++to_string(OID),[Id,Vrest],Acc}, S})
+		    asn1_error(S, {illegal_oid,OidType})
 	    end
     end;
-validate_oid(_, S, OID, [{#seqtag{module=Mod,val=Atom},Value}], [])
-  when is_atom(Atom),is_integer(Value) ->
-    %% this case when an OBJECT IDENTIFIER value has been parsed as a 
-    %% SEQUENCE value
-    Rec = #'Externalvaluereference'{module=Mod,
-				    value=Atom},
-    validate_objectidentifier1(S, OID, [Rec,Value]);
-validate_oid(_, S, OID, [{#seqtag{module=Mod,val=Atom},EVRef}], [])
-  when is_atom(Atom),is_record(EVRef,'Externalvaluereference') ->
-    %% this case when an OBJECT IDENTIFIER value has been parsed as a 
-    %% SEQUENCE value OTP-4354
-    Rec = #'Externalvaluereference'{module=Mod,
-				    value=Atom},
-    validate_objectidentifier1(S, OID, [Rec,EVRef]);
-validate_oid(_, S, OID, [#seqtag{module=Mod,val=Atom}|Rest], Acc)
-  when is_atom(Atom) ->
-    Rec = #'Externalvaluereference'{module=Mod,
-				    value=Atom},
-    validate_oid(true,S, OID, [Rec|Rest],Acc);
-validate_oid(_, S, OID, V, Acc) ->
-    error({value, {"illegal "++to_string(OID),V,Acc},S}).
-
-is_object_id(OID,S,ERef=#'Externaltypereference'{}) ->
-    {_,OI} = get_referenced_type(S,ERef),
-    is_object_id(OID,S,OI#typedef.typespec);
-is_object_id(o_id,_S,'OBJECT IDENTIFIER') ->
-    true;
-is_object_id(rel_oid,_S,'RELATIVE-OID') ->
-    true;
-is_object_id(_,_S,'INTEGER') ->
-    true;
-is_object_id(OID,S,#type{def=Def}) ->
-    is_object_id(OID,S,Def);
-is_object_id(_,_S,_) ->
-    false.
-
-to_string(o_id) ->
-    "OBJECT IDENTIFIER";
-to_string(rel_oid) ->
-    "RELATIVE-OID".
+validate_oid(S, OidType, _V, _Acc) ->
+    asn1_error(S, {illegal_oid,OidType}).
+
+get_oid_type(S, OidType, #type{def=Def}) ->
+    get_oid_type(S, OidType, Def);
+get_oid_type(S, OidType, #'Externaltypereference'{}=Id) ->
+    {_,OI} = get_referenced_type(S, Id),
+    get_oid_type(S, OidType, OI#typedef.typespec);
+get_oid_type(_S, o_id, 'OBJECT IDENTIFIER'=T) ->
+    T;
+get_oid_type(_S, rel_oid, 'RELATIVE-OID'=T) ->
+    T;
+get_oid_type(_S, _, 'INTEGER'=T) ->
+    T;
+get_oid_type(S, OidType, _) ->
+    asn1_error(S, {illegal_oid,OidType}).
 
 %% ITU-T Rec. X.680 Annex B - D
 reserved_objectid('itu-t',[]) -> 0;
@@ -2295,7 +2257,6 @@ reserved_objectid('x',[0,0]) -> 24;
 reserved_objectid('y',[0,0]) -> 25;
 reserved_objectid('z',[0,0]) -> 26;
 
-
 reserved_objectid(iso,[]) -> 1;
 %% arcs below "iso", note that number 1 is not used
 reserved_objectid('standard',[1]) -> 0;
@@ -2307,23 +2268,20 @@ reserved_objectid('joint-iso-ccitt',[]) -> 2;
 
 reserved_objectid(_,_) -> false.
 
-valid_objectid(_OID,[],_Acc) ->
-    true;
-valid_objectid(OID,[H|T],Acc) ->
-    case valid_objectid(OID, H, Acc) of
-	true ->
-	    valid_objectid(OID,T,[H|Acc]);
-	_ ->
-	    false
-    end;
-valid_objectid(o_id,I,[]) when I =:= 0; I =:= 1; I =:= 2 -> true;
-valid_objectid(o_id,_I,[]) -> false;
-valid_objectid(o_id,I,[0]) when I >= 0; I =< 4 -> true;
-valid_objectid(o_id,_I,[0]) -> false;
-valid_objectid(o_id,I,[1]) when I =:= 0; I =:= 2; I =:= 3 -> true;
-valid_objectid(o_id,_I,[1]) -> false;
-valid_objectid(o_id,_I,[2]) -> true;
-valid_objectid(_,_,_) -> true.
+validate_oid_path(_, rel_oid, _) ->
+    ok;
+validate_oid_path(_, o_id, [0,I|_]) when 0 =< I, I =< 9 ->
+    ok;
+validate_oid_path(_, o_id, [1,I|_]) when 0 =< I, I =< 3 ->
+    ok;
+validate_oid_path(_, o_id, [2|_]) ->
+    ok;
+validate_oid_path(S, o_id=OidType, _) ->
+    asn1_error(S, {illegal_oid,OidType}).
+
+%%%
+%%% End of OBJECT IDENTFIER/RELATIVE-OID validation.
+%%%
 
 convert_external(S=#state{type=Vtype}, Value) ->
     case Vtype of
@@ -2545,12 +2503,10 @@ normalize_octetstring(S, Value) ->
     end.
 
 normalize_objectidentifier(S, Value) ->
-    {ok,Val} = validate_objectidentifier(S, o_id, Value, []),
-    Val.
+    validate_objectidentifier(S, o_id, Value).
 
-normalize_relative_oid(S,Value) ->
-    {ok,Val} = validate_objectidentifier(S, rel_oid, Value, []),
-    Val.
+normalize_relative_oid(S, Value) ->
+    validate_objectidentifier(S, rel_oid, Value).
 
 normalize_objectdescriptor(Value) ->
     Value.
@@ -6599,6 +6555,10 @@ format_error(illegal_integer_value) ->
     "expecting an integer value";
 format_error(illegal_object) ->
     "expecting an object";
+format_error({illegal_oid,o_id}) ->
+    "illegal OBJECT IDENTIFIER";
+format_error({illegal_oid,rel_oid}) ->
+    "illegal RELATIVE-OID";
 format_error(illegal_octet_string_value) ->
     "expecting a bstring or an hstring as value for an OCTET STRING";
 format_error({illegal_typereference,Name}) ->
diff --git a/lib/asn1/test/asn1_SUITE_data/InfObj.asn b/lib/asn1/test/asn1_SUITE_data/InfObj.asn
index aadd642f97..b24d747f0e 100644
--- a/lib/asn1/test/asn1_SUITE_data/InfObj.asn
+++ b/lib/asn1/test/asn1_SUITE_data/InfObj.asn
@@ -360,6 +360,26 @@ object-with-optional-bit-string PUBLIC-KEY ::= {
  OPTIONAL-BIT-STRING {digitalSignature, nonRepudiation, keyEncipherment}
 }
 
+-- Test object identifiers from objects.
+
+CONTAINER ::= CLASS {
+ &id   OBJECT IDENTIFIER UNIQUE,
+ &rid  RELATIVE-OID OPTIONAL,
+ &Type OPTIONAL
+} WITH SYNTAX {
+  IDENTIFIED BY &id
+  [REL-OID &rid]
+  [TYPE &Type]
+}
+
+id1 OBJECT IDENTIFIER ::= {1 2 42}
+obj1 CONTAINER ::= { IDENTIFIED BY id1 REL-OID {100 101} }
+
+value-2 OBJECT IDENTIFIER ::= { value-1 25 }
+value-1 OBJECT IDENTIFIER ::= obj1.&id
+value-3 RELATIVE-OID ::= obj1.&rid
+value-4 OBJECT IDENTIFIER ::= { 1 2 value-3 }
+
 END
 
 
diff --git a/lib/asn1/test/asn1_SUITE_data/ObjIdValues.asn1 b/lib/asn1/test/asn1_SUITE_data/ObjIdValues.asn1
index 9368e8dceb..9193ed495c 100644
--- a/lib/asn1/test/asn1_SUITE_data/ObjIdValues.asn1
+++ b/lib/asn1/test/asn1_SUITE_data/ObjIdValues.asn1
@@ -50,6 +50,7 @@ itu-t-o OBJECT IDENTIFIER ::= {itu-t recommendation o}
 itu-t-p OBJECT IDENTIFIER ::= {itu-t recommendation p}
 itu-t-q OBJECT IDENTIFIER ::= {itu-t recommendation q}
 itu-t-r OBJECT IDENTIFIER ::= {itu-t recommendation r}
+itu-t-s OBJECT IDENTIFIER ::= {itu-t recommendation s}
 itu-t-t OBJECT IDENTIFIER ::= {itu-t recommendation t}
 itu-t-u OBJECT IDENTIFIER ::= {itu-t recommendation u}
 itu-t-v OBJECT IDENTIFIER ::= {itu-t recommendation v}
diff --git a/lib/asn1/test/asn1_SUITE_data/ValueTest.asn b/lib/asn1/test/asn1_SUITE_data/ValueTest.asn
index 739c8a4e45..156d23ee62 100644
--- a/lib/asn1/test/asn1_SUITE_data/ValueTest.asn
+++ b/lib/asn1/test/asn1_SUITE_data/ValueTest.asn
@@ -23,8 +23,15 @@ vENUMERATED RadioButton ::= button1
 vBS BSNNL ::= {zero,two}
 vNULL NULL ::= NULL
 vOS OCTET STRING ::= '313233'H
-vOD OBJECT IDENTIFIER ::= {2 1 1}
 
+-- OBJECT IDENTIFIER
+vOD OBJECT IDENTIFIER ::= {2 1 1}
+one INTEGER ::= 1
+integer-first OBJECT IDENTIFIER ::= {one 2}
+rel-oid-1 RELATIVE-OID ::= {2 4 5}
+include-roid OBJECT IDENTIFIER ::= {0 rel-oid-1}
+include-oid OBJECT IDENTIFIER ::= {integer-first 1}
+include-all OBJECT IDENTIFIER ::= {integer-first 1 rel-oid-1 42}
 
 --Character strings
 numericstring NumericString ::= "01234567"
diff --git a/lib/asn1/test/error_SUITE.erl b/lib/asn1/test/error_SUITE.erl
index 49ba47aed5..f718847c9c 100644
--- a/lib/asn1/test/error_SUITE.erl
+++ b/lib/asn1/test/error_SUITE.erl
@@ -22,8 +22,8 @@
 	 already_defined/1,bitstrings/1,
 	 classes/1,constraints/1,enumerated/1,
 	 imports/1,instance_of/1,integers/1,objects/1,
-	 object_field_extraction/1, object_sets/1,
-	 parameterization/1, syntax/1,values/1]).
+	 object_field_extraction/1,oids/1,rel_oids/1,
+	 object_sets/1,parameterization/1, syntax/1,values/1]).
 
 -include_lib("test_server/include/test_server.hrl").
 
@@ -45,6 +45,8 @@ groups() ->
        objects,
        object_field_extraction,
        object_sets,
+       oids,
+       rel_oids,
        parameterization,
        syntax,
        values]}].
@@ -311,6 +313,109 @@ object_sets(Config) ->
     } = run(P, Config),
     ok.
 
+oids(Config) ->
+    M = 'OIDS',
+    P = {M,<<"OIDS DEFINITIONS AUTOMATIC TAGS ::= BEGIN\n"
+	    "CONTAINER ::= CLASS { &id OBJECT IDENTIFIER UNIQUE,\n"
+	    "                      &int INTEGER OPTIONAL,\n"
+	    "                      &seq SEQUENCE { a INTEGER } OPTIONAL\n"
+	    "}\n"
+
+	    "-- This is line 6.\n"
+	    "object-1 CONTAINER ::= { &id {1 2 3}, &int 42 }\n"
+	    "object-2 CONTAINER ::= { &id {1 999}, &int 0 }\n"
+	    "object-3 CONTAINER ::= { &id {1 2}, &seq { a 42 } }\n"
+	    "oid-1 OBJECT IDENTIFIER ::= object-1.&int\n"
+	    "oid-2 OBJECT IDENTIFIER ::= object-2.&id\n"
+	    "oid-3 OBJECT IDENTIFIER ::= object-3.&seq\n"
+	    "-- This is line 13.\n"
+
+	    "oid-5 OBJECT IDENTIFIER ::= { a 42, b 19 }\n"
+
+	    "oid-6 OBJECT IDENTIFIER ::= int\n"
+	    "int INTEGER ::= 42\n"
+
+	    "oid-7 OBJECT IDENTIFIER ::= seq\n"
+	    "seq SEQUENCE { x INTEGER } ::= { x 11 }\n"
+
+	    "oid-8 OBJECT IDENTIFIER ::= os\n"
+	    "os OCTET STRING ::= '1234'H\n"
+
+	    "oid-9 OBJECT IDENTIFIER ::= { 1 os }\n"
+
+	    "oid-10 OBJECT IDENTIFIER ::= { 1 invalid }\n"
+
+	    "-- This is line 23.\n"
+	    "oid-11 OBJECT IDENTIFIER ::= { 0 legal-oid }\n"
+	    "legal-oid OBJECT IDENTIFIER ::= {1 2 3}\n"
+
+	    "bad-root-1 OBJECT IDENTIFIER ::= {99}\n"
+	    "bad-root-2 OBJECT IDENTIFIER ::= {0 42}\n"
+
+	    "oid-object-ref-1 OBJECT IDENTIFIER ::= object-1\n"
+	    "oid-object-ref-2 OBJECT IDENTIFIER ::= { object-1 19 } \n"
+
+	    "oid-int OBJECT IDENTIFIER ::= 42\n"
+	    "oid-sequence OBJECT IDENTIFIER ::= {a 42, b 35}\n"
+
+	     "END\n">>},
+    {error,
+     [
+      {structured_error,{M,8},asn1ct_check,{illegal_oid,o_id}},
+      {structured_error,{M,10},asn1ct_check,{illegal_oid,o_id}},
+      {structured_error,{M,11},asn1ct_check,{illegal_oid,o_id}},
+      {structured_error,{M,12},asn1ct_check,{illegal_oid,o_id}},
+      {structured_error,{M,14},asn1ct_check,{illegal_oid,o_id}},
+      {structured_error,{M,15},asn1ct_check,{illegal_oid,o_id}},
+      {structured_error,{M,17},asn1ct_check,{illegal_oid,o_id}},
+      {structured_error,{M,19},asn1ct_check,{illegal_oid,o_id}},
+      {structured_error,{M,21},asn1ct_check,{illegal_oid,o_id}},
+      {structured_error,{M,22},asn1ct_check,{illegal_oid,o_id}},
+      {structured_error,{M,24},asn1ct_check,{illegal_oid,o_id}},
+      {structured_error,{M,26},asn1ct_check,{illegal_oid,o_id}},
+      {structured_error,{M,27},asn1ct_check,{illegal_oid,o_id}},
+      {structured_error,{M,28},asn1ct_check,{illegal_oid,o_id}},
+      {structured_error,{M,29},asn1ct_check,{illegal_oid,o_id}},
+      {structured_error,{M,30},asn1ct_check,{illegal_oid,o_id}},
+      {structured_error,{M,31},asn1ct_check,{illegal_oid,o_id}}
+     ]
+    } = run(P, Config),
+    ok.
+
+rel_oids(Config) ->
+    M = 'REL-OIDS',
+    P = {M,<<"REL-OIDS DEFINITIONS AUTOMATIC TAGS ::= BEGIN\n"
+	     "legal-oid OBJECT IDENTIFIER ::= {1 2}\n"
+	     "legal-roid RELATIVE-OID ::= {1 2}\n"
+	     "CONTAINER ::= CLASS { &oid OBJECT IDENTIFIER OPTIONAL,\n"
+	     "                      &int INTEGER OPTIONAL,\n"
+	     "                      &seq SEQUENCE { a INTEGER } OPTIONAL\n"
+	     "}\n"
+	     "object-1 CONTAINER ::= { &oid {1 2 3},\n"
+	     "                         &int 42,\n",
+	     "                         &seq {a 42}\n"
+	     "                       }\n"
+
+	     "wrong-type-rel-oid-1 RELATIVE-OID ::= legal-oid\n"
+	     "wrong-type-rel-oid-2 RELATIVE-OID ::= object-1.&oid\n"
+	     "wrong-type-rel-oid-3 RELATIVE-OID ::= object-1.&int\n"
+	     "wrong-type-rel-oid-4 RELATIVE-OID ::= object-1.&seq\n"
+	     "wrong-type-rel-oid-5 RELATIVE-OID ::= object-1.&undef\n"
+
+	     "oid-bad-first OBJECT IDENTIFIER ::= {legal-roid 3}\n"
+	     "END\n">>},
+    {error,
+     [
+      {structured_error,{M,12},asn1ct_check,{illegal_oid,rel_oid}},
+      {structured_error,{M,13},asn1ct_check,{illegal_oid,rel_oid}},
+      {structured_error,{M,14},asn1ct_check,{illegal_oid,rel_oid}},
+      {structured_error,{M,15},asn1ct_check,{illegal_oid,rel_oid}},
+      {structured_error,{M,16},asn1ct_check,{undefined_field,undef}},
+      {structured_error,{M,17},asn1ct_check,{illegal_oid,o_id}}
+     ]
+    } = run(P, Config),
+    ok.
+
 
 parameterization(Config) ->
     M = 'Parameterization',
@@ -350,6 +455,10 @@ syntax(Config) ->
 	   "  obj15 CL ::= { CODE 42 OBJ-SET { A B } }\n"
 	   "  obj16 CL ::= { CODE 42 OBJ-SET SEQUENCE { an INTEGER } }\n"
 
+	   "  obj17 CL ::= { CODE 42 OID {seqtag 42} }\n"
+	   "  obj18 CL ::= { CODE 42 OID {seqtag 42, seqtag-again 43} }\n"
+	   "  obj19 CL ::= { CODE 42 OID {one 1 two 2} }\n"
+
 	   "  BAD-SYNTAX-1 ::= CLASS {\n"
 	   "    &code INTEGER UNIQUE\n"
 	   "  } WITH SYNTAX {\n"
@@ -366,9 +475,11 @@ syntax(Config) ->
 	   "    &code INTEGER UNIQUE,\n"
 	   "    &enum ENUMERATED { a, b, c} OPTIONAL,\n"
 	   "    &Type OPTIONAL,\n"
-	   "    &ObjSet CL OPTIONAL\n"
+	   "    &ObjSet CL OPTIONAL,\n"
+	   "    &oid OBJECT IDENTIFIER OPTIONAL\n"
 	   "  } WITH SYNTAX {\n"
 	   "    CODE &code [ENUM &enum] [TYPE &Type] [OBJ-SET &ObjSet]\n"
+           "    [OID &oid]\n"
 	   "  }\n"
 
 	   "  bs-value BIT STRING ::= '1011'B\n"
@@ -412,8 +523,14 @@ syntax(Config) ->
       {structured_error,{M,18},asn1ct_check,
        {syntax_nomatch,"SEQUENCE"}},
       {structured_error,{M,19},asn1ct_check,
+       {syntax_nomatch,"\"seqtag 42\""}},
+      {structured_error,{M,20},asn1ct_check,
+       {syntax_nomatch,"\"seqtag 42 seqtag-again 43\""}},
+      {structured_error,{M,21},asn1ct_check,
+       {syntax_nomatch,"\"one 1 two 2\""}},
+      {structured_error,{M,22},asn1ct_check,
        {syntax_undefined_field,bad}},
-      {structured_error,{M,24},asn1ct_check,
+      {structured_error,{M,27},asn1ct_check,
        {syntax_undefined_field,'Bad'}}
     ]
     } = run(P, Config),
diff --git a/lib/asn1/test/testInfObj.erl b/lib/asn1/test/testInfObj.erl
index 268bdcf60f..aa617b632f 100644
--- a/lib/asn1/test/testInfObj.erl
+++ b/lib/asn1/test/testInfObj.erl
@@ -146,6 +146,11 @@ main(_Erule) ->
 
     roundtrip('InfObj', 'ExtClassSeq', {'ExtClassSeq', 4}),
 
+    {1,2,42} = 'InfObj':'value-1'(),
+    {1,2,42,25} = 'InfObj':'value-2'(),
+    {100,101} = 'InfObj':'value-3'(),
+    {1,2,100,101} = 'InfObj':'value-4'(),
+
     ok.
 
 test_objset(Type, Keys) ->
diff --git a/lib/asn1/test/testValueTest.erl b/lib/asn1/test/testValueTest.erl
index 24a2862b40..d1532c3ef0 100644
--- a/lib/asn1/test/testValueTest.erl
+++ b/lib/asn1/test/testValueTest.erl
@@ -33,7 +33,14 @@ main() ->
     [zero,two] = M:'vBS'(),
     'NULL' = M:'vNULL'(),
     <<16#31,16#32,16#33>> = M:'vOS'(),
+
+    %% OID
     {2,1,1} = M:'vOD'(),
+    {1,2} = M:'integer-first'(),
+    {2,4,5} = M:'rel-oid-1'(),
+    {0,2,4,5} = M:'include-roid'(),
+    {1,2,1} = M:'include-oid'(),
+    {1,2,1,2,4,5,42} = M:'include-all'(),
 
     %% Character strings
     "01234567" = M:'numericstring'(),