test: Ignore cores in debug build for crash dumps

3 files changed, 184 insertions, 2 deletions

diff --git a/lib/kernel/test/Makefile b/lib/kernel/test/Makefile
index 8eca37029d..7fd3afe93c 100644
--- a/lib/kernel/test/Makefile
+++ b/lib/kernel/test/Makefile
@@ -73,6 +73,7 @@ MODULES= \
 	seq_trace_SUITE \
 	wrap_log_reader_SUITE \
 	cleanup \
+	ignore_cores \
 	zlib_SUITE \
 	loose_node \
 	sendfile_SUITE
diff --git a/lib/kernel/test/heart_SUITE.erl b/lib/kernel/test/heart_SUITE.erl
index 2ec3b7c297..320b23bea1 100644
--- a/lib/kernel/test/heart_SUITE.erl
+++ b/lib/kernel/test/heart_SUITE.erl
@@ -83,10 +83,10 @@ init_per_suite(Config) when is_list(Config) ->
 	{win32, windows} ->
 	    {skipped, "No use to run on Windows 95/98"};
 	_ ->
-	    Config
+	    ignore_cores:init(Config)
     end.
 end_per_suite(Config) when is_list(Config) ->
-    Config.
+    ignore_cores:fini(Config).
 
 
 start_check(Type, Name) ->
@@ -188,8 +188,20 @@ reboot(Config) when is_list(Config) ->
 %%   Check that a node is up and running after a crash.
 %%   This test exhausts the atom table on the remote node.
 %%   ERL_CRASH_DUMP_SECONDS=0 will force beam not to dump an erl_crash.dump.
+%% May currently dump core in beam debug build due to lock-order violation
+%% This should be removed when a non-lockad information retriever is implemented
+%% for crash dumps
 node_start_immediately_after_crash(suite) -> {req, [{time, 10}]};
 node_start_immediately_after_crash(Config) when is_list(Config) ->
