Implement dumping of maps in crash dumps

Maps would be dumped as the atom 'undefined', which is
not very informative.

3 files changed, 97 insertions, 4 deletions

diff --git a/lib/observer/src/crashdump_viewer.erl b/lib/observer/src/crashdump_viewer.erl
index 95e12887cd..bc3ce5d547 100644
--- a/lib/observer/src/crashdump_viewer.erl
+++ b/lib/observer/src/crashdump_viewer.erl
@@ -2589,8 +2589,26 @@ parse_heap_term("Ys"++Line0, Addr, BinAddrAdj, D0) ->	%Sub binary.
 		   end
 	   end,
     D = gb_trees:insert(Addr, Term, D0),
-    {Term,Line,D}.
-
+    {Term,Line,D};
+parse_heap_term("Mf"++Line0, Addr, BinAddrAdj, D0) -> %Flatmap.
+    {Size,":"++Line1} = get_hex(Line0),
+    {Keys,":"++Line2,D1} = parse_term(Line1, BinAddrAdj, D0),
+    {Values,Line,D2} = parse_tuple(Size, Line2, Addr,BinAddrAdj, D1, []),
+    Pairs = zip_tuples(tuple_size(Keys), Keys, Values, []),
+    Map = maps:from_list(Pairs),
+    D = gb_trees:update(Addr, Map, D2),
+    {Map,Line,D};
+parse_heap_term("Mh"++Line0, Addr, BinAddrAdj, D0) -> %Head node in a hashmap.
+    {MapSize,":"++Line1} = get_hex(Line0),
+    {N,":"++Line2} = get_hex(Line1),
+    {Nodes,Line,D1} = parse_tuple(N, Line2, Addr, BinAddrAdj, D0, []),
+    Map = maps:from_list(flatten_hashmap_nodes(Nodes)),
+    MapSize = maps:size(Map),                   %Assertion.
+    D = gb_trees:update(Addr, Map, D1),
+    {Map,Line,D};
+parse_heap_term("Mn"++Line0, Addr, BinAddrAdj, D) -> %Interior node in a hashmap.
+    {N,":"++Line} = get_hex(Line0),
+    parse_tuple(N, Line, Addr, BinAddrAdj, D, []).
 
 parse_tuple(0, Line, Addr, _, D0, Acc) ->
     Tuple = list_to_tuple(lists:reverse(Acc)),
@@ -2604,6 +2622,25 @@ parse_tuple(N, Line0, Addr, BinAddrAdj, D0, Acc) ->
 	    parse_tuple(N-1, Line, Addr, BinAddrAdj, D, [Term|Acc])
     end.
 
+zip_tuples(0, _T1, _T2, Acc) ->
+    Acc;
+zip_tuples(N, T1, T2, Acc) when N =< tuple_size(T1) ->
+    zip_tuples(N-1, T1, T2, [{element(N, T1),element(N, T2)}|Acc]).
+
+flatten_hashmap_nodes(Tuple) ->
+    flatten_hashmap_nodes_1(tuple_size(Tuple), Tuple, []).
+
+flatten_hashmap_nodes_1(0, _Tuple, Acc) ->
+    Acc;
+flatten_hashmap_nodes_1(N, Tuple0, Acc0) ->
+    case element(N, Tuple0) of
+        [K|V] ->
+            flatten_hashmap_nodes_1(N-1, Tuple0, [{K,V}|Acc0]);
+        Tuple when is_tuple(Tuple) ->
+            Acc = flatten_hashmap_nodes_1(N-1, Tuple0, Acc0),
+            flatten_hashmap_nodes_1(tuple_size(Tuple), Tuple, Acc)
+    end.
+
 parse_term([$H|Line0], BinAddrAdj, D) ->        %Pointer to heap term.
     {Ptr,Line} = get_hex(Line0),
     deref_ptr(Ptr, Line, BinAddrAdj, D);
diff --git a/lib/observer/test/crashdump_helper.erl b/lib/observer/test/crashdump_helper.erl
index f37d9057cb..04c8773498 100644
--- a/lib/observer/test/crashdump_helper.erl
+++ b/lib/observer/test/crashdump_helper.erl
@@ -19,7 +19,8 @@
 %%
 
 -module(crashdump_helper).
--export([n1_proc/2,remote_proc/2]).
+-export([n1_proc/2,remote_proc/2,
+         dump_maps/0,create_maps/0]).
 -compile(r18).
 -include_lib("common_test/include/ct.hrl").
 
