ose: Add module that allows interaction with any OSE process

The interface of this module is made to be as generic as possible
in order for other IPC mechanisms to mimic it and allow porting of
code between different os:es.

6 files changed, 1251 insertions, 6 deletions

diff --git a/lib/kernel/doc/src/Makefile b/lib/kernel/doc/src/Makefile
index de3ca1e176..7f8023aba4 100644
--- a/lib/kernel/doc/src/Makefile
+++ b/lib/kernel/doc/src/Makefile
@@ -32,6 +32,12 @@ APPLICATION=kernel
 RELSYSDIR = $(RELEASE_PATH)/lib/$(APPLICATION)-$(VSN)
 
 # ----------------------------------------------------
+# Help application directory specification
+# ----------------------------------------------------
+EDOC_DIR = $(ERL_TOP)/lib/edoc
+SYNTAX_TOOLS_DIR = $(ERL_TOP)/lib/syntax_tools
+
+# ----------------------------------------------------
 # Target Specs
 # ----------------------------------------------------
 XML_APPLICATION_FILES = ref_man.xml
@@ -65,6 +71,12 @@ XML_REF3_FILES = application.xml \
 	user.xml \
 	zlib_stub.xml
 
+ifeq ($(findstring ose,$(TARGET)),ose)
+XML_EDOC_FILES = ose.xml
+else
+XML_EDOC_FILES =
+endif
+
 XML_REF4_FILES = app.xml config.xml
 
 XML_REF6_FILES = kernel_app.xml
@@ -76,8 +88,8 @@ BOOK_FILES = book.xml
 
 XML_FILES = \
 	$(BOOK_FILES) $(XML_CHAPTER_FILES) \
-	$(XML_PART_FILES) $(XML_REF3_FILES) $(XML_REF4_FILES) \
-	 $(XML_REF6_FILES) $(XML_APPLICATION_FILES)
+	$(XML_PART_FILES) $(XML_REF3_FILES) $(XML_EDOC_FILES)\
+	$(XML_REF4_FILES) $(XML_REF6_FILES) $(XML_APPLICATION_FILES)
 
 # ----------------------------------------------------
 
@@ -103,7 +115,7 @@ TOP_SPECS_FILE = specs.xml
 # ----------------------------------------------------
 XML_FLAGS += 
 
-SPECS_ESRC = ../../src
+SRC_DIR = ../../src
 
 SPECS_FLAGS = -I../../include
 
@@ -148,6 +160,15 @@ $(SPECDIR)/specs_zlib_stub.xml:
 	escript $(SPECS_EXTRACTOR) $(SPECS_FLAGS) \
                 -o$(dir $@) -module zlib_stub
 
+ose.xml: $(SRC_DIR)/ose.erl
+	escript $(DOCGEN)/priv/bin/xml_from_edoc.escript $(SRC_DIR)/$(@:%.xml=%.erl)
+ref_man.xml: ref_man.xml.src
+ifeq ($(findstring ose,$(TARGET)),ose)
+	sed -e 's:\(os.xml"/>\):\1\n<xi\:include href="ose.xml"/>:' $< > $@
+else
+	cp $< $@
+endif
+
 # ----------------------------------------------------
 # Release Target
 # ---------------------------------------------------- 
diff --git a/lib/kernel/doc/src/ref_man.xml b/lib/kernel/doc/src/ref_man.xml.src
index c1b9eac9d7..bd25d1e78d 100644
--- a/lib/kernel/doc/src/ref_man.xml
+++ b/lib/kernel/doc/src/ref_man.xml.src
@@ -13,12 +13,12 @@
       compliance with the License. You should have received a copy of the
       Erlang Public License along with this software. If not, it can be
       retrieved online at http://www.erlang.org/.
-    
+
       Software distributed under the License is distributed on an "AS IS"
       basis, WITHOUT WARRANTY OF ANY KIND, either express or implied. See
       the License for the specific language governing rights and limitations
       under the License.
-    
+
     </legalnotice>
 
     <title>Kernel Reference Manual</title>
@@ -65,4 +65,3 @@
   <xi:include href="app.xml"/>
   <xi:include href="config.xml"/>
 </application>
-
diff --git a/lib/kernel/src/Makefile b/lib/kernel/src/Makefile
index cb3c0a49f4..5379006784 100644
--- a/lib/kernel/src/Makefile
+++ b/lib/kernel/src/Makefile
@@ -117,6 +117,10 @@ MODULES = \
 	user_sup \
 	wrap_log_reader
 
+ifeq ($(findstring ose,$(TARGET)),ose)
+MODULES+=ose
+endif
+
 HRL_FILES= ../include/file.hrl ../include/inet.hrl ../include/inet_sctp.hrl \
 	../include/dist.hrl ../include/dist_util.hrl \
 	../include/net_address.hrl 
