[common_test] Fix cth_surefire

The following corrections/changes are done in the cth_surefire hook:

* Earlier there would always be a 'properties' element under the
  'testsuites' element. This would exist even if there were now
  'property' element inside it. This has been changed so if there are
  no 'property' elements to display, then there will not be a
  'properties' element either.

* The XML file will now (unless other is specified) be stored in the
  top log directory. Earlier, the default directory would be the
  current working directory for the erlang node, which would mostly,
  but not always, be the top log directory.

* The 'hostname' attribute in the 'testsuite' element would earlier
  never have the correct value. This has been corrected.

* The 'errors' attribute in the 'testsuite' element would earlier
  display the number of failed testcases. This has been changed and
  will now always have the value 0, while the 'failures' attribute
  will show the number of failed testcases.

* A new attribute 'skipped' is added to the 'testsuite' element. This
  will display the number of skipped testcases. These would earlier be
  included in the number of failed test cases.

* The total number of tests displayed by the 'tests' attribute in the
  'testsuite' element would earlier include init/end_per_suite and
  init/end_per_group. This is no longer the case. The 'tests'
  attribute will now only count "real" test cases.

* Earlier, auto skipped test cases would have no value in the 'log'
  attribute. This is now corrected.

* A new attributes 'log' is added to the 'testsuite' element.

* A new option named 'url_base' is added for this hook. If this
  option is used, a new attribute named 'url' will be added to the
  'testcase' and 'testsuite' elements.

Tests are added for the ct_surefire hook.

1 files changed, 149 insertions, 34 deletions

diff --git a/lib/common_test/src/cth_surefire.erl b/lib/common_test/src/cth_surefire.erl
index 76b0f0b5ea..e6eaad8d48 100644
--- a/lib/common_test/src/cth_surefire.erl
+++ b/lib/common_test/src/cth_surefire.erl
@@ -1,3 +1,22 @@
+%%--------------------------------------------------------------------
+%% %CopyrightBegin%
+%%
+%% Copyright Ericsson AB 2012. All Rights Reserved.
+%%
+%% The contents of this file are subject to the Erlang Public License,
+%% Version 1.1, (the "License"); you may not use this file except in
+%% compliance with the License. You should have received a copy of the
+%% Erlang Public License along with this software. If not, it can be
+%% retrieved online at http://www.erlang.org/.
+%%
+%% Software distributed under the License is distributed on an "AS IS"
+%% basis, WITHOUT WARRANTY OF ANY KIND, either express or implied. See
+%% the License for the specific language governing rights and limitations
+%% under the License.
+%%
+%% %CopyrightEnd%
+%%--------------------------------------------------------------------
+
 %%% @doc Common Test Framework functions handling test specifications.
 %%%
 %%% <p>This module creates a junit report of the test run if plugged in
@@ -27,18 +46,28 @@
 -export([terminate/1]).
 
 -record(state, { filepath, axis, properties, package, hostname,
-		 curr_suite, curr_suite_ts, curr_group = [], curr_tc,
-		 curr_log_dir, timer, tc_log,
+		 curr_suite, curr_suite_ts, curr_group = [],
+		 curr_log_dir, timer, tc_log, url_base,
 		 test_cases = [],
 		 test_suites = [] }).
 
--record(testcase, { log, group, classname, name, time, failure, timestamp }).
--record(testsuite, { errors, failures, hostname, name, tests,
+-record(testcase, { log, url, group, classname, name, time, result, timestamp }).
+-record(testsuite, { errors, failures, skipped, hostname, name, tests,
 		     time, timestamp, id, package,
-		     properties, testcases }).
+		     properties, testcases, log, url }).
+
+-define(default_report,"junit_report.xml").
+-define(suite_log,"suite.log.html").
+
+%% Number of dirs from log root to testcase log file.
+%% ct_run.<node>.<timestamp>/<test_name>/run.<timestamp>/<tc_log>.html
+-define(log_depth,3).
 
 id(Opts) ->