@@ -92,3 +93,31 @@ remote_proc(P1,Creator) ->
 		  Creator ! {self(),done},
 		  receive after infinity -> ok end
 	  end).
+
+
+%%%
+%%% Test dumping of maps. Dumping of maps only from OTP 20.2.
+%%%
+
+dump_maps() ->
+    Parent = self(),
+    F = fun() ->
+                register(aaaaaaaa_maps, self()),
+                put(maps, create_maps()),
+                Parent ! {self(),done},
+                receive _ -> ok end
+        end,
+    Pid = spawn_link(F),
+    receive
+        {Pid,done} ->
+            {ok,Pid}
+    end.
+
+create_maps() ->
+    Map0 = maps:from_list([{I,[I,I+1]} || I <- lists:seq(1, 40)]),
+    Map1 = maps:from_list([{I,{a,[I,I*I],{}}} || I <- lists:seq(1, 100)]),
+    Map2 = maps:from_list([{{I},(I*I) bsl 24} || I <- lists:seq(1, 10000)]),
+    Map3 = lists:foldl(fun(I, A) ->
+                               A#{I=>I*I}
+                       end, Map2, lists:seq(-10, 0)),
+    #{a=>Map0,b=>Map1,c=>Map2,d=>Map3,e=>#{}}.
diff --git a/lib/observer/test/crashdump_viewer_SUITE.erl b/lib/observer/test/crashdump_viewer_SUITE.erl
index f9ac884743..0ec6d8dcfc 100644
--- a/lib/observer/test/crashdump_viewer_SUITE.erl
+++ b/lib/observer/test/crashdump_viewer_SUITE.erl
@@ -513,6 +513,22 @@ special(File,Procs) ->
             io:format("  unicode table name ok",[]),
 
             ok;
+        ".maps" ->
+	    %% I registered a process as aaaaaaaa_maps in the map dump
+	    %% to make sure it will be the first in the list when sorted
+	    %% on names.
+	    [#proc{pid=Pid0,name=Name}|_Rest] = lists:keysort(#proc.name,Procs),
+            "aaaaaaaa_maps" = Name,
+	    Pid = pid_to_list(Pid0),
+	    {ok,ProcDetails=#proc{},[]} = crashdump_viewer:proc_details(Pid),
+	    io:format("  process details ok",[]),
+
+	    #proc{dict=Dict} = ProcDetails,
+            io:format("~p\n", [Dict]),
+            Maps = crashdump_helper:create_maps(),
+            Maps = proplists:get_value(maps,Dict),
+            io:format("  maps ok",[]),
+            ok;
 	_ ->
 	    ok
     end,
@@ -582,8 +598,9 @@ do_create_dumps(DataDir,Rel) ->
                                  "-env ERL_CRASH_DUMP_BYTES " ++
                                      integer_to_list(Bytes)),
             CD6 = dump_with_unicode_atoms(DataDir,Rel,"unicode"),
+            CD7 = dump_with_maps(DataDir,Rel,"maps"),
             TruncatedDumps = truncate_dump(CD1),
-	    {[CD1,CD2,CD3,CD4,CD5,CD6|TruncatedDumps], DosDump};
+	    {[CD1,CD2,CD3,CD4,CD5,CD6,CD7|TruncatedDumps], DosDump};
 	_ ->
 	    {[CD1,CD2], DosDump}
     end.
@@ -699,6 +716,16 @@ dump_with_unicode_atoms(DataDir,Rel,DumpName) ->
     ?t:stop_node(n1),
     CD.
 
+dump_with_maps(DataDir,Rel,DumpName) ->
+    Opt = rel_opt(Rel),
+    Pz = "-pz \"" ++ filename:dirname(code:which(?MODULE)) ++ "\"",
+    PzOpt = [{args,Pz}],
+    {ok,N1} = ?t:start_node(n1,peer,Opt ++ PzOpt),
+    {ok,_Pid} = rpc:call(N1,crashdump_helper,dump_maps,[]),
+    CD = dump(N1,DataDir,Rel,DumpName),
+    ?t:stop_node(n1),
+    CD.
+
 dump(Node,DataDir,Rel,DumpName) ->
     Crashdump = filename:join(DataDir, dump_prefix(Rel)++DumpName),
     rpc:call(Node,os,putenv,["ERL_CRASH_DUMP",Crashdump]),