dialyzer: Suppress warns on generated case stmts

Warnings about clauses that cannot match and are also compiler generated
are suppressed unless none of the clauses return.

This feature is useful for non-Erlang BEAM languages (such as Elixir)
that compile to Erlang and expand certain language constructs into case
statements. In that case, as long as the language construct can succeed,
these warnings are undesired and appear spurious to users that do not
check the Erlang code that their program expands into.

Thanks to José Valim for the test (slightly modified).

3 files changed, 111 insertions, 3 deletions

diff --git a/lib/dialyzer/test/Makefile b/lib/dialyzer/test/Makefile
index f43e04dd59..0d8fba438c 100644
--- a/lib/dialyzer/test/Makefile
+++ b/lib/dialyzer/test/Makefile
@@ -12,6 +12,7 @@ AUXILIARY_FILES=\
 	dialyzer_common.erl\
 	file_utils.erl\
 	dialyzer_SUITE.erl\
+	abstract_SUITE.erl\
 	plt_SUITE.erl
 
 # ----------------------------------------------------
diff --git a/lib/dialyzer/test/abstract_SUITE.erl b/lib/dialyzer/test/abstract_SUITE.erl
new file mode 100644
index 0000000000..269db3e836
--- /dev/null
+++ b/lib/dialyzer/test/abstract_SUITE.erl
@@ -0,0 +1,102 @@
+%% This suite contains cases that cannot be written
+%% in Erlang itself and must be done via the abstract
+%% format.
+
+-module(abstract_SUITE).
+
+-include_lib("common_test/include/ct.hrl").
+-include("dialyzer_test_constants.hrl").
+
+-export([suite/0, all/0, init_per_suite/0, init_per_suite/1]).
+-export([generated_case/1]).
+
+suite() ->
+    [{timetrap, {minutes, 1}}].
+all() ->
+    [generated_case].
+
+init_per_suite() ->
+  [{timetrap, ?plt_timeout}].
+init_per_suite(Config) ->
+  OutDir = ?config(priv_dir, Config),
+  case dialyzer_common:check_plt(OutDir) of
+    fail -> {skip, "Plt creation/check failed."};
+    ok -> [{dialyzer_options, []}|Config]
+  end.
+
+generated_case(Config) when is_list(Config) ->
+    %% Equivalent to:
+    %%
+    %% -module(foo).
+    %% -export(bar).
+    %% bar() ->
+    %%     Arg = sample,
+    %%     case Arg of
+    %%         #{} -> map;
+    %%         _ -> Arg:fn()
+    %%     end.
+    %%
+    %% Except the case statement and its clauses are marked as autogenerated.
+    [] =
+	test([{attribute,1,module,foo},
+	      {attribute,2,export,[{bar,0}]},
+	      {function,3,bar,0,
+	       [{clause,3,[],[],
+		 [{match,4,{var,4,'Arg'},{atom,4,sample}},
+		  {'case',[{location,5},{generated,true}],{var,5,'Arg'},
+		   [{clause,[{location,6},{generated,true}],[{map,6,[]}],[],
+		     [{atom,6,map}]},
+		    {clause,[{location,7},{generated,true}],[{var,7,'_'}],[],
+		     [{call,7,{remote,7,{var,7,'Arg'},{atom,7,fn}},[]}]}]}]}]}],
+	     Config, [], []),
+    %% With the first clause not auto-generated
+    [{warn_matching,{_,6},_}] =
+	test([{attribute,1,module,foo},
+	      {attribute,2,export,[{bar,0}]},
+	      {function,3,bar,0,
+	       [{clause,3,[],[],
+		 [{match,4,{var,4,'Arg'},{atom,4,sample}},
+		  {'case',[{location,5},{generated,true}],{var,5,'Arg'},
+		   [{clause,6,[{map,6,[]}],[],
+		     [{atom,6,map}]},
+		    {clause,[{location,7},{generated,true}],[{var,7,'_'}],[],
+		     [{call,7,{remote,7,{var,7,'Arg'},{atom,7,fn}},[]}]}]}]}]}],
+	     Config, [], []),
+    %% With Arg set to [] so neither clause matches
+    [{warn_return_no_exit,{_,3},_},
+     {warn_matching,{_,6},_},
+     {warn_failing_call,{_,7},_}] =
+	test([{attribute,1,module,foo},
+	      {attribute,2,export,[{bar,0}]},
+	      {function,3,bar,0,
+	       [{clause,3,[],[],
+		 [{match,4,{var,4,'Arg'},{nil,4}},
+		  {'case',[{location,5},{generated,true}],{var,5,'Arg'},
+		   [{clause,[{location,6},{generated,true}],[{map,6,[]}],[],
+		     [{atom,6,map}]},
+		    {clause,[{location,7},{generated,true}],[{var,7,'_'}],[],
+		     [{call,7,{remote,7,{var,7,'Arg'},{atom,7,fn}},[]}]}]}]}]}],
+	     Config, [], []),
+    ok.
+
+test(Prog, Config, COpts, DOpts) ->
+    {ok, BeamFile} = compile(Config, Prog, COpts),
+    run_dialyzer(Config, succ_typings, [BeamFile], DOpts).
+
+compile(Config, Prog, CompileOpts) ->
+    OutDir = ?config(priv_dir, Config),
+    Opts = [{outdir, OutDir}, debug_info, return_errors | CompileOpts],
+    {ok, Module, Source} = compile:forms(Prog, Opts),
+    BeamFile = filename:join([OutDir, lists:concat([Module, ".beam"])]),
+    ok = file:write_file(BeamFile, Source),
+    {ok, BeamFile}.
+
+run_dialyzer(Config, Analysis, Files, Opts) ->
+    OutDir = ?config(priv_dir, Config),
+    PltFilename = dialyzer_common:plt_file(OutDir),
+    dialyzer:run([{analysis_type, Analysis},
+		  {files, Files},
+		  {init_plt, PltFilename},
+		  {check_plt, false},
+		  {from, byte_code} |
+		  Opts]).
diff --git a/lib/dialyzer/test/dialyzer_common.erl b/lib/dialyzer/test/dialyzer_common.erl
index d2b1026c06..48083a2731 100644
--- a/lib/dialyzer/test/dialyzer_common.erl
+++ b/lib/dialyzer/test/dialyzer_common.erl
@@ -7,7 +7,7 @@
 
 -module(dialyzer_common).
 