-    filename:absname(proplists:get_value(path, Opts, "junit_report.xml")).
+    case proplists:get_value(path, Opts) of
+	undefined -> ?default_report;
+	Path -> filename:absname(Path)
+    end.
 
 init(Path, Opts) ->
     {ok, Host} = inet:gethostname(),
@@ -47,10 +76,24 @@ init(Path, Opts) ->
 	    package = proplists:get_value(package,Opts),
 	    axis = proplists:get_value(axis,Opts,[]),
 	    properties = proplists:get_value(properties,Opts,[]),
+	    url_base = proplists:get_value(url_base,Opts),
 	    timer = now() }.
 
 pre_init_per_suite(Suite,Config,#state{ test_cases = [] } = State) ->
-    {Config, init_tc(State#state{ curr_suite = Suite, curr_suite_ts = now() },
+    TcLog = proplists:get_value(tc_logfile,Config),
+    CurrLogDir = filename:dirname(TcLog),
+    Path =
+	case State#state.filepath of
+	    ?default_report ->
+		RootDir = get_test_root(TcLog),
+		filename:join(RootDir,?default_report);
+	    P ->
+		P
+	end,
+    {Config, init_tc(State#state{ filepath = Path,
+				  curr_suite = Suite,
+				  curr_suite_ts = now(),
+				  curr_log_dir = CurrLogDir},
 		     Config) };
 pre_init_per_suite(Suite,Config,State) ->
     %% Have to close the previous suite
@@ -59,7 +102,8 @@ pre_init_per_suite(Suite,Config,State) ->
 post_init_per_suite(_Suite,Config, Result, State) ->
     {Result, end_tc(init_per_suite,Config,Result,State)}.
 
-pre_end_per_suite(_Suite,Config,State) -> {Config, init_tc(State, Config)}.
+pre_end_per_suite(_Suite,Config,State) ->
+    {Config, init_tc(State, Config)}.
 
 post_end_per_suite(_Suite,Config,Result,State) ->
     {Result, end_tc(end_per_suite,Config,Result,State)}.
@@ -71,13 +115,15 @@ pre_init_per_group(Group,Config,State) ->
 post_init_per_group(_Group,Config,Result,State) ->
     {Result, end_tc(init_per_group,Config,Result,State)}.
 
-pre_end_per_group(_Group,Config,State) -> {Config, init_tc(State, Config)}.
+pre_end_per_group(_Group,Config,State) ->
+    {Config, init_tc(State, Config)}.
 
 post_end_per_group(_Group,Config,Result,State) ->
     NewState = end_tc(end_per_group, Config, Result, State),
     {Result, NewState#state{ curr_group = tl(NewState#state.curr_group)}}.
 
-pre_init_per_testcase(_TC,Config,State) -> {Config, init_tc(State, Config)}.
+pre_init_per_testcase(_TC,Config,State) ->
+    {Config, init_tc(State, Config)}.
 
 post_end_per_testcase(TC,Config,Result,State) ->
     {Result, end_tc(TC,Config, Result,State)}.
@@ -88,11 +134,19 @@ on_tc_fail(_TC, Res, State) ->
     TCs = State#state.test_cases,
     TC = hd(TCs),
     NewTC = TC#testcase{
-	      failure =
+	      result =
 		  {fail,lists:flatten(io_lib:format("~p",[Res]))} },
     State#state{ test_cases = [NewTC | tl(TCs)]}.
 
-on_tc_skip(Tc,{Type,_Reason} = Res, State) when Type == tc_auto_skip ->
+on_tc_skip(Tc,{Type,_Reason} = Res, State0) when Type == tc_auto_skip ->
+    TcStr = atom_to_list(Tc),
+    State =
+	case State0#state.test_cases of
+	    [#testcase{name=TcStr}|TCs] ->
+		State0#state{test_cases=TCs};
+	    _ ->
+		State0
+	end,
     do_tc_skip(Res, end_tc(Tc,[],Res,init_tc(State,[])));
 on_tc_skip(_Tc, _Res, State = #state{test_cases = []}) ->
     State;
@@ -103,7 +157,7 @@ do_tc_skip(Res, State) ->
     TCs = State#state.test_cases,
     TC = hd(TCs),
     NewTC = TC#testcase{
-	      failure =
+	      result =
 		  {skipped,lists:flatten(io_lib:format("~p",[Res]))} },
     State#state{ test_cases = [NewTC | tl(TCs)]}.
 
@@ -117,33 +171,52 @@ end_tc(Func, Config, Res, State) when is_atom(Func) ->
     end_tc(atom_to_list(Func), Config, Res, State);
 end_tc(Name, _Config, _Res, State = #state{ curr_suite = Suite,
 					    curr_group = Groups,
-					    timer = TS, tc_log = Log } ) ->
+					    curr_log_dir = CurrLogDir,
+					    timer = TS,
+					    tc_log = Log0,
+					    url_base = UrlBase } ) ->
+    Log =
+	case Log0 of
+	    "" ->
+		LowerSuiteName = string:to_lower(atom_to_list(Suite)),
+		filename:join(CurrLogDir,LowerSuiteName++"."++Name++".html");
+	    _ ->
+		Log0
+	end,
+    Url = make_url(UrlBase,Log),
     ClassName = atom_to_list(Suite),
     PGroup = string:join([ atom_to_list(Group)||
 			     Group <- lists:reverse(Groups)],"."),
     TimeTakes = io_lib:format("~f",[timer:now_diff(now(),TS) / 1000000]),
     State#state{ test_cases = [#testcase{ log = Log,
