[snmp|agent|test] Tweaked the (agent) test manager

The test manager used in the agent tests has been tweaked
in order to increase the readability (both of the code
and the output).

1 files changed, 100 insertions, 82 deletions

diff --git a/lib/snmp/test/snmp_test_mgr_misc.erl b/lib/snmp/test/snmp_test_mgr_misc.erl
index f3f97b5ac4..9e76452345 100644
--- a/lib/snmp/test/snmp_test_mgr_misc.erl
+++ b/lib/snmp/test/snmp_test_mgr_misc.erl
@@ -200,88 +200,24 @@ packet_loop(SnmpMgr, UdpId, AgentIp, UdpPort, VsnHdr, Version, MsgData) ->
 handle_udp_packet(_V, undefined, 
 		  UdpId, Ip, UdpPort,
 		  Bytes, SnmpMgr, AgentIp) ->
-    M = (catch snmp_pdus:dec_message_only(Bytes)),
-    MsgData3 =
-	case M of
-	    Message when Message#message.version =:= 'version-3' ->
-		d("handle_udp_packet -> version 3"),
-		case catch handle_v3_msg(Bytes, Message) of
-		    {ok, NewData, MsgData2} ->
-			Msg = Message#message{data = NewData},
-			case SnmpMgr of
-			    {pdu, Pid} ->
-				Pdu = get_pdu(Msg), 
-				d("handle_udp_packet -> "
-				  "send pdu(v3) to manager (~w): "
-                                  "~n   ~p", [Pid, Pdu]),
-				Pid ! {snmp_pdu, Pdu};
-			    {msg, Pid} ->
-				d("packet_loop -> "
-				  "send msg(v3) to manager (~p): "
-                                  "~n   ~p", [Pid, Msg]),
-				Pid ! {snmp_msg, Msg, Ip, UdpPort}
-			end,
-			MsgData2;
-		    {error, Reason, B} ->
-			udp_send(UdpId, AgentIp, UdpPort, B),
-			error("Decoding error. Auto-sending Report.\n"
-			      "Reason: ~w "
-			      "(UDPport: ~w, Ip: ~w)",
-			      [Reason, UdpPort, Ip]),
-			[];
-		    {error, Reason} ->
-			error("Decoding error. "
-				      "Bytes: ~w ~n Reason: ~w "
-			      "(UDPport: ~w, Ip: ~w)",
-			      [Bytes, Reason, UdpPort, Ip]),
-			[]
-		end;
-	    Message when is_record(Message, message) ->
-		%% v1 or v2c
-		d("handle_udp_packet -> version v1 or v2c"),
-		case catch snmp_pdus:dec_pdu(Message#message.data) of
-		    Pdu when is_record(Pdu, pdu) ->
-			case SnmpMgr of
-			    {pdu, Pid} ->
-				d("handle_udp_packet -> "
-				  "send pdu to manager (~w): ~p", 
-				  [Pid, Pdu]),
-				Pid ! {snmp_pdu, Pdu};
-			    {msg, Pid} ->
-				d("handle_udp_packet -> "
-				  "send msg to manager (~p): "
-                                  "~n   ~p", [Pid, Pdu]),
-				Msg = Message#message{data = Pdu},
-				Pid ! {snmp_msg, Msg, Ip, UdpPort}
-			end;
-		    Pdu when is_record(Pdu, trappdu) ->
-			case SnmpMgr of
-			    {pdu, Pid} ->
-				d("handle_udp_packet -> "
-				  "send trap-pdu to manager (~w): ~p", 
-				  [Pid, Pdu]),
-				Pid ! {snmp_pdu, Pdu};
-			    {msg, Pid} ->
-				d("handle_udp_packet -> "
-				  "send trap-msg to manager (~w): "
-                                  "~n   ~p", [Pid, Pdu]),
-				Msg = Message#message{data = Pdu},
-				Pid ! {snmp_msg, Msg, Ip, UdpPort}
-			end;
-		    Reason ->
-			error("Decoding error. "
-			      "Bytes: ~w ~n Reason: ~w "
-			      "(UDPport: ~w, Ip: ~w)",
-			      [Bytes, Reason, UdpPort, Ip])
-		end,
-		[];
-	    Reason ->
-		error("Decoding error. Bytes: ~w ~n Reason: ~w "
-		      "(UDPport: ~w, Ip: ~w)",
-		      [Bytes, Reason, UdpPort, Ip]),
-		[]
-	end,
-    MsgData3;
+    try snmp_pdus:dec_message_only(Bytes) of
+        Message when Message#message.version =:= 'version-3' ->
+            d("handle_udp_packet -> version 3"),
+            handle_v3_message(SnmpMgr, UdpId, Ip, UdpPort, AgentIp,
+                              Bytes, Message);
+
+        Message when is_record(Message, message) ->
+            d("handle_udp_packet -> version 1 or 2"),
+            handle_v1_or_v2_message(SnmpMgr, UdpId, Ip, UdpPort, AgentIp,
+                                    Bytes, Message)
+
+    catch
+        Class:Error:_ ->
+            error("Decoding error (~w). Bytes: ~w ~n Error: ~w "
+                  "(UDPport: ~w, Ip: ~w)",
+                  [Class, Bytes, Error, UdpPort, Ip]),
+            []
+    end;
 handle_udp_packet(V, {DiscoReqMsg, From}, _UdpId, _Ip, _UdpPort, 
 		  Bytes, _, _AgentIp) ->
     DiscoRspMsg = (catch snmp_pdus:dec_message(Bytes)),
@@ -299,6 +235,88 @@ handle_udp_packet(V, {DiscoReqMsg, From}, _UdpId, _Ip, _UdpPort,
 	    []
     end.
 
+handle_v3_message(Mgr, UdpId, Ip, UdpPort, AgentIp,
+                  Bytes, Message) ->
+    try handle_v3_msg(Bytes, Message) of
+        {ok, NewData, MsgData} ->
+            Msg = Message#message{data = NewData},
+            case Mgr of
+                {pdu, Pid} ->
+                    Pdu = get_pdu(Msg), 
+                    d("handle_v3_message -> send pdu to manager (~p): "
+                      "~n   ~p", [Pid, Pdu]),
+                    Pid ! {snmp_pdu, Pdu};
+                {msg, Pid} ->
+                    d("handle_v3_message -> send msg to manager (~p): "
+                      "~n   ~p", [Pid, Msg]),
+                    Pid ! {snmp_msg, Msg, Ip, UdpPort}
+            end,
+            MsgData
+
+        catch
+            throw:{error, Reason, B}:_ ->
+                udp_send(UdpId, AgentIp, UdpPort, B),
+                error("Decoding (v3) error. Auto-sending Report.\n"
+                      "~n   Reason: ~w "
+                      "(UDPport: ~w, Ip: ~w)",
+                      [Reason, UdpPort, Ip]),
+                [];
+
+            throw:{error, Reason}:_ ->
+                error("Decoding (v3) error. "
+                      "~n   Bytes: ~w"
+                      "~n   Reason: ~w "
+                      "(UDPport: ~w, Ip: ~w)",
+                      [Bytes, Reason, UdpPort, Ip]),
+                [];
+
+            Class:Error:_ ->
+                error("Decoding (v3) error (~w). "
+                      "~n   Bytes: ~w"
+                      "~n   Error: ~w "
+                      "(UDPport: ~w, Ip: ~w)",
+                      [Class, Bytes, Error, UdpPort, Ip]),
+                []
+
+    end.
+
+handle_v1_or_v2_message(Mgr, _UdpId, Ip, UdpPort, _AgentIp,
+                        Bytes, Message) ->
+    try snmp_pdus:dec_pdu(Message#message.data) of
+        Pdu when is_record(Pdu, pdu) ->
+            case Mgr of
+                {pdu, Pid} ->
+                    d("handle_v1_or_v2_message -> send pdu to manager (~p): "
+                      "~n   ~p", [Pid, Pdu]),
+                    Pid ! {snmp_pdu, Pdu};
+                {msg, Pid} ->
+                    d("handle_v1_or_v2_message -> send msg to manager (~p): "
+                      "~n   ~p", [Pid, Pdu]),
+                    Msg = Message#message{data = Pdu},
+                    Pid ! {snmp_msg, Msg, Ip, UdpPort}
+            end;
+        Pdu when is_record(Pdu, trappdu) ->
+            case Mgr of
+                {pdu, Pid} ->
+                    d("handle_v1_or_v2_message -> send trap-pdu to manager (~p): "
+                      "~n   ~p", [Pid, Pdu]),
+                    Pid ! {snmp_pdu, Pdu};
+                {msg, Pid} ->
+                    d("handle_v1_or_v2_message -> send trap-msg to manager (~p): "
+                      "~n   ~p", [Pid, Pdu]),
+                    Msg = Message#message{data = Pdu},
+                    Pid ! {snmp_msg, Msg, Ip, UdpPort}
+            end
+
+    catch
+        Class:Error:_ ->
+            error("Decoding (v1 or v2) error (~w): "
+                  "~n   Bytes: ~w"
+                  "~n   Error: ~w "
+                  "(UDPport: ~w, Ip: ~w)",
+                  [Class, Bytes, Error, UdpPort, Ip])
+    end.
+
 
 %% This function assumes that the agent and the manager (thats us) 
 %% has the same version.