diameter_spec_util -> diameter_dict_util and adapt to parser

Errors are now detected after the parse with format_error/1
providing understandable error messages, pointing to the
offending line number(s) in the dictionary source.

4 files changed, 1137 insertions, 1089 deletions

diff --git a/lib/diameter/src/compiler/diameter_dict_util.erl b/lib/diameter/src/compiler/diameter_dict_util.erl
new file mode 100644
index 0000000000..7c992316f9
--- /dev/null
+++ b/lib/diameter/src/compiler/diameter_dict_util.erl
@@ -0,0 +1,1108 @@
+%%
+%% %CopyrightBegin%
+%%
+%% Copyright Ericsson AB 2010-2011. All Rights Reserved.
+%%
+%% The contents of this file are subject to the Erlang Public License,
+%% Version 1.1, (the "License"); you may not use this file except in
+%% compliance with the License. You should have received a copy of the
+%% Erlang Public License along with this software. If not, it can be
+%% retrieved online at http://www.erlang.org/.
+%%
+%% Software distributed under the License is distributed on an "AS IS"
+%% basis, WITHOUT WARRANTY OF ANY KIND, either express or implied. See
+%% the License for the specific language governing rights and limitations
+%% under the License.
+%%
+%% %CopyrightEnd%
+%%
+
+%%
+%% This module turns a dictionary file into the orddict that
+%% diameter_codegen.erl in turn morphs into .erl and .hrl files for
+%% encode and decode of Diameter messages and AVPs.
+%%
+
+-module(diameter_dict_util).
+
+-export([parse/2,
+         format_error/1]).
+
+-include("diameter_vsn.hrl").
+
+-define(RETURN(T), throw({T, ?MODULE, ?LINE})).
+-define(RETURN(T, Args), ?RETURN({T, Args})).
+
+-define(A, list_to_atom).
+-define(L, atom_to_list).
+
+%% ===========================================================================
+%% parse/2
+%% ===========================================================================
+
+-spec parse(File, Opts)
+   -> {ok, orddict:orddict()}
+    | {error, term()}
+ when File :: {path, string()}
+            | string()
+            | binary(),
+      Opts :: list().
+
+parse(File, Opts) ->
+    put({?MODULE, verbose}, lists:member(verbose, Opts)),
+    try
+        {ok, do_parse(File, Opts)}
+    catch
+        {Reason, ?MODULE, _Line} ->
+            {error, Reason}
+    after
+        erase({?MODULE, verbose})
+    end.
+
+%% ===========================================================================
+%% format_error/1
+%% ===========================================================================
+
+format_error({read, Reason}) ->
+    file:format_error(Reason);
+format_error({scan, Reason}) ->
+    diameter_dict_scanner:format_error(Reason);
+format_error({parse, {Line, _Mod, Reason}}) ->
+    lists:flatten(["Line ", integer_to_list(Line), ", ", Reason]);
+
+format_error(T) ->
+    {Fmt, As} = fmt(T),
+    lists:flatten(io_lib:format(Fmt, As)).
+
+fmt({avp_code_already_defined, [Code, false, Name, Line, L]}) ->
+    {"AVP ~p (~s) at line ~p already defined at line ~p",
+     [Code, Name, Line, L]};
+
+fmt({Reason, As}) ->
+    {fmt(Reason), As};
+
+fmt(avp_code_already_defined) ->
+    "AVP ~p/~p (~s) at line ~p already defined at line ~p";
+
+fmt(imported_avp_already_defined) ->
+    "AVP ~s imported by @inherits ~p at line ~p defined at line ~p";
+fmt(duplicate_import) ->
+    "AVP ~s is imported by more than one @inherits, both at line ~p "
+    "and at line ~p";
+
+fmt(duplicate_section) ->
+    "Section @~s at line ~p already declared at line ~p";
+
+fmt(already_declared) ->
+    "Section @~p ~s at line ~p already declared at line ~p";
+
+fmt(inherited_avp_already_defined) ->
+    "AVP ~s inherited at line ~p defined in @avp_types at line ~p";
+fmt(avp_already_defined) ->
+    "AVP ~s at line ~p already in @~p at line ~p";
+fmt(key_already_defined) ->
+    "Value for ~s:~s in @~p at line ~p already provided at line ~p";
+
+fmt(messages_without_id) ->
+    "@messages at line ~p but @id not declared";
+
+fmt(avp_name_already_defined) ->
+    "AVP ~s at line ~p already defined at line ~p";
+fmt(avp_has_unknown_type) ->
+    "AVP ~s at line ~p defined with unknown type ~s";
+fmt(avp_has_invalid_flag) ->
+    "AVP ~s at line ~p specifies invalid flag ~c";
+fmt(avp_has_duplicate_flag) ->
+    "AVP ~s at line ~p specifies duplicate flag ~c";
+fmt(avp_has_vendor_id) ->
+    "AVP ~s at line ~p does not specify V flag "
+    "but is assigned vendor id ~p at line ~p";
+fmt(avp_has_no_vendor) ->
+    "AVP ~s at line ~p specifies V flag "
+    "but neither @vendor_avp_id nor @vendor supplies a value";
+
+fmt(group_already_defined) ->
+    "Group ~s at line ~p already defined at line ~p";
+fmt(grouped_avp_code_mismatch) ->
+    "AVP ~s at line ~p has with code ~p "
+    "but @avp_types specifies ~p at line ~p";
+fmt(grouped_avp_has_wrong_type) ->
+    "Grouped AVP ~s at line ~p defined with type ~s at line ~p";
+fmt(grouped_avp_not_defined) ->
+    "Grouped AVP ~s on line ~p not defined in @avp_types";
+fmt(grouped_vendor_id_without_flag) ->
+    "Grouped AVP ~s at line ~p has vendor id "
+    "but definition at line ~p does not specify V flag";
+fmt(grouped_vendor_id_mismatch) ->
+    "Grouped AVP ~s at line ~p has vendor id ~p "
+    "but ~p specified at line ~p";
+
+fmt(message_name_already_defined) ->
+    "Message ~s at line ~p already defined at line ~p";
+fmt(message_code_already_defined) ->
+    "~s message with code ~p at line ~p already defined at line ~p";
+fmt(message_has_duplicate_flag) ->
+    "Message ~s has duplicate flag ~s at line ~p";
+fmt(message_application_id_mismatch) ->
+    "Message ~s has application id ~p at line ~p "
+    "but @id specifies ~p at line ~p";
+
+fmt(invalid_avp_order) ->
+    "AVP reference ~c~s~c at line ~p breaks fixed/required/optional order";
+fmt(invalid_qualifier) ->
+    "Qualifier ~p*~p at line ~p has Min > Max";
+fmt(avp_already_referenced) ->
+    "AVP ~s at line ~p already referenced at line ~p";
+
+fmt(message_missing) ->
+    "~s message at line ~p but no ~s message is defined";
+
+fmt(requested_avp_not_found) ->
+    "@inherit ~s at line ~p requests AVP ~s at line ~p "
+    "but module does not define that AVP";
+
+fmt(enumerated_avp_has_wrong_local_type) ->
+    "Enumerated AVP ~s in @enum at line ~p defined with type ~s at line ~p";
+fmt(enumerated_avp_has_wrong_inherited_type) ->
+    "Enumerated AVP ~s in @enum at line ~p "
+    "inherited with type ~s from module ~s at line ~p";
+fmt(enumerated_avp_not_defined) ->
+    "Enumerated AVP ~s in @enum at line ~p neither defined nor inherited";
+
+fmt(avp_not_defined) ->
+    "AVP ~s referenced at line ~p neither defined nor inherited";
+
+fmt(beam_not_on_path) ->
+    "Module ~s not found";
+
+fmt(recompile) ->
+    "Module ~p appears to have been compiler with an incompatible "
+    "version of the dictionary compiler and must be recompiled";
+fmt(no_dict) ->
+    "Module ~p does not appear to be a diameter dictionary".
+
+%% ===========================================================================
+%% ===========================================================================
+
+do_parse(File, Opts) ->
+    Bin  = do([fun read/1, File], read),
+    Toks = do([fun diameter_dict_scanner:scan/1, Bin], scan),
+    Tree = do([fun diameter_dict_parser:parse/1, Toks], parse),
+    make_dict(Tree, Opts).
+
+do([F|A], E) ->
+    case apply(F,A) of
+        {ok, T} ->
+            T;
+        {error, Reason} ->
+            ?RETURN({E, Reason})
+    end.
+
+read({path, Path}) ->
+    file:read_file(Path);
+read(File) ->
+    {ok, File}.
+
+make_dict(Parse, Opts) ->
+    make_orddict(pass4(pass3(pass2(pass1(reset(make_dict(Parse),
+                                               Opts))),
+                             Opts))).
+
+%% make_orddict/1
+
+make_orddict(Dict) ->
+    dict:fold(fun mo/3,
+              orddict:from_list([{K,[]} || K <- [avp_types,
+                                                 messages,
+                                                 grouped,
+                                                 inherits,
+                                                 custom_types,
+                                                 codecs,
+                                                 avp_vendor_id,
+                                                 enum,
+                                                 define]]),
+              Dict).
+
+mo(K, Sects, Dict)
+  when is_atom(K) ->
+    orddict:store(K, make(K, Sects), Dict);
+
+mo(_, _, Dict) ->
+    Dict.
+
+make(K, [[_Line, {_, _, X}]])
+  when K == id;
+       K == name;
+       K == prefix ->
+    X;
+
+make(vendor, [[_Line, {_, _, Id}, {_, _, Name}]]) ->
+    {Id, Name};
+
+make(K, T)
+  when K == command_codes;
+       K == import_avps;
+       K == import_groups;
+       K == import_enums ->
+    T;
+
+make(K, Sects) ->
+    post(K, foldl(fun([_L|B], A) -> make(K,B,A) end,
+                  [],
+                  Sects)).
+
+post(avp_types, L) ->
+    lists:sort(L);
+
+post(K, L)
+  when K == grouped;
+       K == messages;
+       K == enum;
+       K == define ->
+    lists:reverse(L);
+
+post(_, L) ->
+    L.
+
+make(K, [{_,_,Name} | Body], Acc)
+  when K == enum;
+       K == define;
+       K == avp_vendor_id;
+       K == custom_types;
+       K == inherits;
+       K == codecs ->
+    [{Name, mk(K, Body)} | Acc];
+
+make(K, Body, Acc) ->
+    foldl(fun(T,A) -> [mk(K, T) | A] end, Acc, Body).
+
+mk(avp_types, [{_,_,Name}, {_,_,Code}, {_,_,Type}, {_,_,Flags}]) ->
+    {Name, Code, type(Type), Flags};
+
+mk(messages, [{'answer-message' = A, _}, false | Avps]) ->
+    {?L(A), -1, ['ERR', 'PXY'], [], make_body(Avps)};
+
+mk(messages, [{_,_,Name}, [{_,_,Code}, Flags, ApplId] | Avps]) ->
+    {Name,
+     Code,
+     lists:map(fun({F,_}) -> F end, Flags),
+     opt(ApplId),
+     make_body(Avps)};
+
+mk(grouped, [{_,_,Name}, [{_,_,Code}, Vid] | Avps]) ->
+    {Name, Code, opt(Vid), make_body(Avps)};
+
+mk(K, Body)
+  when K == enum;
+       K == define ->
+    lists:map(fun([{_,_,Name}, {_,_,Value}]) -> {Name, Value} end, Body);
+
+mk(K, Avps)
+  when K == avp_vendor_id;
+       K == custom_types;
+       K == inherits;
+       K == codecs ->
+    lists:map(fun({_,_,N}) -> N end, Avps).
+
+opt(false) ->
+    [];
+opt({_,_,X}) ->
+    [X].
+
+make_body(Avps) ->
+    lists:map(fun avp/1, Avps).
+
+avp([false, D, Avp]) ->
+    avp(D, Avp);
+avp([Q, D, Avp]) ->
+    {qual(Q), avp(D, Avp)}.
+
+avp(D, {'AVP', _}) ->
+    delim(D, "AVP");
+avp(D, {_, _, Name}) ->
+    delim(D, Name).
+
+delim($<, N) ->
+    {{N}};
+delim(${, N) ->
+    {N};
+delim($[, N) ->
+    [N].
+
+qual({true, {_,_,N}}) ->
+    {'*', N};
+qual({{_,_,N}, true}) ->
+    {N, '*'};
+qual({{_,_,N},{_,_,M}}) ->
+    {N, M};
+qual(true) ->
+    '*'.
+
+%% Optional reports when running verbosely.
+report(What, [F | A])
+  when is_function(F) ->
+    report(What, apply(F, A));
+report(What, Data) ->
+    report(get({?MODULE, verbose}), What, Data).
+
+report(true, Tag, Data) ->
+    io:format("##~n## ~p ~p~n", [Tag, Data]);
+report(false, _, _) ->
+    ok.
+
+%% ------------------------------------------------------------------------
+%% make_dict/1
+%%
+%% Turn a parsed dictionary into an dict.
+
+make_dict(Parse) ->
+    foldl(fun(T,A) ->
+                  report(section, T),
+                  section(T,A)
+          end,
+          dict:new(),
+          Parse).
+
+section([{T, L} | Rest], Dict)
+  when T == name;
+       T == prefix;
+       T == id;
+       T == vendor ->
+    case find(T, Dict) of
+        [] ->
+            dict:store(T, [[L | Rest]], Dict);
+        [[Line | _]] ->
+            ?RETURN(duplicate_section, [T, L, Line])
+    end;
+
+section([{T, L} | Rest], Dict)
+  when T == avp_types;
+       T == messages;
+       T == grouped;
+       T == inherits;
+       T == custom_types;
+       T == codecs;
+       T == avp_vendor_id;
+       T == enum;
+       T == define ->
+    dict:append(T, [L | Rest], Dict).
+
+%% ===========================================================================
+%% reset/2
+%%
+%% Reset sections from options.
+
+reset(Dict, Opts) ->
+    foldl([fun reset/3, Opts], Dict, [name, prefix, inherits]).
+
+reset(K, Dict, Opts) ->
+    foldl(fun opt/2, Dict, [T || {A,_} = T <- Opts, A == K]).
+
+opt({inherits = Key, "-"}, Dict) ->
+    dict:erase(Key, Dict);
+opt({inherits = Key, Mod}, Dict) ->
+    dict:append(Key, [0, {word, 0, Mod}], Dict);
+opt({Key, Val}, Dict) ->
+    dict:store(Key, [0, {word, 0, Val}], Dict);
+opt(_, Dict) ->
+    Dict.
+
+%% ===========================================================================
+%% pass1/1
+%%
+%% Explode sections into additional dictionary entries plus semantic
+%% checks.
+
+pass1(Dict) ->
+    true = no_messages_without_id(Dict),
+
+    foldl(fun(K,D) -> foldl([fun p1/3, K], D, find(K,D)) end,
+          Dict,
+          [avp_types,  %% must precede inherits, grouped, enum
+           avp_vendor_id,
+           custom_types,
+           codecs,
+           inherits,
+           grouped,
+           messages,
+           enum,
+           define]).
+
+%% Multiple sections are allowed as long as their bodies don't
+%% overlap. (Except enum/define.)
+
+p1([_Line, X | Body], Dict, K)
+  when K == avp_vendor_id;
+       K == custom_types;
+       K == codecs;
+       K == inherits ->
+    foldl([fun explode/4, X, K], Dict, Body);
+
+p1([_Line, X | Body], Dict, K)
+  when K == define;
+       K == enum ->
+    {_, L, Name} = X,
+    foldl([fun explode2/4, X, K],
+          store_new({K, Name},
+                    [L, Body],
+                    Dict,
+                    [K, Name, L],
+                    already_declared),
+          Body);
+
+p1([_Line | Body], Dict, K)
+  when K == avp_types;
+       K == grouped;
+       K == messages ->
+    foldl([fun explode/3, K], Dict, Body).
+
+no_messages_without_id(Dict) ->
+    case find(messages, Dict) of
+        [] ->
+            true;
+        [[Line | _] | _] ->
+            [] /= find(id, Dict) orelse ?RETURN(messages_without_id, [Line])
+    end.
+
+%% Note that the AVP's in avp_vendor_id, custom_types, codecs and
+%% enum can all be inherited, as can the AVP content of messages and
+%% grouped AVP's. Check that the referenced AVP's exist after
+%% importing definitions.
+
+%% explode/4
+%%
+%% {avp_vendor_id, AvpName}                 -> [Lineno, Id::integer()]
+%% {custom_types|codecs|inherits,  AvpName} -> [Lineno, Mod::string()]
+
+explode({_, Line, AvpName}, Dict, {_, _, X}, K) ->
+    true = K /= inherits orelse avp_not_local(AvpName, Line, Dict),
+
+    store_new({key(K), AvpName},
+              [Line, X],
+              Dict,
+              [AvpName, Line, K],
+              avp_already_defined).
+
+%% explode2/4
+
+%% {define, {Name, Key}} -> [Lineno, Value::integer(), enum|define]
+
+explode2([{_, Line, Key}, {_, _, Value}], Dict, {_, _, X}, K) ->
+    store_new({key(K), {X, Key}},
+              [Line, Value, K],
+              Dict,
+              [X, Key, K, Line],
+              key_already_defined).
+
+%% key/1
+%%
+%% Conflate keys that are equivalent as far as uniqueness of
+%% definition goes.
+
+key(K)
+  when K == enum;
+       K == define ->
+    define;
+key(K)
+  when K == custom_types;
+       K == codecs ->
+    custom;
+key(K) ->
+    K.
+
+%% explode/3
+
+%% {avp_types, AvpName}       -> [Line | Toks]
+%% {avp_types, {Code, IsReq}} -> [Line, AvpName]
+%%
+%% where AvpName = string()
+%%       Code    = integer()
+%%       IsReq   = boolean()
+
+explode([{_, Line, Name} | Toks], Dict0, avp_types = K) ->
+    %% Each AVP can be defined only once.
+    Dict1 = store_new({K, Name},
+                      [Line | Toks],
+                      Dict0,
+                      [Name, Line],
+                      avp_name_already_defined),
+
+    [{number, _, _Code}, {word, _, Type}, {word, _, _Flags}] = Toks,
+
+    true = avp_type_known(Type, Name, Line),
+
+    Dict1;
+
+%% {grouped, Name}            -> [Line, HeaderTok | AvpToks]
+%% {grouped, {Name, AvpName}} -> [Line, Qual, Delim]
+%%
+%% where Name  = string()
+%%       AvpName = string()
+%%       Qual  = {Q, Q} | boolean()
+%%       Q     = true | NumberTok
+%%       Delim = $< | ${ | $[
+
+explode([{_, Line, Name}, Header | Avps], Dict0, grouped = K) ->
+    Dict = store_new({K, Name},
+                     [Line, Header | Avps],
+                     Dict0,
+                     [Name, Line],
+                     group_already_defined),
+
+    [{_,_, Code}, Vid] = Header,
+    {DefLine, {_, _, Flags}} = grouped_flags(Name, Code, Dict0, Line),
+    V = lists:member($V, Flags),
+
+    false = vendor_id_mismatch(Vid, V, Name, Dict0, Line, DefLine),
+
+    explode_avps(Avps, Dict, K, Name);
+
+%% {messages, Name}            -> [Line, HeaderTok | AvpToks]
+%% {messages, {Code, IsReq}}   -> [Line, NameTok]
+%% {messages, Code}            -> [[Line, NameTok, IsReq]]
+%% {messages, {Name, Flag}}    -> [Line]
+%% {messages, {Name, AvpName}} -> [Line, Qual, Delim]
+%%
+%% where Name  = string()
+%%       Code  = integer()
+%%       IsReq = boolean()
+%%       Flag  = 'REQ' | 'PXY'
+%%       AvpName = string()
+%%       Qual  = true | {Q,Q}
+%%       Q     = true | NumberTok
+%%       Delim = $< | ${ | ${
+
+explode([{'answer-message' = A, Line}, false = H | Avps],
+        Dict0,
+        messages = K) ->
+    Name = ?L(A),
+    Dict1 = store_new({K, Name},
+                      [Line, H, Avps],
+                      Dict0,
+                      [Name, Line],
+                      message_name_already_defined),
+
+    explode_avps(Avps, Dict1, K, Name);
+
+explode([{_, Line, MsgName} = M, Header | Avps],
+        Dict0,
+        messages = K) ->
+    %% There can be at most one message with a given name.
+    Dict1 = store_new({K, MsgName},
+                      [Line, Header | Avps],
+                      Dict0,
+                      [MsgName, Line],
+                      message_name_already_defined),
+
+    [{_, _, Code}, Bits, ApplId] = Header,
+
+    %% An application id specified as part of the message definition
+    %% has to agree with @id. The former is parsed just because RFC
+    %% 3588 specifies it.
+    false = application_id_mismatch(ApplId, Dict1, MsgName),
+
+    IsReq = lists:keymember('REQ', 1, Bits),
+
+    %% For each command code, there can be at most one request and
+    %% one answer.
+    Dict2 = store_new({K, {Code, IsReq}},
+                      [Line, M],
+                      Dict1,
+                      [choose(IsReq, "Request", "Answer"), Code, Line],
+                      message_code_already_defined),
+
+    %% For each message, each flag can occur at most once.
+    Dict3 = foldl(fun({F,L},D) ->
+                          store_new({K, {MsgName, F}},
+                                    [L],
+                                    D,
+                                    [MsgName, ?L(F)],
+                                    message_has_duplicate_flag)
+                  end,
+                  Dict2,
+                  Bits),
+
+    dict:append({K, Code},
+                [Line, M, IsReq],
+                explode_avps(Avps, Dict3, K, MsgName)).
+
+%% explode_avps/4
+%%
+%% Ensure required AVP order and sane qualifiers. Can't check for AVP
+%% names until after they've been imported.
+%%
+%% RFC 3588 allows a trailing fixed while 3588bis doesn't. Parse the
+%% former.
+
+explode_avps(Avps, Dict, Key, Name) ->
+    xa("<{[<", Avps, Dict, Key, Name).
+
+xa(_, [], Dict, _, _) ->
+    Dict;
+
+xa(Ds, [[Qual, D, {'AVP', Line}] | Avps], Dict, Key, Name) ->
+    xa(Ds, [[Qual, D, {word, Line, "AVP"}] | Avps], Dict, Key, Name);
+
+xa([], [[_Qual, D, {_, Line, Name}] | _], _, _, _) ->
+    ?RETURN(invalid_avp_order, [D, Name, close(D), Line]);
+
+xa([D|_], [[{{_, Line, Min}, {_, _, Max}}, D, _] | _], _, _, _)
+  when Min > Max ->
+    ?RETURN(invalid_qualifier, [Min, Max, Line]);
+
+xa([D|_] = Ds, [[Qual, D, {_, Line, AvpName}] | Avps], Dict, Key, Name) ->
+    xa(Ds,
+       Avps,
+       store_new({Key, {Name, AvpName}},
+                 [Line, Qual, D],
+                 Dict,
+                 [Name, Line],
+                 avp_already_referenced),
+       Key,
+       Name);
+
+xa([_|Ds], Avps, Dict, Key, Name) ->
+    xa(Ds, Avps, Dict, Key, Name).
+
+close($<) -> $>;
+close(${) -> $};
+close($[) -> $].
+
+%% application_id_mismatch/3
+
+application_id_mismatch({number, Line, Id}, Dict, MsgName) ->
+    [[_, {_, L, I}]] = dict:fetch(id, Dict),
+
+    I /= Id andalso ?RETURN(message_application_id_mismatch,
+                            [MsgName, Id, Line, I, L]);
+
+application_id_mismatch(false = No, _, _) ->
+    No.
+
+%% avp_not_local/3
+
+avp_not_local(Name, Line, Dict) ->
+    A = find({avp_types, Name}, Dict),
+
+    [] == A orelse ?RETURN(inherited_avp_already_defined,
+                           [Name, Line, hd(A)]).
+
+%% avp_type_known/3
+
+avp_type_known(Type, Name, Line) ->
+    false /= type(Type)
+        orelse ?RETURN(avp_has_unknown_type, [Name, Line, Type]).
+
+%% vendor_id_mismatch/6
+
+vendor_id_mismatch({_,_,_}, false, Name, _, Line, DefLine) ->
+    ?RETURN(grouped_vendor_id_without_flag, [Name, Line, DefLine]);
+
+vendor_id_mismatch({_, _, I}, true, Name, Dict, Line, _) ->
+    case vendor_id(Name, Dict) of
+        {avp_vendor_id, L, N} ->
+            I /= N andalso
+                ?RETURN(grouped_vendor_id_mismatch, [Name, Line, I, N, L]);
+        _ ->
+            false
+    end;
+
+vendor_id_mismatch(_, _, _, _, _, _) ->
+    false.
+
+%% grouped_flags/4
+
+grouped_flags(Name, Code, Dict, Line) ->
+    case find({avp_types, Name}, Dict) of
+        [L, {_, _, Code}, {_, _, "Grouped"}, Flags] ->
+            {L, Flags};
+        [_, {_, L, C}, {_, _, "Grouped"}, _Flags] ->
+            ?RETURN(grouped_avp_code_mismatch, [Name, Line, Code, C, L]);
+        [_, _Code, {_, L, T}, _] ->
+            ?RETURN(grouped_avp_has_wrong_type, [Name, Line, T, L]);
+        [] ->
+            ?RETURN(grouped_avp_not_defined, [Name, Line])
+    end.
+
+%% vendor_id/2
+
+%% Look for a vendor id in @avp_vendor_id, then @vendor.
+vendor_id(Name, Dict) ->
+    case find({avp_vendor_id, Name}, Dict) of
+        [Line, Id] when is_integer(Id) ->
+            {avp_vendor_id, Line, Id};
+        [] ->
+            vendor(Dict)
+    end.
+
+vendor(Dict) ->
+    case find(vendor, Dict) of
+        [[_Line, {_, _, Id}, {_, _, _}]] ->
+            {vendor, Id};
+        [] ->
+            false
+    end.
+
+%% find/2
+
+find(Key, Dict) ->
+    case dict:find(Key, Dict) of
+        {ok, L} when is_list(L) ->
+            L;
+        error ->
+            []
+    end.
+
+%% store_new/5
+
+store_new(Key, Value, Dict, Args, Err) ->
+    case dict:find(Key, Dict) of
+        {ok, [L | _]} ->
+            ?RETURN(Err, Args ++ [L]);
+        error ->
+            dict:store(Key, Value, Dict)
+    end.
+
+%% type/1
+
+type("DiamIdent") ->
+    "DiameterIdentity";
+type("DiamURI") ->
+    "DiameterURI";
+type(T)
+  when T == "OctetString";
+       T == "Integer32";
+       T == "Integer64";
+       T == "Unsigned32";
+       T == "Unsigned64";
+       T == "Float32";
+       T == "Float64";
+       T == "Grouped";
+       T == "Enumerated";
+       T == "Address";
+       T == "Time";
+       T == "UTF8String";
+       T == "DiameterIdentity";
+       T == "DiameterURI";
+       T == "IPFilterRule";
+       T == "QoSFilterRule" ->
+    T;
+type(_) ->
+    false.
+
+%% ===========================================================================
+%% pass2/1
+%%
+%% More explosion, but that requires the previous pass to write its
+%% entries.
+
+pass2(Dict) ->
+    foldl(fun(K,D) -> foldl([fun p2/3, K], D, find(K,D)) end,
+          Dict,
+          [avp_types]).
+
+p2([_Line | Body], Dict, avp_types) ->
+    foldl(fun explode_avps/2, Dict, Body);
+
+p2([], Dict, _) ->
+    Dict.
+
+explode_avps([{_, Line, Name} | Toks], Dict) ->
+    [{number, _, Code}, {word, _, _Type}, {word, _, Flags}] = Toks,
+
+    true = avp_flags_valid(Flags, Name, Line),
+
+    Vid = avp_vendor_id(Flags, Name, Line, Dict),
+
+    %% An AVP is uniquely defined by its AVP code and vendor id (if any).
+    %% Ensure there are no duplicate.
+    store_new({avp_types, {Code, Vid}},
+              [Line, Name],
+              Dict,
+              [Code, Vid, Name, Line],
+              avp_code_already_defined).
+
+%% avp_flags_valid/3
+
+avp_flags_valid(Flags, Name, Line) ->
+    Bad = lists:filter(fun(C) -> not lists:member(C, "MVP") end, Flags),
+    [] == Bad
+        orelse ?RETURN(avp_has_invalid_flag, [Name, Line, hd(Bad)]),
+
+    Dup = Flags -- "MVP",
+    [] == Dup
+        orelse ?RETURN(avp_has_duplicate_flag, [Name, Line, hd(Dup)]).
+
+%% avp_vendor_id/4
+
+avp_vendor_id(Flags, Name, Line, Dict) ->
+    V = lists:member($V, Flags),
+
+    case vendor_id(Name, Dict) of
+        {avp_vendor_id, _, I} when V ->
+            I;
+        {avp_vendor_id, L, I} ->
+            ?RETURN(avp_has_vendor_id, [Name, Line, I, L]);
+        {vendor, I} when V ->
+            I;
+        false when V ->
+            ?RETURN(avp_has_no_vendor, [Name, Line]);
+        _ ->
+            false
+    end.
+
+%% ===========================================================================
+%% pass3/2
+%%
+%% Import AVPs.
+
+pass3(Dict, Opts) ->
+    import_enums(import_groups(import_avps(insert_codes(Dict), Opts))).
+
+%% insert_codes/1
+%%
+%% command_codes -> [{Code, ReqNameTok, AnsNameTok}]
+
+insert_codes(Dict) ->
+    dict:store(command_codes,
+               dict:fold(fun make_code/3, [], Dict),
+               Dict).
+
+make_code({messages, Code}, Names, Acc)
+  when is_integer(Code) ->
+    [mk_code(Code, Names) | Acc];
+make_code(_, _, Acc) ->
+    Acc.
+
+mk_code(Code, [[_, _, false] = Ans, [_, _, true] = Req]) ->
+    mk_code(Code, [Req, Ans]);
+
+mk_code(Code, [[_, {_,_,Req}, true], [_, {_,_,Ans}, false]]) ->
+    {Code, Req, Ans};
+
+mk_code(_Code, [[Line, _Name, IsReq]]) ->
+    ?RETURN(message_missing, [choose(IsReq, "Request", "Answer"),
+                              Line,
+                              choose(IsReq, "answer", "request")]).
+
+%% import_avps/2
+
+import_avps(Dict, Opts) ->
+    Import = inherit(Dict, Opts),
+    report(imported, Import),
+
+    %% pass4/1 tests that all referenced AVP's are either defined
+    %% or imported.
+
+    dict:store(import_avps,
+               lists:map(fun({M, _, As}) -> {M, [A || {_,A} <- As]} end,
+                         lists:reverse(Import)),
+               foldl(fun explode_imports/2, Dict, Import)).
+
+explode_imports({Mod, Line, Avps}, Dict) ->
+    foldl([fun xi/4, Mod, Line], Dict, Avps).
+
+xi({L, {Name, _Code, _Type, _Flags} = A}, Dict, Mod, Line) ->
+    store_new({avp_types, Name},
+              [0, Mod, Line, L, A],
+              store_new({import, Name},
+                        [Line],
+                        Dict,
+                        [Name, Line],
+                        duplicate_import),
+              [Name, Mod, Line],
+              imported_avp_already_defined).
+
+%% import_groups/1
+%% import_enums/1
+%%
+%% For each inherited module, store the content of imported AVP's of
+%% type grouped/enumerated in a new key.
+
+import_groups(Dict) ->
+    dict:store(import_groups, import(grouped, Dict), Dict).
+
+import_enums(Dict) ->
+    dict:store(import_enums, import(enum, Dict), Dict).
+
+import(Key, Dict) ->
+    flatmap([fun import_key/2, Key], dict:fetch(import_avps, Dict)).
+
+import_key({Mod, Avps}, Key) ->
+    As = lists:flatmap(fun(T) ->
+                               N = element(1,T),
+                               choose(lists:keymember(N, 1, Avps), [T], [])
+                       end,
+                       orddict:fetch(Key, dict(Mod))),
+    if As == [] ->
+            [];
+       true ->
+            [{Mod, As}]
+    end.
+
+%% ------------------------------------------------------------------------
+%% inherit/2
+%%
+%% Return a {Mod, Line, [{Lineno, Avp}]} list, where Mod is a module
+%% name, Line points to the corresponding @inherit and each Avp is
+%% from Mod:dict(). Lineno is 0 if the import is implicit.
+
+inherit(Dict, Options) ->
+    Path = [D || {include, D} <- Options]
+        ++ [".", code:lib_dir(diameter, ebin)],
+    foldl([fun find_avps/3, Path], [], find(inherits, Dict)).
+%% Note that the module order of the returned lists is reversed
+%% relative to @inherits.
+
+find_avps([Line, {_,_,M} | Names], Acc, Path) ->
+    Mod = ?A(M),
+    report(inherit_from, Mod),
+    Avps = avps_from_beam(find_beam(Mod, Path), Mod),  %% could be empty
+    case find_avps(Names, Avps) of
+        {_, [{_, L, N} | _]} ->
+            ?RETURN(requested_avp_not_found, [Mod, Line, N, L]);
+        {Found, []} ->
+            [{Mod, Line, lists:sort(Found)} | Acc]
+    end.
+
+%% Import everything not defined locally ...
+find_avps([], Avps) ->
+    {[{0, A} || A <- Avps], []};
+
+%% ... or specified AVPs.
+find_avps(Names, Avps) ->
+    foldl(fun fa/2, {[], Names}, Avps).
+
+fa({Name, _Code, _Type, _Flags} = A, {Found, Not} = Acc) ->
+    case lists:keyfind(Name, 3, Not) of
+        {_, Line, Name} ->
+            {[{Line, A} | Found], lists:keydelete(Name, 3, Not)};
+        false ->
+            Acc
+    end.
+
+%% find_beam/2
+
+find_beam(Mod, Dirs)
+  when is_atom(Mod) ->
+    find_beam(atom_to_list(Mod), Dirs);
+find_beam(Mod, Dirs) ->
+    Beam = Mod ++ code:objfile_extension(),
+    case try_path(Dirs, Beam) of
+        {value, Path} ->
+            Path;
+        false ->
+            ?RETURN(beam_not_on_path, [Mod])
+    end.
+
+try_path([D|Ds], Fname) ->
+    Path = filename:join(D, Fname),
+    case file:read_file_info(Path) of
+        {ok, _} ->
+            {value, Path};
+        _ ->
+            try_path(Ds, Fname)
+    end;
+try_path([], _) ->
+    false.
+
+%% avps_from_beam/2
+
+avps_from_beam(Path, Mod) ->
+    report(beam, Path),
+    ok = load_module(code:is_loaded(Mod), Mod, Path),
+    orddict:fetch(avp_types, dict(Mod)).
+
+load_module(false, Mod, Path) ->
+    R = filename:rootname(Path, code:objfile_extension()),
+    {module, Mod} = code:load_abs(R),
+    ok;
+load_module({file, _}, _, _) ->
+    ok.
+
+dict(Mod) ->
+    try Mod:dict() of
+        [?VERSION | Dict] ->
+            Dict;
+        _ ->
+            ?RETURN(recompile, [Mod])
+    catch
+        error:_ ->
+            ?RETURN(no_dict, [Mod])
+    end.
+
+%% ===========================================================================
+%% pass4/1
+%%
+%% Sanity checks.
+
+pass4(Dict) ->
+    dict:fold(fun(K, V, _) -> p4(K, V, Dict) end, ok, Dict),
+    Dict.
+
+%% Ensure enum AVP's have type Enumerated.
+p4({enum, Name}, [Line | _], Dict)
+  when is_list(Name) ->
+    true = is_enumerated_avp(Name, Dict, Line);
+
+%% Ensure all referenced AVP's are either defined locally or imported.
+p4({K, {Name, AvpName}}, [Line | _], Dict)
+  when (K == grouped orelse K == messages),
+       is_list(Name),
+       is_list(AvpName),
+       AvpName /= "AVP" ->
+    true = avp_is_defined(AvpName, Dict, Line);
+
+%% Ditto.
+p4({K, AvpName}, [Line | _], Dict)
+  when K == avp_vendor_id;
+       K == custom_types;
+       K == codecs ->
+    true = avp_is_defined(AvpName, Dict, Line);
+
+p4(_, _, _) ->
+    ok.
+
+%% has_enumerated_type/3
+
+is_enumerated_avp(Name, Dict, Line) ->
+    case find({avp_types, Name}, Dict) of
+        [_Line, _Code, {_, _, "Enumerated"}, _Flags] ->   %% local
+            true;
+        [_Line, _Code, {_, L, T}, _] ->
+            ?RETURN(enumerated_avp_has_wrong_local_type,
+                    [Name, Line, T, L]);
+        [0, _, _, _, {_Name, _Code, "Enumerated", _Flags}] ->   %% inherited
+            true;
+        [0, Mod, LM, LA, {_Name, _Code, Type, _Flags}] ->
+            ?RETURN(enumerated_avp_has_wrong_inherited_type,
+                    [Name, Line, Type, Mod, choose(0 == LA, LM, LA)]);
+        [] ->
+            ?RETURN(enumerated_avp_not_defined, [Name, Line])
+    end.
+
+avp_is_defined(Name, Dict, Line) ->
+    case find({avp_types, Name}, Dict) of
+        [_Line, _Code, _Type, _Flags] ->   %% local
+            true;
+        [0, _, _, _, {Name, _Code, _Type, _Flags}] ->  %% inherited
+            true;
+        [] ->
+            ?RETURN(avp_not_defined, [Name, Line])
+    end.
+
+%% ===========================================================================
+
+choose(true, X, _)  -> X;
+choose(false, _, X) -> X.
+
+foldl(F, Acc, List) ->
+    lists:foldl(fun(T,A) -> eval([F,T,A]) end, Acc, List).
+
+flatmap(F, List) ->
+    lists:flatmap(fun(T) -> eval([F,T]) end, List).
+
+eval([[F|X] | A]) ->
+    eval([F | A ++ X]);
+eval([F|A]) ->
+    apply(F,A).
diff --git a/lib/diameter/src/compiler/diameter_forms.hrl b/lib/diameter/src/compiler/diameter_forms.hrl
index d93131df34..4cd86c32aa 100644
--- a/lib/diameter/src/compiler/diameter_forms.hrl
+++ b/lib/diameter/src/compiler/diameter_forms.hrl
@@ -21,6 +21,13 @@
 %% Macros used when building abstract code.
 %%
 
+%% Generated functions that could have no generated clauses will have
+%% a trailing ?BADARG clause that should never execute as called
+%% by diameter.
+-define(BADARG(N), {?clause, [?VAR('_') || _ <- lists:seq(1,N)],
+                    [],
+                    [?APPLY(erlang, error, [?ATOM(badarg)])]}).
+
 %% Form tag with line number.
 -define(F(T), T, ?LINE).
 %% Yes, that's right. The replacement is to the first unmatched ')'.
diff --git a/lib/diameter/src/compiler/diameter_spec_util.erl b/lib/diameter/src/compiler/diameter_spec_util.erl
deleted file mode 100644
index 62536bf06d..0000000000
--- a/lib/diameter/src/compiler/diameter_spec_util.erl
+++ /dev/null
@@ -1,1089 +0,0 @@
-%%
-%% %CopyrightBegin%
-%%
-%% Copyright Ericsson AB 2010-2011. All Rights Reserved.
-%%
-%% The contents of this file are subject to the Erlang Public License,
-%% Version 1.1, (the "License"); you may not use this file except in
-%% compliance with the License. You should have received a copy of the
-%% Erlang Public License along with this software. If not, it can be
-%% retrieved online at http://www.erlang.org/.
-%%
-%% Software distributed under the License is distributed on an "AS IS"
-%% basis, WITHOUT WARRANTY OF ANY KIND, either express or implied. See
-%% the License for the specific language governing rights and limitations
-%% under the License.
-%%
-%% %CopyrightEnd%
-%%
-
-%%
-%% This module turns a .dia (aka spec) file into the orddict that
-%% diameter_codegen.erl in turn morphs into .erl and .hrl files for
-%% encode and decode of Diameter messages and AVPs.
-%%
-
--module(diameter_spec_util).
-
--export([parse/2]).
-
--define(ERROR(T), erlang:error({T, ?MODULE, ?LINE})).
--define(ATOM, list_to_atom).
-
-%% parse/1
-%%
-%% Output: orddict()
-
-parse(Path, Opts) ->
-    put({?MODULE, verbose}, lists:member(verbose, Opts)),
-    {ok, B} = file:read_file(Path),
-    Chunks = chunk(B),
-    Spec = reset(make_spec(Chunks), Opts, [name, prefix, inherits]),
-    true = groups_defined(Spec),  %% sanity checks
-    true = customs_defined(Spec), %%
-    Full = import_enums(import_groups(import_avps(insert_codes(Spec), Opts))),
-    true = enums_defined(Full),   %% sanity checks
-    true = v_flags_set(Spec),
-    Full.
-
-reset(Spec, Opts, Keys) ->
-    lists:foldl(fun(K,S) ->
-                        reset([{A,?ATOM(V)} || {A,V} <- Opts, A == K], S)
-                end,
-                Spec,
-                Keys).
-
-reset(L, Spec)
-  when is_list(L) ->
-    lists:foldl(fun reset/2, Spec, L);
-
-reset({inherits = Key, '-'}, Spec) ->
-    orddict:erase(Key, Spec);
-reset({inherits = Key, Dict}, Spec) ->
-    orddict:append(Key, Dict, Spec);
-reset({Key, Atom}, Spec) ->
-    orddict:store(Key, Atom, Spec);
-reset(_, Spec) ->
-    Spec.
-    
-%% Optional reports when running verbosely.
-report(What, Data) ->
-    report(get({?MODULE, verbose}), What, Data).
-
-report(true, Tag, Data) ->
-    io:format("##~n## ~p ~p~n", [Tag, Data]);
-report(false, _, _) ->
-    ok.
-
-%% chunk/1
-
-chunk(B) ->
-    chunkify(normalize(binary_to_list(B))).
-
-%% normalize/1
-%%
-%% Replace CR NL by NL, multiple NL by one, tab by space, and strip
-%% comments and leading/trailing space from each line. Precludes
-%% semicolons being used for any other purpose than comments.
-
-normalize(Str) ->
-    nh(Str, []).
-
-nh([], Acc) ->
-    lists:reverse(Acc);
-
-%% Trim leading whitespace.
-nh(Str, Acc) ->
-    nb(trim(Str), Acc).
-
-%% tab -> space
-nb([$\t|Rest], Acc) ->
-    nb(Rest, [$\s|Acc]);
-
-%% CR NL -> NL
-nb([$\r,$\n|Rest], Acc) ->
-    nt(Rest, Acc);
-
-%% Gobble multiple newlines before starting over again.
-nb([$\n|Rest], Acc) ->
-    nt(Rest, Acc);
-
-%% Comment.
-nb([$;|Rest], Acc) ->
-    nb(lists:dropwhile(fun(C) -> C /= $\n end, Rest), Acc);
-
-%% Just an ordinary character. Boring ...
-nb([C|Rest], Acc) ->
-    nb(Rest, [C|Acc]);
-
-nb([] = Str, Acc) ->
-    nt(Str, Acc).
-
-%% Discard a subsequent newline.
-nt(T, [$\n|_] = Acc) ->
-    nh(T, trim(Acc));
-
-%% Trim whitespace from the end of the line before continuing.
-nt(T, Acc) ->
-    nh(T, [$\n|trim(Acc)]).
-
-trim(S) ->
-    lists:dropwhile(fun(C) -> lists:member(C, "\s\t") end, S).
-
-%% chunkify/1
-%%
-%% Split the spec file into pieces delimited by lines starting with
-%% @Tag. Returns a list of {Tag, Args, Chunk} where Chunk is the
-%% string extending to the next delimiter. Note that leading
-%% whitespace has already been stripped.
-
-chunkify(Str) ->
-    %% Drop characters to the start of the first chunk.
-    {_, Rest} = split_chunk([$\n|Str]),
-    chunkify(Rest, []).
-
-chunkify([], Acc) ->
-    lists:reverse(Acc);
-
-chunkify(Rest, Acc) ->
-    {H,T} = split_chunk(Rest),
-    chunkify(T, [split_tag(H) | Acc]).
-
-split_chunk(Str) ->
-    split_chunk(Str, []).
-
-split_chunk([] = Rest, Acc) ->
-    {lists:reverse(Acc), Rest};
-split_chunk([$@|Rest], [$\n|_] = Acc) ->
-    {lists:reverse(Acc), Rest};
-split_chunk([C|Rest], Acc) ->
-    split_chunk(Rest, [C|Acc]).
-
-%% Expect a tag and its arguments on a single line.
-split_tag(Str) ->
-    {L, Rest} = get_until($\n, Str),
-    [{tag, Tag} | Toks] = diameter_spec_scan:parse(L),
-    {Tag, Toks, trim(Rest)}.
-
-get_until(EndT, L) ->
-    {H, [EndT | T]} = lists:splitwith(fun(C) -> C =/= EndT end, L),
-    {H,T}.
-
-%% ------------------------------------------------------------------------
-%% make_spec/1
-%%
-%% Turn chunks into spec.
-
-make_spec(Chunks) ->
-    lists:foldl(fun(T,A) -> report(chunk, T), chunk(T,A) end,
-                orddict:new(),
-                Chunks).
-
-chunk({T, [X], []}, Dict)
-  when T == name;
-       T == prefix ->
-    store(T, atomize(X), Dict);
-
-chunk({id = T, [{number, I}], []}, Dict) ->
-    store(T, I, Dict);
-
-chunk({vendor = T, [{number, I}, N], []}, Dict) ->
-    store(T, {I, atomize(N)}, Dict);
-
-%% inherits -> [{Mod, [AvpName, ...]}, ...]
-chunk({inherits = T, [_,_|_] = Args, []}, Acc) ->
-    Mods = [atomize(A) || A <- Args],
-    append_list(T, [{M,[]} || M <- Mods], Acc);
-chunk({inherits = T, [Mod], Body}, Acc) ->
-    append(T, {atomize(Mod), parse_avp_names(Body)}, Acc);
-
-%% avp_types -> [{AvpName, Code, Type, Flags, Encr}, ...]
-chunk({avp_types = T, [], Body}, Acc) ->
-    store(T, parse_avp_types(Body), Acc);
-
-%% custom_types -> [{Mod, [AvpName, ...]}, ...]
-chunk({custom_types = T, [Mod], Body}, Dict) ->
-    [_|_] = Avps = parse_avp_names(Body),
-    append(T, {atomize(Mod), Avps}, Dict);
-
-%% messages -> [{MsgName, Code, Type, Appl, Avps}, ...]
-chunk({messages = T, [], Body}, Acc) ->
-    store(T, parse_messages(Body), Acc);
-
-%% grouped -> [{AvpName, Code, Vendor, Avps}, ...]
-chunk({grouped = T, [], Body}, Acc) ->
-    store(T, parse_groups(Body), Acc);
-
-%% avp_vendor_id -> [{Id, [AvpName, ...]}, ...]
-chunk({avp_vendor_id = T, [{number, I}], Body}, Dict) ->
-    [_|_] = Names = parse_avp_names(Body),
-    append(T, {I, Names}, Dict);
-
-%% enums -> [{AvpName, [{Value, Name}, ...]}, ...]
-chunk({enum, [N], Str}, Dict) ->
-    append(enums, {atomize(N), parse_enums(Str)}, Dict);
-
-%% defines -> [{DefineName, [{Value, Name}, ...]}, ...]
-chunk({define, [N], Str}, Dict) ->
-    append(defines, {atomize(N), parse_enums(Str)}, Dict);
-chunk({result_code, [_] = N, Str}, Dict) ->  %% backwards compatibility
-    chunk({define, N, Str}, Dict);
-
-%% commands -> [{Name, Abbrev}, ...]
-chunk({commands = T, [], Body}, Dict) ->
-    store(T, parse_commands(Body), Dict);
-
-chunk(T, _) ->
-    ?ERROR({unknown_tag, T}).
-
-store(Key, Value, Dict) ->
-    error == orddict:find(Key, Dict) orelse ?ERROR({duplicate, Key}),
-    orddict:store(Key, Value, Dict).
-append(Key, Value, Dict) ->
-    orddict:append(Key, Value, Dict).
-append_list(Key, Values, Dict) ->
-    orddict:append_list(Key, Values, Dict).
-
-atomize({tag, T}) ->
-    T;
-atomize({name, T}) ->
-    ?ATOM(T).
-
-get_value(Keys, Spec)
-  when is_list(Keys) ->
-    [get_value(K, Spec) || K <- Keys];
-get_value(Key, Spec) ->
-    proplists:get_value(Key, Spec, []).
-
-%% ------------------------------------------------------------------------
-%% enums_defined/1
-%% groups_defined/1
-%% customs_defined/1
-%%
-%% Ensure that every local enum/grouped/custom is defined as an avp
-%% with an appropriate type.
-
-enums_defined(Spec) ->
-    Avps = get_value(avp_types, Spec),
-    Import = get_value(import_enums, Spec),
-    lists:all(fun({N,_}) ->
-                      true = enum_defined(N, Avps, Import)
-              end,
-              get_value(enums, Spec)).
-
-enum_defined(Name, Avps, Import) ->
-    case lists:keyfind(Name, 1, Avps) of
-        {Name, _, 'Enumerated', _, _} ->
-            true;
-        {Name, _, T, _, _} ->
-            ?ERROR({avp_has_wrong_type, Name, 'Enumerated', T});
-        false ->
-            lists:any(fun({_,Is}) -> lists:keymember(Name, 1, Is) end, Import)
-                orelse ?ERROR({avp_not_defined, Name, 'Enumerated'})
-    end.
-%% Note that an AVP is imported only if referenced by a message or
-%% grouped AVP, so the final branch will fail if an enum definition is
-%% extended without this being the case.
-
-groups_defined(Spec) ->
-    Avps = get_value(avp_types, Spec),
-    lists:all(fun({N,_,_,_}) -> true = group_defined(N, Avps) end,
-              get_value(grouped, Spec)).
-
-group_defined(Name, Avps) ->
-    case lists:keyfind(Name, 1, Avps) of
-        {Name, _, 'Grouped', _, _} ->
-            true;
-        {Name, _, T, _, _} ->
-            ?ERROR({avp_has_wrong_type, Name, 'Grouped', T});
-        false ->
-            ?ERROR({avp_not_defined, Name, 'Grouped'})
-    end.
-
-customs_defined(Spec) ->
-    Avps = get_value(avp_types, Spec),
-    lists:all(fun(A) -> true = custom_defined(A, Avps) end,
-              lists:flatmap(fun last/1, get_value(custom_types, Spec))).
-
-custom_defined(Name, Avps) ->
-    case lists:keyfind(Name, 1, Avps) of
-        {Name, _, T, _, _} when T == 'Grouped';
-                                T == 'Enumerated' ->
-            ?ERROR({avp_has_invalid_custom_type, Name, T});
-        {Name, _, _, _, _} ->
-            true;
-        false ->
-            ?ERROR({avp_not_defined, Name})
-    end.
-
-last({_,Xs}) -> Xs.
-
-%% ------------------------------------------------------------------------
-%% v_flags_set/1
-
-v_flags_set(Spec) ->
-    Avps = get_value(avp_types, Spec)
-        ++ lists:flatmap(fun last/1, get_value(import_avps, Spec)),
-    Vs = lists:flatmap(fun last/1, get_value(avp_vendor_id, Spec)),
-
-    lists:all(fun(N) -> vset(N, Avps) end, Vs).
-
-vset(Name, Avps) ->
-    A = lists:keyfind(Name, 1, Avps),
-    false == A andalso ?ERROR({avp_not_defined, Name}),
-    {Name, _Code, _Type, Flags, _Encr} = A,
-    lists:member('V', Flags) orelse ?ERROR({v_flag_not_set, A}).
-
-%% ------------------------------------------------------------------------
-%% insert_codes/1
-
-insert_codes(Spec) ->
-    [Msgs, Cmds] = get_value([messages, commands], Spec),
-
-    %% Code -> [{Name, Flags}, ...]
-    Dict = lists:foldl(fun({N,C,Fs,_,_}, D) -> dict:append(C,{N,Fs},D) end,
-                       dict:new(),
-                       Msgs),
-
-    %% list() of {Code, {ReqName, ReqAbbr}, {AnsName, AnsAbbr}}
-    %% If the name and abbreviation are the same then the 2-tuples
-    %% are replaced by the common atom()-valued name.
-    Codes = dict:fold(fun(C,Ns,A) -> [make_code(C, Ns, Cmds) | A] end,
-                      [],
-                      dict:erase(-1, Dict)),  %% answer-message
-
-    orddict:store(command_codes, Codes, Spec).
-
-make_code(Code, [_,_] = Ns, Cmds) ->
-    {Req, Ans} = make_names(Ns, lists:map(fun({_,Fs}) ->
-                                                  lists:member('REQ', Fs)
-                                          end,
-                                          Ns)),
-    {Code, abbrev(Req, Cmds), abbrev(Ans, Cmds)};
-
-make_code(Code, Cs, _) ->
-    ?ERROR({missing_request_or_answer, Code, Cs}).
-
-%% 3.3.  Diameter Command Naming Conventions
-%%
-%%    Diameter command names typically includes one or more English words
-%%    followed by the verb Request or Answer.  Each English word is
-%%    delimited by a hyphen.  A three-letter acronym for both the request
-%%    and answer is also normally provided.
-
-make_names([{Rname,_},{Aname,_}], [true, false]) ->
-    {Rname, Aname};
-make_names([{Aname,_},{Rname,_}], [false, true]) ->
-    {Rname, Aname};
-make_names([_,_] = Names, _) ->
-    ?ERROR({inconsistent_command_flags, Names}).
-
-abbrev(Name, Cmds) ->
-    case abbr(Name, get_value(Name, Cmds)) of
-        Name ->
-            Name;
-        Abbr ->
-            {Name, Abbr}
-    end.
-
-%% No explicit abbreviation: construct.
-abbr(Name, []) ->
-    ?ATOM(abbr(string:tokens(atom_to_list(Name), "-")));
-
-%% Abbreviation was specified.
-abbr(_Name, Abbr) ->
-    Abbr.
-
-%% No hyphens: already abbreviated.
-abbr([Abbr]) ->
-    Abbr;
-
-%% XX-Request/Answer ==> XXR/XXA
-abbr([[_,_] = P, T])
-  when T == "Request";
-       T == "Answer" ->
-    P ++ [hd(T)];
-
-%% XXX-...-YYY-Request/Answer ==> X...YR/X...YA
-abbr([_,_|_] = L) ->
-    lists:map(fun erlang:hd/1, L).
-
-%% ------------------------------------------------------------------------
-%% import_avps/2
-
-import_avps(Spec, Options) ->
-    Msgs = get_value(messages, Spec),
-    Groups = get_value(grouped, Spec),
-
-    %% Messages and groups require AVP's referenced by them.
-    NeededAvps
-        = ordsets:from_list(lists:flatmap(fun({_,_,_,_,As}) ->
-                                                  [avp_name(A) || A <- As]
-                                          end,
-                                          Msgs)
-                            ++ lists:flatmap(fun({_,_,_,As}) ->
-                                                     [avp_name(A) || A <- As]
-                                             end,
-                                             Groups)),
-    MissingAvps = missing_avps(NeededAvps, Spec),
-
-    report(needed, NeededAvps),
-    report(missing, MissingAvps),
-
-    Import = inherit(get_value(inherits, Spec), Options),
-
-    report(imported, Import),
-
-    ImportedAvps = lists:map(fun({N,_,_,_,_}) -> N end,
-                             lists:flatmap(fun last/1, Import)),
-
-    Unknown = MissingAvps -- ImportedAvps,
-
-    [] == Unknown orelse ?ERROR({undefined_avps, Unknown}),
-
-    orddict:store(import_avps, Import, orddict:erase(inherits, Spec)).
-
-%% missing_avps/2
-%%
-%% Given a list of AVP names and parsed spec, return the list of
-%% AVP's that aren't defined in this spec.
-
-missing_avps(NeededNames, Spec) ->
-    Avps = get_value(avp_types, Spec),
-    Groups = lists:map(fun({N,_,_,As}) ->
-                               {N, [avp_name(A) || A <- As]}
-                       end,
-                       get_value(grouped, Spec)),
-    Names = ordsets:from_list(['AVP' | lists:map(fun({N,_,_,_,_}) -> N end,
-                                                 Avps)]),
-    missing_avps(NeededNames, [], {Names, Groups}).
-
-avp_name({'<',A,'>'}) -> A;
-avp_name({A}) -> A;
-avp_name([A]) -> A;
-avp_name({_, A}) -> avp_name(A).
-
-missing_avps(NeededNames, MissingNames, {Names, _} = T) ->
-    missing(ordsets:filter(fun(N) -> lists:member(N, NeededNames) end, Names),
-            ordsets:union(NeededNames, MissingNames),
-            T).
-
-%% Nothing found locally.
-missing([], MissingNames, _) ->
-    MissingNames;
-
-%% Or not. Keep looking for for the AVP's needed by the found AVP's of
-%% type Grouped.
-missing(FoundNames, MissingNames, {_, Groups} = T) ->
-    NeededNames = lists:flatmap(fun({N,As}) ->
-                                  choose(lists:member(N, FoundNames), As, [])
-                          end,
-                          Groups),
-    missing_avps(ordsets:from_list(NeededNames),
-                 ordsets:subtract(MissingNames, FoundNames),
-                 T).
-
-%% inherit/2
-
-inherit(Inherits, Options) ->
-    Dirs = [D || {include, D} <- Options] ++ ["."],
-    lists:foldl(fun(T,A) -> find_avps(T, A, Dirs) end, [], Inherits).
-
-find_avps({Mod, AvpNames}, Acc, Path) ->
-    report(inherit_from, Mod),
-    Avps = avps_from_beam(find_beam(Mod, Path), Mod),  %% could be empty
-    [{Mod, lists:sort(find_avps(AvpNames, Avps))} | Acc].
-
-find_avps([], Avps) ->
-    Avps;
-find_avps(Names, Avps) ->
-    lists:filter(fun({N,_,_,_,_}) -> lists:member(N, Names) end, Avps).
-
-%% find_beam/2
-
-find_beam(Mod, Dirs)
-  when is_atom(Mod) ->
-    find_beam(atom_to_list(Mod), Dirs);
-find_beam(Mod, Dirs) ->
-    Beam = Mod ++ code:objfile_extension(),
-    case try_path(Dirs, Beam) of
-        {value, Path} ->
-            Path;
-        false ->
-            ?ERROR({beam_not_on_path, Beam, Dirs})
-    end.
-
-try_path([D|Ds], Fname) ->
-    Path = filename:join(D, Fname),
-    case file:read_file_info(Path) of
-        {ok, _} ->
-            {value, Path};
-        _ ->
-            try_path(Ds, Fname)
-    end;
-try_path([], _) ->
-    false.
-
-%% avps_from_beam/2
-
-avps_from_beam(Path, Mod) ->
-    report(beam, Path),
-    ok = load_module(code:is_loaded(Mod), Mod, Path),
-    orddict:fetch(avp_types, Mod:dict()).
-
-load_module(false, Mod, Path) ->
-    R = filename:rootname(Path, code:objfile_extension()),
-    {module, Mod} = code:load_abs(R),
-    ok;
-load_module({file, _}, _, _) ->
-    ok.
-
-choose(true, X, _)  -> X;
-choose(false, _, X) -> X.
-
-%% ------------------------------------------------------------------------
-%% import_groups/1
-%% import_enums/1
-%%
-%% For each inherited module, store the content of imported AVP's of
-%% type grouped/enumerated in a new key.
-
-import_groups(Spec) ->
-    orddict:store(import_groups, import(grouped, Spec), Spec).
-
-import_enums(Spec) ->
-    orddict:store(import_enums, import(enums, Spec), Spec).
-
-import(Key, Spec) ->
-    lists:flatmap(fun(T) -> import_key(Key, T) end,
-                  get_value(import_avps, Spec)).
-
-import_key(Key, {Mod, Avps}) ->
-    Imports = lists:flatmap(fun(T) ->
-                                    choose(lists:keymember(element(1,T),
-                                                           1,
-                                                           Avps),
-                                           [T],
-                                           [])
-                            end,
-                            get_value(Key, Mod:dict())),
-    if Imports == [] ->
-            [];
-       true ->
-            [{Mod, Imports}]
-    end.
-
-%% ------------------------------------------------------------------------
-%% parse_enums/1
-%%
-%% Enums are specified either as the integer value followed by the
-%% name or vice-versa. In the former case the name of the enum is
-%% taken to be the string up to the end of line, which may contain
-%% whitespace. In the latter case the integer may be parenthesized,
-%% specified in hex and followed by an inline comment. This is
-%% historical and will likely be changed to require a precise input
-%% format.
-%%
-%% Output: list() of {integer(), atom()}
-
-parse_enums(Str) ->
-    lists:flatmap(fun(L) -> parse_enum(trim(L)) end, string:tokens(Str, "\n")).
-
-parse_enum([]) ->
-    [];
-
-parse_enum(Str) ->
-    REs = [{"^(0[xX][0-9A-Fa-f]+|[0-9]+)\s+(.*?)\s*$", 1, 2},
-           {"^(.+?)\s+(0[xX][0-9A-Fa-f]+|[0-9]+)(\s+.*)?$", 2, 1},
-           {"^(.+?)\s+\\((0[xX][0-9A-Fa-f]+|[0-9]+)\\)(\s+.*)?$", 2, 1}],
-    parse_enum(Str, REs).
-
-parse_enum(Str, REs) ->
-    try lists:foreach(fun(R) -> enum(Str, R) end, REs) of
-        ok ->
-            ?ERROR({bad_enum, Str})
-    catch
-        throw: {enum, T} ->
-            [T]
-    end.
-
-enum(Str, {Re, I, N}) ->
-    case re:run(Str, Re, [{capture, all_but_first, list}]) of
-        {match, Vs} ->
-            T = list_to_tuple(Vs),
-            throw({enum, {to_int(element(I,T)), ?ATOM(element(N,T))}});
-        nomatch ->
-            ok
-    end.
-
-to_int([$0,X|Hex])
-  when X == $x;
-       X == $X ->
-    {ok, [I], _} = io_lib:fread("~#", "16#" ++ Hex),
-    I;
-to_int(I) ->
-    list_to_integer(I).
-
-%% ------------------------------------------------------------------------
-%% parse_messages/1
-%%
-%% Parse according to the ABNF for message specifications in 3.2 of
-%% RFC 3588 (shown below). We require all message and AVP names to
-%% start with a digit or uppercase character, except for the base
-%% answer-message, which is treated as a special case. Allowing names
-%% that start with a digit is more than the RFC specifies but the name
-%% doesn't affect what's sent over the wire. (Certains 3GPP standards
-%% use names starting with a digit. eg 3GPP-Charging-Id in TS32.299.)
-
-%%
-%% Sadly, not even the RFC follows this grammar. In particular, except
-%% in the example in 3.2, it wraps each command-name in angle brackets
-%% ('<' '>') which makes parsing a sequence of specifications require
-%% lookahead: after 'optional' avps have been parsed, it's not clear
-%% whether a '<' is a 'fixed' or whether it's the start of a
-%% subsequent message until we see whether or not '::=' follows the
-%% closing '>'. Require the grammar as specified.
-%%
-%% Output: list of {Name, Code, Flags, ApplId, Avps}
-%%
-%%         Name   = atom()
-%%         Code   = integer()
-%%         Flags  = integer()
-%%         ApplId = [] | [integer()]
-%%         Avps   = see parse_avps/1
-
-parse_messages(Str) ->
-    p_cmd(trim(Str), []).
-
-%%   command-def      = command-name "::=" diameter-message
-%%
-%%   command-name     = diameter-name
-%%
-%%   diameter-name    = ALPHA *(ALPHA / DIGIT / "-")
-%%
-%%   diameter-message = header  [ *fixed] [ *required] [ *optional]
-%%                      [ *fixed]
-%%
-%%   header           = "<" Diameter-Header:" command-id
-%%                      [r-bit] [p-bit] [e-bit] [application-id]">"
-%%
-%% The header spec (and example that follows it) is slightly mangled
-%% and, given the examples in the RFC should as follows:
-%%
-%%   header           = "<" "Diameter Header:" command-id
-%%                      [r-bit] [p-bit] [e-bit] [application-id]">"
-%%
-%% This is what's required/parsed below, modulo whitespace. This is
-%% also what's specified in the current draft standard at
-%% http://ftp.ietf.org/drafts/wg/dime.
-%%
-%% Note that the grammar specifies the order fixed, required,
-%% optional. In practise there seems to be little difference between
-%% the latter two since qualifiers can be used to change the
-%% semantics. For example 1*[XXX] and *1{YYY} specify 1 or more of the
-%% optional avp XXX and 0 or 1 of the required avp YYY, making the
-%% iotional avp required and the required avp optional. The current
-%% draft addresses this somewhat by requiring that min for a qualifier
-%% on an optional avp must be 0 if present. It doesn't say anything
-%% about required avps however, so specifying a min of 0 would still
-%% be possible. The draft also does away with the trailing *fixed.
-%%
-%% What will be parsed here will treat required and optional
-%% interchangeably. That is. only require that required/optional
-%% follow and preceed fixed, not that optional avps must follow
-%% required ones. We already have several specs for which this parsing
-%% is necessary and there seems to be no harm in accepting it.
-
-p_cmd("", Acc) ->
-    lists:reverse(Acc);
-
-p_cmd(Str, Acc) ->
-    {Next, Rest} = split_def(Str),
-    report(command, Next),
-    p_cmd(Rest, [p_cmd(Next) | Acc]).
-
-p_cmd("answer-message" ++ Str) ->
-    p_header([{name, 'answer-message'} | diameter_spec_scan:parse(Str)]);
-
-p_cmd(Str) ->
-    p_header(diameter_spec_scan:parse(Str)).
-
-%% p_header/1
-
-p_header(['<', {name, _} = N, '>' | Toks]) ->
-    p_header([N | Toks]);
-
-p_header([{name, 'answer-message' = N}, '::=',
-          '<', {name, "Diameter"}, {name, "Header"}, ':', {tag, code},
-          ',', {name, "ERR"}, '[', {name, "PXY"}, ']', '>'
-          | Toks]) ->
-    {N, -1, ['ERR', 'PXY'], [], parse_avps(Toks)};
-
-p_header([{name, Name}, '::=',
-          '<', {name, "Diameter"}, {name, "Header"}, ':', {number, Code}
-          | Toks]) ->
-    {Flags, Rest} = p_flags(Toks),
-    {ApplId, [C|_] = R} = p_appl(Rest),
-    '>' == C orelse ?ERROR({invalid_flag, {Name, Code, Flags, ApplId}, R}),
-    {?ATOM(Name), Code, Flags, ApplId, parse_avps(tl(R))};
-
-p_header(Toks) ->
-    ?ERROR({invalid_header, Toks}).
-
-%%   application-id   = 1*DIGIT
-%%
-%%   command-id       = 1*DIGIT
-%%                      ; The Command Code assigned to the command
-%%
-%%   r-bit            = ", REQ"
-%%                      ; If present, the 'R' bit in the Command
-%%                      ; Flags is set, indicating that the message
-%%                      ; is a request, as opposed to an answer.
-%%
-%%   p-bit            = ", PXY"
-%%                      ; If present, the 'P' bit in the Command
-%%                      ; Flags is set, indicating that the message
-%%                      ; is proxiable.
-%%
-%%   e-bit            = ", ERR"
-%%                      ; If present, the 'E' bit in the Command
-%%                      ; Flags is set, indicating that the answer
-%%                      ; message contains a Result-Code AVP in
-%%                      ; the "protocol error" class.
-
-p_flags(Toks) ->
-    lists:foldl(fun p_flags/2, {[], Toks}, ["REQ", "PXY", "ERR"]).
-
-p_flags(N, {Acc, [',', {name, N} | Toks]}) ->
-    {[?ATOM(N) | Acc], Toks};
-
-p_flags(_, T) ->
-    T.
-
-%% The RFC doesn't specify ',' before application-id but this seems a
-%% bit inconsistent. Accept a comma if it exists.
-p_appl([',', {number, I} | Toks]) ->
-    {[I], Toks};
-p_appl([{number, I} | Toks]) ->
-    {[I], Toks};
-p_appl(Toks) ->
-    {[], Toks}.
-
-%% parse_avps/1
-%%
-%% Output: list() of Avp | {Qual, Avp}
-%%
-%%         Qual = '*' | {Min, '*'} | {'*', Max} | {Min, Max}
-%%         Avp  = {'<', Name, '>'} | {Name} | [Name]
-%%
-%%         Min, Max = integer() >= 0
-
-parse_avps(Toks) ->
-    p_avps(Toks, ['<', '|', '<'], []).
-%% The list corresponds to the delimiters expected at the front, middle
-%% and back of the avp specification, '|' representing '{' and '['.
-
-%%   fixed            = [qual] "<" avp-spec ">"
-%%                      ; Defines the fixed position of an AVP
-%%
-%%   required         = [qual] "{" avp-spec "}"
-%%                      ; The AVP MUST be present and can appear
-%%                      ; anywhere in the message.
-%%
-%%   optional         = [qual] "[" avp-name "]"
-%%                      ; The avp-name in the 'optional' rule cannot
-%%                      ; evaluate to any AVP Name which is included
-%%                      ; in a fixed or required rule.  The AVP can
-%%                      ; appear anywhere in the message.
-%%
-%%   qual             = [min] "*" [max]
-%%                      ; See ABNF conventions, RFC 2234 Section 6.6.
-%%                      ; The absence of any qualifiers depends on whether
-%%                      ; it precedes a fixed, required, or optional
-%%                      ; rule.  If a fixed or required rule has no
-%%                      ; qualifier, then exactly one such AVP MUST
-%%                      ; be present.  If an optional rule has no
-%%                      ; qualifier, then 0 or 1 such AVP may be
-%%                      ; present.
-%%                      ;
-%%                      ; NOTE:  "[" and "]" have a different meaning
-%%                      ; than in ABNF (see the optional rule, above).
-%%                      ; These braces cannot be used to express
-%%                      ; optional fixed rules (such as an optional
-%%                      ; ICV at the end).  To do this, the convention
-%%                      ; is '0*1fixed'.
-%%
-%%   min              = 1*DIGIT
-%%                      ; The minimum number of times the element may
-%%                      ; be present.  The default value is zero.
-%%
-%%   max              = 1*DIGIT
-%%                      ; The maximum number of times the element may
-%%                      ; be present.  The default value is infinity.  A
-%%                      ; value of zero implies the AVP MUST NOT be
-%%                      ; present.
-%%
-%%   avp-spec         = diameter-name
-%%                      ; The avp-spec has to be an AVP Name, defined
-%%                      ; in the base or extended Diameter
-%%                      ; specifications.
-%%
-%%   avp-name         = avp-spec / "AVP"
-%%                      ; The string "AVP" stands for *any* arbitrary
-%%                      ; AVP Name, which does not conflict with the
-%%                      ; required or fixed position AVPs defined in
-%%                      ; the command code definition.
-%%
-
-p_avps([], _, Acc) ->
-    lists:reverse(Acc);
-
-p_avps(Toks, Delim, Acc) ->
-    {Qual, Rest} = p_qual(Toks),
-    {Avp, R, D} = p_avp(Rest, Delim),
-    T = if Qual == false ->
-                Avp;
-           true ->
-                {Qual, Avp}
-        end,
-    p_avps(R, D, [T | Acc]).
-
-p_qual([{number, Min}, '*', {number, Max} | Toks]) ->
-    {{Min, Max}, Toks};
-p_qual([{number, Min}, '*' = Max | Toks]) ->
-    {{Min, Max}, Toks};
-p_qual(['*' = Min, {number, Max} | Toks]) ->
-    {{Min, Max}, Toks};
-p_qual(['*' = Q | Toks]) ->
-    {Q, Toks};
-p_qual(Toks) ->
-    {false, Toks}.
-
-p_avp([B, {name, Name}, E | Toks], [_|_] = Delim) ->
-    {avp(B, ?ATOM(Name), E),
-     Toks,
-     delim(choose(B == '<', B, '|'), Delim)};
-p_avp(Toks, Delim) ->
-    ?ERROR({invalid_avp, Toks, Delim}).
-
-avp('<' = B, Name, '>' = E) ->
-    {B, Name, E};
-avp('{', Name, '}') ->
-    {Name};
-avp('[', Name, ']') ->
-    [Name];
-avp(B, Name, E) ->
-    ?ERROR({invalid_avp, B, Name, E}).
-
-delim(B, D) ->
-    if B == hd(D) -> D; true -> tl(D) end.
-
-%% split_def/1
-%%
-%% Strip one command definition off head of a string.
-
-split_def(Str) ->
-    sdh(Str, []).
-
-%% Look for the "::=" starting off the definition.
-sdh("", _) ->
-    ?ERROR({missing, '::='});
-sdh("::=" ++ Rest, Acc) ->
-    sdb(Rest, [$=,$:,$:|Acc]);
-sdh([C|Rest], Acc) ->
-    sdh(Rest, [C|Acc]).
-
-%% Look for the "::=" starting off the following definition.
-sdb("::=" ++ _ = Rest, Acc) ->
-    sdt(trim(Acc), Rest);
-sdb("" = Rest, Acc) ->
-    sd(Acc, Rest);
-sdb([C|Rest], Acc) ->
-    sdb(Rest, [C|Acc]).
-
-%% Put name characters of the subsequent specification back into Rest.
-sdt([C|Acc], Rest)
-  when C /= $\n, C /= $\s ->
-    sdt(Acc, [C|Rest]);
-
-sdt(Acc, Rest) ->
-    sd(Acc, Rest).
-
-sd(Acc, Rest) ->
-    {trim(lists:reverse(Acc)), Rest}.
-%% Note that Rest is already trimmed of leading space.
-
-%% ------------------------------------------------------------------------
-%% parse_groups/1
-%%
-%% Parse according to the ABNF for message specifications in 4.4 of
-%% RFC 3588 (shown below). Again, allow names starting with a digit
-%% and also require "AVP Header" without "-" since this is what
-%% the RFC uses in all examples.
-%%
-%% Output: list of {Name, Code, Vendor, Avps}
-%%
-%%         Name   = atom()
-%%         Code   = integer()
-%%         Vendor = [] | [integer()]
-%%         Avps   = see parse_avps/1
-
-parse_groups(Str) ->
-    p_group(trim(Str), []).
-
-%%      grouped-avp-def  = name "::=" avp
-%%
-%%      name-fmt         = ALPHA *(ALPHA / DIGIT / "-")
-%%
-%%      name             = name-fmt
-%%                         ; The name has to be the name of an AVP,
-%%                         ; defined in the base or extended Diameter
-%%                         ; specifications.
-%%
-%%      avp              = header  [ *fixed] [ *required] [ *optional]
-%%                         [ *fixed]
-%%
-%%      header           = "<" "AVP-Header:" avpcode [vendor] ">"
-%%
-%%      avpcode          = 1*DIGIT
-%%                         ; The AVP Code assigned to the Grouped AVP
-%%
-%%      vendor           = 1*DIGIT
-%%                         ; The Vendor-ID assigned to the Grouped AVP.
-%%                         ; If absent, the default value of zero is
-%%                         ; used.
-
-p_group("", Acc) ->
-    lists:reverse(Acc);
-
-p_group(Str, Acc) ->
-    {Next, Rest} = split_def(Str),
-    report(group, Next),
-    p_group(Rest, [p_group(diameter_spec_scan:parse(Next)) | Acc]).
-
-p_group([{name, Name}, '::=', '<', {name, "AVP"}, {name, "Header"},
-         ':', {number, Code}
-         | Toks]) ->
-    {Id, [C|_] = R} = p_vendor(Toks),
-    C == '>' orelse ?ERROR({invalid_group_header, R}),
-    {?ATOM(Name), Code, Id, parse_avps(tl(R))};
-
-p_group(Toks) ->
-    ?ERROR({invalid_group, Toks}).
-
-p_vendor([{number, I} | Toks]) ->
-    {[I], Toks};
-p_vendor(Toks) ->
-    {[], Toks}.
-
-%% ------------------------------------------------------------------------
-%% parse_avp_names/1
-
-parse_avp_names(Str) ->
-    [p_name(N) || N <- diameter_spec_scan:parse(Str)].
-
-p_name({name, N}) ->
-    ?ATOM(N);
-p_name(T) ->
-    ?ERROR({invalid_avp_name, T}).
-
-%% ------------------------------------------------------------------------
-%% parse_avp_types/1
-%%
-%% Output: list() of {Name, Code, Type, Flags, Encr}
-
-parse_avp_types(Str) ->
-    p_avp_types(Str, []).
-
-p_avp_types(Str, Acc) ->
-    p_type(diameter_spec_scan:split(Str, 3), Acc).
-
-p_type({[],[]}, Acc) ->
-    lists:reverse(Acc);
-
-p_type({[{name, Name}, {number, Code}, {name, Type}], Str}, Acc) ->
-    {Flags, Encr, Rest} = try
-                              p_avp_flags(trim(Str), [])
-                          catch
-                              throw: {?MODULE, Reason} ->
-                                  ?ERROR({invalid_avp_type, Reason})
-                          end,
-    p_avp_types(Rest, [{?ATOM(Name), Code, ?ATOM(type(Type)), Flags, Encr}
-                       | Acc]);
-
-p_type(T, _) ->
-    ?ERROR({invalid_avp_type, T}).
-
-p_avp_flags([C|Str], Acc)
-  when C == $M;
-       C == $P;
-       C == $V ->
-    p_avp_flags(Str, [?ATOM([C]) | Acc]);
-%% Could support lowercase here if there's a use for distinguishing
-%% between Must and Should in the future in deciding whether or not
-%% to set a flag.
-
-p_avp_flags([$-|Str], Acc) ->
-    %% Require encr on same line as flags if specified.
-    {H,T} = lists:splitwith(fun(C) -> C /= $\n end, Str),
-
-    {[{name, [$X|X]} | Toks], Rest} = diameter_spec_scan:split([$X|H], 2),
-
-    "" == X orelse throw({?MODULE, {invalid_avp_flag, Str}}),
-
-    Encr = case Toks of
-               [] ->
-                   "-";
-               [{_, E}] ->
-                   (E == "Y" orelse E == "N")
-                       orelse throw({?MODULE, {invalid_encr, E}}),
-                   E
-           end,
-
-    Flags = ordsets:from_list(lists:reverse(Acc)),
-
-    {Flags, ?ATOM(Encr), Rest ++ T};
-
-p_avp_flags(Str, Acc) ->
-    p_avp_flags([$-|Str], Acc).
-
-type("DiamIdent")   -> "DiameterIdentity";  %% RFC 3588
-type("DiamURI")     -> "DiameterURI";       %% RFC 3588
-type("IPFltrRule")  -> "IPFilterRule";      %% RFC 4005
-type("QoSFltrRule") -> "QoSFilterRule";     %% RFC 4005
-type(N)
-  when N == "OctetString";
-       N == "Integer32";
-       N == "Integer64";
-       N == "Unsigned32";
-       N == "Unsigned64";
-       N == "Float32";
-       N == "Float64";
-       N == "Grouped";
-       N == "Enumerated";
-       N == "Address";
-       N == "Time";
-       N == "UTF8String";
-       N == "DiameterIdentity";
-       N == "DiameterURI";
-       N == "IPFilterRule";
-       N == "QoSFilterRule" ->
-    N;
-type(N) ->
-    ?ERROR({invalid_avp_type, N}).
-
-%% ------------------------------------------------------------------------
-%% parse_commands/1
-
-parse_commands(Str) ->
-    p_abbr(diameter_spec_scan:parse(Str), []).
-
- p_abbr([{name, Name}, {name, Abbrev} | Toks], Acc)
-  when length(Abbrev) < length(Name) ->
-    p_abbr(Toks, [{?ATOM(Name), ?ATOM(Abbrev)} | Acc]);
-
-p_abbr([], Acc) ->
-    lists:reverse(Acc);
-
-p_abbr(T, _) ->
-    ?ERROR({invalid_command, T}).
diff --git a/lib/diameter/src/compiler/diameter_vsn.hrl b/lib/diameter/src/compiler/diameter_vsn.hrl
new file mode 100644
index 0000000000..024d047adc
--- /dev/null
+++ b/lib/diameter/src/compiler/diameter_vsn.hrl
@@ -0,0 +1,22 @@
+%%
+%% %CopyrightBegin%
+%%
+%% Copyright Ericsson AB 2010-2011. All Rights Reserved.
+%%
+%% The contents of this file are subject to the Erlang Public License,
+%% Version 1.1, (the "License"); you may not use this file except in
+%% compliance with the License. You should have received a copy of the
+%% Erlang Public License along with this software. If not, it can be
+%% retrieved online at http://www.erlang.org/.
+%%
+%% Software distributed under the License is distributed on an "AS IS"
+%% basis, WITHOUT WARRANTY OF ANY KIND, either express or implied. See
+%% the License for the specific language governing rights and limitations
+%% under the License.
+%%
+%% %CopyrightEnd%
+%%
+
+%% The version of the format of the return value of dict/0 in
+%% generated dictionary modules.
+-define(VERSION, 1).