[mnesia] Mnesia schema merge tested with 2 nodes, r13b04 -> r14b (dev)

The do_merge_schema function now converts cstructs from a remote node
when it detects that they are different. In order to be compatible the
other way around, mnesia_controller:get_cstructs() detects a remote caller,
and converts the cstructs before sending them.

1 files changed, 57 insertions, 2 deletions

diff --git a/lib/mnesia/src/mnesia_controller.erl b/lib/mnesia/src/mnesia_controller.erl
index d4b2c7b5cc..8a02fe0226 100644
--- a/lib/mnesia/src/mnesia_controller.erl
+++ b/lib/mnesia/src/mnesia_controller.erl
@@ -57,7 +57,8 @@
 	 release_schema_commit_lock/0,
 	 create_table/1,
 	 get_disc_copy/1,
-	 get_cstructs/0,
+	 get_remote_cstructs/0,  % new function
+	 get_cstructs/0,         % old function
 	 sync_and_block_table_whereabouts/4,
 	 sync_del_table_copy_whereabouts/2,
 	 block_table/1,
@@ -278,9 +279,63 @@ rec_tabs([], _, _, Init) ->
     unlink(Init),
     ok.
 
-get_cstructs() ->
+%% New function that does exactly what get_cstructs() used to do.
+%% When this function is called, we know that the calling node knows
+%% how to convert cstructs on the receiving end (should they differ).
+get_remote_cstructs() ->
     call(get_cstructs).
 
+%% Old function kept for backwards compatibility; converts cstructs before sending.
+get_cstructs() ->
+    {cstructs, Cstructs, Running} = Reply = call(get_cstructs),
+    case is_remote_call() of
+	{true, Node} ->
+	    {cstructs, normalize_cstructs(Cstructs, Node), Running};
+	false ->
+	    Reply
+    end.
+
+is_remote_call() ->
+    case node(group_leader()) of
+	N when N =/= node() ->
+	    {true, N};
+	_ ->
+	    false
+    end.
+
+normalize_cstructs(Cstructs, Node) ->
+    %% backward-compatibility hack; normalize before returning
+    case rpc:call(Node, mnesia_lib, val, [{schema,cstruct}]) of
+	{badrpc, _} ->
+	    %% assume it's not a schema merge
+	    Cstructs;
+	#cstruct{} ->
+	    %% same format
+	    Cstructs;
+	Cstruct ->
+	    %% some other format
+	    RemoteFields = [F || {F,_} <- rpc:call(Node, mnesia_schema, cs2list, [Cstruct])],
+	    [convert_cs(Cs, RemoteFields) || Cs <- Cstructs]
+    end.
+
+convert_cs(Cs, Fields) ->
+    MyFields = record_info(fields, cstruct),
+    convert(tl(tuple_to_list(Cs)), MyFields, Fields, []).
+
+convert([H|T], [F|FsL], [F|FsR], Acc) ->
+    convert(T, FsL, FsR, [H|Acc]);
+convert([H|T], [Fl|FsL] = L, [Fr|FsR] = R, Acc) ->
+    case {lists:member(Fl, FsR), lists:member(Fr, FsL)} of
+	{true, false} ->
+	    convert(T, L, FsR, [H|Acc]);
+	{false, true} ->
+	    %% Field Fl doesn't exist on receiver side; skip.
+	    convert(T, FsL, R, Acc)
+    end;
+convert([], _, _, Acc) ->
+    list_to_tuple([cstruct|lists:reverse(Acc)]).
+
+
 update(Fun) ->
     call({update,Fun}).