Merge tag 'OTP-20.0' into sverker/20/binary_to_atom-utf8-crash/ERL-474/OTP-14590

10 files changed, 508 insertions, 21 deletions

diff --git a/lib/hipe/test/basic_SUITE_data/basic_bugs_hipe.erl b/lib/hipe/test/basic_SUITE_data/basic_bugs_hipe.erl
index caa0e71d0b..430e097b91 100644
--- a/lib/hipe/test/basic_SUITE_data/basic_bugs_hipe.erl
+++ b/lib/hipe/test/basic_SUITE_data/basic_bugs_hipe.erl
@@ -18,6 +18,7 @@ test() ->
   ok = test_R12B5_seg_fault(),
   ok = test_switch_neg_int(),
   ok = test_icode_range_anal(),
+  ok = test_icode_range_call(),
   ok.
 
 %%-----------------------------------------------------------------------
@@ -461,3 +462,44 @@ g(X, Z) ->
     test -> non_zero_test;
     other -> other
   end.
+
+%%-----------------------------------------------------------------------
+%% From: Rich Neswold
+%% Date: Oct 5, 2016
+%%
+%% The following was a bug in the HiPE compiler's range analysis. The
+%% function range_client/2 below would would not stop when N reached 0,
+%% but keep recursing into the second clause forever.
+%%
+%% The problem turned out to be in hipe_icode_range:analyse_call/2,
+%% which would note update the argument ranges of the callee if the
+%% result of the call was ignored.
+%% -----------------------------------------------------------------------
+-define(TIMEOUT, 42).
+
+test_icode_range_call() ->
+    Self = self(),
+    Client = spawn_link(fun() -> range_client(Self, 4) end),
+    range_server(4, Client).
+
+range_server(0, _Client) ->
+    receive
+        stopping -> ok;
+        {called_with, 0} -> error(failure)
+    after ?TIMEOUT -> error(timeout)
+    end;
+range_server(N, Client) ->
+    receive
+        {called_with, N} ->
+            Client ! proceed
+    after ?TIMEOUT -> error(timeout)
+    end,
+    range_server(N-1, Client). % tailcall (so the bug does not affect it)
+
+range_client(Server, 0) ->
+    Server ! stopping;
+range_client(Server, N) ->
+    Server ! {called_with, N},
+    receive proceed -> ok end,
+    range_client(Server, N - 1), % non-tailrecursive call with ignored result
+    ok.
diff --git a/lib/hipe/test/basic_SUITE_data/basic_edge_cases.erl b/lib/hipe/test/basic_SUITE_data/basic_edge_cases.erl
new file mode 100644
index 0000000000..9bf5cf52cd
--- /dev/null
+++ b/lib/hipe/test/basic_SUITE_data/basic_edge_cases.erl
@@ -0,0 +1,142 @@
+%%% -*- erlang-indent-level: 2 -*-
+%%%----------------------------------------------------------------------
+%%% Contains
+%%%----------------------------------------------------------------------
+-module(basic_edge_cases).
+
+-export([test/0]).
+
+test() ->
+  ok = test_float_spills(),
+  ok = test_infinite_loops(),
+  ok.
+
+%% Contains more float temps live at a single point than there are float
+%% registers in any backend
+
+test_float_spills() ->
+    {{{2942.0,4670.0,3198.0,4926.0,2206.0,4734.0},
+      {3118.0,2062.0,5174.0,3038.0,3618.0,3014.0},
+      {2542.0,2062.0,4934.0,2590.0,3098.0,3062.0},
+      {2950.0,3666.0,2574.0,5038.0,1866.0,2946.0},
+      {3126.0,3050.0,3054.0,5070.0,2258.0,2714.0},
+      {4734.0,2206.0,4926.0,3198.0,4670.0,2942.0}},
+     58937.0} =
+	mat66_flip_sum(35.0,86.0,32.0,88.0,33.0,57.0,
+		       22.0,77.0,91.0,80.0,14.0,33.0,
+		       51.0,28.0,87.0,20.0,91.0,11.0,
+		       68.0,83.0,64.0,82.0,10.0,86.0,
+		       74.0,18.0,08.0,52.0,10.0,14.0,
+		       89.0,34.0,64.0,66.0,58.0,55.0,
+		       0.0, 5),
+    ok.
+
+mat66_flip_sum(M11, M12, M13, M14, M15, M16,
+	       M21, M22, M23, M24, M25, M26,
+	       M31, M32, M33, M34, M35, M36,
+	       M41, M42, M43, M44, M45, M46,
+	       M51, M52, M53, M54, M55, M56,
+	       M61, M62, M63, M64, M65, M66,
+	       Acc, Ctr)
+  when is_float(M11), is_float(M12), is_float(M13),
+       is_float(M14), is_float(M15), is_float(M16),
+       is_float(M21), is_float(M22), is_float(M23),
+       is_float(M24), is_float(M25), is_float(M26),
+       is_float(M31), is_float(M32), is_float(M33),
+       is_float(M34), is_float(M35), is_float(M36),
+       is_float(M41), is_float(M42), is_float(M43),
+       is_float(M44), is_float(M45), is_float(M46),
+       is_float(M51), is_float(M52), is_float(M53),
+       is_float(M54), is_float(M55), is_float(M56),
+       is_float(M61), is_float(M62), is_float(M63),
+       is_float(M64), is_float(M65), is_float(M66),
+       is_float(Acc) ->
+    R11 = M66+M11, R12 = M65+M12, R13 = M64+M13,
+    R14 = M63+M14, R15 = M62+M15, R16 = M61+M16,
+    R21 = M56+M21, R22 = M55+M22, R23 = M54+M23,
+    R24 = M53+M24, R25 = M52+M25, R26 = M51+M26,
+    R31 = M46+M31, R32 = M45+M32, R33 = M44+M33,
+    R34 = M43+M34, R35 = M42+M35, R36 = M41+M36,
+    R41 = M26+M41, R42 = M25+M42, R43 = M24+M43,
+    R44 = M23+M44, R45 = M22+M45, R46 = M21+M46,
+    R51 = M36+M51, R52 = M35+M52, R53 = M34+M53,
+    R54 = M33+M54, R55 = M32+M55, R56 = M31+M56,
+    R61 = M16+M61, R62 = M15+M62, R63 = M14+M63,
+    R64 = M13+M64, R65 = M12+M65, R66 = M11+M66,
+    case Ctr of
+	0 ->
+	    {{{R11, R12, R13, R14, R15, R16},
+	      {R21, R22, R23, R24, R25, R26},
+	      {R31, R32, R33, R34, R35, R36},
+	      {R41, R42, R43, R44, R45, R46},
+	      {R51, R52, R53, R54, R55, R56},
+	      {R61, R62, R63, R64, R65, R66}},
+	     Acc};
+	_ ->
+	    NewAcc = 0.0 + M11 + M12 + M13 + M14 + M15 + M16 +
+		+ M21 + M22 + M23 + M24 + M25 + M26
+		+ M31 + M32 + M33 + M34 + M35 + M36
+		+ M41 + M42 + M43 + M44 + M45 + M46
+		+ M51 + M52 + M53 + M54 + M55 + M56
+		+ M61 + M62 + M63 + M64 + M65 + M66
+		+ Acc,
+	    mat66_flip_sum(R11+1.0, R12+1.0, R13+1.0, R14+1.0, R15+1.0, R16+1.0,
+			   R21+1.0, R22+1.0, R23+1.0, R24+1.0, R25+1.0, R26+1.0,
+			   R31+1.0, R32+1.0, R33+1.0, R34+1.0, R35+1.0, R36+1.0,
+			   R41+1.0, R42+1.0, R43+1.0, R44+1.0, R45+1.0, R46+1.0,
+			   R51+1.0, R52+1.0, R53+1.0, R54+1.0, R55+1.0, R56+1.0,
+			   R61+1.0, R62+1.0, R63+1.0, R64+1.0, R65+1.0, R66+1.0,
+			   NewAcc, Ctr-1)
+    end.
+
+%% Infinite loops must receive reduction tests, and might trip up basic block
+%% weighting, leading to infinite weights and/or divisions by zero.
+
+test_infinite_loops() ->
+  OldTrapExit = process_flag(trap_exit, true),
+  ok = test_infinite_loop(fun infinite_recursion/0),
+  ok = test_infinite_loop(fun infinite_corecursion/0),
+  RecursiveFun = fun RecursiveFun() -> RecursiveFun() end,
+  ok = test_infinite_loop(RecursiveFun),
+  CorecursiveFunA = fun CorecursiveFunA() ->
+		       CorecursiveFunA1 = fun () -> CorecursiveFunA() end,
+		       CorecursiveFunA1()
+		   end,
+  ok = test_infinite_loop(CorecursiveFunA),
+  CorecursiveFunB1 = fun(CorecursiveFunB) -> CorecursiveFunB() end,
+  CorecursiveFunB = fun CorecursiveFunB() ->
+		       CorecursiveFunB1(CorecursiveFunB)
+		   end,
+  ok = test_infinite_loop(CorecursiveFunB),
+  CorecursiveFunC1 = fun CorecursiveFunC1(Other) ->
+			 Other(CorecursiveFunC1)
+		     end,
+  CorecursiveFunC = fun CorecursiveFunC(Other) ->
+		       Other(CorecursiveFunC)
+		   end,
+  ok = test_infinite_loop(fun() -> CorecursiveFunC(CorecursiveFunC1) end),
+  ok = test_infinite_loop(fun() -> CorecursiveFunC(CorecursiveFunC) end),
+  true = process_flag(trap_exit, OldTrapExit),
+  ok.
+
+-define(INFINITE_LOOP_TIMEOUT, 100).
+test_infinite_loop(Fun) ->
+  Tester = spawn_link(Fun),
+  kill_soon(Tester),
+  receive {'EXIT', Tester, awake} ->
+      undefined = process_info(Tester),
+      ok
+  after ?INFINITE_LOOP_TIMEOUT -> error(timeout)
+  end.
+
+infinite_recursion() -> infinite_recursion().
+
+infinite_corecursion() -> infinite_corecursion_1().
+infinite_corecursion_1() -> infinite_corecursion().
+
+kill_soon(Pid) ->
+  _ = spawn_link(fun() ->
+		     timer:sleep(1),
+		     erlang:exit(Pid, awake)
+		 end),
+  ok.
diff --git a/lib/hipe/test/basic_SUITE_data/basic_num_bif.erl b/lib/hipe/test/basic_SUITE_data/basic_num_bif.erl
new file mode 100644
index 0000000000..807c4b0d0d
--- /dev/null
+++ b/lib/hipe/test/basic_SUITE_data/basic_num_bif.erl
@@ -0,0 +1,217 @@
+%%% -*- erlang-indent-level: 2 -*-
+%%%-------------------------------------------------------------------
+%%% File	: basic_num_bif.erl
+%%% Description : Taken from the compiler test suite
+%%%-------------------------------------------------------------------
+-module(basic_num_bif).
+
+-export([test/0]).
+
+%% Tests optimization of the BIFs:
+%% 	abs/1
+%%	float/1
+%%	float_to_list/1
+%%	integer_to_list/1
+%%	list_to_float/1
+%%	list_to_integer/1
+%%	round/1
+%%	trunc/1
+
+test() -> 
+  Funs = [fun t_abs/0, fun t_float/0,
+	  fun t_float_to_list/0, fun t_integer_to_list/0,
+	  fun t_list_to_float_safe/0, fun t_list_to_float_risky/0,
+	  fun t_list_to_integer/0, fun t_round/0, fun t_trunc/0],
+  lists:foreach(fun (F) -> ok = F() end, Funs).
+
+t_abs() ->
+  %% Floats.
+  5.5 = abs(5.5),
+  0.0 = abs(0.0),
+  100.0 = abs(-100.0),
+  %% Integers.
+  5 = abs(5),
+  0 = abs(0),
+  100 = abs(-100),
+  %% The largest smallnum. OTP-3190.
+  X = (1 bsl 27) - 1,
+  X = abs(X),
+  X = abs(X-1)+1,
+  X = abs(X+1)-1,
+  X = abs(-X),
+  X = abs(-X-1)-1,
+  X = abs(-X+1)+1,
+  %% Bignums.
+  BigNum = 13984792374983749,
+  BigNum = abs(BigNum),
+  BigNum = abs(-BigNum),
+  ok.
+
+t_float() ->
+  0.0 = float(0),
+  2.5 = float(2.5),
+  0.0 = float(0.0),
+  -100.55 = float(-100.55),
+  42.0 = float(42),
+  -100.0 = float(-100),
+  %% Bignums.
+  4294967305.0 = float(4294967305),
+  -4294967305.0 = float(-4294967305),
+  %% Extremely big bignums.
+  Big = list_to_integer(lists:duplicate(2000, $1)),
+  {'EXIT', {badarg, _}} = (catch float(Big)),
+  ok.
+
+%% Tests float_to_list/1.
+
+t_float_to_list() ->
+  test_ftl("0.0e+0", 0.0),
+  test_ftl("2.5e+1", 25.0),
+  test_ftl("2.5e+0", 2.5),
+  test_ftl("2.5e-1", 0.25),
+  test_ftl("-3.5e+17", -350.0e15),
+  ok.
+
+test_ftl(Expect, Float) ->
+  %% No on the next line -- we want the line number from t_float_to_list.
+  Expect = remove_zeros(lists:reverse(float_to_list(Float)), []).
+
+%% Removes any non-significant zeros in a floating point number.
+%% Example: 2.500000e+01 -> 2.5e+1
+
+remove_zeros([$+, $e|Rest], [$0, X|Result]) ->
+  remove_zeros([$+, $e|Rest], [X|Result]);
+remove_zeros([$-, $e|Rest], [$0, X|Result]) ->
+  remove_zeros([$-, $e|Rest], [X|Result]);
+remove_zeros([$0, $.|Rest], [$e|Result]) ->
+  remove_zeros(Rest, [$., $0, $e|Result]);
+remove_zeros([$0|Rest], [$e|Result]) ->
+  remove_zeros(Rest, [$e|Result]);
+remove_zeros([Char|Rest], Result) ->
+  remove_zeros(Rest, [Char|Result]);
+remove_zeros([], Result) ->
+  Result.
+
+%% Tests integer_to_list/1.
+
+t_integer_to_list() ->
+  "0" = integer_to_list(0),
+  "42" = integer_to_list(42),
+  "-42" = integer_to_list(-42),
+  "-42" = integer_to_list(-42),
+  "32768" = integer_to_list(32768),
+  "268435455" = integer_to_list(268435455),
+  "-268435455" = integer_to_list(-268435455),
+  "123456932798748738738" = integer_to_list(123456932798748738738),
+  Big_List = lists:duplicate(2000, $1),
+  Big = list_to_integer(Big_List),
+  Big_List = integer_to_list(Big),
+  ok.
+
+%% Tests list_to_float/1.
+
+t_list_to_float_safe() ->
+  0.0 = list_to_float("0.0"),
+  0.0 = list_to_float("-0.0"),
+  0.5 = list_to_float("0.5"),
+  -0.5 = list_to_float("-0.5"),
+  100.0 = list_to_float("1.0e2"),
+  127.5 = list_to_float("127.5"),
+  -199.5 = list_to_float("-199.5"),
+  ok.
+
+%% This might crash the emulator...
+%% (Known to crash the Unix version of Erlang 4.4.1)
+
+t_list_to_float_risky() ->
+  Many_Ones = lists:duplicate(25000, $1),
+  _ = list_to_float("2."++Many_Ones),
+  {'EXIT', {badarg, _}} = (catch list_to_float("2"++Many_Ones)),
+  ok.
+
+%% Tests list_to_integer/1.
+
+t_list_to_integer() ->
+  0 = list_to_integer("0"),
+  0 = list_to_integer("00"),
+  0 = list_to_integer("-0"),
+  1 = list_to_integer("1"),
+  -1 = list_to_integer("-1"),
+  42 = list_to_integer("42"),
+  -12 = list_to_integer("-12"),
+  32768 = list_to_integer("32768"),
+  268435455 = list_to_integer("268435455"),
+  -268435455 = list_to_integer("-268435455"),
+  %% Bignums.
+  123456932798748738738 = list_to_integer("123456932798748738738"),
+  _ = list_to_integer(lists:duplicate(2000, $1)),
+  ok.
+
+%% Tests round/1.
+
+t_round() ->
+  0 = round(0.0),
+  0 = round(0.4),
+  1 = round(0.5),
+  0 = round(-0.4),
+  -1 = round(-0.5),
+  255 = round(255.3),
+  256 = round(255.6),
+  -1033 = round(-1033.3),
+  -1034 = round(-1033.6),
+  %% OTP-3722:
+  X = (1 bsl 27) - 1,
+  MX = -X,
+  MXm1 = -X-1,
+  MXp1 = -X+1,
+  F = X + 0.0,
+  X = round(F),
+  X = round(F+1)-1,
+  X = round(F-1)+1,
+  MX = round(-F),
+  MXm1 = round(-F-1),
+  MXp1 = round(-F+1),
+  X = round(F+0.1),
+  X = round(F+1+0.1)-1,
+  X = round(F-1+0.1)+1,
+  MX = round(-F+0.1),
+  MXm1 = round(-F-1+0.1),
+  MXp1 = round(-F+1+0.1),
+  X = round(F-0.1),
+  X = round(F+1-0.1)-1,
+  X = round(F-1-0.1)+1,
+  MX = round(-F-0.1),
+  MXm1 = round(-F-1-0.1),
+  MXp1 = round(-F+1-0.1),
+  0.5 = abs(round(F+0.5)-(F+0.5)),
+  0.5 = abs(round(F-0.5)-(F-0.5)),
+  0.5 = abs(round(-F-0.5)-(-F-0.5)),
+  0.5 = abs(round(-F+0.5)-(-F+0.5)),
+  %% Bignums.
+  4294967296 = round(4294967296.1),
+  4294967297 = round(4294967296.9),
+  -4294967296 = -round(4294967296.1),
+  -4294967297 = -round(4294967296.9),
+  ok.
+
+t_trunc() ->
+  0 = trunc(0.0),
+  5 = trunc(5.3333),
+  -10 = trunc(-10.978987),
+  %% The largest smallnum, converted to float (OTP-3722):
+  X = (1 bsl 27) - 1,
+  F = X + 0.0,
+  %%  io:format("X = ~p/~w/~w, F = ~p/~w/~w, trunc(F) = ~p/~w/~w~n",
+  %%	      [X, X, binary_to_list(term_to_binary(X)),
+  %%	       F, F, binary_to_list(term_to_binary(F)),
+  %%	       trunc(F), trunc(F), binary_to_list(term_to_binary(trunc(F)))]),
+  X = trunc(F),
+  X = trunc(F+1)-1,
+  X = trunc(F-1)+1,
+  X = -trunc(-F),
+  X = -trunc(-F-1)-1,
+  X = -trunc(-F+1)+1,
+  %% Bignums.
+  4294967305 = trunc(4294967305.7),
+  -4294967305 = trunc(-4294967305.7),
+  ok.
diff --git a/lib/hipe/test/basic_SUITE_data/basic_tuples.erl b/lib/hipe/test/basic_SUITE_data/basic_tuples.erl
index 94c187e364..96e39d565a 100644
--- a/lib/hipe/test/basic_SUITE_data/basic_tuples.erl
+++ b/lib/hipe/test/basic_SUITE_data/basic_tuples.erl
@@ -55,6 +55,8 @@ test_element(T0, T1, T2, N) ->
   List = lists:seq(1, N),
   Tuple = list_to_tuple(List),
   ok = get_elements(List, Tuple, 1),