--export([check_plt/1, check/4, create_all_suites/0, new_tests/2]).
+-export([check_plt/1, check/4, create_all_suites/0, new_tests/2, plt_file/1]).
 
 -include_lib("kernel/include/file.hrl").
 
@@ -39,7 +39,7 @@
 
 check_plt(OutDir) ->
     io:format("Checking plt:"),
-    PltFilename = filename:join(OutDir, ?plt_filename),
+    PltFilename = plt_file(OutDir),
     case file:read_file_info(PltFilename) of
 	{ok, _} -> dialyzer_check_plt(PltFilename);
 	{error, _ } ->
@@ -63,6 +63,11 @@ check_plt(OutDir) ->
 	    end
     end.
 
+-spec plt_file(string()) -> string().
+
+plt_file(OutDir) ->
+    filename:join(OutDir, ?plt_filename).
+
 dialyzer_check_plt(PltFilename) ->
     try dialyzer:run([{analysis_type, plt_check},
 		      {init_plt, PltFilename}]) of
@@ -119,7 +124,7 @@ build_plt(PltFilename) ->
 		   'same' | {differ, [term()]}.
 
 check(TestCase, Opts, Dir, OutDir) ->
-    PltFilename = filename:join(OutDir, ?plt_filename),
+    PltFilename = plt_file(OutDir),
     SrcDir = filename:join(Dir, ?input_files_directory),
     ResDir = filename:join(Dir, ?result_files_directory),
     Filename = filename:join(SrcDir, atom_to_list(TestCase)),