+					  url = Url,
 					  timestamp = now_to_string(TS),
 					  classname = ClassName,
 					  group = PGroup,
 					  name = Name,
 					  time = TimeTakes,
-					  failure = passed }| State#state.test_cases]}.
+					  result = passed }|
+			       State#state.test_cases],
+		 tc_log = ""}. % so old tc_log is not set if next is on_tc_skip
 close_suite(#state{ test_cases = [] } = State) ->
     State;
-close_suite(#state{ test_cases = TCs } = State) ->
-    Total = length(TCs),
-    Succ = length(lists:filter(fun(#testcase{ failure = F }) ->
-				       F == passed
-			       end,TCs)),
-    Fail = Total - Succ,
+close_suite(#state{ test_cases = TCs, url_base = UrlBase } = State) ->
+    {Total,Fail,Skip} = count_tcs(TCs,0,0,0),
     TimeTaken = timer:now_diff(now(),State#state.curr_suite_ts) / 1000000,
+    SuiteLog = filename:join(State#state.curr_log_dir,?suite_log),
+    SuiteUrl = make_url(UrlBase,SuiteLog),
     Suite = #testsuite{ name = atom_to_list(State#state.curr_suite),
 			package = State#state.package,
+			hostname = State#state.hostname,
 			time = io_lib:format("~f",[TimeTaken]),
 			timestamp = now_to_string(State#state.curr_suite_ts),
-			errors = Fail, tests = Total,
-			testcases = lists:reverse(TCs) },
+			errors = 0,
+			failures = Fail,
+			skipped = Skip,
+			tests = Total,
+			testcases = lists:reverse(TCs),
+			log = SuiteLog,
+			url = SuiteUrl},
     State#state{ test_cases = [],
 		 test_suites = [Suite | State#state.test_suites]}.
 
@@ -159,14 +232,15 @@ terminate(State) ->
 
 
 
-to_xml(#testcase{ group = Group, classname = CL, log = L, name = N, time = T, timestamp = TS, failure = F}) ->
+to_xml(#testcase{ group = Group, classname = CL, log = L, url = U, name = N, time = T, timestamp = TS, result = R}) ->
     ["<testcase ",
-     [["group=\"",Group,"\""]||Group /= ""]," "
+     [["group=\"",Group,"\" "]||Group /= ""],
      "name=\"",N,"\" "
      "time=\"",T,"\" "
-     "timestamp=\"",TS,"\" "
+     "timestamp=\"",TS,"\" ",
+     [["url=\"",U,"\" "]||U /= undefined],
      "log=\"",L,"\">",
-     case F of
+     case R of
 	 passed ->
 	     [];
 	 {skipped,Reason} ->
@@ -176,22 +250,29 @@ to_xml(#testcase{ group = Group, classname = CL, log = L, name = N, time = T, ti
 	     ["<failure message=\"Test ",N," in ",CL," failed!\" type=\"crash\">",
 	      sanitize(Reason),"</failure>"]
      end,"</testcase>"];
-to_xml(#testsuite{ package = P, hostname = H, errors = E, time = Time,
-		   timestamp = TS, tests = T, name = N, testcases = Cases }) ->
+to_xml(#testsuite{ package = P, hostname = H, errors = E, failures = F,
+		   skipped = S, time = Time, timestamp = TS, tests = T, name = N,
+		   testcases = Cases, log = Log, url = Url }) ->
     ["<testsuite ",
      [["package=\"",P,"\" "]||P /= undefined],
-     [["hostname=\"",P,"\" "]||H /= undefined],
-     [["name=\"",N,"\" "]||N /= undefined],
-     [["time=\"",Time,"\" "]||Time /= undefined],
-     [["timestamp=\"",TS,"\" "]||TS /= undefined],
+     "hostname=\"",H,"\" "
+     "name=\"",N,"\" "
+     "time=\"",Time,"\" "
+     "timestamp=\"",TS,"\" "
      "errors=\"",integer_to_list(E),"\" "
-     "tests=\"",integer_to_list(T),"\">",
+     "failures=\"",integer_to_list(F),"\" "
+     "skipped=\"",integer_to_list(S),"\" "
+     "tests=\"",integer_to_list(T),"\" ",
+     [["url=\"",Url,"\" "]||Url /= undefined],
+     "log=\"",Log,"\">",
      [to_xml(Case) || Case <- Cases],
      "</testsuite>"];
 to_xml(#state{ test_suites = TestSuites, axis = Axis, properties = Props }) ->
     ["<testsuites>",properties_to_xml(Axis,Props),
      [to_xml(TestSuite) || TestSuite <- TestSuites],"</testsuites>"].
 
+properties_to_xml([],[]) ->
+    [];
 properties_to_xml(Axis,Props) ->
     ["<properties>",
      [["<property name=\"",Name,"\" axis=\"yes\" value=\"",Value,"\" />"] || {Name,Value} <- Axis],
@@ -217,3 +298,37 @@ sanitize([]) ->
 now_to_string(Now) ->
     {{YY,MM,DD},{HH,Mi,SS}} = calendar:now_to_local_time(Now),
     io_lib:format("~p-~2..0B-~2..0BT~2..0B:~2..0B:~2..0B",[YY,MM,DD,HH,Mi,SS]).
+
+make_url(undefined,_) ->
+    undefined;
+make_url(_,[]) ->
+    undefined;
+make_url(UrlBase0,Log) ->
+    UrlBase = string:strip(UrlBase0,right,$/),
+    RelativeLog = get_relative_log_url(Log),
+    string:join([UrlBase,RelativeLog],"/").
+
+get_test_root(Log) ->
+    LogParts = filename:split(Log),
+    filename:join(lists:sublist(LogParts,1,length(LogParts)-?log_depth)).
+
+get_relative_log_url(Log) ->
+    LogParts = filename:split(Log),
+    Start = length(LogParts)-?log_depth,
+    Length = ?log_depth+1,
+    string:join(lists:sublist(LogParts,Start,Length),"/").
+
+count_tcs([#testcase{name=ConfCase}|TCs],Ok,F,S)
+  when ConfCase=="init_per_suite";
+       ConfCase=="end_per_suite";
+       ConfCase=="init_per_group";
+       ConfCase=="end_per_group" ->
+    count_tcs(TCs,Ok,F,S);
+count_tcs([#testcase{result=passed}|TCs],Ok,F,S) ->
+    count_tcs(TCs,Ok+1,F,S);
+count_tcs([#testcase{result={fail,_}}|TCs],Ok,F,S) ->
+    count_tcs(TCs,Ok,F+1,S);
+count_tcs([#testcase{result={skipped,_}}|TCs],Ok,F,S) ->
+    count_tcs(TCs,Ok,F,S+1);
+count_tcs([],Ok,F,S) ->
+    {Ok+F+S,F,S}.