Suppress warnings for expressions that are assigned to '_'

In c34ad2d5, the compiler learned to silence some warnings for
expressions that were explicitly assigned to the '_' variable,
as in this example:

  _ = list_to_integer(S),
  ok

That commit intentionally only made it possible to silence warnings
for BIFs that could cause an exception. Warnings would still be
produced for:

  _ = date(),
  ok

because date/0 can never fail and thus making the call completely
useless. The reasoning was that such warnings can always be
eliminated by eliminating the offending code.

While that is true, there is the question about rules and their
consistency. It is surprising that '_' can be used to silence
some warnings, but has no effect on other warnings.

Therefore, we will teach the compiler to silence warnings for
the following constructs:

  * Calls to safe BIFs such as date/0
  * Expressions that will cause an exception such as 'X/0'
  * Terms that are built but not used, such as '{x,X}'

3 files changed, 79 insertions, 38 deletions

diff --git a/lib/compiler/src/sys_core_fold.erl b/lib/compiler/src/sys_core_fold.erl
index 7066cebb2b..eeb3535936 100644
--- a/lib/compiler/src/sys_core_fold.erl
+++ b/lib/compiler/src/sys_core_fold.erl
@@ -680,23 +680,15 @@ count_bits_1(Int, Bits) -> count_bits_1(Int bsr 64, Bits+64).
 %%  a rewritten expression consisting of a sequence of
 %%  the arguments only is returned.
 
-useless_call(effect, #c_call{anno=Anno,
-			     module=#c_literal{val=Mod},
+useless_call(effect, #c_call{module=#c_literal{val=Mod},
 			     name=#c_literal{val=Name},
 			     args=Args}=Call) ->
     A = length(Args),
     case erl_bifs:is_safe(Mod, Name, A) of
 	false ->
 	    case erl_bifs:is_pure(Mod, Name, A) of
-		true ->
-		    case member(result_not_wanted, Anno) of
-			false ->
-			    add_warning(Call, result_ignored);
-			true ->
-			    ok
-		    end;
-		false ->
-		    ok
+		true -> add_warning(Call, result_ignored);
+		false -> ok
 	    end,
 	    no;
 	true ->
@@ -3101,7 +3093,7 @@ add_bin_opt_info(Core, Term) ->
     end.
 
 add_warning(Core, Term) ->
-    case is_compiler_generated(Core) of
+    case suppress_warning(Core) of
 	true ->
 	    ok;
 	false ->
@@ -3126,9 +3118,17 @@ get_file([{file,File}|_]) -> File;
 get_file([_|T]) -> get_file(T);
 get_file([]) -> "no_file". % should not happen
 
+suppress_warning(Core) ->
+    is_compiler_generated(Core) orelse
+	is_result_unwanted(Core).
+
 is_compiler_generated(Core) ->
-    Anno = core_lib:get_anno(Core),
-    member(compiler_generated, Anno).
+    Ann = cerl:get_ann(Core),
+    member(compiler_generated, Ann).
+
+is_result_unwanted(Core) ->
+    Ann = cerl:get_ann(Core),
+    member(result_not_wanted, Ann).
 
 get_warnings() ->
     ordsets:from_list((erase({?MODULE,warnings}))).