+  %% element/2 of larger tuple with omitted bounds test
+  true = lists:all(fun(I) -> I * I =:= square(I) end, lists:seq(1, 20)),
   %% some cases that throw exceptions
   {'EXIT', _} = (catch my_element(0, T2)),
   {'EXIT', _} = (catch my_element(3, T2)),
@@ -73,6 +75,18 @@ get_elements([Element|Rest], Tuple, Pos) ->
 get_elements([], _Tuple, _Pos) ->
   ok.
 
+squares() ->
+  {1*1,   2*2,   3*3,   4*4,   5*5,   6*6,   7*7,   8*8,   9*9,   10*10,
+   11*11, 12*12, 13*13, 14*14, 15*15, 16*16, 17*17, 18*18, 19*19, 20*20}.
+
+square(N) when is_integer(N), N >= 1, N =< 20 ->
+  %% The guard tests lets the range analysis conclude N to be an integer in the
+  %% 1..20 range. 20-1=19 is bigger than ?SET_LIMIT in erl_types.erl, and will
+  %% thus be represented by an ?int_range() rather than an ?int_set().
+  %% Because of the range analysis, the bounds test of this element/2 call
+  %% should be omitted.
+  element(N, squares()).
+
 %%--------------------------------------------------------------------
 %% Tests set_element/3.
 