diff --git a/lib/kernel/src/ose.erl b/lib/kernel/src/ose.erl
new file mode 100644
index 0000000000..ff7147233f
--- /dev/null
+++ b/lib/kernel/src/ose.erl
@@ -0,0 +1,452 @@
+%%
+%% %CopyrightBegin%
+%%
+%% Copyright Ericsson AB 2013. All Rights Reserved.
+%%
+%% The contents of this file are subject to the Erlang Public License,
+%% Version 1.1, (the "License"); you may not use this file except in
+%% compliance with the License. You should have received a copy of the
+%% Erlang Public License along with this software. If not, it can be
+%% retrieved online at http://www.erlang.org/.
+%%
+%% Software distributed under the License is distributed on an "AS IS"
+%% basis, WITHOUT WARRANTY OF ANY KIND, either express or implied. See
+%% the License for the specific language governing rights and limitations
+%% under the License.
+%%
+%% %CopyrightEnd%
+%%
+%% @doc Interface module for OSE messaging and process monitoring from Erlang
+%%
+%% For each mailbox created through {@link open/1} a OSE phantom process with
+%% that name is started. Since phantom processes are used the memory footprint
+%% of each mailbox is quite small.
+%%
+%% To receive messages you first have to subscribe to the specific message
+%% numbers that you are interested in with {@link listen/2}. The messages
+%% will be sent to the Erlang process that created the mailbox.
+%%
+%% @end
+%%
+-module(ose).
+
+%%==============================================================================
+%% Exported API
+%%==============================================================================
+-export([open/1,
+         close/1,
+         get_id/1,
+         get_name/2,
+         hunt/2,
+         dehunt/2,
+         attach/2,
+         detach/2,
+         send/4,
+         send/5,
+	 listen/2
+	]).
+
+%%==============================================================================
+%% Types
+%%==============================================================================
+-opaque mailbox() :: port().
+%% Mailbox handle.  Implemented as an erlang port.
+
+-opaque mailbox_id() :: integer().
+%% Mailbox ID, this is the same as the process id of an OSE process.
+%% An integer.
+
+-type message_number() :: 0..4294967295.
+%% OSE Signal number
+
+-opaque hunt_ref() :: {mailbox(),integer()}.
+%% Reference from a hunt request.  This term will be included
+%% in a successful hunt response.
+
+-opaque attach_ref() :: {mailbox(),integer()}.
+%% Reference from an attach request.  This term will be included
+%% in the term returned when the attached mailbox disappears.
+
+-export_type([mailbox_id/0,
+	      message_number/0,
+	      mailbox/0,
+	      hunt_ref/0,
+	      attach_ref/0]).
+
+%%==============================================================================
+%% Defines
+%%==============================================================================
+-define(DRIVER_NAME, "ose_signal_drv").
+-define(GET_SPID, 1).
+-define(GET_NAME, 2).
+-define(HUNT, 100).
+-define(DEHUNT, 101).
+-define(ATTACH, 102).
+-define(DETACH, 103).
+-define(SEND, 104).
+-define(SEND_W_S, 105).
+-define(LISTEN, 106).
+-define(OPEN, 200).
+
+-define(INT_32BIT(Int),(is_integer(Int) andalso (Int >= 0) andalso (Int < (1 bsl 32)))).
+
+%%==============================================================================
+%% API functions
+%%==============================================================================
+
+%%------------------------------------------------------------------------------
+%% @doc Create a mailbox with the given name and return a port that handles
+%% the mailbox.
+%%
+%% An OSE phantom process with the given name will be created that will send any
+%% messages sent through this mailbox. Any messages sent to the new OSE process
+%% will automatically be converted to an Erlang message and sent to the Erlang
+%% process that calls this function. See {@link listen/2} for details about the
+%% format of the message sent.
+%%
+%% The caller gets linked to the created mailbox.
+%%
+%% raises: `badarg' | `system_limit'
+%%
+%% @see liten/2
+%% @end
+%%------------------------------------------------------------------------------
+-spec open(Name) -> Port when
+      Name :: iodata(),
+      Port :: mailbox().
+open(Name) ->
+    try open_port({spawn_driver,?DRIVER_NAME}, [binary]) of
+	Port ->
+	    try port_command(Port,[?OPEN,Name]) of
+		true ->
+		    receive
+			{ose_drv_reply,Port,{error,Error}} ->
+			    close(Port),
+			    erlang:error(Error,[Name]);
+			{ose_drv_reply,Port,ok} ->
+			    Port
+		    end
+	    catch
+		error:badarg  -> close(Port),erlang:error(badarg,[Name])
+	    end
+    catch
+	error:badarg  -> erlang:error(badarg,[Name])
+    end.
+
+%%------------------------------------------------------------------------------
+%% @doc Close a mailbox
+%%
+%% This kills the OSE phantom process associated with this mailbox.
+%%
+%% Will also consume any ``{'EXIT',Port,_}'' message from the port that comes
+%% due to the port closing when the calling process traps exits.
+%%
+%% raises: `badarg'
+%% @end
+%%------------------------------------------------------------------------------
+-spec close(Port) -> ok when
+      Port :: mailbox().
+close(Port) when is_port(Port) ->
+    %% Copied from prim_inet
+    case erlang:process_info(self(), trap_exit) of
+	{trap_exit,true} ->
+	    link(Port),
+	    catch erlang:port_close(Port),
+	    receive {'EXIT',Port,_} -> ok end;
+	{trap_exit,false} ->
+	    catch erlang:port_close(Port),
+	    ok
+    end;
+close(NotPort) ->
+    erlang:error(badarg,[NotPort]).
+
+%%------------------------------------------------------------------------------
+%% @doc Get the mailbox id for the given port.
+%%
+%% The mailbox id is the same as the OSE process id of the OSE phantom process
+%% that this mailbox represents.
+%%
+%% raises: `badarg'
+%% @end
+%%------------------------------------------------------------------------------
+-spec get_id(Port) -> Pid when
+      Port :: mailbox(),
+      Pid :: mailbox_id().
+get_id(Port) ->
+    try port_control(Port, ?GET_SPID, <<>>) of
+	<<Spid:32>> -> Spid
+    catch error:_Error ->
+	    erlang:error(badarg,[Port])
+    end.
+
+%%------------------------------------------------------------------------------
+%% @doc Get the mailbox name for the given mailbox id.
+%%
+%% The mailbox name is the name of the OSE process with process id Pid.
+%%
+%% This call will fail with badarg if the underlying system does not support
+%% getting the name from a process id.
+%%
+%% raises: `badarg'
+%% @end
+%%------------------------------------------------------------------------------
+-spec get_name(Port, Pid) -> Name | undefined when
+      Port :: mailbox(),
+      Pid :: mailbox_id(),
+      Name :: binary().
+get_name(Port, Pid) when ?INT_32BIT(Pid) ->
+    try port_control(Port, ?GET_NAME, <<Pid:32>>) of
+	[] -> undefined;
+	Res -> Res
+    catch error:_Error ->
+	    erlang:error(badarg,[Port,Pid])
+    end;
+get_name(Port, Pid) ->
+    erlang:error(badarg,[Port,Pid]).
+
+
+%%------------------------------------------------------------------------------
+%% @doc Hunt for OSE process by name.
+%%
+%% Will send `{mailbox_up, Port, Ref, MboxId}'
+%% to the calling process when the OSE process becomes available.
+%%
+%% Returns a reference term that can be used to cancel the hunt
+%% using {@link dehunt/2}.
+%%
+%% raises: `badarg'
+%%
+%% @end
+%%------------------------------------------------------------------------------
+-spec hunt(Port, HuntPath) -> Ref when
+      Port :: mailbox(),
+      HuntPath :: iodata(),
+      Ref :: hunt_ref().
+hunt(Port, HuntPath) ->
+    try port_command(Port, [?HUNT,HuntPath]) of
+	true ->
+	    receive
+		{ose_drv_reply,Port,{error,Error}} ->
+		    erlang:error(Error,[Port,HuntPath]);
+		{ose_drv_reply,Port,Ref} ->
+		    Ref
+	    end
+    catch error:_Error ->
+	    erlang:error(badarg,[Port,HuntPath])
+    end.
+
+%%------------------------------------------------------------------------------
+%% @doc Stop hunting for OSE process.
+%%
+%% If a message for this hunt has been sent but not received
+%% by the calling process, it is removed from the message queue.
+%% Note that this only works if the same process that did
+%% the hunt does the dehunt.
+%%
+%% raises: `badarg'
+%%
+%% @see hunt/2
+%% @end
+%%------------------------------------------------------------------------------
+-spec dehunt(Port, Ref) -> ok when
+      Port :: mailbox(),
+      Ref :: hunt_ref().
+dehunt(Port, {Port,Ref}) when ?INT_32BIT(Ref) ->
+    try port_command(Port, <<?DEHUNT:8, Ref:32>>) of
+	true ->
+	    receive
+		{ose_drv_reply,Port,{error,enoent}} ->
+		    %% enoent could mean that it is in the message queue
+		    receive
+			{mailbox_up, Port, {Port,Ref}, _} ->
+			    ok
+		    after 0 ->
+			    ok
+		    end;
+		{ose_drv_reply,Port,ok} ->
+		    ok
+	    end
+    catch error:_Error ->
+	    erlang:error(badarg,[Port,{Port,Ref}])
+    end;
+dehunt(Port,Ref) ->
+    erlang:error(badarg,[Port,Ref]).
+
+%%------------------------------------------------------------------------------
+%% @doc Attach to an OSE process.
+%%
+%% Will send `{mailbox_down, Port, Ref, MboxId}'
+%% to the calling process if the OSE process exits.
+%%
+%% Returns a reference that can be used to cancel the attachment
+%% using {@link detach/2}.
+%%
+%% raises: `badarg' | `enomem'
+%%
+%% @end
+%%------------------------------------------------------------------------------
+-spec attach(Port,Pid) -> Ref when
+      Port :: mailbox(),
+      Pid :: mailbox_id(),
+      Ref :: attach_ref().
+attach(Port, Spid) when ?INT_32BIT(Spid) ->
+    try port_command(Port, <<?ATTACH:8, Spid:32>>) of
+	true ->
+	    receive
+		{ose_drv_reply,Port,{error,Error}} ->
+		    erlang:error(Error,[Port,Spid]);
+		{ose_drv_reply,Port,Ref} ->
+		    Ref
+	    end
+    catch error:_Error ->
+	    erlang:error(badarg,[Port,Spid])
+    end;
+attach(Port,Spid) ->
+    erlang:error(badarg,[Port,Spid]).
+
+
+%%------------------------------------------------------------------------------
+%% @doc Remove attachment to an OSE process.
+%%
+%% If a message for this monitor has been sent but not received
+%% by the calling process, it is removed from the message queue.
+%% Note that this only works of the same process
+%% that did the attach does the detach.
+%%
+%% raises: `badarg'
+%%
+%% @see attach/2
+%% @end
+%%------------------------------------------------------------------------------
+-spec detach(Port,Ref) -> ok when
+      Port :: mailbox(),
+      Ref :: attach_ref().
+detach(Port, {Port,Ref} ) when ?INT_32BIT(Ref) ->
+    try port_command(Port, <<?DETACH:8, Ref:32>>) of
+	true ->
+	    receive
+		{ose_drv_reply,Port,{error,enoent}} ->
+		    %% enoent could mean that it is in the message queue
+		    receive
+			{mailbox_down,Port,{Port,Ref},_} ->
+			    ok
+		    after 0 ->
+			    ok
+		    end;
+		{ose_drv_reply,Port,ok} ->
+		    ok
+	    end
+    catch error:_Error ->
+	    erlang:error(badarg,[Port,{Port,Ref}])
+    end;
+detach(Port,Ref) ->
+    erlang:error(badarg,[Port,Ref]).
+
+%%------------------------------------------------------------------------------
+%% @doc Send an OSE message.
+%%
+%% The message is sent from the OSE process' own ID that is: `get_id(Port)'.
+%%
+%% raises: `badarg'
+%%
+%% @see send/5
+%% @end
+%%------------------------------------------------------------------------------
+-spec send(Port,Pid,SigNo,SigData) -> ok when
+      Port :: mailbox(),
+      Pid :: mailbox_id(),
+      SigNo :: message_number(),
+      SigData :: iodata().
+send(Port, Spid, SigNo, SigData) when ?INT_32BIT(Spid), ?INT_32BIT(SigNo) ->
+    try erlang:port_command(Port, [<<?SEND:8, Spid:32, SigNo:32>>, SigData]) of
+	true -> ok
+    catch error:_Error ->
+	    erlang:error(badarg,[Port,Spid,SigNo,SigData])
+    end;
+send(Port,Spid,SigNo,SigData) ->
+    erlang:error(badarg,[Port,Spid,SigNo,SigData]).
+
+
+%%------------------------------------------------------------------------------
+%% @doc Send an OSE message with different sender.
+%%
+%% As {@link send/4} but the sender will be `SenderPid'.
+%%
+%% raises: `badarg'
+%%
+%% @see send/4
+%% @end
+%%------------------------------------------------------------------------------
+-spec send(Port,Pid,SenderPid,SigNo,SigData) -> ok when
+      Port :: mailbox(),
+      Pid :: mailbox_id(),
+      SenderPid :: mailbox_id(),
+      SigNo :: message_number(),
+      SigData :: iodata().
+send(Port, Spid, SenderPid, SigNo, SigData)
+  when ?INT_32BIT(Spid), ?INT_32BIT(SenderPid), ?INT_32BIT(SigNo) ->
+    try erlang:port_command(Port, [<<?SEND_W_S:8, Spid:32, SenderPid:32,
+				     SigNo:32>>, SigData]) of
+	true -> ok
+    catch error:_Error ->
+	    erlang:error(badarg,[Port,Spid,SenderPid,SigNo,SigData])
+    end;
+send(Port,Spid,SenderPid,SigNo,SigData) ->
+    erlang:error(badarg,[Port,Spid,SenderPid,SigNo,SigData]).
+
+%%------------------------------------------------------------------------------
+%% @doc Start listening for specified OSE signal numbers.
+%%
+%% The mailbox will send `{message,Port,{FromMboxId,ToMboxId,MsgNo,MsgData}}'
+%% to the process that created the mailbox when an OSE message with any
+%% of the specified `SigNos' arrives.
+%%
+%% Repeated calls to listen will replace the current set of signal numbers to
+%% listen to. i.e
+%%
+%% ```1>ose:listen(MsgB,[1234,12345]).
+%%  ok
+%%  2> ose:listen(MsgB,[1234,123456]).
+%%  ok.'''
+%%
+%% The above will first listen for signals with numbers 1234 and 12345, and then
+%% replace that with only listening to 1234 and 123456.
+%%
+%% With the current implementation it is not possible to listen to all signal
+%% numbers.
+%%
+%% raises: `badarg' | `enomem'
+%%
+%% @end
+%%------------------------------------------------------------------------------
+-spec listen(Port, SigNos) -> ok when
+      Port :: mailbox(),
+      SigNos :: list(message_number()).
+listen(Port, SigNos) when is_list(SigNos) ->
+    USSigNos = lists:usort(SigNos),
+    BinSigNos = try
+		    << <<SigNo:32>> ||
+			SigNo <- USSigNos,
+			?INT_32BIT(SigNo) orelse erlang:error(badarg)
+		    >>
+		catch _:_ ->
+			erlang:error(badarg,[Port,SigNos])
+		end,
+    try port_command(Port, [?LISTEN, BinSigNos]) of
+	true ->
+	    receive
+		{ose_drv_reply,Port,{error,Error}} ->
+		    erlang:error(Error,[Port,SigNos]);
+		{ose_drv_reply,Port,Else} ->
+		    Else
+	    end
+    catch error:_Error ->
+	    erlang:error(badarg,[Port,SigNos])
+    end;
+listen(Port, SigNos) ->
+    erlang:error(badarg,[Port,SigNos]).
+
+
+%%%=============================================================================
+%%% Internal functions
+%%%=============================================================================
diff --git a/lib/kernel/test/Makefile b/lib/kernel/test/Makefile
index f1b8a105ed..ac28d1aae9 100644
--- a/lib/kernel/test/Makefile
+++ b/lib/kernel/test/Makefile
@@ -79,6 +79,10 @@ MODULES= \
 	loose_node \
 	sendfile_SUITE
 
+ifeq ($(findstring ose,$(TARGET)),ose)
+MODULES+=ose_SUITE
+endif
+
 APP_FILES = \
 	appinc.app \
 	appinc1.app \
diff --git a/lib/kernel/test/ose_SUITE.erl b/lib/kernel/test/ose_SUITE.erl
new file mode 100644
index 0000000000..7e81b19894
--- /dev/null
+++ b/lib/kernel/test/ose_SUITE.erl
@@ -0,0 +1,765 @@
+%%
+%% %CopyrightBegin%
+%%
+%% Copyright Ericsson AB 1998-2013. All Rights Reserved.
+%%
+%% The contents of this file are subject to the Erlang Public License,
+%% Version 1.1, (the "License"); you may not use this file except in
+%% compliance with the License. You should have received a copy of the
+%% Erlang Public License along with this software. If not, it can be
+%% retrieved online at http://www.erlang.org/.
+%%
+%% Software distributed under the License is distributed on an "AS IS"
+%% basis, WITHOUT WARRANTY OF ANY KIND, either express or implied. See
+%% the License for the specific language governing rights and limitations
+%% under the License.
+%%
+%% %CopyrightEnd%
+%%
+-module(ose_SUITE).
+
+%-compile(export_all).
+
+-export([all/0, suite/0,groups/0,init_per_suite/1, end_per_suite/1,
+	 init_per_group/2,end_per_group/2,init_per_testcase/2,
+	 end_per_testcase/2]).
+-export([
+	 basic/1,stress/1,multi_msg_numbers/1,multi_mailboxes/1,
+	 hunt/1,multi_hunt/1,dehunt/1,multi_dehunt/1,
+	 attach/1,multi_attach/1,detach/1,multi_detach/1,
+	 open_errors/1,close_errors/1,get_id_errors/1,get_name_errors/1,
+	 hunt_errors/1,dehunt_errors/1,attach_errors/1,detach_errors/1,
+	 send_errors/1,send_w_s_errors/1,listen_errors/1
+	]).
+
+-define(INTERFACE,ose).
+
+
+init_per_testcase(_Func, Config) ->
+    Config.
+end_per_testcase(_Func, _Config) ->
+    ok.
+
+suite() -> [{timeout,{30,seconds}}].
+
+all() ->
+    [
+     basic,stress,multi_msg_numbers,multi_mailboxes,
+     hunt,multi_hunt,dehunt,multi_dehunt,
+     attach,multi_attach,detach,multi_detach,
+
+     open_errors,close_errors,get_id_errors,get_name_errors,
+     hunt_errors,dehunt_errors,attach_errors,detach_errors,
+     send_errors,send_w_s_errors,listen_errors
+    ].
+
+groups() ->
+    [].
+
+init_per_suite(Config) ->
+    case os:type() of
+	{ose,_} ->
+	    Config;
+	_Else ->
+	    {skip,"Only run on OSE"}
+    end.
+
+end_per_suite(_Config) ->
+    ok.
+
+init_per_group(_GroupName, Config) ->
+    Config.
+
+end_per_group(_GroupName, Config) ->
+    Config.
+
+basic(_Config) ->
+
+    [P1,P2] = multi_open(2,[42]),
+    P1Id = ?INTERFACE:get_id(P1),
+    P2Id = ?INTERFACE:get_id(P2),
+
+    ok = ?INTERFACE:send(P2,P1Id,42,<<"ping">>),
+    receive
+	{message,P1,V1} ->
+	    {P2Id,P1Id,42,<<"ping">>} = V1,
+	    ?INTERFACE:send(P1,P2Id,42,<<"pong">>);
+	Else1 ->
+	    ct:fail({got_wrong_message,Else1})
+    end,
+
+    receive
+	{message,P2,V2} ->
+	    {P1Id,P2Id,42,<<"pong">>} = V2;
+	Else2 ->
+	    ct:fail({got_wrong_message,Else2})
+    end,
+
+    ?INTERFACE:close(P1),
+    ?INTERFACE:close(P2).
+
+%% Send 1000 messages and see if we can cope and that msg order is preserved
+stress(_Config) ->
+
+    Iterations = 1000,
+
+    [P1,P2] = multi_open(2,[42]),
+    P1Id = ?INTERFACE:get_id(P1),
+    P2Id = ?INTERFACE:get_id(P2),
+
+    spawn(fun() ->
+		  n(fun(N) ->
+			    Msg = [<<"ping">>|integer_to_list(N)],
+			    ?INTERFACE:send(P2,P1Id,42,Msg)
+		    end,Iterations)
+	  end),
+    timer:sleep(100),
+    n(fun(N) ->
+	      receive
+		  {message,P1,Value} ->
+		      Int = integer_to_binary(N),
+		      {P2Id,P1Id,42,<<"ping",Int/binary>>} = Value,
+		      ok;
+		  Else ->
+		      ct:fail({got_wrong_message,Else})
+	      end
+      end,Iterations),
+
+    ?INTERFACE:close(P1),
+    ?INTERFACE:close(P2).
+
+%% Listen to 1000 different message numbers and send some random messages
+multi_msg_numbers(_Config) ->
+
+    Iterations = 100,
+
+    [P1,P2] = multi_open(2,lists:seq(2000,3000)),
+    P1Id = ?INTERFACE:get_id(P1),
+
+    n(fun(_) ->
+	      Num = random:uniform(1000)+2000,
+	      ?INTERFACE:send(P2,P1Id,Num,<<"ping",(integer_to_binary(Num))/binary>>)
+      end,Iterations),
+
+    n(fun(_) ->
+	      receive
+		  {message,P1,{_,_,Id,<<"ping",Num/binary>>}} when Id > 2000;
+								   Id =< 3000 ->
+		      Id = binary_to_integer(Num),
+		      ok;
+		  Else ->
+		      ct:fail({got_wrong_message,Else})
+	      end
+      end,Iterations),
+
+    ?INTERFACE:close(P1),
+    ?INTERFACE:close(P2).
+
+
+%% Create 100 mailboxes and send messages to them
+multi_mailboxes(_Config) ->
+
+    Mailboxes = 100,
+
+    [P1|MBs] = multi_open(Mailboxes,[42]),
+
+    [?INTERFACE:send(P1,?INTERFACE:get_id(P),42,[<<"ping">>,?INTERFACE:get_name(P,?INTERFACE:get_id(P))]) || P <- MBs],
+
+    [receive
+	 {message,P,Value} ->
+	     Name = ?INTERFACE:get_name(P,?INTERFACE:get_id(P)),
+	     {_,_,42,<<"ping",Name/binary>>} = Value,
+	     ok
+     end || P <- MBs],
+
+    [?INTERFACE:close(P) || P <- [P1|MBs]],
+    ok.
+
+hunt(_Config) ->
+    [P1,P2] = multi_open(2,[]),
+
+    Ref = ?INTERFACE:hunt(P1,"p2"),
+    receive
+	{mailbox_up,P1,Ref,Pid} ->
+	    Pid = ?INTERFACE:get_id(P2),
+	    ?INTERFACE:close(P1),
+	    ?INTERFACE:close(P2);
+	Else ->
+	    ct:fail({got_wrong_message,Else,Ref})
+    end.
+
+multi_hunt(_Config) ->
+
+    Iterations = 100,
+
+    P = ?INTERFACE:open("p"),
+
+    Refs = [?INTERFACE:hunt(P,"p"++integer_to_list(N))|| N <- lists:seq(1,Iterations)],
+
+    Pids = [begin
+		Prt = ?INTERFACE:open("p"++integer_to_list(N)),
+		Pid = ?INTERFACE:get_id(Prt),
+		?INTERFACE:close(Prt),
+		Pid
+	    end || N <- lists:seq(1,Iterations)],
+
+    [receive
+	 {mailbox_up,P,Ref,Pid} ->
+	     ok
+     after 10 ->
+	     ct:fail({did_not_get,Pid,Ref})
+     end || {Pid,Ref} <- lists:zip(Pids,Refs)],
+    ?INTERFACE:close(P).
+
+
+dehunt(_Config)  ->
+    [P1] = multi_open(1,[]),
+    Ref = ?INTERFACE:hunt(P1,"p2"),
+    receive
+	_Else -> ct:fail({got,_Else})
+    after 1000 ->
+	    ok
+    end,
+    P2 = ?INTERFACE:open("p2"),
+
+    % Make sure any messages are sent
+    receive after 10 -> ok end,
+
+    ok = ?INTERFACE:dehunt(P1,Ref),
+
+    % Make sure no messages are received
+    receive
+	_Else2 -> ct:fail({got,_Else2})
+    after 1000 ->
+	    ?INTERFACE:close(P1),
+	    ?INTERFACE:close(P2)
+    end.
+
+%%%
+%%% This testcase basically:
+%%%  spawn 10 processes that in parallel
+%%%        adds some hunts for different OSE processes
+%%%        maybe create hunted OSE process
+%%%        dehunt half of the hunts
+%%%        create more hunts
+%%%        if not created create hunted OSE process
+%%%        veryify that all expected hunt messages are received
+%%%  verify that all processes exited correctly
+%%%
+%%% This complex test is done to make sure that the internal handling
+%%% of dehunt works as expected.
+%%%
+multi_dehunt(_Config) ->
+    [P1] = multi_open(1,[]),
+
+    Scenario =
+	fun(Iterations) ->
+
+	      Hunted = "p"++integer_to_list(Iterations),
+	      %% Start a couple of hunts
+	      Refs = [?INTERFACE:hunt(P1,Hunted) || _ <- lists:seq(1,Iterations)],
+
+	      %% We alternate if the process is opened before or after the dehunt
+	      P2O = if Iterations rem 2 == 0 ->
+			    ?INTERFACE:open(Hunted);
+		       true ->
+			    undefined
+		    end,
+
+	      %% Remove half of them
+	      {RemRefs,_} = lists:mapfoldl(fun(Ref,Acc) when Acc rem 2 == 0 ->
+						   ok = ?INTERFACE:dehunt(P1,Ref),
+						   {[],Acc+1};
+					      (Ref,Acc) ->
+						   {Ref,Acc+1}
+					   end,0,Refs),
+
+	      %% Add some new ones
+	      NewRefs = [?INTERFACE:hunt(P1,Hunted)
+			 || _ <- lists:seq(1,Iterations div 4)]
+		    ++ lists:flatten(RemRefs),
+
+	      P2 = if P2O == undefined ->
+			   ?INTERFACE:open(Hunted);
+		      true ->
+			   P2O
+		   end,
+	      P2Id = ?INTERFACE:get_id(P2),
+
+	      %% Receive all the expected ones
+	      lists:foreach(fun(Ref) ->
+				    receive
+					{mailbox_up,P1,Ref,P2Id} ->
+					    ok
+				    after 1000 ->
+					    io:format("Flush: ~p~n",[flush()]),
+					    io:format("~p~n",[{Iterations,{did_not_get, Ref}}]),
+					    ok = Ref
+				    end
+			    end,NewRefs),
+
+	      %% Check that no other have arrived
+	      receive
+		  _Else ->
+		      io:format("Flush: ~p~n",[flush()]),
+		      io:format("~p~n",[{Iterations,{got, _Else}}]),
+		      ok = _Else
+	      after 100 ->
+		      ok
+	      end,
+	      ?INTERFACE:close(P2)
+      end,
+
+    Self = self(),
+
+    n(fun(N) ->
+	      spawn(fun() -> Self !
+				 Scenario(N*25)
+		    end),
+	      ok
+      end,10),
+
+    n(fun(_N) ->
+	      receive ok -> ok
+	      after 60000 -> ct:fail(failed)
+	      end
+      end,10),
+    ?INTERFACE:close(P1).
+
+attach(_Config) ->
+    [P1,P2] = multi_open(2,[]),
+
+    P2Id = ?INTERFACE:get_id(P2),
+    Ref = ?INTERFACE:attach(P1,P2Id),
+    ?INTERFACE:close(P2),
+    receive
+	{mailbox_down,P1,Ref,P2Id} ->
+	    ?INTERFACE:close(P1);
+	_Else ->
+	    ct:fail({got,_Else, {P1,Ref,P2Id}})
+    after 1000 ->
+	    ct:fail({did_not_get,P1,Ref,P2Id})
+    end.
+
+multi_attach(_Config) ->
+
+    Iterations = 100,
+
+    [P1|Pids] = multi_open(Iterations,[]),
+
+    Refs = [{?INTERFACE:get_id(Pid),?INTERFACE:attach(P1,?INTERFACE:get_id(Pid))} || Pid <- Pids],
+
+    [?INTERFACE:close(Pid) || Pid <- Pids],
+
+    [receive
+	 {mailbox_down,P1,Ref,Pid} ->
+	     ok
+     after 10000 ->
+	     ct:fail({did_not_get,Pid,Ref})
+     end || {Pid,Ref} <- Refs],
+    ?INTERFACE:close(P1).
+
+detach(_Config)  ->
+    [P1,P2] = multi_open(2,[]),
+    P2Id = ?INTERFACE:get_id(P2),
+    Ref = ?INTERFACE:attach(P1,P2Id),
+    receive
+	_Else -> ct:fail({got,_Else})
+    after 100 ->
+	    ok
+    end,
+
+    ?INTERFACE:close(P2),
+
+    % Make sure any messages are sent
+    receive after 10 -> ok end,
+
+    ?INTERFACE:detach(P1,Ref),
+
+    % Make sure no messages are received
+    receive
+	_Else2 -> ct:fail({got,_Else2})
+    after 1000 ->
+	    ?INTERFACE:close(P1)
+    end.
+
+%%%
+%%% This testcase basically:
+%%%  spawn 10 processes that in parallel
+%%%        adds some attach for different OSE processes
+%%%        maybe close OSE process
+%%%        dehunt half of the hunts
+%%%        create more hunts
+%%%        if not closed close attached OSE process
+%%%        veryify that all expected attach messages are received
+%%%  verify that all processes exited correctly
+%%%
+%%% This complex test is done to make sure that the internal handling
+%%% of dehunt works as expected.
+%%%
+multi_detach(_Config) ->
+    [P1] = multi_open(1,[]),
+
+    Scenario =
+	fun(Iterations) ->
+
+	      Attached = ?INTERFACE:open("p"++integer_to_list(Iterations)),
+	      AttachedId = ?INTERFACE:get_id(Attached),
+	      %% Start a couple of attachs
+	      Refs = [?INTERFACE:attach(P1,AttachedId) || _ <- lists:seq(1,Iterations)],
+
+	      %% We alternate if the process is closed before or after the detach
+	      P2O = if Iterations rem 2 == 0 ->
+			    ?INTERFACE:close(Attached);
+		       true ->
+			    undefined
+		    end,
+
+	      %% Remove half of them
+	      {RemRefs,_} = lists:mapfoldl(fun(Ref,Acc) when Acc rem 2 == 0 ->
+						   ok = ?INTERFACE:detach(P1,Ref),
+						   {[],Acc+1};
+					      (Ref,Acc) ->
+						   {Ref,Acc+1}
+					   end,0,Refs),
+
+	      %% Add some new ones
+	      NewRefs = [?INTERFACE:attach(P1,AttachedId)
+			 || _ <- lists:seq(1,Iterations div 4)]
+		    ++ lists:flatten(RemRefs),
+
+	      if P2O == undefined ->
+		      ?INTERFACE:close(Attached);
+		 true ->
+		      P2O
+	      end,
+
+	      %% Receive all the expected ones
+	      lists:foreach(fun(Ref) ->
+				    receive
+					{mailbox_down,P1,Ref,AttachedId} ->
+					    ok
+				    after 1000 ->
+					    io:format("Flush: ~p~n",[flush()]),
+					    io:format("~p~n",[{Iterations,{did_not_get, Ref}}]),
+					    ok = Ref
+				    end
+			    end,NewRefs),
+
+	      %% Check that no other have arrived
+	      receive
+		  _Else ->
+		      io:format("Flush: ~p~n",[flush()]),
+		      io:format("~p~n",[{Iterations,{got, _Else}}]),
+		      ok = _Else
+	      after 100 ->
+		      ok
+	      end
+      end,
+
+    Self = self(),
+
+    n(fun(N) ->
+	      spawn(fun() -> Self !
+				 Scenario(N*5)
+		    end),
+	      ok
+      end,10),
+
+    n(fun(_N) ->
+	      receive ok -> ok
+	      after 60000 -> ct:fail(failed)
+	      end
+      end,10),
+    ?INTERFACE:close(P1).
+
+
+open_errors(_Config) ->
+    {'EXIT',{badarg,[{?INTERFACE,open,[inval],_}|_]}} =
+	(catch ?INTERFACE:open(inval)),
+    {'EXIT',{badarg,[{?INTERFACE,open,[["p"|1]],_}|_]}} =
+	(catch ?INTERFACE:open(["p"|1])),
+    {'EXIT',{badarg,[{?INTERFACE,open,[["p",1234]],_}|_]}} =
+	(catch ?INTERFACE:open(["p",1234])),
+
+    ok.
+
+close_errors(_Config) ->
+    {'EXIT',{badarg,[{?INTERFACE,close,[inval],_}|_]}} =
+	(catch ?INTERFACE:close(inval)),
+
+    P1 = ?INTERFACE:open("p1"),
+    ok = ?INTERFACE:close(P1),
+    ok = ?INTERFACE:close(P1).
+
+
+get_id_errors(_Config) ->
+    {'EXIT',{badarg,[{?INTERFACE,get_id,[inval],_}|_]}} =
+	(catch ?INTERFACE:get_id(inval)),
+
+    P1 = ?INTERFACE:open("p1"),
+    ok = ?INTERFACE:close(P1),
+    {'EXIT',{badarg,[{?INTERFACE,get_id,[P1],_}|_]}} =
+	(catch ?INTERFACE:get_id(P1)),
+
+    ok.
+
+get_name_errors(_Config) ->
+    P1 = ?INTERFACE:open("p1"),
+    {'EXIT',{badarg,[{?INTERFACE,get_name,[P1,inval],_}|_]}} =
+	(catch ?INTERFACE:get_name(P1,inval)),
+
+    undefined = ?INTERFACE:get_name(P1,1234),
+
+    P2 = ?INTERFACE:open("p2"),
+    P2Id = ?INTERFACE:get_id(P2),
+    ok = ?INTERFACE:close(P1),
+    {'EXIT',{badarg,[{?INTERFACE,get_name,[P1,P2Id],_}|_]}} =
+	(catch ?INTERFACE:get_name(P1,P2Id)),
+    ?INTERFACE:close(P2),
+
+    P3 = ?INTERFACE:open([255]),
+    <<255>> = ?INTERFACE:get_name(P3, ?INTERFACE:get_id(P3)),
+    ?INTERFACE:close(P3),
+
+    ok.
+
+hunt_errors(_Config) ->
+
+    {'EXIT',{badarg,[{?INTERFACE,hunt,[inval,"hello"],_}|_]}} =
+	(catch ?INTERFACE:hunt(inval,"hello")),
+
+    P1 = ?INTERFACE:open("p1"),
+    {'EXIT',{badarg,[{?INTERFACE,hunt,[P1,["hello",12345]],_}|_]}} =
+	(catch ?INTERFACE:hunt(P1,["hello",12345])),
+
+    P2 = ?INTERFACE:open(<<255>>),
+    P2Pid = ?INTERFACE:get_id(P2),
+    Ref = ?INTERFACE:hunt(P1,[255]),
+    receive
+	{mailbox_up,P1,Ref,P2Pid} ->
+	    ok;
+	Else ->
+	    ct:fail({got,Else,{mailbox_up,P1,Ref,P2Pid}})
+    after 150 ->
+	    ct:fail({did_not_get,{mailbox_up,P1,Ref,P2Pid}})
+    end,
+
+    ok = ?INTERFACE:close(P1),
+    ok = ?INTERFACE:close(P2),
+    {'EXIT',{badarg,[{?INTERFACE,hunt,[P1,["hello"]],_}|_]}} =
+	(catch ?INTERFACE:hunt(P1,["hello"])),
+
+    ok.
+
+dehunt_errors(_Config) ->
+    P1 = ?INTERFACE:open("p1"),
+    Ref = ?INTERFACE:hunt(P1,"p2"),
+
+    {'EXIT',{badarg,[{?INTERFACE,dehunt,[inval,Ref],_}|_]}} =
+	(catch ?INTERFACE:dehunt(inval,Ref)),
+
+    {'EXIT',{badarg,[{?INTERFACE,dehunt,[P1,inval],_}|_]}} =
+	(catch ?INTERFACE:dehunt(P1,inval)),
+
+    ok = ?INTERFACE:dehunt(P1,Ref),
+    ok = ?INTERFACE:dehunt(P1,Ref),
+
+    ok = ?INTERFACE:close(P1),
+
+    {'EXIT',{badarg,[{?INTERFACE,dehunt,[P1,Ref],_}|_]}} =
+	(catch ?INTERFACE:dehunt(P1,Ref)),
+
+    case ?INTERFACE of
+	ose -> ok;
+	_ ->
+	    P2 = ?INTERFACE:open("p2"),
+	    ok = ?INTERFACE:close(P2)
+    end,
+
+    receive
+	Else -> ct:fail({got,Else})
+    after 100 ->
+	    ok
+    end.
+
+attach_errors(_Config) ->
+    P1 = ?INTERFACE:open("p1"),
+    P2 = ?INTERFACE:open("p2"),
+    P2Id = ?INTERFACE:get_id(P2),
+
+    {'EXIT',{badarg,[{?INTERFACE,attach,[inval,P2Id],_}|_]}} =
+	(catch ?INTERFACE:attach(inval,P2Id)),
+
+    {'EXIT',{badarg,[{?INTERFACE,attach,[P1,[12345]],_}|_]}} =
+	(catch ?INTERFACE:attach(P1,[12345])),
+
+    ok = ?INTERFACE:close(P1),
+    ok = ?INTERFACE:close(P2),
+    {'EXIT',{badarg,[{?INTERFACE,attach,[P1,P2Id],_}|_]}} =
+	(catch ?INTERFACE:attach(P1,P2Id)),
+
+    ok.
+
+detach_errors(_Config) ->
+    P1 = ?INTERFACE:open("p1"),
+    P2 = ?INTERFACE:open("p2"),
+    P2Id = ?INTERFACE:get_id(P2),
+
+    Ref = ?INTERFACE:attach(P1,P2Id),
+
+    {'EXIT',{badarg,[{?INTERFACE,detach,[inval,Ref],_}|_]}} =
+	(catch ?INTERFACE:detach(inval,Ref)),
+
+    {'EXIT',{badarg,[{?INTERFACE,detach,[P1,inval],_}|_]}} =
+	(catch ?INTERFACE:detach(P1,inval)),
+
+    ok = ?INTERFACE:detach(P1,Ref),
+    ok = ?INTERFACE:detach(P1,Ref),
+
+    case ?INTERFACE of
+	ose -> ok;
+	_ ->
+	    ok = ?INTERFACE:close(P1)
+    end,
+
+    ok = ?INTERFACE:close(P2),
+    ok = ?INTERFACE:close(P1),
+
+    {'EXIT',{badarg,[{?INTERFACE,detach,[P1,Ref],_}|_]}} =
+	(catch ?INTERFACE:detach(P1,Ref)),
+
+    receive
+	Else -> ct:fail({got,Else})
+    after 100 ->
+	    ok
+    end.
+
+send_errors(_Config) ->
+    P1 = ?INTERFACE:open("p1"),
+    P2 = ?INTERFACE:open("p2"),
+    P2Id = ?INTERFACE:get_id(P2),
+
+    {'EXIT',{badarg,[{?INTERFACE,send,[inval,P2Id,42,"hello"],_}|_]}} =
+	(catch ?INTERFACE:send(inval,P2Id,42,"hello")),
+    {'EXIT',{badarg,[{?INTERFACE,send,[P1,inval,42,"hello"],_}|_]}} =
+	(catch ?INTERFACE:send(P1,inval,42,"hello")),
+    {'EXIT',{badarg,[{?INTERFACE,send,[P1,P2Id,inval,"hello"],_}|_]}} =
+	(catch ?INTERFACE:send(P1,P2Id,inval,"hello")),
+    {'EXIT',{badarg,[{?INTERFACE,send,[P1,P2Id,42,inval],_}|_]}} =
+	(catch ?INTERFACE:send(P1,P2Id,42,inval)),
+
+    ok = ?INTERFACE:close(P2),
+    ok = ?INTERFACE:send(P1,P2Id,42,"hello"),
+    ok = ?INTERFACE:close(P1),
+
+    {'EXIT',{badarg,[{?INTERFACE,send,[P1,P2Id,42,"hello"],_}|_]}} =
+	(catch ?INTERFACE:send(P1,P2Id,42,"hello")),
+
+    receive
+	Else -> ct:fail({got,Else})
+    after 100 ->
+	    ok
+    end.
+
+send_w_s_errors(_Config) ->
+    P1 = ?INTERFACE:open("p1"),
+    P1Id = ?INTERFACE:get_id(P1),
+    P2 = ?INTERFACE:open("p2"),
+    P2Id = ?INTERFACE:get_id(P2),
+    P3 = ?INTERFACE:open("p3"),
+    P3Id = ?INTERFACE:get_id(P3),
+
+    {'EXIT',{badarg,[{?INTERFACE,send,[inval,P2Id,P1Id,42,"hello"],_}|_]}} =
+	(catch ?INTERFACE:send(inval,P2Id,P1Id,42,"hello")),
+    {'EXIT',{badarg,[{?INTERFACE,send,[P2,-1,P1Id,42,"hello"],_}|_]}} =
+	(catch ?INTERFACE:send(P2,-1,P1Id,42,"hello")),
+    {'EXIT',{badarg,[{?INTERFACE,send,[P2,P2Id,1 bsl 32,42,"hello"],_}|_]}} =
+	(catch ?INTERFACE:send(P2,P2Id,1 bsl 32,42,"hello")),
+    {'EXIT',{badarg,[{?INTERFACE,send,[P2,P2Id,P1Id,inval,"hello"],_}|_]}} =
+	(catch ?INTERFACE:send(P2,P2Id,P1Id,inval,"hello")),
+    {'EXIT',{badarg,[{?INTERFACE,send,[P2,P2Id,P1Id,42,inval],_}|_]}} =
+	(catch ?INTERFACE:send(P2,P2Id,P1Id,42,inval)),
+
+    ok = ?INTERFACE:close(P3),
+    ok = ?INTERFACE:send(P2,P3Id,P1Id,42,"hello"),
+
+    ok = ?INTERFACE:close(P1),
+    ok = ?INTERFACE:send(P2,P2Id,P1Id,42,"hello"),
+    ok = ?INTERFACE:close(P2),
+
+    {'EXIT',{badarg,[{?INTERFACE,send,[P1,P2Id,P1Id,42,"hello"],_}|_]}} =
+	(catch ?INTERFACE:send(P1,P2Id,P1Id,42,"hello")),
+
+    receive
+	Else -> ct:fail({got,Else})
+    after 100 ->
+	    ok
+    end.
+
+listen_errors(_Config) ->
+
+    P1 = ?INTERFACE:open("p1"),
+    P1Id = ?INTERFACE:get_id(P1),
+
+    {'EXIT',{badarg,[{?INTERFACE,listen,[inval,[42]],_}|_]}} =
+	(catch ?INTERFACE:listen(inval,[42])),
+    {'EXIT',{badarg,[{?INTERFACE,listen,[P1,inval],_}|_]}} =
+	(catch ?INTERFACE:listen(P1,inval)),
+    {'EXIT',{badarg,[{?INTERFACE,listen,[P1,[1 bsl 33]],_}|_]}} =
+	(catch ?INTERFACE:listen(P1,[1 bsl 33])),
+
+    ok = ?INTERFACE:listen(P1,[42,42,42,42,42,42,42,42,42,42,42,42,42]),
+
+    case ?INTERFACE of
+	ose -> ok;
+	_ ->
+	    ?INTERFACE:send(P1,P1Id,42,"hello"),
+	    timer:sleep(50),
+	    ?INTERFACE:listen(P1,[]),
+	    ?INTERFACE:send(P1,P1Id,42,"hello2"),
+
+	    receive
+		{message,P1,42,"hello"} -> ok
+	    end,
+
+	    receive
+		Else -> ct:fail({got,Else})
+	    after 100 ->
+		    ok
+	    end
+    end,
+
+    ok = ?INTERFACE:close(P1),
+    {'EXIT',{badarg,[{?INTERFACE,listen,[P1,[42]],_}|_]}} =
+	(catch ?INTERFACE:listen(P1,[42])),
+
+    ok.
+
+%%
+%% Internal functions
+%%
+multi_open(N,ListenNums) ->
+    multi_open(N,ListenNums,[]).
+
+multi_open(0,_,Acc) ->
+    Acc;
+multi_open(N,ListenNums,Acc) ->
+    P = ?INTERFACE:open("p"++integer_to_list(N)),
+    ok = ?INTERFACE:listen(P,ListenNums),
+    multi_open(N-1,ListenNums,[P|Acc]).
+
+n(_F,0) ->
+    ok;
+n(F,N) ->
+    ok = F(N),
+    n(F,N-1).
+
+
+flush() ->
+    receive
+	Msg ->
+	    [Msg|flush()]
+    after 0 ->
+	    []
+    end.