diff --git a/lib/compiler/src/v3_core.erl b/lib/compiler/src/v3_core.erl
index a9b54005d1..f0b90ff31c 100644
--- a/lib/compiler/src/v3_core.erl
+++ b/lib/compiler/src/v3_core.erl
@@ -515,16 +515,16 @@ exprs([], St) -> {[],St}.
 %%  Generate an internal core expression.
 
 expr({var,L,V}, St) -> {#c_var{anno=lineno_anno(L, St),name=V},[],St};
-expr({char,L,C}, St) -> {#c_literal{anno=lineno_anno(L, St),val=C},[],St};
-expr({integer,L,I}, St) -> {#c_literal{anno=lineno_anno(L, St),val=I},[],St};
-expr({float,L,F}, St) -> {#c_literal{anno=lineno_anno(L, St),val=F},[],St};
-expr({atom,L,A}, St) -> {#c_literal{anno=lineno_anno(L, St),val=A},[],St};
-expr({nil,L}, St) -> {#c_literal{anno=lineno_anno(L, St),val=[]},[],St};
-expr({string,L,S}, St) -> {#c_literal{anno=lineno_anno(L, St),val=S},[],St};
+expr({char,L,C}, St) -> {#c_literal{anno=full_anno(L, St),val=C},[],St};
+expr({integer,L,I}, St) -> {#c_literal{anno=full_anno(L, St),val=I},[],St};
+expr({float,L,F}, St) -> {#c_literal{anno=full_anno(L, St),val=F},[],St};
+expr({atom,L,A}, St) -> {#c_literal{anno=full_anno(L, St),val=A},[],St};
+expr({nil,L}, St) -> {#c_literal{anno=full_anno(L, St),val=[]},[],St};
+expr({string,L,S}, St) -> {#c_literal{anno=full_anno(L, St),val=S},[],St};
 expr({cons,L,H0,T0}, St0) ->
     {H1,Hps,St1} = safe(H0, St0),
     {T1,Tps,St2} = safe(T0, St1),
-    A = lineno_anno(L, St2),
+    A = full_anno(L, St2),
     {annotate_cons(A, H1, T1, St2),Hps ++ Tps,St2};
 expr({lc,L,E,Qs0}, St0) ->
     {Qs1,St1} = preprocess_quals(L, Qs0, St0),
@@ -536,7 +536,7 @@ expr({tuple,L,Es0}, St0) ->
     A = record_anno(L, St1),
     {annotate_tuple(A, Es1, St1),Eps,St1};
 expr({map,L,Es0}, St0) ->
-    map_build_pairs(#c_literal{val=#{}}, Es0, lineno_anno(L, St0), St0);
+    map_build_pairs(#c_literal{val=#{}}, Es0, full_anno(L, St0), St0);
 expr({map,L,M0,Es0}, St0) ->
     try expr_map(M0,Es0,lineno_anno(L, St0),St0) of
 	{_,_,_}=Res -> Res
@@ -551,7 +551,7 @@ expr({map,L,M0,Es0}, St0) ->
 		    args=As},[],St}
     end;
 expr({bin,L,Es0}, St0) ->
-    try expr_bin(Es0, lineno_anno(L, St0), St0) of
+    try expr_bin(Es0, full_anno(L, St0), St0) of
 	{_,_,_}=Res -> Res
     catch
 	throw:bad_binary ->
@@ -641,11 +641,11 @@ expr({'catch',L,E0}, St0) ->
     Lanno = lineno_anno(L, St1),
     {#icatch{anno=#a{anno=Lanno},body=Eps ++ [E1]},[],St1};
 expr({'fun',L,{function,F,A},{_,_,_}=Id}, St) ->
-    Lanno = lineno_anno(L, St),
+    Lanno = full_anno(L, St),
     {#c_var{anno=Lanno++[{id,Id}],name={F,A}},[],St};
 expr({'fun',L,{function,M,F,A}}, St0) ->
     {As,Aps,St1} = safe_list([M,F,A], St0),
-    Lanno = lineno_anno(L, St1),
+    Lanno = full_anno(L, St1),
     {#icall{anno=#a{anno=Lanno},
 	    module=#c_literal{val=erlang},
 	    name=#c_literal{val=make_fun},
@@ -656,13 +656,9 @@ expr({named_fun,L,'_',Cs,Id}, St) ->
     fun_tq(Id, Cs, L, St, unnamed);
 expr({named_fun,L,Name,Cs,Id}, St) ->
     fun_tq(Id, Cs, L, St, {named,Name});
-expr({call,L,{remote,_,M,F},As0}, #core{wanted=Wanted}=St0) ->
+expr({call,L,{remote,_,M,F},As0}, St0) ->
     {[M1,F1|As1],Aps,St1} = safe_list([M,F|As0], St0),
-    Lanno = lineno_anno(L, St1),
-    Anno = case Wanted of
-	       false -> [result_not_wanted|Lanno];
-	       true -> Lanno
-	   end,
+    Anno = full_anno(L, St1),
     {#icall{anno=#a{anno=Anno},module=M1,name=F1,args=As1},Aps,St1};
 expr({call,Lc,{atom,Lf,F},As0}, St0) ->
     {As1,Aps,St1} = safe_list(As0, St0),
@@ -724,13 +720,13 @@ expr({op,L,'orelse',E1,E2}, St0) ->
     expr(E, St);
 expr({op,L,Op,A0}, St0) ->
     {A1,Aps,St1} = safe(A0, St0),
-    LineAnno = lineno_anno(L, St1),
+    LineAnno = full_anno(L, St1),
     {#icall{anno=#a{anno=LineAnno},		%Must have an #a{}
 	    module=#c_literal{anno=LineAnno,val=erlang},
 	    name=#c_literal{anno=LineAnno,val=Op},args=[A1]},Aps,St1};
 expr({op,L,Op,L0,R0}, St0) ->
     {As,Aps,St1} = safe_list([L0,R0], St0),
-    LineAnno = lineno_anno(L, St1),
+    LineAnno = full_anno(L, St1),
     {#icall{anno=#a{anno=LineAnno},		%Must have an #a{}
 	    module=#c_literal{anno=LineAnno,val=erlang},
 	    name=#c_literal{anno=LineAnno,val=Op},args=As},Aps,St1}.
@@ -971,7 +967,7 @@ fun_tq({_,_,Name}=Id, Cs0, L, St0, NameInfo) ->
     {Cs1,Ceps,St1} = clauses(Cs0, St0),
     {Args,St2} = new_vars(Arity, St1),
     {Ps,St3} = new_vars(Arity, St2),		%Need new variables here
-    Anno = lineno_anno(L, St3),
+    Anno = full_anno(L, St3),
     Fc = function_clause(Ps, Anno, {Name,Arity}),
     Fun = #ifun{anno=#a{anno=Anno},
 		id=[{id,Id}],				%We KNOW!
@@ -2341,16 +2337,21 @@ record_anno(L, St) when L >= ?REC_OFFSET ->
         true ->
             [record | lineno_anno(L - ?REC_OFFSET, St)];
         false ->
-            lineno_anno(L, St)
+            full_anno(L, St)
     end;
 record_anno(L, St) when L < -?REC_OFFSET ->
     case member(dialyzer, St#core.opts) of
         true ->
             [record | lineno_anno(L + ?REC_OFFSET, St)];
         false ->
-            lineno_anno(L, St)
+            full_anno(L, St)
     end;
 record_anno(L, St) ->
+    full_anno(L, St).
+
+full_anno(L, #core{wanted=false}=St) ->
+    [result_not_wanted|lineno_anno(L, St)];
+full_anno(L, #core{wanted=true}=St) ->
     lineno_anno(L, St).
 
 lineno_anno(L, St) ->
diff --git a/lib/compiler/test/warnings_SUITE.erl b/lib/compiler/test/warnings_SUITE.erl
index 6e5a7d35e9..d59c89b264 100644
--- a/lib/compiler/test/warnings_SUITE.erl
+++ b/lib/compiler/test/warnings_SUITE.erl
@@ -39,7 +39,7 @@
 	 guard/1,bad_arith/1,bool_cases/1,bad_apply/1,
          files/1,effect/1,bin_opt_info/1,bin_construction/1,
 	 comprehensions/1,maps/1,redundant_boolean_clauses/1,
-	 latin1_fallback/1]).
+	 latin1_fallback/1,underscore/1]).
 
 % Default timetrap timeout (set in init_per_testcase).
 -define(default_timeout, ?t:minutes(2)).
@@ -64,7 +64,8 @@ groups() ->
       [pattern,pattern2,pattern3,pattern4,guard,
        bad_arith,bool_cases,bad_apply,files,effect,
        bin_opt_info,bin_construction,comprehensions,maps,
-       redundant_boolean_clauses,latin1_fallback]}].
+       redundant_boolean_clauses,latin1_fallback,
+       underscore]}].
 
 init_per_suite(Config) ->
     Config.
@@ -678,6 +679,45 @@ latin1_fallback(Conf) when is_list(Conf) ->
 
     ok.
 
+underscore(Config) when is_list(Config) ->
+    S0 = <<"f(A) ->
+              _VAR1 = <<A>>,
+              _VAR2 = {ok,A},
+              _VAR3 = [A],
+              ok.
+	    g(A) ->
+              _VAR1 = A/0,
+              _VAR2 = date(),
+	      ok.
+            h() ->
+               _VAR1 = fun() -> ok end,
+	      ok.
+            i(A) ->
+               _VAR1 = #{A=>42},
+	      ok.
+	 ">>,
+    Ts0 = [{underscore0,
+	    S0,
+	    [],
+	    {warnings,[{2,sys_core_fold,useless_building},
+		       {3,sys_core_fold,useless_building},
+		       {4,sys_core_fold,useless_building},
+		       {7,sys_core_fold,result_ignored},
+		       {8,sys_core_fold,{no_effect,{erlang,date,0}}},
+		       {11,sys_core_fold,useless_building},
+		       {14,sys_core_fold,useless_building}
+		      ]}}],
+    [] = run(Config, Ts0),
+
+    %% Replace all "_VAR<digit>" variables with a plain underscore.
+    %% Now there should be no warnings.
+    S1 = re:replace(S0, "_VAR\\d+", "_", [global]),
+    io:format("~s\n", [S1]),
+    Ts1 = [{underscore1,S1,[],[]}],
+    [] = run(Config, Ts1),
+
+    ok.
+
 %%%
 %%% End of test cases.
 %%%