Make Mnesia DCD dump behaviour available via API

If a DCD dump is desired on-demand, use the function
mnesia_controller:snapshot_dcd(Tables). Tables must be a list of
tables that have a local disc_copy, otherwise an error will be
returned. Once the operation actually executes, any table that doesn't
have a local disc_copy is ignored.

Specifically, the dump_log worker record has been changed to allow an
arity-0 fun instead of the default log dump. This fun will be executed
as if it were a normal log dump, and must return 'dumped'. This could
also be used to e.g. insert a backup operation between log dumps.

2 files changed, 42 insertions, 3 deletions

diff --git a/lib/mnesia/src/mnesia_controller.erl b/lib/mnesia/src/mnesia_controller.erl
index a83e55ac62..2c2f284abf 100644
--- a/lib/mnesia/src/mnesia_controller.erl
+++ b/lib/mnesia/src/mnesia_controller.erl
@@ -51,6 +51,7 @@
 	 force_load_table/1,
 	 async_dump_log/1,
 	 sync_dump_log/1,
+	 snapshot_dcd/1,
 	 connect_nodes/1,
          connect_nodes/2,
 	 wait_for_schema_commit_lock/0,
@@ -139,7 +140,8 @@ max_loaders() ->
 -record(block_controller, {owner}).
 
 -record(dump_log, {initiated_by,
-		   opt_reply_to
+		   opt_reply_to,
+		   operation = dump_log
 		  }).
 
 -record(net_load, {table,
@@ -201,6 +203,15 @@ async_dump_log(InitBy) ->
     ?SERVER_NAME ! {async_dump_log, InitBy},
     ok.
 
+snapshot_dcd(Tables) when is_list(Tables) ->
+    case [T || T <- Tables,
+	       mnesia_lib:storage_type_at_node(node(), T) =/= disc_copies] of
+	[] ->
+	    call({snapshot_dcd, Tables});
+	BadTabs ->
+	    {error, {not_disc_copies, BadTabs}}
+    end.
+
 %% Wait for tables to be active
 %% If needed, we will wait for Mnesia to start
 %% If Mnesia stops, we will wait for Mnesia to restart
@@ -647,6 +658,15 @@ handle_call({sync_dump_log, InitBy}, From, State) ->
     State2 = add_worker(Worker, State),
     noreply(State2);
 
+handle_call({snapshot_dcd, Tables}, From, State) ->
+    Worker = #dump_log{initiated_by = user,
+		       opt_reply_to = From,
+		       operation = fun() ->
+					   mnesia_dumper:snapshot_dcd(Tables)
+				   end},
+    State2 = add_worker(Worker, State),
+    noreply(State2);
+
 handle_call(wait_for_schema_commit_lock, From, State) ->
     Worker = #schema_commit_lock{owner = From},
     State2 = add_worker(Worker, State),
@@ -2083,7 +2103,12 @@ start_remote_sender(Node, Tab, Receiver, Storage) ->
 
 dump_and_reply(ReplyTo, Worker) ->
     %% No trap_exit, die intentionally instead
-    Res = mnesia_dumper:opt_dump_log(Worker#dump_log.initiated_by),
+    Res = case Worker#dump_log.operation of
+	      dump_log ->
+		  mnesia_dumper:opt_dump_log(Worker#dump_log.initiated_by);
+	      F when is_function(F, 0) ->
+		  F()
+	  end,
     ReplyTo ! #dumper_done{worker_pid = self(),
 			   worker_res = Res},
     unlink(ReplyTo),
diff --git a/lib/mnesia/src/mnesia_dumper.erl b/lib/mnesia/src/mnesia_dumper.erl
index b784f2aca3..509b765dee 100644
--- a/lib/mnesia/src/mnesia_dumper.erl
+++ b/lib/mnesia/src/mnesia_dumper.erl
@@ -39,7 +39,8 @@
 	 raw_named_dump_table/2,
 	 start_regulator/0,
 	 opt_dump_log/1,
-	 update/3
+	 update/3,
+	 snapshot_dcd/1
 	]).
 
  %% Internal stuff
@@ -100,6 +101,19 @@ opt_dump_log(InitBy) ->
 	  end,
     perform_dump(InitBy, Reg).
 
+snapshot_dcd(Tables) ->
+    lists:foreach(
+      fun(Tab) ->
+	      case mnesia_lib:storage_type_at_node(node(), Tab) of
+		  disc_copies ->
+		      mnesia_log:ets2dcd(Tab);
+		  _ ->
+		      %% Storage type was checked before queueing the op, though
+		      skip
+	      end
+      end, Tables),
+    dumped.
+
 %% Scan for decisions
 perform_dump(InitBy, Regulator) when InitBy == scan_decisions ->
     ?eval_debug_fun({?MODULE, perform_dump}, [InitBy]),