+    Config2 = ignore_cores:setup(?MODULE, node_start_immediately_after_crash, Config, true),
+    try
+	node_start_immediately_after_crash_test(Config2)
+    after
+	ignore_cores:restore(Config2)
+    end.
+ 
+
+node_start_immediately_after_crash_test(Config) when is_list(Config) ->
     {ok, Node} = start_check(loose, heart_test_imm, [{"ERL_CRASH_DUMP_SECONDS", "0"}]),
 
     ok = rpc:call(Node, heart, set_cmd,
@@ -228,8 +240,19 @@ node_start_immediately_after_crash(Config) when is_list(Config) ->
 %%   This test exhausts the atom table on the remote node.
 %%   ERL_CRASH_DUMP_SECONDS=10 will force beam
 %%   to only dump an erl_crash.dump for 10 seconds.
+%% May currently dump core in beam debug build due to lock-order violation
+%% This should be removed when a non-lockad information retriever is implemented
+%% for crash dumps
 node_start_soon_after_crash(suite) -> {req, [{time, 10}]};
 node_start_soon_after_crash(Config) when is_list(Config) ->
+    Config2 = ignore_cores:setup(?MODULE, node_start_soon_after_crash, Config, true),
+    try
+	node_start_soon_after_crash_test(Config2)
+    after
+	ignore_cores:restore(Config2)
+    end.
+ 
+node_start_soon_after_crash_test(Config) when is_list(Config) ->
     {ok, Node} = start_check(loose, heart_test_soon, [{"ERL_CRASH_DUMP_SECONDS", "10"}]),
 
     ok = rpc:call(Node, heart, set_cmd,
diff --git a/lib/kernel/test/ignore_cores.erl b/lib/kernel/test/ignore_cores.erl
new file mode 100644
index 0000000000..8b1ac0fe6c
--- /dev/null
+++ b/lib/kernel/test/ignore_cores.erl
@@ -0,0 +1,158 @@
+%%
+%% %CopyrightBegin%
+%%
+%% Copyright Ericsson AB 2008-2010. All Rights Reserved.
+%%
+%% The contents of this file are subject to the Erlang Public License,
+%% Version 1.1, (the "License"); you may not use this file except in
+%% compliance with the License. You should have received a copy of the
+%% Erlang Public License along with this software. If not, it can be
+%% retrieved online at http://www.erlang.org/.
+%%
+%% Software distributed under the License is distributed on an "AS IS"
+%% basis, WITHOUT WARRANTY OF ANY KIND, either express or implied. See
+%% the License for the specific language governing rights and limitations
+%% under the License.
+%%
+%% %CopyrightEnd%
+%%
+
+%%%-------------------------------------------------------------------
+%%% File    : ignore_cores.erl
+%%% Author  : Rickard Green <[email protected]>
+%%% Description : 
+%%%
+%%% Created : 11 Feb 2008 by Rickard Green <[email protected]>
+%%%-------------------------------------------------------------------
+
+-module(ignore_cores).
+
+-include_lib("test_server/include/test_server.hrl").
+
+-export([init/1, fini/1, setup/3, setup/4, restore/1, dir/1]).
+
+-record(ignore_cores, {org_cwd,
+		       org_path,
+		       org_pwd_env,
+		       ign_dir = false,
+		       cores_dir = false}).
+
+%%
+%% Takes a testcase config
+%%
+
+init(Config) ->
+    {ok, OrgCWD} = file:get_cwd(),
+    [{ignore_cores,
+      #ignore_cores{org_cwd = OrgCWD,
+		    org_path = code:get_path(),
+		    org_pwd_env = os:getenv("PWD")}}
+     | lists:keydelete(ignore_cores, 1, Config)].
+    
+fini(Config) ->
+    #ignore_cores{org_cwd = OrgCWD,
+		  org_path = OrgPath,
+		  org_pwd_env = OrgPWD} = ?config(ignore_cores, Config),
+    ok = file:set_cwd(OrgCWD),
+    true = code:set_path(OrgPath),
+    case OrgPWD of
+	false -> ok;
+	_ -> true = os:putenv("PWD", OrgPWD)
+    end,
+    lists:keydelete(ignore_cores, 1, Config).
+
+setup(Suite, Testcase, Config) ->
+    setup(Suite, Testcase, Config, false).
+
+setup(Suite, Testcase, Config, SetCwd) when is_atom(Suite), 
+                                            is_atom(Testcase),
+                                            is_list(Config) ->
+    #ignore_cores{org_cwd = OrgCWD,
+		  org_path = OrgPath,
+		  org_pwd_env = OrgPWD} = ?config(ignore_cores, Config),
+    Path = lists:map(fun (".") -> OrgCWD; (Dir) -> Dir end, OrgPath),
+    true = code:set_path(Path),
+    PrivDir = ?config(priv_dir, Config),
+    IgnDir = filename:join([PrivDir,
+			 atom_to_list(Suite)
+			 ++ "_"
+			 ++ atom_to_list(Testcase)
+			 ++ "_wd"]),
+    ok = file:make_dir(IgnDir),
+    case SetCwd of
+	false ->
+	    ok;
+	_ ->
+	    ok = file:set_cwd(IgnDir),
+	    OrgPWD = case os:getenv("PWD") of
+			 false -> false;
+			 PWD ->
+			     os:putenv("PWD", IgnDir),
+			     PWD
+		     end
+    end,
+    ok = file:write_file(filename:join([IgnDir, "ignore_core_files"]), <<>>),
+    %% cores are dumped in /cores on MacOS X
+    CoresDir = case {?t:os_type(), filelib:is_dir("/cores")} of
+		   {{unix,darwin}, true} ->
+		       filelib:fold_files("/cores",
+					  "^core.*$",
+					  false,
+					  fun (C,Cs) -> [C|Cs] end,
+					  []);
+		   _ ->
+		       false
+	       end,
+    lists:keyreplace(ignore_cores,
+		     1,
+		     Config,
+		     {ignore_cores,
+		      #ignore_cores{org_cwd = OrgCWD,
+				    org_path = OrgPath,
+				    org_pwd_env = OrgPWD,
+				    ign_dir = IgnDir,
+				    cores_dir = CoresDir}}).
+
+restore(Config) ->
+    #ignore_cores{org_cwd = OrgCWD,
+		  org_path = OrgPath,
+		  org_pwd_env = OrgPWD,
+		  ign_dir = IgnDir,
+		  cores_dir = CoresDir} = ?config(ignore_cores, Config),
+    try
+	case CoresDir of
+	    false ->
+		ok;
+	    _ ->
+		%% Move cores dumped by these testcases in /cores
+		%% to cwd.
+		lists:foreach(fun (C) ->
+				      case lists:member(C, CoresDir) of
+					  true -> ok;
+					  _ ->
+					      Dst = filename:join(
+						      [IgnDir,
+						       filename:basename(C)]),
+					      {ok, _} = file:copy(C, Dst),
+					      file:delete(C)
+				      end
+			      end,
+			      filelib:fold_files("/cores",
+						 "^core.*$",
+						 false,
+						 fun (C,Cs) -> [C|Cs] end,
+						 []))
+	end
+    after
+	catch file:set_cwd(OrgCWD),
+	catch code:set_path(OrgPath),
+	case OrgPWD of
+	    false -> ok;
+	    _ -> catch os:putenv("PWD", OrgPWD)
+	end
+    end.
+
+
+dir(Config) ->
+    #ignore_cores{ign_dir = Dir} = ?config(ignore_cores, Config),
+    Dir.