Add SASL test suite

1 files changed, 98 insertions, 0 deletions

diff --git a/lib/sasl/test/sasl_SUITE.erl b/lib/sasl/test/sasl_SUITE.erl
new file mode 100644
index 0000000000..454095db6a
--- /dev/null
+++ b/lib/sasl/test/sasl_SUITE.erl
@@ -0,0 +1,98 @@
+%%
+%% %CopyrightBegin%
+%%
+%% Copyright Ericsson AB 2011. All Rights Reserved.
+%%
+%% The contents of this file are subject to the Erlang Public License,
+%% Version 1.1, (the "License"); you may not use this file except in
+%% compliance with the License. You should have received a copy of the
+%% Erlang Public License along with this software. If not, it can be
+%% retrieved online at http://www.erlang.org/.
+%%
+%% Software distributed under the License is distributed on an "AS IS"
+%% basis, WITHOUT WARRANTY OF ANY KIND, either express or implied. See
+%% the License for the specific language governing rights and limitations
+%% under the License.
+%%
+%% %CopyrightEnd%
+%%
+-module(sasl_SUITE).
+-include_lib("common_test/include/ct.hrl").
+
+
+% Default timetrap timeout (set in init_per_testcase).
+-define(default_timeout, ?t:minutes(1)).
+-define(application, sasl).
+
+% Test server specific exports
+-export([all/0,groups/0,init_per_group/2,end_per_group/2]).
+-export([init_per_testcase/2, end_per_testcase/2]).
+
+% Test cases must be exported.
+-export([app_test/1,
+	 log_mf_h_env/1]).
+
+all() -> 
+    [app_test, log_mf_h_env].
+
+groups() -> 
+    [].
+
+init_per_group(_GroupName, Config) ->
+    Config.
+
+end_per_group(_GroupName, Config) ->
+    Config.
+
+
+init_per_testcase(_Case, Config) ->
+    ?line Dog=test_server:timetrap(?default_timeout),
+    [{watchdog, Dog}|Config].
+end_per_testcase(_Case, Config) ->
+    Dog=?config(watchdog, Config),
+    test_server:timetrap_cancel(Dog),
+    ok.
+
+app_test(Config) when is_list(Config) ->
+    ?line ?t:app_test(sasl, allow),
+    ok.
+
+%% OTP-9185 - fail sasl start if some but not all log_mf_h env vars
+%% are given.
+log_mf_h_env(Config) ->
+    PrivDir = ?config(priv_dir,Config),
+    LogDir = filename:join(PrivDir,sasl_SUITE_log_dir),
+    ok = file:make_dir(LogDir),
+    application:stop(sasl),
+    SaslEnv = application:get_all_env(sasl),
+    lists:foreach(fun({E,_V}) -> application:unset_env(sasl,E) end, SaslEnv),
+
+    ok = application:set_env(sasl,error_logger_mf_dir,LogDir),
+    match_error(missing_config,application:start(sasl)),
+
+    ok = application:set_env(sasl,error_logger_mf_maxbytes,"xx"),
+    match_error(bad_config,application:start(sasl)),
+
+    ok = application:set_env(sasl,error_logger_mf_maxbytes,50000),
+    match_error(missing_config,application:start(sasl)),
+
+    ok = application:set_env(sasl,error_logger_mf_maxfiles,"xx"),
+    match_error(bad_config,application:start(sasl)),
+
+    ok = application:set_env(sasl,error_logger_mf_maxfiles,2),
+    ok = application:unset_env(sasl,error_logger_mf_dir),
+    match_error(missing_config,application:start(sasl)),
+
+    ok = application:set_env(sasl,error_logger_mf_dir,xx),
+    match_error(bad_config,application:start(sasl)),
+
+    ok = application:set_env(sasl,error_logger_mf_dir,LogDir),
+    ok = application:start(sasl).
+
+
+%%-----------------------------------------------------------------
+%% Internal
+match_error(Expected,{error,{bad_return,{_,{'EXIT',{Expected,{sasl,_}}}}}}) ->
+    ok;
+match_error(Expected,Actual) ->
+    ?t:fail({unexpected_return,Expected,Actual}).