dialyzer: Silence useless warnings about list comprehensions

Dialyzer will warn if the value of list comprehension is
ignored by putting it in a sequence like this:

  [SomeSideEffect(E) || E <- Es],
  ok

To avoid a warning, you'll have to write:

  _ = [SomeSideEffect(E) || E <- Es],
  ok

Most of the time, this warning is merely annoying because it does
not point out any real errors.

Kostis Sagonas suggested that by suppressing the warning for
list comprehension that return a list of a simple type (e.g. ['ok']),
there would be no warning for code such as:

  [io:format("~p\n", [E]) || E <- Es],
  ok

but there would be still be a warning for:

  [file:close(Fd) || Fd <- Fds],
  ok

because an error condition is ignored.

4 files changed, 110 insertions, 0 deletions

diff --git a/lib/dialyzer/test/unmatched_returns_SUITE_data/dialyzer_options b/lib/dialyzer/test/unmatched_returns_SUITE_data/dialyzer_options
new file mode 100644
index 0000000000..49ac917f61
--- /dev/null
+++ b/lib/dialyzer/test/unmatched_returns_SUITE_data/dialyzer_options
@@ -0,0 +1 @@
+{dialyzer_options, [{warnings, [unmatched_returns]}]}.
diff --git a/lib/dialyzer/test/unmatched_returns_SUITE_data/results/lc_warnings b/lib/dialyzer/test/unmatched_returns_SUITE_data/results/lc_warnings
new file mode 100644
index 0000000000..2784f2119e
--- /dev/null
+++ b/lib/dialyzer/test/unmatched_returns_SUITE_data/results/lc_warnings
@@ -0,0 +1,5 @@
+
+lc_warnings.erl:32: Expression produces a value of type [opaque_atom_adt:opaque_atom()], but this value is unmatched
+lc_warnings.erl:43: Expression produces a value of type [array()], but this value is unmatched
+lc_warnings.erl:65: Expression produces a value of type [lc_warnings:opaque_tuple()], but this value is unmatched
+lc_warnings.erl:7: Expression produces a value of type ['ok' | {'error',atom()}], but this value is unmatched
diff --git a/lib/dialyzer/test/unmatched_returns_SUITE_data/src/lc_warnings/lc_warnings.erl b/lib/dialyzer/test/unmatched_returns_SUITE_data/src/lc_warnings/lc_warnings.erl
new file mode 100644
index 0000000000..cb01a8fde3
--- /dev/null
+++ b/lib/dialyzer/test/unmatched_returns_SUITE_data/src/lc_warnings/lc_warnings.erl
@@ -0,0 +1,95 @@
+-module(lc_warnings).
+-compile([export_all]).
+
+close(Fs) ->
+    %% There should be a warning since we ignore a potential
+    %% {error,Error} return from file:close/1.
+    [file:close(F) || F <- Fs],
+
+    %% No warning because the type of unmatched return will be ['ok']
+    %% (which is a list of a simple type).
+    [ok = file:close(F) || F <- Fs],
+
+    %% Suppressed.
+    _ = [file:close(F) || F <- Fs],
+    ok.
+
+format(X) ->
+    %% No warning since the result of the list comprehension is
+    %% a list of simple.
+    [io:format("~p\n", [E]) || E <- X],
+
+    %% Warning explicitly suppressed.
+    _ = [io:format("~p\n", [E]) || E <- X],
+    ok.
+
+opaque1() ->
+    List = gen_atom(),
+    %% This is a list of an externally defined opaque type. Since
+    %% we are not allowed to peek inside opaque types, there should
+    %% be a warning (even though the type in this case happens to be
+    %% an atom).
+    [E || E <- List],
+
+    %% Suppressed.
+    _ = [E || E <- List],
+    ok.
+
+opaque2() ->
+    List = gen_array(),
+    %% This is an list of an externally defined opaque type. Since
+    %% we are not allowed to peek inside opaque types, there should
+    %% be a warning.
+    [E || E <- List],
+
+    %% Suppressed.
+    _ = [E || E <- List],
+    ok.
+
+opaque3() ->
+    List = gen_int(),
+
+    %% No warning, since we are allowed to look into the type and can
+    %% see that it is a simple type.
+    [E || E <- List],
+
+    %% Suppressed.
+    _ = [E || E <- List],
+    ok.
+
+opaque4() ->
+    List = gen_tuple(),
+
+    %% There should be a warning, since we are allowed to look inside
+    %% the opaque type and see that it is a tuple (non-simple).
+    [E || E <- List],
+
+    %% Suppressed.
+    _ = [E || E <- List],
+    ok.
+
+gen_atom() ->
+    [opaque_atom_adt:atom(ok)].
+
+gen_array() ->
+    [array:new()].
+
+
+gen_int() ->
+    [opaque_int(42)].
+
+gen_tuple() ->
+    [opaque_tuple(x, 25)].
+
+-opaque opaque_int() :: integer().
+
+-spec opaque_int(integer()) -> opaque_int().
+
+opaque_int(Int) -> Int.
+
+-opaque opaque_tuple() :: {any(),any()}.
+
+-spec opaque_tuple(any(), any()) -> opaque_tuple().
+
+opaque_tuple(X, Y) ->
+    {X,Y}.
diff --git a/lib/dialyzer/test/unmatched_returns_SUITE_data/src/lc_warnings/opaque_atom_adt.erl b/lib/dialyzer/test/unmatched_returns_SUITE_data/src/lc_warnings/opaque_atom_adt.erl
new file mode 100644
index 0000000000..b5b51fe75b
--- /dev/null
+++ b/lib/dialyzer/test/unmatched_returns_SUITE_data/src/lc_warnings/opaque_atom_adt.erl
@@ -0,0 +1,9 @@
+-module(opaque_atom_adt).
+-export([atom/1]).
+
+-opaque opaque_atom() :: atom().
+
+-spec atom(atom()) -> opaque_atom().
+
+atom(Atom) ->
+    Atom.