diff --git a/lib/hipe/test/bs_SUITE_data/bs_pmatch_bugs.erl b/lib/hipe/test/bs_SUITE_data/bs_pmatch_bugs.erl
index b280705a47..d9f3278b45 100644
--- a/lib/hipe/test/bs_SUITE_data/bs_pmatch_bugs.erl
+++ b/lib/hipe/test/bs_SUITE_data/bs_pmatch_bugs.erl
@@ -9,6 +9,7 @@ test() ->
   <<49,50,51>> = lex_digits1(Bin, 1, []),
   <<49,50,51>> = lex_digits2(Bin, 1, []),
   ok = var_bind_bug(<<1, 2, 3, 4, 5, 6, 7, 8>>),
+  ok = bs_match_string_bug(),
   ok.
 
 %%--------------------------------------------------------------------
@@ -65,3 +66,50 @@ var_bind_bug(<<A:1/binary, B:8/integer, _C:B/binary, _Rest/binary>>) ->
     B -> wrong;
     _ -> ok
   end.
+
+%%--------------------------------------------------------------------
+%% From: Andreas Schultz
+%% Date: 2/11/2016
+%%
+%% Either HiPE is messing up binary matches in some cases or I'm not
+%% seeing the problem. ... <SNIP PROGRAM - CLEANED UP VERSION BELOW>
+%% With Erlang 19.1.3 the HiPE compiled version behaves differently
+%% than the non-HiPE version: ... <SNIP TEST RUNS>
+%% So, do I do something wrong here or is this a legitimate HiPE bug?
+%%
+%% Yes, this was a legitimate HiPE bug: The BEAM to ICode tranaslation
+%% of the bs_match_string instruction, written long ago for binaries
+%% (i.e., with byte-sized strings), tried to do a `clever' translation
+%% of even bit-sized strings using a HiPE primop that took a `Size'
+%% argument expressed in *bytes*. ICode is not really the place to do
+%% such a thing, and moreover there is really no reason for the HiPE
+%% primop not to take a Size argument expressed in *bits* instead.
+%% The bug was fixed by changing the `Size' argument to be in bits,
+%% postponing the translation of the bs_match_string primop until RTL
+%% and doing a proper translation using bit-sized quantities there.
+%%--------------------------------------------------------------------
+
+bs_match_string_bug() ->
+  ok = test0(<<50>>),
+  Bin = data(),
+  ok = test1(Bin),
+  ok = test2(Bin),
+  ok.
+
+%% Minimal test case showing the problem matching with strings
+test0(<<6:5, 0:1, 0:2>>) -> weird;
+test0(<<6:5, _:1, _:2>>) -> ok;
+test0(_) -> default.
+
+data() -> <<50,16,0>>.
+
+%% This was the problematic test case in HiPE: 'default' was returned
+test1(<<1:3, 1:1, _:1, 0:1, 0:1, 0:1, _/binary>>) -> weird;
+test1(<<1:3, 1:1, _:1, _:1, _:1, _:1, _/binary>>) -> ok;
+test1(_) -> default.
+
+%% This variation of test1/1 above worked OK, even in HiPE
+test2(<<1:3, 1:1, _:1, A:1, B:1, C:1, _/binary>>)
+  when A =:= 1; B =:= 1; C =:= 1 -> ok;
+test2(<<1:3, 1:1, _:1, 0:1, 0:1, 0:1, _/binary>>) -> weird;
+test2(_) -> default.
diff --git a/lib/hipe/test/hipe_SUITE.erl b/lib/hipe/test/hipe_SUITE.erl
index a5b3924aa8..b9adb660f2 100644
--- a/lib/hipe/test/hipe_SUITE.erl
+++ b/lib/hipe/test/hipe_SUITE.erl
@@ -16,7 +16,11 @@
 %%
 -module(hipe_SUITE).
 
--compile([export_all]).
+-export([all/0, groups/0,
+	 init_per_suite/1, end_per_suite/1,
+	 init_per_group/2, end_per_group/2,
+	 app/0, app/1, appup/0, appup/1]).
+
 -include_lib("common_test/include/ct.hrl").
 
 all() ->
diff --git a/lib/hipe/test/hipe_testsuite_driver.erl b/lib/hipe/test/hipe_testsuite_driver.erl
index 03ec7adfd0..88576775ca 100644
--- a/lib/hipe/test/hipe_testsuite_driver.erl
+++ b/lib/hipe/test/hipe_testsuite_driver.erl
@@ -99,7 +99,7 @@ write_suite(Suite) ->
 write_header(#suite{suitename = SuiteName, outputfile = OutputFile,
 		    testcases = TestCases}) ->
     Exports = format_export(TestCases),
-    TimeLimit = 3,	%% with 1 or 2 it fails on some slow machines...
+    TimeLimit = 6,	%% with 1, 2, or 3 it fails on some slow machines...
     io:format(OutputFile,
 	      "%% ATTENTION!\n"
 	      "%% This is an automatically generated file. Do not edit.\n\n"
@@ -168,6 +168,10 @@ run(TestCase, Dir, _OutDir) ->
     HiPEOpts = try TestCase:hipe_options() catch error:undef -> [] end,
     {ok, TestCase} = hipe:c(TestCase, HiPEOpts),
     ok = TestCase:test(),
+    {ok, TestCase} = hipe:c(TestCase, [o1|HiPEOpts]),
+    ok = TestCase:test(),
+    {ok, TestCase} = hipe:c(TestCase, [o0|HiPEOpts]),
+    ok = TestCase:test(),
     ToLLVM = try TestCase:to_llvm() catch error:undef -> true end,
     case ToLLVM andalso hipe:llvm_support_available() of
 	true ->
diff --git a/lib/hipe/test/maps_SUITE_data/maps_redundant_branch_is_key.erl b/lib/hipe/test/maps_SUITE_data/maps_redundant_branch_is_key.erl
new file mode 100644
index 0000000000..17c3acd6af
--- /dev/null
+++ b/lib/hipe/test/maps_SUITE_data/maps_redundant_branch_is_key.erl
@@ -0,0 +1,14 @@
+-module(maps_redundant_branch_is_key).
+-export([test/0]).
+
+test() ->
+    ok = thingy(#{a => 1}),
+    ok = thingy(#{a => 2}),
+    ok.
+
+thingy(Map) ->
+    try
+	#{a := _} = Map,
+	ok
+    catch _ -> error
+    end.
diff --git a/lib/hipe/test/maps_SUITE_data/maps_warn_pair_key_overloaded.erl b/lib/hipe/test/maps_SUITE_data/maps_warn_pair_key_overloaded.erl
index 76b2a91f94..cce91530f4 100644
--- a/lib/hipe/test/maps_SUITE_data/maps_warn_pair_key_overloaded.erl
+++ b/lib/hipe/test/maps_SUITE_data/maps_warn_pair_key_overloaded.erl
@@ -14,7 +14,6 @@ test() ->
 	    "hi2" => lists:subtract([1,2],[1]),
 	    "hi3" => +3,
 	    "hi1" => erlang:min(1,2),
-	    "hi1" => erlang:hash({1,2},35),
 	    "hi1" => erlang:phash({1,2},33),
 	    "hi1" => erlang:phash2({1,2},34),
 	    "hi1" => erlang:integer_to_binary(1337),
diff --git a/lib/hipe/test/opt_verify_SUITE.erl b/lib/hipe/test/opt_verify_SUITE.erl
index 61952e81d7..86083fa02b 100644
--- a/lib/hipe/test/opt_verify_SUITE.erl
+++ b/lib/hipe/test/opt_verify_SUITE.erl
@@ -1,6 +1,9 @@
 -module(opt_verify_SUITE).
 
--compile([export_all]).
+-export([all/0, groups/0,
+	 init_per_suite/1, end_per_suite/1,
+	 init_per_group/2, end_per_group/2,
+	 call_elim/0, call_elim/1]).
 
 all() ->
     [call_elim].
@@ -23,23 +26,6 @@ init_per_group(_GroupName, Config) ->
 end_per_group(_GroupName, Config) ->
     Config.
 
-call_elim_test_file(Config, FileName, Option) ->
-    PrivDir = test_server:lookup_config(priv_dir, Config),
-    TempOut = test_server:temp_name(filename:join(PrivDir, "call_elim_out")),
-    {ok, TestCase} = compile:file(FileName),
-    {ok, TestCase} = hipe:c(TestCase, [Option, {pp_range_icode, {file, TempOut}}]),
-    {ok, Icode} = file:read_file(TempOut),
-    ok = file:delete(TempOut),
-    Icode.
-
-substring_count(Icode, Substring) ->
-    substring_count(Icode, Substring, 0).
-substring_count(Icode, Substring, N) ->
-    case string:str(Icode, Substring) of
-        0 -> N;
-        I -> substring_count(lists:nthtail(I, Icode), Substring, N+1)
-    end.
-
 call_elim() ->
     [{doc, "Test that the call elimination optimization pass is ok"}].
 call_elim(Config) ->
@@ -60,3 +46,20 @@ call_elim(Config) ->
     Icode6 = call_elim_test_file(Config, F3, no_icode_call_elim),
     3 = substring_count(binary:bin_to_list(Icode6), "is_key"),
     ok.
+
+call_elim_test_file(Config, FileName, Option) ->
+    PrivDir = test_server:lookup_config(priv_dir, Config),
+    TempOut = test_server:temp_name(filename:join(PrivDir, "call_elim_out")),
+    {ok, TestCase} = compile:file(FileName),
+    {ok, TestCase} = hipe:c(TestCase, [Option, {pp_range_icode, {file, TempOut}}]),
+    {ok, Icode} = file:read_file(TempOut),
+    ok = file:delete(TempOut),
+    Icode.
+
+substring_count(Icode, Substring) ->
+    substring_count(Icode, Substring, 0).
+substring_count(Icode, Substring, N) ->
+    case string:str(Icode, Substring) of
+        0 -> N;
+        I -> substring_count(lists:nthtail(I, Icode), Substring, N+1)
+    end.