inets,ftp: Break out FTP from inets

- Created initial directory structure for the FTP application.
- Updated inets Makefiles to not include FTP related modules.
- Remove ftp code from inets
- Implement backward compatibility layer for FTP
- Add inets_ftp_wrapper
- Fix failing TCs

Change-Id: I120ec5bdef0c3df4cee2d7880db2aec581505bc4

17 files changed, 3307 insertions, 0 deletions

diff --git a/lib/ftp/test/Makefile b/lib/ftp/test/Makefile
new file mode 100644
index 0000000000..38b85449f8
--- /dev/null
+++ b/lib/ftp/test/Makefile
@@ -0,0 +1,252 @@
+#
+# %CopyrightBegin%
+#
+# Copyright Ericsson AB 1997-2018. All Rights Reserved.
+#
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+#
+# %CopyrightEnd%
+#
+#
+# For an outline of how this all_SUITE_data stuff works, see the
+# make file ../../ssl/test/Makefile.
+#
+include $(ERL_TOP)/make/target.mk
+include $(ERL_TOP)/make/$(TARGET)/otp.mk
+
+# ----------------------------------------------------
+# Application version
+# ----------------------------------------------------
+include ../vsn.mk
+VSN = $(FTP_VSN)
+
+
+# ----------------------------------------------------
+# Release directory specification
+# ----------------------------------------------------
+RELSYSDIR = $(RELEASE_PATH)/lib/$(APPLICATION)-$(VSN)
+
+
+# ----------------------------------------------------
+# Target Specs
+# ----------------------------------------------------
+INCLUDES = -I. \
+	-I$(ERL_TOP)/lib/ftp/src
+
+CP = cp
+
+ifeq ($(TESTROOT_DIR),)
+TESTROOT_DIR = /ldisk/tests/$(USER)/ftp
+endif
+
+ifeq ($(FTP_DATA_DIR),)
+FTP_DATA_DIR = $(TESTROOT_DIR)/data_dir
+endif
+
+ifeq ($(FTP_PRIV_DIR),)
+FTP_PRIV_DIR = $(TESTROOT_DIR)/priv_dir
+endif
+
+FTP_FLAGS = -Dftp__data_dir='"$(FTP_DATA_DIR)"'       \
+              -Dftp_priv_dir='"$(FTP_PRIV_DIR)"'
+
+
+### 
+### test suite debug flags
+### 
+ifeq ($(FTP_DEBUG_CLIENT),)
+  FTP_DEBUG_CLIENT = y
+endif
+
+ifeq ($(FTP_DEBUG_CLIENT),)
+  FTP_FLAGS += -Dftp_debug_client
+endif
+
+ifeq ($(FTP_TRACE_CLIENT),)
+  FTP_DEBUG_CLIENT = y
+endif
+
+ifeq ($(FTP_TRACE_CLIENT),y)
+  FTP_FLAGS += -Dftp_trace_client
+endif
+
+ifneq ($(FTP_DEBUG),)
+  FTP_DEBUG = s
+endif
+
+ifeq ($(FTP_DEBUG),l)
+  FTP_FLAGS += -Dftp_log
+endif
+
+ifeq ($(FTP_DEBUG),d)
+  FTP_FLAGS += -Dftp_debug -Dftp_log
+endif
+
+
+FTP_FLAGS += -pa ../ftp/ebin
+
+FTP_ROOT = ../ftp
+
+MODULES =                 		\
+	erl_make_certs                  \
+	ftp_SUITE 	  		\
+	ftp_format_SUITE                \
+	inets_test_lib
+
+
+EBIN = .
+
+HRL_FILES = \
+	ftp_internal.hrl \
+	inets_test_lib.hrl
+
+ERL_FILES = $(MODULES:%=%.erl)
+
+SOURCE = $(ERL_FILES) $(HRL_FILES) 
+
+TARGET_FILES = $(MODULES:%=$(EBIN)/%.$(EMULATOR))
+
+FTP_SPECS = ftp.spec ftp_bench.spec
+COVER_FILE = ftp.cover
+FTP_FILES = ftp.config $(FTP_SPECS)
+
+
+FTP_DATADIRS   = ftp_SUITE_data  
+
+DATADIRS     = $(FTP_DATADIRS)
+
+EMAKEFILE  = Emakefile
+MAKE_EMAKE = $(wildcard $(ERL_TOP)/make/make_emakefile)
+
+ifeq ($(MAKE_EMAKE),)
+BUILDTARGET   = $(TARGET_FILES)
+RELTEST_FILES = $(COVER_FILE) $(FTP_SPECS) $(SOURCE)
+else
+BUILDTARGET   = emakebuild
+RELTEST_FILES = $(EMAKEFILE) $(COVER_FILE) $(FTP_SPECS) $(SOURCE)
+endif
+
+
+# ----------------------------------------------------
+# Release directory specification
+# ----------------------------------------------------
+
+RELTESTSYSDIR        = "$(RELEASE_PATH)/ftp_test"
+RELTESTSYSALLDATADIR = $(RELTESTSYSDIR)/all_SUITE_data
+RELTESTSYSBINDIR     = $(RELTESTSYSALLDATADIR)/bin
+
+
+# ----------------------------------------------------
+# FLAGS
+# The path to the test_server ebin dir is needed when 
+# running the target "targets".
+# ----------------------------------------------------
+ERL_COMPILE_FLAGS += \
+	$(INCLUDES) \
+	$(FTP_FLAGS)
+
+# ----------------------------------------------------
+# Targets
+# erl -sname kalle -pa ../ebin
+# If you intend to run the test suite locally (private), then
+# there is some requirements:
+# 1) INETS_PRIV_DIR must be created
+# ----------------------------------------------------
+
+tests debug opt: $(BUILDTARGET) 
+
+targets: $(TARGET_FILES)
+
+.PHONY: emakebuild
+
+emakebuild: $(EMAKEFILE)
+
+$(EMAKEFILE): 
+	$(MAKE_EMAKE) $(ERL_COMPILE_FLAGS) -o$(EBIN) '*_SUITE_make' | grep -v Warning > $(EMAKEFILE)
+	$(MAKE_EMAKE) $(ERL_COMPILE_FLAGS) -o$(EBIN) $(MODULES) | grep -v Warning >> $(EMAKEFILE)
+
+clean:
+	rm -f $(EMAKEFILE)
+	rm -f $(TARGET_FILES)
+	rm -f core *~
+
+docs:
+
+
+# ----------------------------------------------------
+# Release Target
+# ---------------------------------------------------- 
+include $(ERL_TOP)/make/otp_release_targets.mk
+
+release_spec: opt
+	$(INSTALL_DIR)  "$(RELSYSDIR)/test"
+	$(INSTALL_DATA) $(HRL_FILES)   $(ERL_FILES) "$(RELSYSDIR)/test"
+	$(INSTALL_DATA) $(FTP_FILES) "$(RELSYSDIR)/test"
+	@for d in $(DATADIRS); do \
+            echo "installing data dir $$d"; \
+            if test -f $$d/TAR.exclude; then \
+                echo $$d/TAR.exclude2 > $$d/TAR.exclude2; \
+                cat $$d/TAR.exclude >> $$d/TAR.exclude2; \
+                find $$d -name '*.contrib*'     >> $$d/TAR.exclude2; \
+                find $$d -name '*.keep*'        >> $$d/TAR.exclude2; \
+                find $$d -name '*.mkelem*'      >> $$d/TAR.exclude2; \
+                find $$d -name '*~'             >> $$d/TAR.exclude2; \
+                find $$d -name 'erl_crash.dump' >> $$d/TAR.exclude2; \
+                find $$d -name 'core'           >> $$d/TAR.exclude2; \
+                find $$d -name '.cmake.state'   >> $$d/TAR.exclude2; \
+                tar cfX - $$d/TAR.exclude2 $$d | (cd "$(RELSYSDIR)/test"; tar xf -); \
+            else \
+                tar cf - $$d | (cd "$(RELSYSDIR)/test"; tar xf -); \
+            fi; \
+        done
+
+release_tests_spec: opt
+	$(INSTALL_DIR) $(RELTESTSYSDIR)
+	$(INSTALL_DATA) $(RELTEST_FILES) $(RELTESTSYSDIR)
+	chmod -R u+w $(RELTESTSYSDIR)
+	tar chf - $(DATADIRS) | (cd $(RELTESTSYSDIR); tar xf -)
+	$(INSTALL_DIR) $(RELTESTSYSALLDATADIR)
+	$(INSTALL_DIR) $(RELTESTSYSBINDIR)
+	chmod -R +x $(RELTESTSYSBINDIR)
+	$(INSTALL_DIR) $(RELTESTSYSALLDATADIR)/win32/lib	
+
+release_docs_spec:
+
+info:
+	@echo "MAKE_EMAKE        = $(MAKE_EMAKE)"
+	@echo "EMAKEFILE         = $(EMAKEFILE)"
+	@echo "BUILDTARGET       = $(BUILDTARGET)"
+	@echo ""
+	@echo "MODULES           = $(MODULES)"
+	@echo "ERL_FILES         = $(ERL_FILES)"
+	@echo "SOURCE            = $(SOURCE)"
+	@echo "TARGET_FILES      = $(TARGET_FILES)"
+	@echo ""
+	@echo "FTP_SPECS       = $(FTP_SPECS)"
+	@echo "FTP_FILES       = $(FTP_FILES)"
+	@echo ""
+	@echo "RELEASE_PATH      = "$(RELEASE_PATH)""
+	@echo "RELSYSDIR         = "$(RELSYSDIR)""
+	@echo "RELTESTSYSDIR     = $(RELTESTSYSDIR)"
+	@echo "RELTESTSYSALLDATADIR = $(RELTESTSYSALLDATADIR)"
+	@echo "RELTESTSYSBINDIR     = $(RELTESTSYSBINDIR)"
+	@echo ""
+	@echo "DATADIRS          = $(DATADIRS)"
+	@echo "REL_DATADIRS      = $(REL_DATADIRS)"
+	@echo ""
+	@echo "FTP_DATA_DIR    = $(FTP_DATA_DIR)"
+	@echo "FTP_PRIV_DIR    = $(FTP_PRIV_DIR)"
+	@echo "FTP_ROOT        = $(FTP_ROOT)"
+	@echo "FTP_FLAGS         = $(FTP_FLAGS)"
+
+
diff --git a/lib/ftp/test/erl_make_certs.erl b/lib/ftp/test/erl_make_certs.erl
new file mode 100644
index 0000000000..2db95825bc
--- /dev/null
+++ b/lib/ftp/test/erl_make_certs.erl
@@ -0,0 +1,475 @@
+%%
+%% %CopyrightBegin%
+%%
+%% Copyright Ericsson AB 2011-2016. All Rights Reserved.
+%%
+%% Licensed under the Apache License, Version 2.0 (the "License");
+%% you may not use this file except in compliance with the License.
+%% You may obtain a copy of the License at
+%%
+%%     http://www.apache.org/licenses/LICENSE-2.0
+%%
+%% Unless required by applicable law or agreed to in writing, software
+%% distributed under the License is distributed on an "AS IS" BASIS,
+%% WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+%% See the License for the specific language governing permissions and
+%% limitations under the License.
+%%
+%% %CopyrightEnd%
+%%
+
+%% Create test certificates
+
+-module(erl_make_certs).
+-include_lib("public_key/include/public_key.hrl").
+
+-export([make_cert/1, gen_rsa/1, verify_signature/3, write_pem/3]).
+-compile(export_all).
+
+%%--------------------------------------------------------------------
+%% @doc  Create and return a der encoded certificate
+%%   Option                                         Default
+%%   -------------------------------------------------------
+%%   digest                                         sha1
+%%   validity                                       {date(), date() + week()}
+%%   version                                        3
+%%   subject                                        [] list of the following content
+%%      {name,  Name}
+%%      {email, Email} 
+%%      {city,  City}
+%%      {state, State}
+%%      {org, Org}
+%%      {org_unit, OrgUnit}
+%%      {country, Country} 
+%%      {serial, Serial}
+%%      {title, Title}
+%%      {dnQualifer, DnQ}
+%%   issuer = {Issuer, IssuerKey}                   true (i.e. a ca cert is created) 
+%%                                                  (obs IssuerKey migth be {Key, Password}
+%%   key = KeyFile|KeyBin|rsa|dsa|ec                Subject PublicKey rsa, dsa or ec generates key
+%%   
+%%
+%%   (OBS: The generated keys are for testing only)
+%% @spec ([{::atom(), ::term()}]) -> {Cert::binary(), Key::binary()}
+%% @end
+%%--------------------------------------------------------------------
+
+make_cert(Opts) ->
+    SubjectPrivateKey = get_key(Opts),
+    {TBSCert, IssuerKey} = make_tbs(SubjectPrivateKey, Opts),
+    Cert = public_key:pkix_sign(TBSCert, IssuerKey),
+    true = verify_signature(Cert, IssuerKey, undef), %% verify that the keys where ok
+    {Cert, encode_key(SubjectPrivateKey)}.
+
+%%--------------------------------------------------------------------
+%% @doc Writes pem files in Dir with FileName ++ ".pem" and FileName ++ "_key.pem"
+%% @spec (::string(), ::string(), {Cert,Key}) -> ok
+%% @end
+%%--------------------------------------------------------------------
+write_pem(Dir, FileName, {Cert, Key = {_,_,not_encrypted}}) when is_binary(Cert) ->
+    ok = der_to_pem(filename:join(Dir, FileName ++ ".pem"),
+			       [{'Certificate', Cert, not_encrypted}]),
+    ok = der_to_pem(filename:join(Dir, FileName ++ "_key.pem"), [Key]).
+
+%%--------------------------------------------------------------------
+%% @doc Creates a rsa key (OBS: for testing only)
+%%   the size are in bytes
+%% @spec (::integer()) -> {::atom(), ::binary(), ::opaque()}
+%% @end
+%%--------------------------------------------------------------------
+gen_rsa(Size) when is_integer(Size) ->
+    Key = gen_rsa2(Size),
+    {Key, encode_key(Key)}.
+
+%%--------------------------------------------------------------------
+%% @doc Creates a dsa key (OBS: for testing only)
+%%   the sizes are in bytes
+%% @spec (::integer()) -> {::atom(), ::binary(), ::opaque()}
+%% @end
+%%--------------------------------------------------------------------
+gen_dsa(LSize,NSize) when is_integer(LSize), is_integer(NSize) ->
+    Key = gen_dsa2(LSize, NSize),
+    {Key, encode_key(Key)}.
+
+%%--------------------------------------------------------------------
+%% @doc Creates a ec key (OBS: for testing only)
+%%   the sizes are in bytes
+%% @spec (::integer()) -> {::atom(), ::binary(), ::opaque()}
+%% @end
+%%--------------------------------------------------------------------
+gen_ec(Curve) when is_atom(Curve) ->
+    Key = gen_ec2(Curve),
+    {Key, encode_key(Key)}.
+
+%%--------------------------------------------------------------------
+%% @doc Verifies cert signatures
+%% @spec (::binary(), ::tuple()) -> ::boolean()
+%% @end
+%%--------------------------------------------------------------------
+verify_signature(DerEncodedCert, DerKey, _KeyParams) ->
+    Key = decode_key(DerKey),
+    case Key of 
+	#'RSAPrivateKey'{modulus=Mod, publicExponent=Exp} ->
+	    public_key:pkix_verify(DerEncodedCert, 
+				   #'RSAPublicKey'{modulus=Mod, publicExponent=Exp});
+	#'DSAPrivateKey'{p=P, q=Q, g=G, y=Y} ->
+	    public_key:pkix_verify(DerEncodedCert, {Y, #'Dss-Parms'{p=P, q=Q, g=G}});
+	#'ECPrivateKey'{version = _Version, privateKey = _PrivKey,
+			parameters = Params, publicKey = {0, PubKey}} ->
+	    public_key:pkix_verify(DerEncodedCert, {#'ECPoint'{point = PubKey}, Params})
+    end.
+
+%%%%%%%%%%%%%%%%%%%%%%%%% Implementation %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+
+get_key(Opts) ->
+    case proplists:get_value(key, Opts) of
+	undefined -> make_key(rsa, Opts);
+	rsa ->       make_key(rsa, Opts);
+	dsa ->       make_key(dsa, Opts);
+	ec ->        make_key(ec, Opts);
+	Key ->
+	    Password = proplists:get_value(password, Opts, no_passwd),
+	    decode_key(Key, Password)
+    end.
+
+decode_key({Key, Pw}) ->
+    decode_key(Key, Pw);
+decode_key(Key) ->
+    decode_key(Key, no_passwd).
+    
+
+decode_key(#'RSAPublicKey'{} = Key,_) ->
+    Key;
+decode_key(#'RSAPrivateKey'{} = Key,_) ->
+    Key;
+decode_key(#'DSAPrivateKey'{} = Key,_) ->
+    Key;
+decode_key(#'ECPrivateKey'{} = Key,_) ->
+    Key;
+decode_key(PemEntry = {_,_,_}, Pw) ->
+    public_key:pem_entry_decode(PemEntry, Pw);
+decode_key(PemBin, Pw) ->
+    [KeyInfo] = public_key:pem_decode(PemBin),
+    decode_key(KeyInfo, Pw).
+
+encode_key(Key = #'RSAPrivateKey'{}) ->
+    {ok, Der} = 'OTP-PUB-KEY':encode('RSAPrivateKey', Key),
+    {'RSAPrivateKey', Der, not_encrypted};
+encode_key(Key = #'DSAPrivateKey'{}) ->
+    {ok, Der} = 'OTP-PUB-KEY':encode('DSAPrivateKey', Key),
+    {'DSAPrivateKey', Der, not_encrypted};
+encode_key(Key = #'ECPrivateKey'{}) ->
+    {ok, Der} = 'OTP-PUB-KEY':encode('ECPrivateKey', Key),
+    {'ECPrivateKey', Der, not_encrypted}.
+
+make_tbs(SubjectKey, Opts) ->    
+    Version = list_to_atom("v"++integer_to_list(proplists:get_value(version, Opts, 3))),
+
+    IssuerProp = proplists:get_value(issuer, Opts, true),
+    {Issuer, IssuerKey}  = issuer(IssuerProp, Opts, SubjectKey),
+
+    {Algo, Parameters} = sign_algorithm(IssuerKey, Opts),
+    
+    SignAlgo = #'SignatureAlgorithm'{algorithm  = Algo,
+				     parameters = Parameters},    
+    Subject = case IssuerProp of
+		  true -> %% Is a Root Ca
+		      Issuer;
+		  _ ->
+		      subject(proplists:get_value(subject, Opts),false)
+	      end,
+
+    {#'OTPTBSCertificate'{serialNumber = trunc(random:uniform()*100000000)*10000 + 1,
+			  signature    = SignAlgo,
+			  issuer       = Issuer,
+			  validity     = validity(Opts),
+			  subject      = Subject,
+			  subjectPublicKeyInfo = publickey(SubjectKey),
+			  version      = Version,
+			  extensions   = extensions(Opts)
+			 }, IssuerKey}.
+
+issuer(true, Opts, SubjectKey) ->
+    %% Self signed
+    {subject(proplists:get_value(subject, Opts), true), SubjectKey};
+issuer({Issuer, IssuerKey}, _Opts, _SubjectKey) when is_binary(Issuer) ->
+    {issuer_der(Issuer), decode_key(IssuerKey)};
+issuer({File, IssuerKey}, _Opts, _SubjectKey) when is_list(File) ->
+    {ok, [{cert, Cert, _}|_]} = pem_to_der(File),
+    {issuer_der(Cert), decode_key(IssuerKey)}.
+
+issuer_der(Issuer) ->
+    Decoded = public_key:pkix_decode_cert(Issuer, otp),
+    #'OTPCertificate'{tbsCertificate=Tbs} = Decoded,
+    #'OTPTBSCertificate'{subject=Subject} = Tbs,
+    Subject.
+
+subject(undefined, IsRootCA) ->
+    User = if IsRootCA -> "RootCA"; true -> os:getenv("USER", "test_user") end,
+    Opts = [{email, User ++ "@erlang.org"},
+	    {name, User},
+	    {city, "Stockholm"},
+	    {country, "SE"},
+	    {org, "erlang"},
+	    {org_unit, "testing dep"}],
+    subject(Opts);
+subject(Opts, _) ->
+    subject(Opts).
+
+subject(SubjectOpts) when is_list(SubjectOpts) ->
+    Encode = fun(Opt) ->
+		     {Type,Value} = subject_enc(Opt),
+		     [#'AttributeTypeAndValue'{type=Type, value=Value}]
+	     end,
+    {rdnSequence, [Encode(Opt) || Opt <- SubjectOpts]}.
+
+%% Fill in the blanks
+subject_enc({name,  Name}) ->       {?'id-at-commonName', {printableString, Name}};
+subject_enc({email, Email}) ->      {?'id-emailAddress', Email};
+subject_enc({city,  City}) ->       {?'id-at-localityName', {printableString, City}};
+subject_enc({state, State}) ->      {?'id-at-stateOrProvinceName', {printableString, State}};
+subject_enc({org, Org}) ->          {?'id-at-organizationName', {printableString, Org}};
+subject_enc({org_unit, OrgUnit}) -> {?'id-at-organizationalUnitName', {printableString, OrgUnit}};
+subject_enc({country, Country}) ->  {?'id-at-countryName', Country};
+subject_enc({serial, Serial}) ->    {?'id-at-serialNumber', Serial};
+subject_enc({title, Title}) ->      {?'id-at-title', {printableString, Title}};
+subject_enc({dnQualifer, DnQ}) ->   {?'id-at-dnQualifier', DnQ};
+subject_enc(Other) ->               Other.
+
+
+extensions(Opts) ->
+    case proplists:get_value(extensions, Opts, []) of
+	false -> 
+	    asn1_NOVALUE;
+	Exts  -> 
+	    lists:flatten([extension(Ext) || Ext <- default_extensions(Exts)])
+    end.
+
+default_extensions(Exts) ->
+    Def = [{key_usage,undefined}, 
+	   {subject_altname, undefined},
+	   {issuer_altname, undefined},
+	   {basic_constraints, default},
+	   {name_constraints, undefined},
+	   {policy_constraints, undefined},
+	   {ext_key_usage, undefined},
+	   {inhibit_any, undefined},
+	   {auth_key_id, undefined},
+	   {subject_key_id, undefined},
+	   {policy_mapping, undefined}],
+    Filter = fun({Key, _}, D) -> lists:keydelete(Key, 1, D) end,
+    Exts ++ lists:foldl(Filter, Def, Exts).
+       	
+extension({_, undefined}) -> [];
+extension({basic_constraints, Data}) ->
+    case Data of
+	default ->
+	    #'Extension'{extnID = ?'id-ce-basicConstraints',
+			 extnValue = #'BasicConstraints'{cA=true},
+			 critical=true};
+	false -> 
+	    [];
+	Len when is_integer(Len) ->
+	    #'Extension'{extnID = ?'id-ce-basicConstraints',
+			 extnValue = #'BasicConstraints'{cA=true, pathLenConstraint=Len},
+			 critical=true};
+	_ ->
+	    #'Extension'{extnID = ?'id-ce-basicConstraints',
+			 extnValue = Data}
+    end;
+extension({Id, Data, Critical}) ->
+    #'Extension'{extnID = Id, extnValue = Data, critical = Critical}.
+
+
+publickey(#'RSAPrivateKey'{modulus=N, publicExponent=E}) ->
+    Public = #'RSAPublicKey'{modulus=N, publicExponent=E},
+    Algo = #'PublicKeyAlgorithm'{algorithm= ?rsaEncryption, parameters='NULL'},
+    #'OTPSubjectPublicKeyInfo'{algorithm = Algo,
+			       subjectPublicKey = Public};
+publickey(#'DSAPrivateKey'{p=P, q=Q, g=G, y=Y}) ->
+    Algo = #'PublicKeyAlgorithm'{algorithm= ?'id-dsa', 
+				 parameters={params, #'Dss-Parms'{p=P, q=Q, g=G}}},
+    #'OTPSubjectPublicKeyInfo'{algorithm = Algo, subjectPublicKey = Y};
+publickey(#'ECPrivateKey'{version = _Version,
+			  privateKey = _PrivKey,
+			  parameters = Params,
+			  publicKey = {0, PubKey}}) ->
+    Algo = #'PublicKeyAlgorithm'{algorithm= ?'id-ecPublicKey', parameters=Params},
+    #'OTPSubjectPublicKeyInfo'{algorithm = Algo,
+			       subjectPublicKey = #'ECPoint'{point = PubKey}}.
+
+validity(Opts) ->
+    DefFrom0 = calendar:gregorian_days_to_date(calendar:date_to_gregorian_days(date())-1),
+    DefTo0   = calendar:gregorian_days_to_date(calendar:date_to_gregorian_days(date())+7),
+    {DefFrom, DefTo} = proplists:get_value(validity, Opts, {DefFrom0, DefTo0}),
+    Format = fun({Y,M,D}) -> lists:flatten(io_lib:format("~w~2..0w~2..0w000000Z",[Y,M,D])) end,
+    #'Validity'{notBefore={generalTime, Format(DefFrom)},
+		notAfter ={generalTime, Format(DefTo)}}.
+
+sign_algorithm(#'RSAPrivateKey'{}, Opts) ->
+    Type = case proplists:get_value(digest, Opts, sha1) of
+	       sha1 ->   ?'sha1WithRSAEncryption';
+	       sha512 -> ?'sha512WithRSAEncryption';
+	       sha384 -> ?'sha384WithRSAEncryption';
+	       sha256 -> ?'sha256WithRSAEncryption';
+	       md5    -> ?'md5WithRSAEncryption';
+	       md2    -> ?'md2WithRSAEncryption'
+	   end,
+    {Type, 'NULL'};
+sign_algorithm(#'DSAPrivateKey'{p=P, q=Q, g=G}, _Opts) ->
+    {?'id-dsa-with-sha1', {params,#'Dss-Parms'{p=P, q=Q, g=G}}};
+sign_algorithm(#'ECPrivateKey'{}, Opts) ->
+    Type = case proplists:get_value(digest, Opts, sha1) of
+	       sha1 ->   ?'ecdsa-with-SHA1';
+	       sha512 -> ?'ecdsa-with-SHA512';
+	       sha384 -> ?'ecdsa-with-SHA384';
+	       sha256 -> ?'ecdsa-with-SHA256'
+	   end,
+    {Type, 'NULL'}.
+
+make_key(rsa, _Opts) ->
+    %% (OBS: for testing only)
+    gen_rsa2(64);
+make_key(dsa, _Opts) ->
+    gen_dsa2(128, 20);  %% Bytes i.e. {1024, 160}
+make_key(ec, _Opts) ->
+    %% (OBS: for testing only)
+    gen_ec2(secp256k1).
+    
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+%% RSA key generation  (OBS: for testing only)
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+
+-define(SMALL_PRIMES, [65537,97,89,83,79,73,71,67,61,59,53,
+		       47,43,41,37,31,29,23,19,17,13,11,7,5,3]).
+
+gen_rsa2(Size) ->
+    P = prime(Size),
+    Q = prime(Size),
+    N = P*Q,
+    Tot = (P - 1) * (Q - 1),
+    [E|_] = lists:dropwhile(fun(Candidate) -> (Tot rem Candidate) == 0 end, ?SMALL_PRIMES),
+    {D1,D2} = extended_gcd(E, Tot),
+    D = erlang:max(D1,D2),
+    case D < E of
+	true ->
+	    gen_rsa2(Size);
+	false ->
+	    {Co1,Co2} = extended_gcd(Q, P),
+	    Co = erlang:max(Co1,Co2),
+	    #'RSAPrivateKey'{version = 'two-prime',
+			     modulus = N,
+			     publicExponent  = E,
+			     privateExponent = D, 
+			     prime1 = P, 
+			     prime2 = Q, 
+			     exponent1 = D rem (P-1), 
+			     exponent2 = D rem (Q-1), 
+			     coefficient = Co
+			    }
+    end.
+
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+%% DSA key generation  (OBS: for testing only)
+%% See http://en.wikipedia.org/wiki/Digital_Signature_Algorithm
+%% and the fips_186-3.pdf
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+gen_dsa2(LSize, NSize) ->
+    Q  = prime(NSize),  %% Choose N-bit prime Q
+    X0 = prime(LSize),
+    P0 = prime((LSize div 2) +1),
+    
+    %% Choose L-bit prime modulus P such that p-1 is a multiple of q.
+    case dsa_search(X0 div (2*Q*P0), P0, Q, 1000) of
+	error -> 
+	    gen_dsa2(LSize, NSize);
+	P ->	    
+	    G = crypto:mod_pow(2, (P-1) div Q, P), % Choose G a number whose multiplicative order modulo p is q.
+	    %%                 such that This may be done by setting g = h^(p-1)/q mod p, commonly h=2 is used.
+	    
+	    X = prime(20),               %% Choose x by some random method, where 0 < x < q.
+	    Y = crypto:mod_pow(G, X, P), %% Calculate y = g^x mod p.
+	    
+	    #'DSAPrivateKey'{version=0, p = P, q = Q, 
+			     g = crypto:bytes_to_integer(G), y = crypto:bytes_to_integer(Y), x = X}
+    end.
+    
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+%% EC key generation  (OBS: for testing only)
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+
+gen_ec2(CurveId) ->
+     {PubKey, PrivKey} = crypto:generate_key(ecdh, CurveId),
+
+    #'ECPrivateKey'{version = 1,
+		    privateKey = binary_to_list(PrivKey),
+		    parameters = {namedCurve, pubkey_cert_records:namedCurves(CurveId)},
+		    publicKey = {0, PubKey}}.
+
+%% See fips_186-3.pdf
+dsa_search(T, P0, Q, Iter) when Iter > 0 ->
+    P = 2*T*Q*P0 + 1,
+    case is_prime(P, 50) of
+	true -> P;
+	false -> dsa_search(T+1, P0, Q, Iter-1)
+    end;
+dsa_search(_,_,_,_) -> 
+    error.
+
+
+%%%%%%% Crypto Math %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+prime(ByteSize) ->
+    Rand = odd_rand(ByteSize),
+    prime_odd(Rand, 0).
+
+prime_odd(Rand, N) ->
+    case is_prime(Rand, 50) of
+	true -> 
+	    Rand;
+	false -> 
+	    prime_odd(Rand+2, N+1)
+    end.
+
+%% see http://en.wikipedia.org/wiki/Fermat_primality_test
+is_prime(_, 0) -> true;
+is_prime(Candidate, Test) -> 
+    CoPrime = odd_rand(10000, Candidate),
+    Result = crypto:mod_pow(CoPrime, Candidate, Candidate) ,
+    is_prime(CoPrime, crypto:bytes_to_integer(Result), Candidate, Test).
+
+is_prime(CoPrime, CoPrime, Candidate, Test) ->
+    is_prime(Candidate, Test-1);
+is_prime(_,_,_,_) ->
+    false.
+
+odd_rand(Size) ->
+    Min = 1 bsl (Size*8-1),
+    Max = (1 bsl (Size*8))-1,
+    odd_rand(Min, Max).
+
+odd_rand(Min,Max) ->
+    Rand = crypto:rand_uniform(Min,Max),
+    case Rand rem 2 of
+	0 -> 
+	    Rand + 1;
+	_ -> 
+	    Rand
+    end.
+
+extended_gcd(A, B) ->
+    case A rem B of
+	0 ->
+	    {0, 1};
+	N ->
+	    {X, Y} = extended_gcd(B, N),
+	    {Y, X-Y*(A div B)}
+    end.
+
+pem_to_der(File) ->
+    {ok, PemBin} = file:read_file(File),
+    public_key:pem_decode(PemBin).
+
+der_to_pem(File, Entries) ->
+    PemBin = public_key:pem_encode(Entries),
+    file:write_file(File, PemBin).
+
diff --git a/lib/ftp/test/ftp.config b/lib/ftp/test/ftp.config
new file mode 100644
index 0000000000..6c9077594d
--- /dev/null
+++ b/lib/ftp/test/ftp.config
@@ -0,0 +1 @@
+[{inets,[{services,[{httpd,"/ldisk/tests/bmk/inets/priv_dir/8099.conf"}]}]}]. 
diff --git a/lib/ftp/test/ftp.cover b/lib/ftp/test/ftp.cover
new file mode 100644
index 0000000000..5b155991bc
--- /dev/null
+++ b/lib/ftp/test/ftp.cover
@@ -0,0 +1,2 @@
+{incl_app,ftp,details}.
+
diff --git a/lib/ftp/test/ftp.spec b/lib/ftp/test/ftp.spec
new file mode 100644
index 0000000000..faf1e532a8
--- /dev/null
+++ b/lib/ftp/test/ftp.spec
@@ -0,0 +1 @@
+{suites,"../ftp_test", all}.
diff --git a/lib/ftp/test/ftp_SUITE.erl b/lib/ftp/test/ftp_SUITE.erl
new file mode 100644
index 0000000000..3dfec01ba2
--- /dev/null
+++ b/lib/ftp/test/ftp_SUITE.erl
@@ -0,0 +1,1180 @@
+%%
+%% %CopyrightBegin%
+%% 
+%% Copyright Ericsson AB 2004-2017. All Rights Reserved.
+%% 
+%% Licensed under the Apache License, Version 2.0 (the "License");
+%% you may not use this file except in compliance with the License.
+%% You may obtain a copy of the License at
+%%
+%%     http://www.apache.org/licenses/LICENSE-2.0
+%%
+%% Unless required by applicable law or agreed to in writing, software
+%% distributed under the License is distributed on an "AS IS" BASIS,
+%% WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+%% See the License for the specific language governing permissions and
+%% limitations under the License.
+%% 
+%% %CopyrightEnd%
+%%
+%%
+
+%% 
+%% ct:run("../inets_test", ftp_SUITE).
+%%
+
+-module(ftp_SUITE).
+
+-include_lib("kernel/include/file.hrl").
+-include_lib("common_test/include/ct.hrl").
+-include("inets_test_lib.hrl").
+
+%% Note: This directive should only be used in test suites.
+-compile(export_all).
+
+-define(FTP_USER, "anonymous").
+-define(FTP_PASS(Cmnt), (fun({ok,__H}) -> "ftp_SUITE_"++Cmnt++"@" ++ __H;
+			    (_) -> "ftp_SUITE_"++Cmnt++"@localhost"
+			 end)(inet:gethostname())
+       ).
+
+-define(BAD_HOST, "badhostname").
+-define(BAD_USER, "baduser").
+-define(BAD_DIR,  "baddirectory").
+
+-record(progress, {
+	  current = 0,
+	  total
+	 }).
+
+%%--------------------------------------------------------------------
+%% Common Test interface functions -----------------------------------
+%%--------------------------------------------------------------------
+suite() ->
+    [{timetrap,{seconds,20}}].
+
+all() ->
+    [
+     {group, ftp_passive},
+     {group, ftp_active},
+     {group, ftps_passive},
+     {group, ftps_active},
+     error_ehost,
+     clean_shutdown
+    ].
+
+groups() ->
+    [
+     {ftp_passive, [], ftp_tests()},
+     {ftp_active, [], ftp_tests()},
+     {ftps_passive, [], ftp_tests()},
+     {ftps_active, [], ftp_tests()}
+    ].
+
+ftp_tests()->
+    [
+     user,
+     bad_user,
+     pwd, 
+     cd, 
+     lcd,
+     ls, 
+     nlist, 
+     rename, 
+     delete, 
+     mkdir, 
+     rmdir,
+     send, 
+     send_3,
+     send_bin, 
+     send_chunk, 
+     append, 
+     append_bin,
+     append_chunk, 
+     recv, 
+     recv_3, 
+     recv_bin,
+     recv_bin_twice,
+     recv_chunk, 
+     recv_chunk_twice,
+     recv_chunk_three_times,
+     type, 
+     quote, 
+     error_elogin,
+     progress_report_send,
+     progress_report_recv,
+     not_owner,
+     unexpected_call,
+     unexpected_cast,
+     unexpected_bang
+    ].
+
+%%--------------------------------------------------------------------
+
+%%% Config
+%%% key			meaning
+%%% ................................................................
+%%% ftpservers		list of servers to check if they are available
+%%%			The element is:
+%%%			  {Name,         % string(). The os command name
+%%%                        Path,         % string(). The os PATH syntax, e.g "/bin:/usr/bin"
+%%%			   StartCommand, % fun()->{ok,start_result()} | {error,string()}.
+%%%			                 % The command to start the daemon with.
+%%%			   ChkUp,        % fun(start_result()) -> string(). Os command to check
+%%%			                 %       if the server is running. [] if not running.
+%%%			                 %       The string in string() is suitable for logging.
+%%%			   StopCommand,  % fun(start_result()) -> void(). The command to stop the daemon with.
+%%%			   AugmentFun,   % fun(config()) -> config() Adds two funs for transforming names of files
+%%%			                 %       and directories to the form they are returned from this server
+%%%			   ServerHost,   % string(). Mostly "localhost"
+%%%			   ServerPort    % pos_integer()
+%%%			  }
+%%%			  
+
+-define(default_ftp_servers,
+	[{"vsftpd",
+	  "/sbin:/usr/sbin:/usr/local/sbin",
+	  fun(__CONF__, AbsName) -> 
+		  DataDir = proplists:get_value(data_dir,__CONF__),
+		  ConfFile = filename:join(DataDir, "vsftpd.conf"),
+		  PrivDir = proplists:get_value(priv_dir,__CONF__),
+		  AnonRoot = PrivDir,
+		  Cmd = [AbsName ++" "++filename:join(DataDir,"vsftpd.conf"),
+			 " -oftpd_banner=erlang_otp_testing",
+			 " -oanon_root=\"",AnonRoot,"\"",
+			 " -orsa_cert_file=\"",filename:join(DataDir,"server-cert.pem"),"\"",
+			 " -orsa_private_key_file=\"",filename:join(DataDir,"server-key.pem"),"\""
+			],
+		  Result = os:cmd(Cmd),
+		  ct:log("Config file:~n~s~n~nServer start command:~n  ~s~nResult:~n  ~p",
+			 [case file:read_file(ConfFile) of
+			      {ok,X} -> X;
+			      _ -> ""
+			  end,
+			  Cmd, Result
+			 ]),
+		  case Result of
+		      [] -> {ok,'dont care'};
+		      [Msg] -> {error,Msg}
+		  end
+	  end,
+	  fun(_StartResult) -> os:cmd("ps ax | grep erlang_otp_testing | grep -v grep")
+	  end,
+	  fun(_StartResult) -> os:cmd("kill `ps ax | grep erlang_otp_testing | awk '/vsftpd/{print $1}'`")
+	  end,
+	  fun(__CONF__) ->
+		  AnonRoot = proplists:get_value(priv_dir,__CONF__),
+		  [{id2ftp, fun(Id) -> filename:join(AnonRoot,Id) end},
+		   {id2ftp_result,fun(Id) -> filename:join(AnonRoot,Id) end} | __CONF__]
+	  end,
+	  "localhost",
+	  9999
+	 }
+	]
+       ).
+
+
+init_per_suite(Config) ->
+    case find_executable(Config) of
+	false -> 
+	    {skip, "No ftp server found"};
+	{ok,Data} -> 
+	    TstDir = filename:join(proplists:get_value(priv_dir,Config), "test"),
+	    file:make_dir(TstDir),
+	    make_cert_files(dsa, rsa, "server-", proplists:get_value(data_dir,Config)),
+	    start_ftpd([{test_dir,TstDir},
+			{ftpd_data,Data}
+			| Config])
+    end.
+
+end_per_suite(Config) ->
+    ps_ftpd(Config),
+    stop_ftpd(Config),
+    ps_ftpd(Config),
+    ok.
+
+%%--------------------------------------------------------------------
+init_per_group(Group, Config) when Group == ftps_active,
+                                   Group == ftps_passive ->
+    catch crypto:stop(),
+    try crypto:start() of
+        ok ->
+            Config
+    catch
+        _:_ ->
+            {skip, "Crypto did not start"}
+    end;
+
+init_per_group(_Group, Config) -> 
+    Config.
+
+end_per_group(_Group, Config) -> 
+    Config.
+
+%%--------------------------------------------------------------------
+init_per_testcase(Case, Config0) ->
+    Group = proplists:get_value(name, proplists:get_value(tc_group_properties,Config0)),
+    TLS = [{tls,[{reuse_sessions,true}]}],
+    ACTIVE = [{mode,active}],
+    PASSIVE = [{mode,passive}],
+    CaseOpts = case Case of
+		   progress_report_send -> [{progress, {?MODULE,progress,#progress{}}}];
+		   progress_report_recv -> [{progress, {?MODULE,progress,#progress{}}}];
+		   _ -> []
+	       end,
+    ExtraOpts = [verbose | CaseOpts],
+    Config =
+	case Group of
+	    ftp_active   -> ftp__open(Config0,       ACTIVE  ++ ExtraOpts);
+	    ftps_active  -> ftp__open(Config0, TLS++ ACTIVE  ++ ExtraOpts);
+	    ftp_passive  -> ftp__open(Config0,      PASSIVE  ++ ExtraOpts);
+	    ftps_passive -> ftp__open(Config0, TLS++PASSIVE  ++ ExtraOpts);
+	    undefined    -> Config0
+	end,
+    case Case of
+	user           -> Config;
+	bad_user       -> Config;
+	error_elogin   -> Config;
+	error_ehost    -> Config;
+	clean_shutdown -> Config;
+	_ ->
+	    Pid = proplists:get_value(ftp,Config),
+	    ok = ftp:user(Pid, ?FTP_USER, ?FTP_PASS(atom_to_list(Group)++"-"++atom_to_list(Case)) ),
+	    ok = ftp:cd(Pid, proplists:get_value(priv_dir,Config)),
+	    Config
+    end.
+
+    
+end_per_testcase(user, _Config) -> ok;
+end_per_testcase(bad_user, _Config) -> ok;
+end_per_testcase(error_elogin, _Config) -> ok;
+end_per_testcase(error_ehost, _Config) -> ok;
+end_per_testcase(clean_shutdown, _Config) -> ok;
+end_per_testcase(_Case, Config) -> 
+    case proplists:get_value(tc_status,Config) of
+	ok -> ok;
+	_ ->
+	    try ftp:latest_ctrl_response(proplists:get_value(ftp,Config))
+	    of
+		{ok,S} -> ct:log("***~n*** Latest ctrl channel response:~n***     ~p~n***",[S])
+	    catch
+		_:_ -> ok
+	    end
+    end,
+    ftp__close(Config).
+
+%%--------------------------------------------------------------------
+%% Test Cases --------------------------------------------------------
+%%--------------------------------------------------------------------
+user() -> [
+	   {doc, "Open an ftp connection to a host, and logon as anonymous ftp,"
+	    " then logoff"}].
+user(Config) ->
+    Pid = proplists:get_value(ftp, Config),
+    ok = ftp:user(Pid, ?FTP_USER, ?FTP_PASS("")),% logon
+    ok = ftp:close(Pid),			% logoff
+    {error,eclosed} = ftp:pwd(Pid),		% check logoff result
+    ok.
+
+%%-------------------------------------------------------------------------
+bad_user() -> 
+    [{doc, "Open an ftp connection to a host, and logon with bad user."}].
+bad_user(Config) ->
+    Pid = proplists:get_value(ftp, Config),
+    {error, euser} = ftp:user(Pid, ?BAD_USER, ?FTP_PASS("")),
+    ok.
+
+%%-------------------------------------------------------------------------
+pwd() -> 
+    [{doc, "Test ftp:pwd/1 & ftp:lpwd/1"}].
+pwd(Config0) ->
+    Config = set_state([reset], Config0),
+    Pid = proplists:get_value(ftp, Config),
+    {ok, PWD} = ftp:pwd(Pid),
+    {ok, PathLpwd} = ftp:lpwd(Pid),
+    PWD = id2ftp_result("", Config),
+    PathLpwd = id2ftp_result("", Config).
+
+%%-------------------------------------------------------------------------
+cd() -> 
+    ["Open an ftp connection, log on as anonymous ftp, and cd to a"
+     "directory and to a non-existent directory."].
+cd(Config0) ->
+    Dir = "test",
+    Config = set_state([reset,{mkdir,Dir}], Config0),
+    Pid = proplists:get_value(ftp, Config),
+    ok = ftp:cd(Pid, id2ftp(Dir,Config)),
+    {ok, PWD} = ftp:pwd(Pid),
+    ExpectedPWD = id2ftp_result(Dir, Config),
+    PWD = ExpectedPWD,
+    {error, epath} = ftp:cd(Pid, ?BAD_DIR),
+    ok.
+
+%%-------------------------------------------------------------------------
+lcd() ->
+    [{doc, "Test api function ftp:lcd/2"}].
+lcd(Config0) ->
+    Dir = "test",
+    Config = set_state([reset,{mkdir,Dir}], Config0),
+    Pid = proplists:get_value(ftp, Config),
+    ok = ftp:lcd(Pid, id2ftp(Dir,Config)),
+    {ok, PWD} = ftp:lpwd(Pid),
+    ExpectedPWD = id2ftp_result(Dir, Config),
+    PWD = ExpectedPWD,
+    {error, epath} = ftp:lcd(Pid, ?BAD_DIR).
+
+%%-------------------------------------------------------------------------
+ls() -> 
+    [{doc, "Open an ftp connection; ls the current directory, and the "
+      "\"test\" directory. We assume that ls never fails, since "
+      "it's output is meant to be read by humans. "}].
+ls(Config0) ->
+    Config = set_state([reset,{mkdir,"test"}], Config0),
+    Pid = proplists:get_value(ftp, Config),
+    {ok, _R1} = ftp:ls(Pid),
+    {ok, _R2} = ftp:ls(Pid, id2ftp("test",Config)),
+    %% neither nlist nor ls operates on a directory
+    %% they operate on a pathname, which *can* be a 
+    %% directory, but can also be a filename or a group 
+    %% of files (including wildcards).
+    case proplists:get_value(wildcard_support, Config) of
+	true ->
+	    {ok, _R3} = ftp:ls(Pid, id2ftp("te*",Config));
+	_ ->
+	    ok
+    end.
+
+%%-------------------------------------------------------------------------
+nlist() -> 
+    [{doc,"Open an ftp connection; nlist the current directory, and the "
+	       "\"test\" directory. Nlist does not behave consistenly over "
+	       "operating systems. On some it is an error to have an empty "
+	       "directory."}].
+nlist(Config0) ->
+    Config = set_state([reset,{mkdir,"test"}], Config0),
+    Pid = proplists:get_value(ftp, Config),
+    {ok, _R1} = ftp:nlist(Pid),
+    {ok, _R2} = ftp:nlist(Pid, id2ftp("test",Config)),
+    %% neither nlist nor ls operates on a directory
+    %% they operate on a pathname, which *can* be a 
+    %% directory, but can also be a filename or a group 
+    %% of files (including wildcards).
+    case proplists:get_value(wildcard_support, Config) of
+	true ->
+	    {ok, _R3} = ftp:nlist(Pid, id2ftp("te*",Config));
+	_ ->
+	    ok
+    end.
+
+%%-------------------------------------------------------------------------
+rename() -> 
+    [{doc, "Rename a file."}].
+rename(Config0) ->
+    Contents = <<"ftp_SUITE test ...">>,
+    OldFile = "old.txt",
+    NewFile = "new.txt",
+    Config = set_state([reset,{mkfile,OldFile,Contents}], Config0),
+    Pid = proplists:get_value(ftp, Config),
+
+    ok = ftp:rename(Pid, 
+		    id2ftp(OldFile,Config),
+		    id2ftp(NewFile,Config)),
+
+    true = (chk_file(NewFile,Contents,Config) 
+	    and chk_no_file([OldFile],Config)),
+    {error,epath} = ftp:rename(Pid,
+			       id2ftp("non_existing_file",Config),
+			       id2ftp(NewFile,Config)),
+    ok.
+
+%%-------------------------------------------------------------------------
+send() -> 
+    [{doc, "Transfer a file with ftp using send/2."}].
+send(Config0) ->
+    Contents = <<"ftp_SUITE test ...">>,
+    SrcDir = "data",
+    File = "file.txt",
+    Config = set_state([reset,{mkfile,[SrcDir,File],Contents}], Config0),
+    Pid = proplists:get_value(ftp, Config),
+
+    chk_no_file([File],Config),
+    chk_file([SrcDir,File],Contents,Config),
+
+    ok = ftp:lcd(Pid, id2ftp(SrcDir,Config)),
+    ok = ftp:cd(Pid, id2ftp("",Config)),
+    ok = ftp:send(Pid, File),
+    chk_file(File, Contents, Config),
+
+    {error,epath} = ftp:send(Pid, "non_existing_file"),
+    ok.
+
+%%-------------------------------------------------------------------------
+send_3() -> 
+    [{doc, "Transfer a file with ftp using send/3."}].
+send_3(Config0) ->
+    Contents = <<"ftp_SUITE test ...">>,
+    Dir = "incoming",
+    File = "file.txt",
+    RemoteFile = "remfile.txt",
+    Config = set_state([reset,{mkfile,File,Contents},{mkdir,Dir}], Config0),
+    Pid = proplists:get_value(ftp, Config),
+
+    ok = ftp:cd(Pid, id2ftp(Dir,Config)),
+    ok = ftp:lcd(Pid, id2ftp("",Config)),
+    ok = ftp:send(Pid, File, RemoteFile),
+    chk_file([Dir,RemoteFile], Contents, Config),
+
+    {error,epath} = ftp:send(Pid, "non_existing_file", RemoteFile),
+    ok.
+
+%%------------------------------------------------------------------------- 
+send_bin() -> 
+    [{doc, "Send a binary."}].
+send_bin(Config0) ->
+    BinContents = <<"ftp_SUITE test ...">>,
+    File = "file.txt",
+    Config = set_state([reset], Config0),
+    Pid = proplists:get_value(ftp, Config),
+    {error, enotbinary} = ftp:send_bin(Pid, "some string", id2ftp(File,Config)),
+    ok = ftp:send_bin(Pid, BinContents, id2ftp(File,Config)),
+    chk_file(File, BinContents, Config),
+    {error, efnamena} = ftp:send_bin(Pid, BinContents, "/nothere"),
+    ok.
+
+%%-------------------------------------------------------------------------    
+send_chunk() -> 
+    [{doc, "Send a binary using chunks."}].
+send_chunk(Config0) ->
+    Contents1 = <<"1: ftp_SUITE test ...">>,
+    Contents2 = <<"2: ftp_SUITE test ...">>,
+    File = "file.txt",
+    Config = set_state([reset,{mkdir,"incoming"}], Config0),
+    Pid = proplists:get_value(ftp, Config),
+
+    ok = ftp:send_chunk_start(Pid, id2ftp(File,Config)),
+    {error, echunk} = ftp:send_chunk_start(Pid, id2ftp(File,Config)),
+    {error, echunk} = ftp:cd(Pid, "incoming"),
+    {error, enotbinary} = ftp:send_chunk(Pid, "some string"),
+    ok = ftp:send_chunk(Pid, Contents1),
+    ok = ftp:send_chunk(Pid, Contents2),
+    ok = ftp:send_chunk_end(Pid),
+    chk_file(File, <<Contents1/binary,Contents2/binary>>, Config),
+
+    {error, echunk} = ftp:send_chunk(Pid, Contents1),
+    {error, echunk} = ftp:send_chunk_end(Pid),
+    {error, efnamena} = ftp:send_chunk_start(Pid, "/"),
+    ok.
+
+%%-------------------------------------------------------------------------
+delete() -> 
+    [{doc, "Delete a file."}].
+delete(Config0) ->
+    Contents = <<"ftp_SUITE test ...">>,
+    File = "file.txt",
+    Config = set_state([reset,{mkfile,File,Contents}], Config0),
+    Pid = proplists:get_value(ftp, Config),
+    ok = ftp:delete(Pid, id2ftp(File,Config)),
+    chk_no_file([File], Config),
+    {error,epath} = ftp:delete(Pid, id2ftp(File,Config)),
+    ok.
+
+%%-------------------------------------------------------------------------
+mkdir() ->
+    [{doc, "Make a remote directory."}].
+mkdir(Config0) ->
+    NewDir = "new_dir",
+    Config = set_state([reset], Config0),
+    Pid = proplists:get_value(ftp, Config),
+    ok = ftp:mkdir(Pid, id2ftp(NewDir,Config)),
+    chk_dir([NewDir], Config),
+    {error,epath} = ftp:mkdir(Pid, id2ftp(NewDir,Config)),
+    ok.
+
+%%-------------------------------------------------------------------------
+rmdir() -> 
+    [{doc, "Remove a directory."}].
+rmdir(Config0) ->
+    Dir = "dir",
+    Config = set_state([reset,{mkdir,Dir}], Config0),
+    Pid = proplists:get_value(ftp, Config),
+    ok = ftp:rmdir(Pid, id2ftp(Dir,Config)),
+    chk_no_dir([Dir], Config),
+    {error,epath} = ftp:rmdir(Pid, id2ftp(Dir,Config)),
+    ok.
+
+%%-------------------------------------------------------------------------
+append() -> 
+    [{doc, "Append a local file twice to a remote file"}].
+append(Config0) ->
+    SrcFile = "f_src.txt",
+    DstFile = "f_dst.txt",
+    Contents = <<"ftp_SUITE test ...">>,
+    Config = set_state([reset,{mkfile,SrcFile,Contents}], Config0),
+    Pid = proplists:get_value(ftp, Config),
+    ok = ftp:append(Pid, id2ftp(SrcFile,Config), id2ftp(DstFile,Config)),
+    ok = ftp:append(Pid, id2ftp(SrcFile,Config), id2ftp(DstFile,Config)),
+    chk_file(DstFile, <<Contents/binary,Contents/binary>>, Config),
+    {error,epath} = ftp:append(Pid, id2ftp("non_existing_file",Config), id2ftp(DstFile,Config)),
+    ok.
+		
+%%-------------------------------------------------------------------------
+append_bin() -> 
+    [{doc, "Append a local file twice to a remote file using append_bin"}].
+append_bin(Config0) ->
+    DstFile = "f_dst.txt",
+    Contents = <<"ftp_SUITE test ...">>,
+    Config = set_state([reset], Config0),
+    Pid = proplists:get_value(ftp, Config),
+    ok = ftp:append_bin(Pid, Contents, id2ftp(DstFile,Config)),
+    ok = ftp:append_bin(Pid, Contents, id2ftp(DstFile,Config)),
+    chk_file(DstFile, <<Contents/binary,Contents/binary>>, Config).
+
+%%-------------------------------------------------------------------------
+append_chunk() -> 
+    [{doc, "Append chunks."}].
+append_chunk(Config0) ->
+    File = "f_dst.txt",
+    Contents = [<<"ER">>,<<"LE">>,<<"RL">>],
+    Config = set_state([reset], Config0),
+    Pid = proplists:get_value(ftp, Config),
+    ok = ftp:append_chunk_start(Pid, id2ftp(File,Config)),
+    {error, enotbinary} = ftp:append_chunk(Pid, binary_to_list(lists:nth(1,Contents))),
+    ok = ftp:append_chunk(Pid,lists:nth(1,Contents)),
+    ok = ftp:append_chunk(Pid,lists:nth(2,Contents)),
+    ok = ftp:append_chunk(Pid,lists:nth(3,Contents)),
+    ok = ftp:append_chunk_end(Pid),
+    chk_file(File, <<"ERLERL">>, Config).
+
+%%-------------------------------------------------------------------------
+recv() -> 
+    [{doc, "Receive a file using recv/2"}].
+recv(Config0) ->
+    File1 = "f_dst1.txt",
+    File2 = "f_dst2.txt",
+    SrcDir = "a_dir",
+    Contents1 = <<"1 ftp_SUITE test ...">>,
+    Contents2 = <<"2 ftp_SUITE test ...">>,
+    Config = set_state([reset, {mkfile,[SrcDir,File1],Contents1}, {mkfile,[SrcDir,File2],Contents2}], Config0),
+    Pid = proplists:get_value(ftp, Config),
+    ok = ftp:cd(Pid, id2ftp(SrcDir,Config)),
+    ok = ftp:lcd(Pid, id2ftp("",Config)),
+    ok = ftp:recv(Pid, File1),
+    chk_file(File1, Contents1, Config),
+    ok = ftp:recv(Pid, File2),
+    chk_file(File2, Contents2, Config),
+    {error,epath} = ftp:recv(Pid, "non_existing_file"),
+    ok.
+
+%%-------------------------------------------------------------------------
+recv_3() -> 
+    [{doc,"Receive a file using recv/3"}].
+recv_3(Config0) ->
+    DstFile = "f_src.txt",
+    SrcFile = "f_dst.txt",
+    Contents = <<"ftp_SUITE test ...">>,
+    Config = set_state([reset, {mkfile,SrcFile,Contents}], Config0),
+    Pid = proplists:get_value(ftp, Config),
+    ok = ftp:cd(Pid, id2ftp("",Config)),
+    ok = ftp:recv(Pid, SrcFile, id2abs(DstFile,Config)),
+    chk_file(DstFile, Contents, Config).
+
+%%-------------------------------------------------------------------------
+recv_bin() -> 
+    [{doc, "Receive a file as a binary."}].
+recv_bin(Config0) ->
+    File = "f_dst.txt",
+    Contents = <<"ftp_SUITE test ...">>,
+    Config = set_state([reset, {mkfile,File,Contents}], Config0),
+    Pid = proplists:get_value(ftp, Config),
+    {ok,Received} = ftp:recv_bin(Pid, id2ftp(File,Config)),
+    find_diff(Received, Contents),
+    {error,epath} = ftp:recv_bin(Pid, id2ftp("non_existing_file",Config)),
+    ok.
+
+%%-------------------------------------------------------------------------
+recv_bin_twice() -> 
+    [{doc, "Receive two files as a binaries."}].
+recv_bin_twice(Config0) ->
+    File1 = "f_dst1.txt",
+    File2 = "f_dst2.txt",
+    Contents1 = <<"1 ftp_SUITE test ...">>,
+    Contents2 = <<"2 ftp_SUITE test ...">>,
+    Config = set_state([reset, {mkfile,File1,Contents1}, {mkfile,File2,Contents2}], Config0),
+    ct:log("First transfer",[]),
+    Pid = proplists:get_value(ftp, Config),
+    {ok,Received1} = ftp:recv_bin(Pid, id2ftp(File1,Config)),
+    find_diff(Received1, Contents1),
+    ct:log("Second transfer",[]),
+    {ok,Received2} = ftp:recv_bin(Pid, id2ftp(File2,Config)),
+    find_diff(Received2, Contents2),
+    ct:log("Transfers ready!",[]),
+    {error,epath} = ftp:recv_bin(Pid, id2ftp("non_existing_file",Config)),
+    ok.
+%%-------------------------------------------------------------------------
+recv_chunk() -> 
+    [{doc, "Receive a file using chunk-wise."}].
+recv_chunk(Config0) ->
+    File = "big_file.txt",
+    Contents = list_to_binary( lists:duplicate(1000, lists:seq(0,255)) ),
+    Config = set_state([reset, {mkfile,File,Contents}], Config0),
+    Pid = proplists:get_value(ftp, Config),
+    {{error, "ftp:recv_chunk_start/2 not called"},_} = recv_chunk(Pid, <<>>),
+    ok = ftp:recv_chunk_start(Pid, id2ftp(File,Config)),
+    {ok, ReceivedContents, _Ncunks} = recv_chunk(Pid, <<>>),
+    find_diff(ReceivedContents, Contents).
+
+recv_chunk_twice() ->
+    [{doc, "Receive two files using chunk-wise."}].
+recv_chunk_twice(Config0) ->
+    File1 = "big_file1.txt",
+    File2 = "big_file2.txt",
+    Contents1 = list_to_binary( lists:duplicate(1000, lists:seq(0,255)) ),
+    Contents2 = crypto:strong_rand_bytes(1200),
+    Config = set_state([reset, {mkfile,File1,Contents1}, {mkfile,File2,Contents2}], Config0),
+    Pid = proplists:get_value(ftp, Config),
+    {{error, "ftp:recv_chunk_start/2 not called"},_} = recv_chunk(Pid, <<>>),
+    ok = ftp:recv_chunk_start(Pid, id2ftp(File1,Config)),
+    {ok, ReceivedContents1, _Ncunks1} = recv_chunk(Pid, <<>>),
+    ok = ftp:recv_chunk_start(Pid, id2ftp(File2,Config)),
+    {ok, ReceivedContents2, _Ncunks2} = recv_chunk(Pid, <<>>),
+    find_diff(ReceivedContents1, Contents1),
+    find_diff(ReceivedContents2, Contents2).
+
+recv_chunk_three_times() ->
+    [{doc, "Receive two files using chunk-wise."},
+     {timetrap,{seconds,120}}].
+recv_chunk_three_times(Config0) ->
+    File1 = "big_file1.txt",
+    File2 = "big_file2.txt",
+    File3 = "big_file3.txt",
+    Contents1 = list_to_binary( lists:duplicate(1000, lists:seq(0,255)) ),
+    Contents2 = crypto:strong_rand_bytes(1200),
+    Contents3 = list_to_binary( lists:duplicate(1000, lists:seq(255,0,-1)) ),
+
+    Config = set_state([reset, {mkfile,File1,Contents1}, {mkfile,File2,Contents2}, {mkfile,File3,Contents3}], Config0),
+    Pid = proplists:get_value(ftp, Config),
+    {{error, "ftp:recv_chunk_start/2 not called"},_} = recv_chunk(Pid, <<>>),
+
+    ok = ftp:recv_chunk_start(Pid, id2ftp(File1,Config)),
+    {ok, ReceivedContents1, Nchunks1} = recv_chunk(Pid, <<>>),
+
+    ok = ftp:recv_chunk_start(Pid, id2ftp(File2,Config)),
+    {ok, ReceivedContents2, _Nchunks2} = recv_chunk(Pid, <<>>),
+
+    ok = ftp:recv_chunk_start(Pid, id2ftp(File3,Config)),
+    {ok, ReceivedContents3, _Nchunks3} = recv_chunk(Pid, <<>>, 10000, 0, Nchunks1),
+
+    find_diff(ReceivedContents1, Contents1),
+    find_diff(ReceivedContents2, Contents2),
+    find_diff(ReceivedContents3, Contents3).
+
+
+
+recv_chunk(Pid, Acc) -> 
+    recv_chunk(Pid, Acc, 0, 0, undefined).
+
+
+
+%% ExpectNchunks :: integer() | undefined
+recv_chunk(Pid, Acc, DelayMilliSec, N, ExpectNchunks) when N+1 < ExpectNchunks ->
+    %% for all I in integer(), I < undefined
+    recv_chunk1(Pid, Acc, DelayMilliSec, N, ExpectNchunks);
+
+recv_chunk(Pid, Acc, DelayMilliSec, N, ExpectNchunks) ->
+    %% N >= ExpectNchunks-1
+    timer:sleep(DelayMilliSec),
+    recv_chunk1(Pid, Acc, DelayMilliSec, N, ExpectNchunks).
+
+
+recv_chunk1(Pid, Acc, DelayMilliSec, N, ExpectNchunks) ->
+    ct:log("Call ftp:recv_chunk",[]),
+    case ftp:recv_chunk(Pid) of
+	ok -> {ok, Acc, N};
+	{ok, Bin} -> recv_chunk(Pid, <<Acc/binary, Bin/binary>>, DelayMilliSec, N+1, ExpectNchunks);
+	Error -> {Error, N}
+    end.
+
+%%-------------------------------------------------------------------------
+type() -> 
+    [{doc,"Test that we can change btween ASCCI and binary transfer mode"}].
+type(Config) ->
+    Pid = proplists:get_value(ftp, Config),
+    ok = ftp:type(Pid, ascii),
+    ok = ftp:type(Pid, binary),
+    ok = ftp:type(Pid, ascii),
+    {error, etype} = ftp:type(Pid, foobar).
+
+%%-------------------------------------------------------------------------
+quote(Config) ->
+    Pid = proplists:get_value(ftp, Config),
+    ["257 \""++_Rest] = ftp:quote(Pid, "pwd"), %% 257
+    [_| _] = ftp:quote(Pid, "help"),
+    %% This negativ test causes some ftp servers to hang. This test
+    %% is not important for the client, so we skip it for now.
+    %%["425 Can't build data connection: Connection refused."] 
+    %% = ftp:quote(Pid, "list"), 
+    ok.
+
+%%-------------------------------------------------------------------------
+progress_report_send() ->
+    [{doc, "Test the option progress for ftp:send/[2,3]"}].
+progress_report_send(Config) when is_list(Config) ->
+    ReportPid = 
+	spawn_link(?MODULE, progress_report_receiver_init, [self(), 1]),
+    send(Config),
+    receive
+	{ReportPid, ok} ->
+	    ok
+    end.
+
+%%-------------------------------------------------------------------------
+progress_report_recv() ->
+    [{doc, "Test the option progress for ftp:recv/[2,3]"}].
+progress_report_recv(Config) when is_list(Config) ->
+    ReportPid = 
+ 	spawn_link(?MODULE, progress_report_receiver_init, [self(), 3]),
+    recv(Config),
+    receive
+ 	{ReportPid, ok} ->
+ 	    ok
+    end.
+
+%%-------------------------------------------------------------------------
+
+not_owner() ->
+    [{doc, "Test what happens if a process that not owns the connection tries "
+    "to use it"}].
+not_owner(Config) when is_list(Config) ->
+    Pid = proplists:get_value(ftp, Config),
+
+    Parent = self(),
+    OtherPid = spawn_link(
+		 fun() ->
+			 {error, not_connection_owner} = ftp:pwd(Pid),
+			 ftp:close(Pid),
+			 Parent ! {self(), ok}
+		 end),
+    receive
+	{OtherPid, ok} ->
+	    {ok, _} = ftp:pwd(Pid)
+    end.
+
+
+%%-------------------------------------------------------------------------
+
+
+unexpected_call()->
+    [{doc, "Test that behaviour of the ftp process if the api is abused"}].
+unexpected_call(Config) when is_list(Config) ->
+    Flag =  process_flag(trap_exit, true),
+    Pid = proplists:get_value(ftp, Config),
+    
+    %% Serious programming fault, connetion will be shut down 
+    case (catch gen_server:call(Pid, {self(), foobar, 10}, infinity)) of
+	{error, {connection_terminated, 'API_violation'}} ->
+	    ok;
+	Unexpected1 ->
+	    exit({unexpected_result, Unexpected1})
+    end,
+    ct:sleep(500),
+    undefined = process_info(Pid, status),
+    process_flag(trap_exit, Flag).
+%%-------------------------------------------------------------------------
+
+unexpected_cast()->
+    [{doc, "Test that behaviour of the ftp process if the api is abused"}].
+unexpected_cast(Config) when is_list(Config) ->
+    Flag = process_flag(trap_exit, true),
+    Pid = proplists:get_value(ftp, Config),
+    %% Serious programming fault, connetion will be shut down 
+    gen_server:cast(Pid, {self(), foobar, 10}),
+    ct:sleep(500),
+    undefined = process_info(Pid, status),
+    process_flag(trap_exit, Flag).
+%%-------------------------------------------------------------------------
+ 
+unexpected_bang()->
+    [{doc, "Test that connection ignores unexpected bang"}].
+unexpected_bang(Config) when is_list(Config) ->
+    Flag = process_flag(trap_exit, true),
+    Pid = proplists:get_value(ftp, Config),
+    %% Could be an innocent misstake the connection lives. 
+    Pid ! foobar, 
+    ct:sleep(500),
+    {status, _} = process_info(Pid, status),
+    process_flag(trap_exit, Flag).
+    
+%%-------------------------------------------------------------------------
+
+clean_shutdown() -> 
+    [{doc, "Test that owning process that exits with reason "
+     "'shutdown' does not cause an error message. OTP 6035"}].
+
+clean_shutdown(Config) ->
+    Parent = self(),
+    HelperPid = spawn(
+		  fun() ->
+			  ftp__open(Config, [verbose]),
+			  Parent ! ok,
+			  receive
+			      nothing -> ok
+			  end
+		  end),
+    receive
+	ok ->
+	    PrivDir = proplists:get_value(priv_dir, Config),
+	    LogFile = filename:join([PrivDir,"ticket_6035.log"]),
+ 	    error_logger:logfile({open, LogFile}),
+	    exit(HelperPid, shutdown),
+	    timer:sleep(2000),
+	    error_logger:logfile(close),
+	    case is_error_report_6035(LogFile) of
+		true ->  ok;
+		false -> {fail, "Bad logfile"}
+	    end
+    end.
+
+%%%----------------------------------------------------------------
+%%% Error codes not tested elsewhere
+
+error_elogin(Config0) ->
+    Dir = "test",
+    OldFile = "old.txt",
+    NewFile = "new.txt",
+    SrcDir = "data",
+    File = "file.txt",
+    Config = set_state([reset,
+			{mkdir,Dir},
+			{mkfile,OldFile,<<"Contents..">>},
+			{mkfile,[SrcDir,File],<<"Contents..">>}], Config0),
+
+    Pid = proplists:get_value(ftp, Config),
+    ok = ftp:lcd(Pid, id2ftp(SrcDir,Config)),
+    {error,elogin} = ftp:send(Pid, File),
+    ok = ftp:lcd(Pid, id2ftp("",Config)),
+    {error,elogin} = ftp:pwd(Pid),
+    {error,elogin} = ftp:cd(Pid, id2ftp(Dir,Config)),
+    {error,elogin} = ftp:rename(Pid, 
+				id2ftp(OldFile,Config),
+				id2ftp(NewFile,Config)),
+    ok.
+
+error_ehost(_Config) ->
+    {error, ehost} = ftp:open("nohost.nodomain"),
+    ok.
+    
+%%--------------------------------------------------------------------
+%% Internal functions  -----------------------------------------------
+%%--------------------------------------------------------------------
+
+make_cert_files(Alg1, Alg2, Prefix, Dir) ->
+    CaInfo = {CaCert,_} = erl_make_certs:make_cert([{key,Alg1}]),
+    {Cert,CertKey} = erl_make_certs:make_cert([{key,Alg2},{issuer,CaInfo}]),
+    CaCertFile = filename:join(Dir, Prefix++"cacerts.pem"),
+    CertFile = filename:join(Dir, Prefix++"cert.pem"),
+    KeyFile = filename:join(Dir, Prefix++"key.pem"),
+    der_to_pem(CaCertFile, [{'Certificate', CaCert, not_encrypted}]),
+    der_to_pem(CertFile, [{'Certificate', Cert, not_encrypted}]),
+    der_to_pem(KeyFile, [CertKey]),
+    ok.
+
+der_to_pem(File, Entries) ->
+    PemBin = public_key:pem_encode(Entries),
+    file:write_file(File, PemBin).
+
+%%--------------------------------------------------------------------
+chk_file(Path=[C|_], ExpectedContents, Config) when 0<C,C=<255 ->
+    chk_file([Path], ExpectedContents, Config);
+
+chk_file(PathList, ExpectedContents, Config) ->
+    Path = filename:join(PathList),
+    AbsPath = id2abs(Path,Config),
+    case file:read_file(AbsPath) of
+	{ok,ExpectedContents} -> 
+	    true;
+	{ok,ReadContents} -> 
+	    {error,{diff,Pos,RC,LC}} = find_diff(ReadContents, ExpectedContents, 1),
+	    ct:log("Bad contents of ~p.~nGot:~n~p~nExpected:~n~p~nDiff at pos ~p ~nRead: ~p~nExp : ~p",
+		   [AbsPath,ReadContents,ExpectedContents,Pos,RC,LC]),
+	    ct:fail("Bad contents of ~p", [Path]);
+	{error,Error} ->
+	    try begin
+		    {ok,CWD} = file:get_cwd(),
+		    ct:log("file:get_cwd()=~p~nfiles:~n~p",[CWD,file:list_dir(CWD)])
+		end
+	    of _ -> ok
+	    catch _:_ ->ok
+	    end,
+	    ct:fail("Error reading ~p: ~p",[Path,Error])
+    end.
+
+
+chk_no_file(Path=[C|_], Config) when 0<C,C=<255 ->
+    chk_no_file([Path], Config);
+
+chk_no_file(PathList, Config) ->
+    Path = filename:join(PathList),
+    AbsPath = id2abs(Path,Config),
+    case file:read_file(AbsPath) of
+	{error,enoent} -> 
+	    true;
+	{ok,Contents} -> 
+	    ct:log("File ~p exists although it shouldn't. Contents:~n~p",
+		   [AbsPath,Contents]),
+	    ct:fail("File exists: ~p", [Path]);
+	{error,Error} ->
+	    ct:fail("Unexpected error reading ~p: ~p",[Path,Error])
+    end.
+
+
+chk_dir(Path=[C|_], Config) when 0<C,C=<255 ->
+    chk_dir([Path], Config);
+
+chk_dir(PathList, Config) ->
+    Path = filename:join(PathList),
+    AbsPath = id2abs(Path,Config),
+    case file:read_file_info(AbsPath) of
+	{ok, #file_info{type=directory}} ->
+	    true;
+	{ok, #file_info{type=Type}} ->
+	    ct:fail("Expected dir ~p is a ~p",[Path,Type]);
+	{error,Error} ->
+	    ct:fail("Expected dir ~p: ~p",[Path,Error])
+    end.
+
+chk_no_dir(PathList, Config) ->
+    Path = filename:join(PathList),
+    AbsPath = id2abs(Path,Config),
+    case file:read_file_info(AbsPath) of
+	{error,enoent} ->
+	    true;
+	{ok, #file_info{type=directory}} ->
+	    ct:fail("Dir ~p erroneously exists",[Path]);
+	{ok, #file_info{type=Type}} ->
+	    ct:fail("~p ~p erroneously exists",[Type,Path]);
+	{error,Error} ->
+	    ct:fail("Unexpected error for ~p: ~p",[Path,Error])
+    end.
+
+%%--------------------------------------------------------------------
+find_executable(Config) ->
+    search_executable(proplists:get_value(ftpservers, Config, ?default_ftp_servers)).
+
+
+search_executable([{Name,Paths,_StartCmd,_ChkUp,_StopCommand,_ConfigUpd,_Host,_Port}|Srvrs]) ->
+    case os_find(Name,Paths) of
+	false ->
+	    ct:log("~p not found",[Name]),
+	    search_executable(Srvrs);
+	AbsName -> 
+	    ct:comment("Found ~p",[AbsName]),
+	    {ok, {AbsName,_StartCmd,_ChkUp,_StopCommand,_ConfigUpd,_Host,_Port}}
+    end;
+search_executable([]) ->
+    false.
+
+
+os_find(Name, Paths) ->
+    case os:find_executable(Name, Paths) of
+	false -> os:find_executable(Name);
+	AbsName -> AbsName
+    end.
+
+%%%----------------------------------------------------------------
+start_ftpd(Config0) ->
+    {AbsName,StartCmd,_ChkUp,_StopCommand,ConfigRewrite,Host,Port} =
+	proplists:get_value(ftpd_data, Config0),
+    case StartCmd(Config0, AbsName) of
+	{ok,StartResult} ->
+	    Config = [{ftpd_host,Host},
+		      {ftpd_port,Port},
+		      {ftpd_start_result,StartResult} | ConfigRewrite(Config0)],
+	    try
+		ftp__close(ftp__open(Config,[verbose]))
+	    of
+		Config1 when is_list(Config1) ->
+		    ct:log("Usuable ftp server ~p started on ~p:~p",[AbsName,Host,Port]),
+		    Config
+	    catch
+		Class:Exception ->
+		    ct:log("Ftp server ~p started on ~p:~p but is unusable:~n~p:~p",
+			   [AbsName,Host,Port,Class,Exception]),
+		    {skip, [AbsName," started but unusuable"]}
+	    end;
+	{error,Msg} ->
+	    {skip, [AbsName," not started: ",Msg]}
+    end.
+
+stop_ftpd(Config) ->
+    {_Name,_StartCmd,_ChkUp,StopCommand,_ConfigUpd,_Host,_Port} = proplists:get_value(ftpd_data, Config),
+    StopCommand(proplists:get_value(ftpd_start_result,Config)).
+
+ps_ftpd(Config) ->
+    {_Name,_StartCmd,ChkUp,_StopCommand,_ConfigUpd,_Host,_Port} = proplists:get_value(ftpd_data, Config),
+    ct:log( ChkUp(proplists:get_value(ftpd_start_result,Config)) ).
+
+
+ftpd_running(Config) ->
+    {_Name,_StartCmd,ChkUp,_StopCommand,_ConfigUpd,_Host,_Port} = proplists:get_value(ftpd_data, Config),
+    ChkUp(proplists:get_value(ftpd_start_result,Config)).
+
+ftp__open(Config, Options) ->
+    Host = proplists:get_value(ftpd_host,Config),
+    Port = proplists:get_value(ftpd_port,Config),
+    ct:log("Host=~p, Port=~p",[Host,Port]),
+    {ok,Pid} = ftp:open(Host, [{port,Port} | Options]),
+    [{ftp,Pid}|Config].
+
+ftp__close(Config) ->
+    ok = ftp:close(proplists:get_value(ftp,Config)),
+    Config.
+
+split(Cs) -> string:tokens(Cs, "\r\n").
+
+find_diff(Bin1, Bin2) -> 
+    case find_diff(Bin1, Bin2, 1) of
+	{error, {diff,Pos,RC,LC}} ->
+	    ct:log("Contents differ at position ~p.~nOp1: ~p~nOp2: ~p",[Pos,RC,LC]),
+	    ct:fail("Contents differ at pos ~p",[Pos]);
+	Other ->
+	    Other
+    end.
+
+find_diff(A, A, _) -> true;
+find_diff(<<H,T1/binary>>, <<H,T2/binary>>, Pos) -> find_diff(T1, T2, Pos+1);
+find_diff(RC, LC, Pos) -> {error, {diff, Pos, RC, LC}}.
+
+set_state(Ops, Config) when is_list(Ops) -> lists:foldl(fun set_state/2, Config, Ops);
+
+set_state(reset, Config) -> 
+    rm('*', id2abs("",Config)),
+    PrivDir = proplists:get_value(priv_dir,Config),
+    file:set_cwd(PrivDir),
+    ftp:lcd(proplists:get_value(ftp,Config),PrivDir),
+    set_state({mkdir,""},Config);
+set_state({mkdir,Id}, Config) ->
+    Abs = id2abs(Id, Config),
+    mk_path(Abs),
+    file:make_dir(Abs),
+    Config;
+set_state({mkfile,Id,Contents}, Config) ->
+    Abs = id2abs(Id, Config),
+    mk_path(Abs),
+    ok = file:write_file(Abs, Contents),
+    Config.
+
+mk_path(Abs) -> lists:foldl(fun mk_path/2, [], filename:split(filename:dirname(Abs))).
+
+mk_path(F, Pfx) ->
+    case file:read_file_info(AbsName=filename:join(Pfx,F)) of
+	{ok,#file_info{type=directory}} ->
+	    AbsName;
+	{error,eexist} ->
+	    AbsName;
+	{error,enoent} ->
+	    ok = file:make_dir(AbsName),
+	    AbsName
+    end.
+    
+rm('*', Pfx) ->
+    {ok,Fs} = file:list_dir(Pfx),
+    lists:foreach(fun(F) -> rm(F, Pfx) end, Fs);
+rm(F, Pfx) -> 
+    case file:read_file_info(AbsName=filename:join(Pfx,F)) of
+	{ok,#file_info{type=directory}} ->
+	    {ok,Fs} = file:list_dir(AbsName),
+	    lists:foreach(fun(F1) -> rm(F1,AbsName) end, Fs),
+	    ok = file:del_dir(AbsName);
+
+	{ok,#file_info{type=regular}} ->
+	    ok = file:delete(AbsName);
+
+	{error,enoent} ->
+	    ok
+    end.
+
+id2abs(Id, Conf) -> filename:join(proplists:get_value(priv_dir,Conf),ids(Id)).
+id2ftp(Id, Conf) -> (proplists:get_value(id2ftp,Conf))(ids(Id)).
+id2ftp_result(Id, Conf) -> (proplists:get_value(id2ftp_result,Conf))(ids(Id)).
+
+ids([[_|_]|_]=Ids) -> filename:join(Ids);
+ids(Id) -> Id.
+
+
+is_expected_absName(Id, File, Conf) -> File = (proplists:get_value(id2abs,Conf))(Id).
+is_expected_ftpInName(Id, File, Conf) -> File = (proplists:get_value(id2ftp,Conf))(Id).
+is_expected_ftpOutName(Id, File, Conf) -> File = (proplists:get_value(id2ftp_result,Conf))(Id).
+
+
+%%%----------------------------------------------------------------
+%%% Help functions for the option '{progress,Progress}'
+%%%
+
+%%%----------------
+%%% Callback:
+
+progress(#progress{} = P, _File, {file_size, Total} = M) ->
+    ct:pal("Progress: ~p",[M]),
+    progress_report_receiver ! start,
+    P#progress{total = Total};
+
+progress(#progress{current = Current} = P, _File, {transfer_size, 0} = M) ->
+    ct:pal("Progress: ~p",[M]),
+    progress_report_receiver ! finish,
+    case P#progress.total of
+	unknown -> P;
+	Current -> P;
+	Total   -> ct:fail({error, {progress, {total,Total}, {current,Current}}}),
+		   P
+    end;
+
+progress(#progress{current = Current} = P, _File, {transfer_size, Size} = M) ->
+    ct:pal("Progress: ~p",[M]),
+    progress_report_receiver ! update,
+    P#progress{current = Current + Size};
+
+progress(P, _File, M) ->
+    ct:pal("Progress **** Strange: ~p",[M]),
+    P.
+
+
+%%%----------------
+%%% Help process that counts the files transferred:
+
+progress_report_receiver_init(Parent, N) ->
+    register(progress_report_receiver, self()),
+    progress_report_receiver_expect_N_files(Parent, N).
+
+progress_report_receiver_expect_N_files(_Parent, 0) ->
+    ct:pal("progress_report got all files!", []);
+progress_report_receiver_expect_N_files(Parent, N) ->
+    ct:pal("progress_report expects ~p more files",[N]),
+    receive
+	start -> ok
+    end,
+    progress_report_receiver_loop(Parent, N-1).
+
+
+progress_report_receiver_loop(Parent, N) ->
+    ct:pal("progress_report expect update | finish. N = ~p",[N]),
+    receive
+	update ->  
+	    ct:pal("progress_report got update",[]),
+	    progress_report_receiver_loop(Parent, N);
+	finish  -> 
+	    ct:pal("progress_report got finish, send ~p to ~p",[{self(),ok}, Parent]),
+	    Parent ! {self(), ok},
+	    progress_report_receiver_expect_N_files(Parent, N)
+    end.
+
+%%%----------------------------------------------------------------
+%%% Help functions for bug OTP-6035
+
+is_error_report_6035(LogFile) ->
+    case file:read_file(LogFile) of
+	{ok, Bin} -> 
+	    nomatch =/= binary:match(Bin, <<"=ERROR REPORT====">>);
+	_ -> 
+	    false
+    end.
+
diff --git a/lib/ftp/test/ftp_SUITE_data/ftpd_hosts.skel b/lib/ftp/test/ftp_SUITE_data/ftpd_hosts.skel
new file mode 100644
index 0000000000..75096ce687
--- /dev/null
+++ b/lib/ftp/test/ftp_SUITE_data/ftpd_hosts.skel
@@ -0,0 +1,18 @@
+%% Add a host name in the appropriate list
+%% Each "platform" contains a list of hostnames (a string) that can 
+%% be used for testing the ftp client.
+%% The definition below are an example!!
+[{solaris8_sparc,      ["solaris8_sparc_dummy1", "solaris8_sparc_dummy2"]}, 
+ {solaris9_sparc,      ["solaris9_sparc_dummy1"]}, 
+ {solaris10_sparc,     ["solaris10_sparc_dummy1"]}, 
+ {solaris10_x86,       ["solaris10_x86_dummy1", "solaris10_x86_dummy2"]}, 
+ {linux_x86,           ["linux_x86_dummy1", "linux_x86_dummy2"]}, 
+ {linux_ppc,           ["linux_ppc_dummy1"]}, 
+ {macosx_ppc,          ["macosx_ppc_dummy1"]},
+ {macosx_x86,          ["macosx_x86_dummy1", "macosx_x86_dummy2"]},
+ {openbsd_x86,         []},
+ {freebsd_x86,         ["freebsd_x86_dummy1"]},
+ {netbsd_x86,          []},
+ {windows_xp,          []},
+ {windows_2003_server, ["win2003_dummy1"]},
+ {ticket_test,         ["solaris8_x86_dummy1", "linux_x86_dummy1"]}].
diff --git a/lib/ftp/test/ftp_SUITE_data/vsftpd.conf b/lib/ftp/test/ftp_SUITE_data/vsftpd.conf
new file mode 100644
index 0000000000..a5584f5916
--- /dev/null
+++ b/lib/ftp/test/ftp_SUITE_data/vsftpd.conf
@@ -0,0 +1,26 @@
+
+###
+### Some parameters are given in the vsftpd start command.
+### 
+### Typical command-line paramters are such that has a file path
+### component like cert files.
+###
+
+
+listen=YES
+listen_port=9999
+run_as_launching_user=YES
+ssl_enable=YES
+allow_anon_ssl=YES
+
+background=YES
+
+write_enable=YES
+anonymous_enable=YES
+anon_upload_enable=YES
+anon_mkdir_write_enable=YES
+anon_other_write_enable=YES
+anon_world_readable_only=NO
+
+### Shouldn't be necessary....
+require_ssl_reuse=NO
diff --git a/lib/ftp/test/ftp_bench.spec b/lib/ftp/test/ftp_bench.spec
new file mode 100644
index 0000000000..4d1ecf8891
--- /dev/null
+++ b/lib/ftp/test/ftp_bench.spec
@@ -0,0 +1 @@
+{suites,"../ftp_test",[]}.
diff --git a/lib/ftp/test/ftp_format_SUITE.erl b/lib/ftp/test/ftp_format_SUITE.erl
new file mode 100644
index 0000000000..95d594a44b
--- /dev/null
+++ b/lib/ftp/test/ftp_format_SUITE.erl
@@ -0,0 +1,328 @@
+%%
+%% %CopyrightBegin%
+%% 
+%% Copyright Ericsson AB 2005-2016. All Rights Reserved.
+%% 
+%% Licensed under the Apache License, Version 2.0 (the "License");
+%% you may not use this file except in compliance with the License.
+%% You may obtain a copy of the License at
+%%
+%%     http://www.apache.org/licenses/LICENSE-2.0
+%%
+%% Unless required by applicable law or agreed to in writing, software
+%% distributed under the License is distributed on an "AS IS" BASIS,
+%% WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+%% See the License for the specific language governing permissions and
+%% limitations under the License.
+%% 
+%% %CopyrightEnd%
+%%
+%%
+-module(ftp_format_SUITE).
+-author('[email protected]').
+
+-include_lib("common_test/include/ct.hrl").
+-include("ftp_internal.hrl").
+
+%% Note: This directive should only be used in test suites.
+-compile(export_all).
+
+suite() -> 
+    [{ct_hooks,[ts_install_cth]},
+     {timetrap,{seconds,5}}
+    ].
+
+all() -> 
+    [{group, ftp_response}, format_error].
+
+groups() -> 
+    [{ftp_response, [],
+      [ftp_150, ftp_200, ftp_220, ftp_226, ftp_257, ftp_331,
+       ftp_425, ftp_other_status_codes, ftp_multiple_lines_status_in_msg,
+       ftp_multiple_lines, ftp_multipel_ctrl_messages]}].
+
+init_per_suite(Config) ->
+    Config.
+
+end_per_suite(_Config) ->
+    ok.
+
+init_per_group(_GroupName, Config) ->
+    Config.
+
+end_per_group(_GroupName, Config) ->
+    Config.
+
+
+init_per_testcase(_, Config) ->
+    Config.
+end_per_testcase(_, _) ->
+    ok.
+
+%%-------------------------------------------------------------------------
+%% Test cases starts here.
+%%-------------------------------------------------------------------------
+
+ftp_150() ->
+    [{doc, "Especially check that respons can be devided in a random place."}].
+ftp_150(Config) when is_list(Config) ->
+    FtpResponse = ["150 ASCII data conn", "ection for /bin/ls ",
+		   "(134.138.177", ".89,50434) (0 bytes).\r\n"],
+    
+    "150 ASCII data connection for /bin/ls "
+	"(134.138.177.89,50434) (0 bytes).\r\n" = Msg =
+	parse(ftp_response, parse_lines, [[], start], FtpResponse),
+    {pos_prel, _} = ftp_response:interpret(Msg).
+   
+ftp_200() ->
+    [{doc, "Especially check that respons can be devided after the first status "
+    "code character and in the end delimiter."}].
+ftp_200(Config) when is_list(Config) ->
+    FtpResponse = ["2", "00 PORT command successful.", [?CR], [?LF]], 
+    
+    "200 PORT command successful.\r\n" =  Msg =
+	parse(ftp_response, parse_lines, [[], start], FtpResponse),
+    {pos_compl, _} = ftp_response:interpret(Msg),
+    ok.
+
+ftp_220() ->
+    [{doc, "Especially check that respons can be devided after the "
+     "first with space "}].
+ftp_220(Config) when is_list(Config) ->
+    FtpResponse = ["220 ","fingon FTP server (SunOS 5.8) ready.\r\n"], 
+    
+    "220 fingon FTP server (SunOS 5.8) ready.\r\n" = Msg =
+	parse(ftp_response, parse_lines, [[], start], FtpResponse),
+    {pos_compl, _} = ftp_response:interpret(Msg),
+    ok.
+
+ftp_226() ->
+    [{doc, "Especially check that respons can be devided after second status code"
+    " character and in the end delimiter."}].
+ftp_226(Config) when is_list(Config) ->
+    FtpResponse = ["22" "6 Transfer complete.\r", [?LF]],
+    
+    "226 Transfer complete.\r\n"  = Msg =
+	parse(ftp_response, parse_lines, [[], start], FtpResponse),
+    {pos_compl, _} = ftp_response:interpret(Msg),
+    ok.
+
+ftp_257() ->
+    [{doc, "Especially check that quoted chars do not cause a problem."}].
+ftp_257(Config) when is_list(Config) ->
+    FtpResponse = ["257 \"/\" is current directory.\r\n"], 
+    
+    "257 \"/\" is current directory.\r\n" = Msg =
+	parse(ftp_response, parse_lines, [[], start], FtpResponse),
+    {pos_compl, _} = ftp_response:interpret(Msg),
+    ok.
+
+ftp_331() ->
+    [{doc, "Especially check that respons can be devided after the third status "
+    " status code character."}].
+ftp_331(Config) when is_list(Config) ->
+    %% Brake before white space after code
+    FtpResponse = 
+	["331"," Guest login ok, send ient as password.\r\n"],
+    
+    "331 Guest login ok, send ient as password.\r\n" = Msg =
+	parse(ftp_response, parse_lines, [[], start], FtpResponse),
+    {pos_interm, _} = ftp_response:interpret(Msg),
+    ok.
+
+ftp_425() ->
+    [{doc, "Especially check a message that was received in only one part."}].
+ftp_425(Config) when is_list(Config) ->
+    FtpResponse = 
+	["425 Can't build data connection: Connection refused.\r\n"],
+
+    "425 Can't build data connection: Connection refused.\r\n" 
+	= Msg = parse(ftp_response, parse_lines, [[], start], FtpResponse),
+    {trans_neg_compl, _} = ftp_response:interpret(Msg),
+    ok.
+
+ftp_multiple_lines_status_in_msg() ->
+    [{doc, "check that multiple lines gets parsed correct, even if we have "
+      " the status code within the msg being sent"}].
+ftp_multiple_lines_status_in_msg(Config) when is_list(Config) ->
+    ML = "230-User usr-230 is logged in\r\n" ++
+        "230 OK. Current directory is /\r\n",
+    {ok, ML, <<>>} = ftp_response:parse_lines(list_to_binary(ML), [], start),
+    ok.
+
+ftp_multiple_lines() ->
+    [{doc, "Especially check multiple lines devided in significant places"}].
+ftp_multiple_lines(Config) when is_list(Config) ->
+    FtpResponse =   ["21", "4","-The",
+		     " following commands are recognized:\r\n"
+		     "   USER    EPRT    STRU    MAIL*   ALLO    CWD",
+		     "     STAT*   XRMD \r\n"
+		     "   PASS    LPRT    MODE    MSND* "
+		     "  REST*   XCWD    HELP    PWD  ", [?CRLF],
+		     "   ACCT*   EPSV    RETR    MSOM*   RNFR    LIST  "
+		     "  NOOP    XPWD \r\n",
+		     "   REIN*   LPSV    STOR    MSAM*   RNTO    NLST "
+		     "   MKD     CDUP \r\n"
+		     "   QUIT    PASV    APPE    MRSQ*   ABOR    SITE* "
+		     "  XMKD    XCUP \r\n"
+		     "   PORT    TYPE    MLFL*   MRCP*   DELE    SYST "
+		     "   RMD     STOU \r\n"
+		     "214 (*'s => unimplemented)", [?CR], [?LF]],
+
+
+    FtpResponse1 =   ["214-", "The",
+		      " following commands are recognized:\r\n"
+		      "   USER    EPRT    STRU    MAIL*   ALLO    CWD",
+		      "     STAT*   XRMD \r\n"
+		      "   PASS    LPRT    MODE    MSND* "
+		      "  REST*   XCWD    HELP    PWD  ", [?CRLF],
+		      "   ACCT*   EPSV    RETR    MSOM*   RNFR    LIST  "
+		      "  NOOP    XPWD \r\n",
+		      "   REIN*   LPSV    STOR    MSAM*   RNTO    NLST "
+		      "   MKD     CDUP \r\n"
+		      "   QUIT    PASV    APPE    MRSQ*   ABOR    SITE* "
+		      "  XMKD    XCUP \r\n"
+			 "   PORT    TYPE    MLFL*   MRCP*   DELE    SYST "
+		      "   RMD     STOU \r\n"
+		      "2", "14 (*'s => unimplemented)", [?CR], [?LF]],
+    
+    FtpResponse2 =   ["214-", "The",
+		      " following commands are recognized:\r\n"
+		      "   USER    EPRT    STRU    MAIL*   ALLO    CWD",
+		      "     STAT*   XRMD \r\n"
+		      "   PASS    LPRT    MODE    MSND* "
+		      "  REST*   XCWD    HELP    PWD  ", [?CRLF],
+		      "   ACCT*   EPSV    RETR    MSOM*   RNFR    LIST  "
+		      "  NOOP    XPWD \r\n",
+		      "   REIN*   LPSV    STOR    MSAM*   RNTO    NLST "
+		      "   MKD     CDUP \r\n"
+		      "   QUIT    PASV    APPE    MRSQ*   ABOR    SITE* "
+		      "  XMKD    XCUP \r\n"
+		      "   PORT    TYPE    MLFL*   MRCP*   DELE    SYST "
+		      "   RMD     STOU \r\n"
+		      "21", "4"," (*'s => unimplemented)", [?CR], [?LF]],
+    
+    MultiLineResultStr = 
+	"214-The following commands are recognized:\r\n"
+	"   USER    EPRT    STRU    MAIL*   ALLO    CWD     STAT*   "
+	"XRMD \r\n"
+	"   PASS    LPRT    MODE    MSND*   REST*   XCWD    HELP    "
+	"PWD  \r\n"
+	"   ACCT*   EPSV    RETR    MSOM*   RNFR    LIST    NOOP    "
+	"XPWD \r\n"
+	"   REIN*   LPSV    STOR    MSAM*   RNTO    NLST    MKD     "
+	"CDUP \r\n"
+	"   QUIT    PASV    APPE    MRSQ*   ABOR    SITE*   XMKD    "
+	"XCUP \r\n"
+	"   PORT    TYPE    MLFL*   MRCP*   DELE    SYST    RMD     "
+	"STOU \r\n"
+	"214 (*'s => unimplemented)\r\n", 
+    
+    MultiLineResultStr =
+	parse(ftp_response, parse_lines, [[], start], FtpResponse), 
+    {pos_compl, _} = ftp_response:interpret(MultiLineResultStr),
+    
+    MultiLineResultStr = parse(ftp_response, parse_lines, [[], start], 
+			       FtpResponse1),
+    
+    MultiLineResultStr = parse(ftp_response, parse_lines, [[], start], 
+			       FtpResponse2),
+    ok.
+
+ftp_other_status_codes() ->
+    [{doc, "Check that other valid status codes, than the ones above, are handled"
+     "by ftp_response:interpret/1. Note there are som ftp status codes" 
+     "that will not be received with the current ftp instruction support," 
+     "they are not included here."}].
+ftp_other_status_codes(Config) when is_list(Config) ->
+
+    %% 1XX
+    {pos_prel, _ }  = ftp_response:interpret("120 Foobar\r\n"),
+      
+    %% 2XX
+    {pos_compl, _ }  = ftp_response:interpret("202 Foobar\r\n"),
+    {pos_compl, _ }  = ftp_response:interpret("221 Foobar\r\n"),
+    {pos_compl, _ }  = ftp_response:interpret("227 Foobar\r\n"),
+    {pos_compl, _ }  = ftp_response:interpret("230 Foobar\r\n"),
+    {pos_compl, _ }  = ftp_response:interpret("250 Foobar\r\n"),
+    
+    %% 3XX
+    {pos_interm_acct, _ }  = ftp_response:interpret("332 Foobar\r\n"),
+    {pos_interm, _ }  = ftp_response:interpret("350 Foobar\r\n"),
+
+    %% 4XX
+    {trans_neg_compl, _ }  = ftp_response:interpret("421 Foobar\r\n"),
+    {trans_neg_compl, _ }  = ftp_response:interpret("426 Foobar\r\n"),
+    {enofile, _ }  = ftp_response:interpret("450 Foobar\r\n"),
+    {trans_neg_compl, _ }  = ftp_response:interpret("451 Foobar\r\n"),
+    {etnospc, _ }  = ftp_response:interpret("452 Foobar\r\n"),
+
+    %% 5XX
+    {perm_neg_compl, _ }  = ftp_response:interpret("500 Foobar\r\n"),
+    {perm_neg_compl, _ }  = ftp_response:interpret("501 Foobar\r\n"),
+    {perm_neg_compl, _ }  = ftp_response:interpret("503 Foobar\r\n"),
+    {perm_neg_compl, _ }  = ftp_response:interpret("504 Foobar\r\n"),
+    {elogin, _ } = ftp_response:interpret("530 Foobar\r\n"),
+    {perm_neg_compl, _ }  = ftp_response:interpret("532 Foobar\r\n"),
+    {epath, _ }  = ftp_response:interpret("550 Foobar\r\n"),
+    {epnospc, _ }  = ftp_response:interpret("552 Foobar\r\n"),
+    {efnamena, _ }  = ftp_response:interpret("553 Foobar\r\n"),
+    ok.
+       
+ftp_multipel_ctrl_messages() ->
+    [{doc, "The ftp server may send more than one control message as a reply," 
+     "check that they are handled one at the time."}].
+ftp_multipel_ctrl_messages(Config) when is_list(Config) ->
+    FtpResponse = ["200 PORT command successful.\r\n200 Foobar\r\n"], 
+    
+    {"200 PORT command successful.\r\n" = Msg, NextMsg} =
+	parse(ftp_response, parse_lines, [[], start], FtpResponse),
+    {pos_compl, _} = ftp_response:interpret(Msg),
+    NewMsg = parse(ftp_response, parse_lines, [[], start], NextMsg),
+    {pos_compl, _} = ftp_response:interpret(NewMsg),
+    ok. 
+
+
+%%-------------------------------------------------------------------------
+format_error(Config) when is_list(Config) ->
+    "Synchronisation error during chunk sending." =
+	ftp:formaterror(echunk),
+    "Session has been closed." = ftp:formaterror(eclosed),
+    "Connection to remote server prematurely closed." =
+	ftp:formaterror(econn),
+    "File or directory already exists." =  ftp:formaterror(eexists),
+    "Host not found, FTP server not found, or connection rejected." =
+	ftp:formaterror(ehost),
+    "User not logged in." = ftp:formaterror(elogin),
+    "Term is not a binary." = ftp:formaterror(enotbinary),
+    "No such file or directory, already exists, or permission denied."
+	= ftp:formaterror(epath),
+    "No such type." = ftp:formaterror(etype),
+    "User name or password not valid." =  ftp:formaterror(euser),
+    "Insufficient storage space in system." = ftp:formaterror(etnospc),
+    "Exceeded storage allocation (for current directory or dataset)." 
+	= ftp:formaterror(epnospc),
+    "File name not allowed." = ftp:formaterror(efnamena),
+    "Unknown error: foobar" = ftp:formaterror({error, foobar}).
+    
+%%--------------------------------------------------------------------
+%%% Internal functions
+%%--------------------------------------------------------------------
+parse(Module, Function, Args, Bin) when is_binary(Bin) ->
+    parse(Module, Function, Args, [binary_to_list(Bin)]);
+
+parse(Module, Function, [AccLines, StatusCode], [Data | Rest]) ->
+    case  Module:Function(list_to_binary(Data), AccLines, StatusCode) of
+	{ok, Result, <<>>} ->
+	    Result;
+	{ok, Result, Next} ->
+	    {Result, Next};
+	{continue, {NewData, NewAccLines, NewStatusCode}} ->
+	    case Rest of
+		[] ->
+		    ct:fail({wrong_input, Data, Rest});
+		[_ | _] ->
+		    parse(Module, Function, [NewAccLines, NewStatusCode], 
+			  [binary_to_list(NewData) ++ hd(Rest) | tl(Rest)])
+	    end
+    end.
diff --git a/lib/ftp/test/ftp_internal.hrl b/lib/ftp/test/ftp_internal.hrl
new file mode 120000
index 0000000000..2ae5c46460
--- /dev/null
+++ b/lib/ftp/test/ftp_internal.hrl
@@ -0,0 +1 @@
+../src/ftp_internal.hrl
\ No newline at end of file
diff --git a/lib/ftp/test/ftp_property_test_SUITE.erl b/lib/ftp/test/ftp_property_test_SUITE.erl
new file mode 100644
index 0000000000..b314882296
--- /dev/null
+++ b/lib/ftp/test/ftp_property_test_SUITE.erl
@@ -0,0 +1,53 @@
+%%
+%% %CopyrightBegin%
+%% 
+%% Copyright Ericsson AB 2004-2016. All Rights Reserved.
+%% 
+%% Licensed under the Apache License, Version 2.0 (the "License");
+%% you may not use this file except in compliance with the License.
+%% You may obtain a copy of the License at
+%%
+%%     http://www.apache.org/licenses/LICENSE-2.0
+%%
+%% Unless required by applicable law or agreed to in writing, software
+%% distributed under the License is distributed on an "AS IS" BASIS,
+%% WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+%% See the License for the specific language governing permissions and
+%% limitations under the License.
+%% 
+%% %CopyrightEnd%
+%%
+%%
+
+%%% Run like this:
+%%%   ct:run_test([{suite,"ftp_property_test_SUITE"}, {logdir,"/ldisk/OTP/LOG"}]).
+
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+%%%                                                             %%%
+%%%                       WARNING                               %%%
+%%%                                                             %%%
+%%% This is experimental code which may be changed or removed   %%%
+%%%               anytime without any warning.                  %%%
+%%%                                                             %%%
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+
+-module(ftp_property_test_SUITE).
+
+-compile(export_all).
+
+-include_lib("common_test/include/ct.hrl").
+
+all() -> [prop_ftp_case].
+
+
+init_per_suite(Config) ->
+    inets:start(),
+    ct_property_test:init_per_suite(Config).
+    
+
+%%%---- test case
+prop_ftp_case(Config) ->
+    ct_property_test:quickcheck(
+      ftp_simple_client_server:prop_ftp(Config),
+      Config
+     ).
diff --git a/lib/ftp/test/inets_test_lib.erl b/lib/ftp/test/inets_test_lib.erl
new file mode 100644
index 0000000000..2529cc5f9b
--- /dev/null
+++ b/lib/ftp/test/inets_test_lib.erl
@@ -0,0 +1,596 @@
+%%
+%% %CopyrightBegin%
+%%
+%% Copyright Ericsson AB 2001-2015. All Rights Reserved.
+%%
+%% Licensed under the Apache License, Version 2.0 (the "License");
+%% you may not use this file except in compliance with the License.
+%% You may obtain a copy of the License at
+%%
+%%     http://www.apache.org/licenses/LICENSE-2.0
+%%
+%% Unless required by applicable law or agreed to in writing, software
+%% distributed under the License is distributed on an "AS IS" BASIS,
+%% WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+%% See the License for the specific language governing permissions and
+%% limitations under the License.
+%%
+%% %CopyrightEnd%
+%%
+%%
+-module(inets_test_lib).
+
+-include("inets_test_lib.hrl").
+-include_lib("inets/src/http_lib/http_internal.hrl").
+
+%% Note: This directive should only be used in test suites.
+-compile(export_all).
+
+%% -- Misc os command and stuff
+
+has_ipv6_support() ->
+    tsp("has_ipv6_support -> no ipv6_hosts config"),
+    {ok, Hostname} = inet:gethostname(),
+    case inet:getaddrs(Hostname, inet6) of
+	{ok, [Addr|_]} when is_tuple(Addr) andalso 
+			    (element(1, Addr) =/= 0) ->
+	    %% We actually need to test that the addr can be used, 
+	    %% this is done by attempting to create a (tcp) 
+	    %% listen socket
+	    tsp("has_ipv6_support -> check Addr: ~p", [Addr]),
+	    case (catch gen_tcp:listen(0, [inet6, {ip, Addr}])) of
+		{ok, LSock} ->
+		    tsp("has_ipv6_support -> we are ipv6 host"),
+		    gen_tcp:close(LSock),
+		    {ok, Addr};
+		_ ->
+		    undefined
+	    end;
+	_ ->
+	    undefined
+    end.
+    
+has_ipv6_support(Config) ->
+    case lists:keysearch(ipv6_hosts, 1, Config) of
+	false ->
+	    %% Do a basic check to se if 
+	    %% our own host has a working IPv6 address...
+	    has_ipv6_support();
+
+	{value, {_, Hosts}} when is_list(Hosts) ->
+	    %% Check if our host is in the list of *known* IPv6 hosts
+	    tsp("has_ipv6_support -> Hosts: ~p", [Hosts]),
+	    {ok, Hostname} = inet:gethostname(),
+	    case lists:member(list_to_atom(Hostname), Hosts) of
+		true ->
+		    tsp("has_ipv6_support -> we are known ipv6 host"),
+		    {ok, [Addr|_]} = inet:getaddrs(Hostname, inet6),
+		    {ok, Addr};
+		false ->
+		    undefined
+	    end;
+	
+	_ ->
+	    undefined
+
+    end.
+
+oscmd(Cmd) ->
+  string:strip(os:cmd(Cmd), right, $\n).
+
+
+print_system_info([]) ->
+    do_print_system_info("System Info");
+print_system_info(Prefix) when is_list(Prefix) ->
+    NewPrefix = lists:flatten(io_lib:format("~s: System Info", [Prefix])), 
+    do_print_system_info(NewPrefix).
+
+do_print_system_info(Prefix) ->
+    tsp("~s => "
+	"~n"
+	"~n   OS Type:            ~p"
+	"~n   OS version:         ~p"
+	"~n   Sys Arch:           ~p"
+	"~n   CPU Topology:       ~p"
+	"~n   Num logical procs:  ~p"
+	"~n   SMP support:        ~p"
+	"~n   Num schedulers:     ~p"
+	"~n   Scheduler bindings: ~p"
+	"~n   Wordsize:           ~p"
+	"~n~n", [Prefix, 
+		 os:type(), os:version(), 
+		 erlang:system_info(system_architecture),
+		 erlang:system_info(cpu_topology),
+		 erlang:system_info(logical_processors),
+		 erlang:system_info(smp_support),
+		 erlang:system_info(schedulers),
+		 erlang:system_info(scheduler_bindings),
+		 erlang:system_info(wordsize)]),
+    ok.
+    
+    
+run_on_windows(Fun) ->
+    run_on_os(windows, Fun).
+
+run_on_os(windows, Fun) ->
+    case os:type() of
+	{win32, _} ->
+	    Fun();
+	_ ->
+	    ok
+    end.
+	    
+    
+%% -- Misc node operation wrapper functions --
+
+start_node(Name) ->
+    Pa   = filename:dirname(code:which(?MODULE)),
+    Args = case init:get_argument('CC_TEST') of
+               {ok, [[]]} ->
+                   " -pa /clearcase/otp/libraries/snmp/ebin ";
+               {ok, [[Path]]} ->
+                   " -pa " ++ Path;
+               error ->
+                      ""
+              end,
+    A = Args ++ " -pa " ++ Pa,
+    Opts = [{cleanup,false}, {args, A}],
+    case (catch test_server:start_node(Name, slave, Opts)) of
+        {ok, Node} ->
+            Node;
+        Else ->
+            exit({failed_starting_node, Name, Else})
+    end.
+
+stop_node(Node) ->
+    rpc:cast(Node, erlang, halt, []),
+    await_stopped(Node, 5).
+
+await_stopped(_, 0) ->
+    ok;
+await_stopped(Node, N) ->
+    Nodes = erlang:nodes(),
+    case lists:member(Node, Nodes) of
+        true ->
+            sleep(1000),
+            await_stopped(Node, N-1);
+        false ->
+            ok
+    end.
+
+
+%% ----------------------------------------------------------------
+%% Ensure apps are started
+%% This to ensure we dont attempt to run teatcases on platforms 
+%% where there is no working ssl app.
+
+ensure_started([]) ->
+    ok;
+ensure_started([App|Apps]) ->
+    ensure_started(App),
+    ensure_started(Apps);
+ensure_started(crypto = App) ->
+    %% We have to treat crypto in this special way because 
+    %% only this function ensures that the NIF lib is actually
+    %% loaded. And only by loading that lib can we know if it 
+    %% is even possible to run crypto.
+    do_ensure_started(App, fun() -> crypto:start() end);
+ensure_started(App) when is_atom(App) ->
+    do_ensure_started(App, fun() -> application:start(App) end).
+
+do_ensure_started(App, Start) when is_function(Start) ->
+    case (catch Start()) of
+	ok ->
+	    ok;
+	{error, {already_started, _}} ->
+	    ok;
+	Error ->
+	    throw({error, {failed_starting, App, Error}})
+    end.
+
+
+ensure_loaded(App) ->
+    case application:load(App) of
+	ok ->
+	    ok;
+	{error, {already_loaded,inets}} ->
+	    ok;
+	Error ->
+	    Error
+    end.
+
+
+
+%% ----------------------------------------------------------------
+%% HTTPD starter functions
+%%
+
+start_http_server(Conf) ->
+    start_http_server(Conf, ?HTTP_DEFAULT_SSL_KIND).
+
+start_http_server(Conf, essl = _SslTag) ->
+    tsp("start_http_server(essl) -> try start crypto"),
+    application:start(crypto), 
+    tsp("start_http_server(essl) -> try start public_key"),
+    application:start(public_key), 
+    do_start_http_server(Conf);
+start_http_server(Conf, SslTag) ->
+    tsp("start_http_server(~w) -> entry", [SslTag]),
+    do_start_http_server(Conf).
+
+do_start_http_server(Conf) ->
+    tsp("do_start_http_server -> entry with"
+	"~n   Conf: ~p"
+	"~n", [Conf]),
+    tsp("do_start_http_server -> load inets"),
+    case ensure_loaded(inets) of
+	ok ->
+	    tsp("do_start_http_server -> inets loaded - now set_env for httpd"),
+	    case application:set_env(inets, services, [{httpd, Conf}]) of
+		ok ->
+		    tsp("do_start_http_server -> "
+			"httpd conf stored in inets app env"),
+		    case (catch application:start(inets)) of
+			ok ->
+			    tsp("do_start_http_server -> inets started"),
+			    ok;
+			Error1 ->
+			    tsp("<ERROR> Failed starting application: "
+				"~n   Error1: ~p", [Error1]),
+			    tsf({failed_starting_inets, Error1})
+		    end;
+		Error2 ->
+		    tsp("<ERROR> Failed set application env: "
+			"~n   Error: ~p", [Error2]),
+		    tsf({failed_set_env, Error2})
+	    end;
+	{error, Reason} ->
+	    tsp("do_start_http_server -> failed loading inets"
+		"~n   Reason: ~p", [Reason]),
+	    tsf({failed_loading_inets, Reason})
+    end.
+	    
+start_http_server_ssl(FileName) ->
+    start_http_server_ssl(FileName, ?HTTP_DEFAULT_SSL_KIND).
+
+start_http_server_ssl(FileName, essl = _SslTag) ->
+    application:start(crypto), 
+    do_start_http_server_ssl(FileName);
+start_http_server_ssl(FileName, _SslTag) ->
+    do_start_http_server_ssl(FileName).
+
+do_start_http_server_ssl(FileName) ->
+    tsp("start (ssl) http server with "
+	"~n   FileName: ~p"
+	"~n", [FileName]),
+    application:start(ssl),	       
+    catch do_start_http_server(FileName).
+
+
+
+%% ----------------------------------------------------------------------
+%% print functions
+%%
+
+info(F, A, Mod, Line) ->
+    print("INF ", F, A, Mod, Line).
+
+log(F, A, Mod, Line) ->
+    print("LOG ", F, A, Mod, Line).
+
+debug(F, A, Mod, Line) ->
+    print("DBG ", F, A, Mod, Line).
+
+print(P, F, A, Mod, Line) ->
+    io:format("~s[~p:~p:~p] : " ++ F ++ "~n", [P, self(), Mod, Line| A]).
+
+print(F, A, Mod, Line) ->
+    print("", F, A, Mod, Line).
+
+hostname() ->
+   {ok, Name} = inet:gethostname(),
+    Name.
+
+from(H, [H | T]) -> T;
+from(H, [_ | T]) -> from(H, T);
+from(_, []) -> [].
+
+
+copy_file(File, From, To) ->
+    file:copy(filename:join(From, File), filename:join(To, File)).
+
+copy_files(FromDir, ToDir) -> 
+    {ok, Files} = file:list_dir(FromDir),
+    lists:foreach(fun(File) -> 
+			  FullPath = filename:join(FromDir, File),
+			  case filelib:is_file(FullPath) of
+			      true ->
+				  file:copy(FullPath,
+					    filename:join(ToDir, File));
+			      false ->
+				  ok
+			  end
+		  end, Files).
+
+
+copy_dirs(FromDirRoot, ToDirRoot) ->
+    case file:list_dir(FromDirRoot) of
+	{ok, Files}  ->
+	    lists:foreach(
+	      fun(FileOrDir) -> 
+		      %% Check if it's a directory or a file
+		      case filelib:is_dir(filename:join(FromDirRoot, 
+							FileOrDir)) of
+			  true ->
+			      FromDir = filename:join([FromDirRoot, FileOrDir]),
+			      ToDir   = filename:join([ToDirRoot, FileOrDir]),
+			      case file:make_dir(ToDir) of
+				  ok ->
+				      copy_dirs(FromDir, ToDir);
+				  {error, Reason} ->
+				      tsp("<ERROR> Failed creating directory: "
+					  "~n   ToDir:  ~p"
+					  "~n   Reason: ~p"
+					  "~nwhen"
+					  "~n   ToDirRoot:           ~p"
+					  "~n   ToDirRoot file info: ~p", 
+					  [ToDir, 
+					   Reason, 
+					   ToDirRoot, 
+					   file:read_file_info(ToDirRoot)]),
+				      tsf({failed_copy_dir, ToDir, Reason})
+			      end;
+			  false ->
+			      copy_file(FileOrDir, FromDirRoot, ToDirRoot)
+		      end
+	      end, Files);
+	{error, Reason} ->
+	    tsp("<ERROR> Failed get directory file list: "
+		"~n   FromDirRoot: ~p"
+		"~n   Reason:      ~p"
+		"~nwhen"
+		"~n   FromDirRoot file info: ~p", 
+		[FromDirRoot, 
+		 Reason, 
+		 file:read_file_info(FromDirRoot)]),
+	    tsf({failed_list_dir, FromDirRoot, Reason})
+    end.
+	    
+		
+
+del_dirs(Dir) ->
+    case file:list_dir(Dir) of
+	{ok, []} ->
+	    file:del_dir(Dir);
+	{ok, Files} ->
+	    lists:foreach(fun(File) ->
+				  FullPath = filename:join(Dir,File),
+				  case filelib:is_dir(FullPath) of
+				      true ->
+					  del_dirs(FullPath),
+					  file:del_dir(FullPath);	       
+				      false ->
+					  file:delete(FullPath)
+				  end 
+			  end, Files);
+	_ ->
+	    ok
+    end.
+
+check_body(Body) ->
+    case string:rstr(Body, "</html>") of
+	0 ->
+	    case string:rstr(Body, "</HTML>") of
+		0 ->
+		    tsp("Body ~p", [Body]),
+		    tsf(did_not_receive_whole_body);
+		_ ->
+		    ok
+	    end;
+	_ ->
+	    ok
+    end.
+
+%% ----------------------------------------------------------------
+%% Conditional skip of testcases
+%%
+
+non_pc_tc_maybe_skip(Config, Condition, File, Line)
+  when is_list(Config) andalso is_function(Condition) ->
+    %% Check if we shall skip the skip
+    case os:getenv("TS_OS_BASED_SKIP") of
+        "false" ->
+            ok;
+        _ ->
+            case lists:keysearch(ts, 1, Config) of
+                {value, {ts, inets}} ->
+                    %% Always run the testcase if we are using our own
+                    %% test-server...
+                    ok;
+                _ ->
+                    case (catch Condition()) of
+                        true ->
+                            skip(non_pc_testcase, File, Line);
+                        _ ->
+                            ok
+                    end
+            end
+    end.
+
+
+os_based_skip(any) ->
+    true;
+os_based_skip(Skippable) when is_list(Skippable) ->
+    {OsFam, OsName} =
+        case os:type() of
+            {_Fam, _Name} = FamAndName ->
+                FamAndName;
+            Fam ->
+                {Fam, undefined}
+        end,
+    case lists:member(OsFam, Skippable) of
+        true ->
+            true;
+        false ->
+            case lists:keysearch(OsFam, 1, Skippable) of
+                {value, {OsFam, OsName}} ->
+                    true;
+                {value, {OsFam, OsNames}} when is_list(OsNames) ->
+                    lists:member(OsName, OsNames);
+                _ ->
+                    false
+            end
+    end;
+os_based_skip(_) ->
+    false.
+
+
+%% ----------------------------------------------------------------------
+%% Socket functions:
+%% open(SocketType, Host, Port) -> {ok, Socket} | {error, Reason}
+%% SocketType -> ssl | ip_comm
+%% Host       -> atom() | string() | {A, B, C, D} 
+%% Port       -> integer()
+
+connect_bin(SockType, Host, Port) ->
+    connect_bin(SockType, Host, Port, []).
+
+connect_bin(ssl, Host, Port, Opts0) ->
+    Opts = [binary, {packet,0} | Opts0], 
+    connect(ssl, Host, Port, Opts);
+connect_bin(essl, Host, Port, Opts0) ->
+    Opts = [{ssl_imp, new}, binary, {packet,0}| Opts0], 
+    connect(ssl, Host, Port, Opts);
+connect_bin(ip_comm, Host, Port, Opts0) ->
+    Opts = [binary, {packet, 0} | Opts0],
+    connect(ip_comm, Host, Port, Opts);
+connect_bin(Type, Host, Port, Opts) ->
+    connect(Type, Host, Port, Opts).
+
+connect_byte(SockType, Host, Port) ->
+    connect_byte(SockType, Host, Port, []).
+    
+connect_byte(ssl, Host, Port, Opts0) ->
+    Opts = [{packet,0} | Opts0], 
+    connect(ssl, Host, Port, Opts);
+connect_byte(essl, Host, Port, Opts0) ->
+    Opts = [{ssl_imp, new}, {packet,0} | Opts0], 
+    connect(ssl, Host, Port, Opts);
+connect_byte(ip_comm, Host, Port, Opts0) ->
+    Opts = [{packet,0} | Opts0],
+    connect(ip_comm, Host, Port, Opts);
+connect_byte(Type, Host, Port, Opts) ->
+    connect(Type, Host, Port, Opts).
+
+connect(ip_comm, Host, Port, Opts) ->
+    gen_tcp:connect(Host, Port, Opts);
+connect(ssl, Host, Port, Opts) ->
+    ssl:connect(Host, Port, Opts);
+connect(openssl_port, Host, Port, Opts) ->
+    CaCertFile = proplists:get_value(cacertfile, Opts),
+    Cmd = "openssl s_client -quiet -port " ++ integer_to_list(Port)  ++ " -host " ++ Host 
+	++ " -CAfile " ++ CaCertFile,
+    ct:log("openssl cmd: ~p~n", [Cmd]),
+    OpensslPort =  open_port({spawn, Cmd}, [stderr_to_stdout]),
+    read_junk(OpensslPort),
+    {ok, OpensslPort}.
+
+send(ssl, Socket, Data) ->
+    ssl:send(Socket, Data);
+send(essl, Socket, Data) ->
+    ssl:send(Socket, Data);
+send(ip_comm,Socket,Data) ->
+    gen_tcp:send(Socket,Data);
+send(openssl_port, Port, Data) ->
+    true = port_command(Port, Data),
+    ok.
+close(ssl,Socket) ->
+    catch ssl:close(Socket);
+close(essl,Socket) ->
+    catch ssl:close(Socket);
+close(ip_comm,Socket) ->
+    catch gen_tcp:close(Socket);
+close(openssl_port, Port) ->
+    exit(Port, normal).
+
+
+hours(N)   -> trunc(N * 1000 * 60 * 60).
+minutes(N) -> trunc(N * 1000 * 60).
+seconds(N) -> trunc(N * 1000).
+
+
+sleep(infinity) ->
+    receive
+    after infinity ->
+            ok
+    end;
+sleep(MSecs) ->
+    receive
+    after trunc(MSecs) ->
+            ok
+    end,
+    ok.
+
+
+skip(Reason, File, Line) ->
+    exit({skipped, {Reason, File, Line}}).
+
+fail(Reason, File, Line) ->
+    String = lists:flatten(io_lib:format("Failure ~p(~p): ~p~n",
+                                         [File, Line, Reason])),
+    tsf(String).
+
+
+
+flush() ->
+    receive
+        Msg ->
+            [Msg | flush()]
+    after 1000 ->
+            []
+    end.
+
+
+tsp(F) ->
+    tsp(F, []).
+tsp(F, A) ->
+    Timestamp = inets_lib:formated_timestamp(),
+    ct:pal("*** ~s ~p ~p " ++ F ++ "~n", 
+		       [Timestamp, node(), self() | A]).
+
+tsf(Reason) ->
+    ct:fail(Reason).
+
+tss(Time) ->
+    ct:sleep(Time).
+
+timestamp() ->
+    http_util:timestamp().
+
+start_apps(Apps) ->
+    lists:foreach(fun(App) ->
+			  application:stop(App),
+			  application:start(App)
+		  end, Apps).
+stop_apps(Apps) ->
+    lists:foreach(fun(App) ->
+			  application:stop(App)
+		  end, Apps).
+
+inet_port(Node) ->
+    {Port, Socket} = do_inet_port(Node),
+     rpc:call(Node, gen_tcp, close, [Socket]),
+     Port.
+
+do_inet_port(Node) ->
+    {ok, Socket} = rpc:call(Node, gen_tcp, listen, [0, [{reuseaddr, true}]]),
+    {ok, Port} = rpc:call(Node, inet, port, [Socket]),
+    {Port, Socket}.
+
+read_junk(OpensslPort) ->
+    receive
+	{OpensslPort, _} ->
+	    read_junk(OpensslPort)
+    after 500 -> 
+	    ok    
+    end.
diff --git a/lib/ftp/test/inets_test_lib.hrl b/lib/ftp/test/inets_test_lib.hrl
new file mode 100644
index 0000000000..d436395290
--- /dev/null
+++ b/lib/ftp/test/inets_test_lib.hrl
@@ -0,0 +1,28 @@
+%%
+%% %CopyrightBegin%
+%%
+%% Copyright Ericsson AB 2001-2016. All Rights Reserved.
+%%
+%% Licensed under the Apache License, Version 2.0 (the "License");
+%% you may not use this file except in compliance with the License.
+%% You may obtain a copy of the License at
+%%
+%%     http://www.apache.org/licenses/LICENSE-2.0
+%%
+%% Unless required by applicable law or agreed to in writing, software
+%% distributed under the License is distributed on an "AS IS" BASIS,
+%% WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+%% See the License for the specific language governing permissions and
+%% limitations under the License.
+%%
+%% %CopyrightEnd%
+%%
+%%
+%%----------------------------------------------------------------------
+%% Purpose: Define common macros for testing
+%%----------------------------------------------------------------------
+%% - Misc macros -
+
+-define(ENSURE_STARTED(A), inets_test_lib:ensure_started(A)).
+
+
diff --git a/lib/ftp/test/property_test/README b/lib/ftp/test/property_test/README
new file mode 100644
index 0000000000..57602bf719
--- /dev/null
+++ b/lib/ftp/test/property_test/README
@@ -0,0 +1,12 @@
+
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+%%%                                                             %%%
+%%%                       WARNING                               %%%
+%%%                                                             %%%
+%%% This is experimental code which may be changed or removed   %%%
+%%%               anytime without any warning.                  %%%
+%%%                                                             %%%
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+
+The test in this directory are written assuming that the user has a QuickCheck license.  They are to be run manually.  Some may be possible to be run with other tools, e.g. PropEr.
+
diff --git a/lib/ftp/test/property_test/ftp_simple_client_server.erl b/lib/ftp/test/property_test/ftp_simple_client_server.erl
new file mode 100644
index 0000000000..c98d87b514
--- /dev/null
+++ b/lib/ftp/test/property_test/ftp_simple_client_server.erl
@@ -0,0 +1,307 @@
+%%
+%% %CopyrightBegin%
+%% 
+%% Copyright Ericsson AB 2004-2016. All Rights Reserved.
+%% 
+%% Licensed under the Apache License, Version 2.0 (the "License");
+%% you may not use this file except in compliance with the License.
+%% You may obtain a copy of the License at
+%%
+%%     http://www.apache.org/licenses/LICENSE-2.0
+%%
+%% Unless required by applicable law or agreed to in writing, software
+%% distributed under the License is distributed on an "AS IS" BASIS,
+%% WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+%% See the License for the specific language governing permissions and
+%% limitations under the License.
+%% 
+%% %CopyrightEnd%
+%%
+%%
+
+-module(ftp_simple_client_server).
+
+-compile(export_all).
+
+-ifndef(EQC).
+-ifndef(PROPER).
+-define(EQC,true).
+%%-define(PROPER,true).
+-endif.
+-endif.
+
+
+-ifdef(EQC).
+
+-include_lib("eqc/include/eqc.hrl").
+-include_lib("eqc/include/eqc_statem.hrl").
+-define(MOD_eqc, eqc).
+-define(MOD_eqc_gen, eqc_gen).
+-define(MOD_eqc_statem, eqc_statem).
+
+-else.
+-ifdef(PROPER).
+
+-include_lib("proper/include/proper.hrl").
+-define(MOD_eqc, proper).
+-define(MOD_eqc_gen, proper_gen).
+-define(MOD_eqc_statem, proper_statem).
+
+-endif.
+-endif.
+
+-record(state, {
+	  initialized = false,
+	  priv_dir,
+	  data_dir,
+	  servers = [], % [ {IP,Port,Userid,Pwd} ]
+	  clients = [], % [ client_ref() ]
+	  store = []    % [ {Name,Contents} ]
+	 }).
+
+-define(fmt(F,A), io:format(F,A)).
+%%-define(fmt(F,A), ok).
+
+-define(v(K,L), proplists:get_value(K,L)).
+
+%%%================================================================
+%%%
+%%% Properties
+%%% 
+
+%% This function is for normal eqc calls:
+prop_ftp() ->
+    {ok,PWD} = file:get_cwd(),
+    prop_ftp(filename:join([PWD,?MODULE_STRING++"_data"]),
+	     filename:join([PWD,?MODULE_STRING,"_files"])).
+
+%% This function is for calls from common_test test cases:
+prop_ftp(Config) ->
+    prop_ftp(filename:join([?v(property_dir,Config), ?MODULE_STRING++"_data"]),
+	     ?v(priv_dir,Config) ).
+
+
+prop_ftp(DataDir, PrivDir) ->
+    S0 = #state{data_dir = DataDir,
+		priv_dir = PrivDir},
+    ?FORALL(Cmds,  more_commands(10,commands(?MODULE,S0)),
+	 aggregate(command_names(Cmds),
+	   begin {_H,S,Result} = run_commands(?MODULE,Cmds),
+		 % io:format('**** Result=~p~n',[Result]),
+		 % io:format('**** S=~p~n',[S]),
+		 % io:format('**** _H=~p~n',[_H]),
+		 % io:format('**** Cmds=~p~n',[Cmds]),
+		 [cmnd_stop_server(X) || X <- S#state.servers],
+		 [inets:stop(ftpc,X) || {ok,X} <- S#state.clients],
+		 Result==ok
+	   end)
+	   ).
+
+%%%================================================================
+%%%
+%%% State model
+%%% 
+
+%% @doc Returns the state in which each test case starts. (Unless a different 
+%%      initial state is supplied explicitly to, e.g. commands/2.)
+-spec initial_state() ->?MOD_eqc_statem:symbolic_state().
+initial_state() -> 
+    ?fmt("Initial_state()~n",[]),
+    #state{}.
+
+%% @doc Command generator, S is the current state
+-spec command(S :: ?MOD_eqc_statem:symbolic_state()) -> ?MOD_eqc_gen:gen(eqc_statem:call()).
+
+command(#state{initialized=false,
+	       priv_dir=PrivDir}) -> 
+    {call,?MODULE,cmnd_init,[PrivDir]};
+
+command(#state{servers=[],
+	       priv_dir=PrivDir,
+	       data_dir=DataDir}) -> 
+    {call,?MODULE,cmnd_start_server,[PrivDir,DataDir]};
+
+command(#state{servers=Ss=[_|_],
+	       clients=[]}) -> 
+    {call,?MODULE,cmnd_start_client,[oneof(Ss)]};
+
+command(#state{servers=Ss=[_|_],
+	       clients=Cs=[_|_],
+	       store=Store=[_|_]
+	      }) ->
+    frequency([
+	       { 5, {call,?MODULE,cmnd_start_client,[oneof(Ss)]}},
+	       { 5, {call,?MODULE,cmnd_stop_client,[oneof(Cs)]}},
+	       {10, {call,?MODULE,cmnd_put,[oneof(Cs),file_path(),file_contents()]}},
+	       {20, {call,?MODULE,cmnd_get,[oneof(Cs),oneof(Store)]}},
+	       {10, {call,?MODULE,cmnd_delete,[oneof(Cs),oneof(Store)]}}
+	      ]);
+		 
+command(#state{servers=Ss=[_|_],
+	       clients=Cs=[_|_],
+	       store=[]
+	      }) ->
+    frequency([
+	       {5, {call,?MODULE,cmnd_start_client,[oneof(Ss)]}},
+	       {5, {call,?MODULE,cmnd_stop_client,[oneof(Cs)]}},
+	       {10, {call,?MODULE,cmnd_put,[oneof(Cs),file_path(),file_contents()]}}
+	      ]).
+		 
+%% @doc Precondition, checked before command is added to the command sequence. 
+-spec precondition(S :: ?MOD_eqc_statem:symbolic_state(), C :: ?MOD_eqc_statem:call()) -> boolean().
+
+precondition(#state{clients=Cs}, {call, _, cmnd_put, [C,_,_]}) -> lists:member(C,Cs);
+
+precondition(#state{clients=Cs, store=Store}, 
+	     {call, _, cmnd_get, [C,X]}) -> lists:member(C,Cs) andalso lists:member(X,Store);
+
+precondition(#state{clients=Cs, store=Store},
+	     {call, _, cmnd_delete, [C,X]}) -> lists:member(C,Cs) andalso lists:member(X,Store);
+
+precondition(#state{servers=Ss}, {call, _, cmnd_start_client, _}) ->  Ss =/= [];
+
+precondition(#state{clients=Cs}, {call, _, cmnd_stop_client, [C]}) -> lists:member(C,Cs);
+
+precondition(#state{initialized=IsInit}, {call, _, cmnd_init, _}) -> IsInit==false;
+
+precondition(_S, {call, _, _, _}) -> true.
+
+
+%% @doc Postcondition, checked after command has been evaluated
+%%      Note: S is the state before next_state(S,_,C) 
+-spec postcondition(S :: ?MOD_eqc_statem:dynamic_state(), C :: ?MOD_eqc_statem:call(), 
+                    Res :: term()) -> boolean().
+
+postcondition(_S, {call, _, cmnd_get, [_,{_Name,Expected}]}, {ok,Value}) ->
+    Value == Expected;
+
+postcondition(S, {call, _, cmnd_delete, [_,{Name,_Expected}]}, ok) ->
+    ?fmt("file:read_file(..) = ~p~n",[file:read_file(filename:join(S#state.priv_dir,Name))]),
+    {error,enoent} == file:read_file(filename:join(S#state.priv_dir,Name));
+
+postcondition(S, {call, _, cmnd_put,  [_,Name,Value]}, ok) -> 
+    {ok,Bin} = file:read_file(filename:join(S#state.priv_dir,Name)),
+    Bin == unicode:characters_to_binary(Value);
+
+postcondition(_S, {call, _, cmnd_stop_client, _}, ok) -> true;
+
+postcondition(_S, {call, _, cmnd_start_client, _}, {ok,_}) -> true;
+
+postcondition(_S, {call, _, cmnd_init, _}, ok) -> true;
+
+postcondition(_S, {call, _, cmnd_start_server, _}, {ok,_}) -> true.
+
+
+%% @doc Next state transformation, S is the current state. Returns next state.
+-spec next_state(S :: ?MOD_eqc_statem:symbolic_state(), 
+		 V :: ?MOD_eqc_statem:var(), 
+                 C :: ?MOD_eqc_statem:call()) -> ?MOD_eqc_statem:symbolic_state().
+
+next_state(S, _V, {call, _, cmnd_put, [_,Name,Val]}) ->
+    S#state{store = [{Name,Val} | lists:keydelete(Name,1,S#state.store)]};
+
+next_state(S, _V, {call, _, cmnd_delete, [_,{Name,_Val}]}) ->
+    S#state{store = lists:keydelete(Name,1,S#state.store)};
+
+next_state(S, V, {call, _, cmnd_start_client, _}) ->
+    S#state{clients = [V | S#state.clients]};
+
+next_state(S, V, {call, _, cmnd_start_server, _}) ->
+    S#state{servers = [V | S#state.servers]};
+
+next_state(S, _V, {call, _, cmnd_stop_client, [C]}) ->
+    S#state{clients = S#state.clients -- [C]};
+
+next_state(S, _V, {call, _, cmnd_init, _}) ->
+    S#state{initialized=true};
+
+next_state(S, _V, {call, _, _, _}) ->
+    S.
+
+%%%================================================================
+%%%
+%%% Data model
+%%% 
+
+file_path() -> non_empty(list(alphanum_char())).
+%%file_path() -> non_empty( list(oneof([alphanum_char(), utf8_char()])) ).
+
+%%file_contents() -> list(alphanum_char()).
+file_contents() -> list(oneof([alphanum_char(), utf8_char()])).
+    
+alphanum_char() -> oneof(lists:seq($a,$z) ++ lists:seq($A,$Z) ++ lists:seq($0,$9)).
+
+utf8_char() -> oneof("åäöÅÄÖ話话カタカナひらがな").
+
+%%%================================================================
+%%%
+%%% Commands doing something with the System Under Test
+%%% 
+
+cmnd_init(PrivDir) ->
+    ?fmt('Call cmnd_init(~p)~n',[PrivDir]),
+    os:cmd("killall vsftpd"),
+    clear_files(PrivDir),
+    ok.
+
+cmnd_start_server(PrivDir, DataDir) ->
+    ?fmt('Call cmnd_start_server(~p, ~p)~n',[PrivDir,DataDir]),
+    Cmnd = ["vsftpd ", filename:join(DataDir,"vsftpd.conf"),
+	    " -oftpd_banner=erlang_otp_testing"
+	    " -oanon_root=",PrivDir
+	   ],
+    ?fmt("Cmnd=~s~n",[Cmnd]),
+    case os:cmd(Cmnd) of
+	[] ->
+	    {ok,{"localhost",9999,"ftp","[email protected]"}};
+	Other ->
+	    {error,Other}
+    end.
+
+cmnd_stop_server({ok,{_Host,Port,_Usr,_Pwd}}) ->
+    os:cmd("kill `netstat -tpln | grep "++integer_to_list(Port)++" | awk '{print $7}' | awk -F/ '{print $1}'`").
+
+cmnd_start_client({ok,{Host,Port,Usr,Pwd}}) ->
+    ?fmt('Call cmnd_start_client(~p)...',[{Host,Port,Usr,Pwd}]),
+    case inets:start(ftpc, [{host,Host},{port,Port}]) of
+	{ok,Client} ->
+	    ?fmt("~p...",[{ok,Client}]),
+	    case ftp:user(Client, Usr, Pwd) of
+		ok -> 
+		    ?fmt("OK!~n",[]),
+		    {ok,Client};
+		Other -> 
+		    ?fmt("Other1=~p~n",[Other]),
+		    inets:stop(ftpc,Client), Other
+	    end;
+	Other -> 
+	    ?fmt("Other2=~p~n",[Other]),
+	    Other
+    end.
+		     
+cmnd_stop_client({ok,Client}) ->
+    ?fmt('Call cmnd_stop_client(~p)~n',[Client]),
+    inets:stop(ftpc, Client). %% -> ok | Other
+
+cmnd_delete({ok,Client}, {Name,_ExpectedValue}) ->
+    ?fmt('Call cmnd_delete(~p, ~p)~n',[Client,Name]),
+    R=ftp:delete(Client, Name),
+    ?fmt("R=~p~n",[R]),
+    R.
+
+cmnd_put({ok,Client}, Name, Value) ->
+    ?fmt('Call cmnd_put(~p, ~p, ~p)...',[Client, Name, Value]),
+    R = ftp:send_bin(Client, unicode:characters_to_binary(Value), Name), % ok | {error,Error}
+    ?fmt('~p~n',[R]),
+    R.
+
+cmnd_get({ok,Client}, {Name,_ExpectedValue}) ->
+    ?fmt('Call cmnd_get(~p, ~p)~n',[Client,Name]),
+    case ftp:recv_bin(Client, Name) of
+	{ok,Bin} -> {ok, unicode:characters_to_list(Bin)};
+	Other -> Other
+    end.
+
+
+clear_files(Dir) ->
+    os:cmd(["rm -fr ",filename:join(Dir,"*")]).
diff --git a/lib/ftp/test/property_test/ftp_simple_client_server_data/vsftpd.conf b/lib/ftp/test/property_test/ftp_simple_client_server_data/vsftpd.conf
new file mode 100644
index 0000000000..fd48e2abf0
--- /dev/null
+++ b/lib/ftp/test/property_test/ftp_simple_client_server_data/vsftpd.conf
@@ -0,0 +1,26 @@
+
+###
+### Some parameters are given in the vsftpd start command.
+### 
+### Typical command-line paramters are such that has a file path
+### component like cert files.
+###
+
+
+listen=YES
+listen_port=9999
+run_as_launching_user=YES
+ssl_enable=NO
+#allow_anon_ssl=YES
+
+background=YES
+
+write_enable=YES
+anonymous_enable=YES
+anon_upload_enable=YES
+anon_mkdir_write_enable=YES
+anon_other_write_enable=YES
+anon_world_readable_only=NO
+
+### Shouldn't be necessary....
+require_ssl_reuse=NO