ssh: Add simple experimental property test suites

11 files changed, 1240 insertions, 0 deletions

diff --git a/lib/ssh/test/property_test/README b/lib/ssh/test/property_test/README
new file mode 100644
index 0000000000..57602bf719
--- /dev/null
+++ b/lib/ssh/test/property_test/README
@@ -0,0 +1,12 @@
+
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+%%%                                                             %%%
+%%%                       WARNING                               %%%
+%%%                                                             %%%
+%%% This is experimental code which may be changed or removed   %%%
+%%%               anytime without any warning.                  %%%
+%%%                                                             %%%
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+
+The test in this directory are written assuming that the user has a QuickCheck license.  They are to be run manually.  Some may be possible to be run with other tools, e.g. PropEr.
+
diff --git a/lib/ssh/test/property_test/ssh_eqc_client_server.erl b/lib/ssh/test/property_test/ssh_eqc_client_server.erl
new file mode 100644
index 0000000000..3a84acebb3
--- /dev/null
+++ b/lib/ssh/test/property_test/ssh_eqc_client_server.erl
@@ -0,0 +1,602 @@
+%%
+%% %CopyrightBegin%
+%% 
+%% Copyright Ericsson AB 2004-2014. All Rights Reserved.
+%% 
+%% The contents of this file are subject to the Erlang Public License,
+%% Version 1.1, (the "License"); you may not use this file except in
+%% compliance with the License. You should have received a copy of the
+%% Erlang Public License along with this software. If not, it can be
+%% retrieved online at http://www.erlang.org/.
+%% 
+%% Software distributed under the License is distributed on an "AS IS"
+%% basis, WITHOUT WARRANTY OF ANY KIND, either express or implied. See
+%% the License for the specific language governing rights and limitations
+%% under the License.
+%% 
+%% %CopyrightEnd%
+%%
+%%
+
+-module(ssh_eqc_client_server).
+
+-compile(export_all).
+
+-include_lib("common_test/include/ct.hrl").
+
+-ifdef(PROPER).
+%% Proper is not supported.
+-else.
+
+-include_lib("eqc/include/eqc.hrl").
+-include_lib("eqc/include/eqc_statem.hrl").
+-eqc_group_commands(true).
+
+-define(SSH_DIR,"ssh_eqc_client_server_dirs").
+
+-define(sec, *1000).
+-define(min, *60?sec).
+
+-record(srvr,{ref,
+	      address,
+	      port
+	     }).
+
+-record(conn,{ref,
+	      srvr_ref
+	     }).
+
+-record(chan, {ref,
+	       conn_ref,
+	       subsystem,
+	       client_pid
+	      }).
+		 
+-record(state,{
+	  initialized = false,
+	  servers = [],       % [#srvr{}]
+	  clients = [],
+	  connections = [],   % [#conn{}]
+	  channels = [],      % [#chan{}]
+	  data_dir
+	 }).
+
+%%%===============================================================
+%%%
+%%% Specification of addresses, subsystems and such.
+%%%
+
+-define(MAX_NUM_SERVERS, 3).
+-define(MAX_NUM_CLIENTS, 3).
+
+-define(SUBSYSTEMS, ["echo1", "echo2", "echo3", "echo4"]).
+
+-define(SERVER_ADDRESS, { {127,1,1,1}, inet_port({127,1,1,1}) }).
+
+-define(SERVER_EXTRA_OPTIONS,  [{parallel_login,bool()}] ).
+		
+
+%%%================================================================
+%%%
+%%% The properties - one sequantial and one parallel with the same model
+%%%
+%%% Run as
+%%%
+%%%   $ (cd ..; make)
+%%%   $ erl -pz ..
+%%%
+%%%   eqc:quickcheck( ssh_eqc_client_server:prop_seq() ).
+%%%   eqc:quickcheck( ssh_eqc_client_server:prop_parallel() ).
+%%%   eqc:quickcheck( ssh_eqc_client_server:prop_parallel_multi() ).
+%%%
+
+
+%% To be called as eqc:quickcheck( ssh_eqc_client_server:prop_seq() ).
+prop_seq() ->
+    do_prop_seq(?SSH_DIR).
+
+%% To be called from a common_test test suite
+prop_seq(CT_Config) ->
+    do_prop_seq(full_path(?SSH_DIR, CT_Config)).
+
+
+do_prop_seq(DataDir) ->
+    ?FORALL(Cmds,commands(?MODULE, #state{data_dir=DataDir}),
+	    begin
+		{H,Sf,Result} = run_commands(?MODULE,Cmds),
+		present_result(?MODULE, Cmds, {H,Sf,Result}, Result==ok)
+	    end).
+
+full_path(SSHdir, CT_Config) ->
+    filename:join(proplists:get_value(property_dir, CT_Config),
+		  SSHdir).
+%%%----
+prop_parallel() ->
+    do_prop_parallel(?SSH_DIR).
+
+%% To be called from a common_test test suite
+prop_parallel(CT_Config) ->
+    do_prop_parallel(full_path(?SSH_DIR, CT_Config)).
+
+do_prop_parallel(DataDir) ->
+    ?FORALL(Cmds,parallel_commands(?MODULE, #state{data_dir=DataDir}),
+	    begin
+		{H,Sf,Result} = run_parallel_commands(?MODULE,Cmds),
+		present_result(?MODULE, Cmds, {H,Sf,Result}, Result==ok)
+	    end).
+
+%%%----
+prop_parallel_multi() ->
+    do_prop_parallel_multi(?SSH_DIR).
+
+%% To be called from a common_test test suite
+prop_parallel_multi(CT_Config) ->
+    do_prop_parallel_multi(full_path(?SSH_DIR, CT_Config)).
+
+do_prop_parallel_multi(DataDir) ->
+    ?FORALL(Repetitions,?SHRINK(1,[10]),
+	    ?FORALL(Cmds,parallel_commands(?MODULE, #state{data_dir=DataDir}),
+		    ?ALWAYS(Repetitions,
+			    begin
+				{H,Sf,Result} = run_parallel_commands(?MODULE,Cmds),
+				present_result(?MODULE, Cmds, {H,Sf,Result}, Result==ok)
+			    end))).
+
+%%%================================================================
+%%% State machine spec
+
+%%% called when using commands/1
+initial_state() -> 
+    S = initial_state(#state{}),
+    S#state{initialized=true}.
+
+%%% called when using commands/2
+initial_state(S) ->
+    application:stop(ssh),
+    ssh:start(),
+    setup_rsa(S#state.data_dir).
+
+%%%----------------
+weight(S, ssh_send) -> 5*length([C || C<-S#state.channels, has_subsyst(C)]);
+weight(S, ssh_start_subsyst) -> 3*length([C || C<-S#state.channels, no_subsyst(C)]);
+weight(S, ssh_close_channel) -> 2*length([C || C<-S#state.channels, has_subsyst(C)]);
+weight(S, ssh_open_channel) ->  length(S#state.connections);
+weight(_S, _) -> 1.
+
+%%%----------------
+%%% Initialize
+
+initial_state_pre(S) -> not S#state.initialized.
+
+initial_state_args(S) -> [S].
+
+initial_state_next(S, _, _) -> S#state{initialized=true}.
+
+%%%----------------
+%%% Start a new daemon
+%%% Precondition: not more than ?MAX_NUM_SERVERS started
+
+ssh_server_pre(S) -> S#state.initialized andalso 
+			 length(S#state.servers) < ?MAX_NUM_SERVERS.
+
+ssh_server_args(S) -> [?SERVER_ADDRESS, S#state.data_dir, ?SERVER_EXTRA_OPTIONS]. 
+
+ssh_server({IP,Port}, DataDir, ExtraOptions) ->
+    ok(ssh:daemon(IP, Port, 
+		  [
+		   {system_dir, system_dir(DataDir)},
+		   {user_dir, user_dir(DataDir)},
+		   {subsystems, [{SS, {ssh_eqc_subsys, [SS]}} || SS <- ?SUBSYSTEMS]}
+		   | ExtraOptions
+		  ])).
+
+ssh_server_post(_S, _Args, Result) -> is_ok(Result).
+
+ssh_server_next(S, Result, [{IP,Port},_,_]) ->
+    S#state{servers=[#srvr{ref = Result,
+			   address = IP,
+			   port = Port}
+		     | S#state.servers]}.
+
+%%%----------------
+%%% Start a new client
+%%% Precondition: not more than ?MAX_NUM_CLIENTS started
+
+ssh_client_pre(S) -> S#state.initialized andalso 
+			 length(S#state.clients) < ?MAX_NUM_CLIENTS.
+
+ssh_client_args(_S) -> [].
+
+ssh_client() -> spawn(fun client_init/0).
+
+ssh_client_next(S, Pid, _) -> S#state{clients=[Pid|S#state.clients]}.
+
+
+client_init() -> client_loop().
+
+client_loop() ->
+    receive
+	{please_do,Fun,Ref,Pid} ->
+	    Pid ! {my_pleasure, catch Fun(), Ref},
+	    client_loop()
+    end.
+    
+do(Pid, Fun) -> do(Pid, Fun, 30?sec).
+
+do(Pid, Fun, Timeout) when is_function(Fun,0) ->
+    Pid ! {please_do,Fun,Ref=make_ref(),self()},
+    receive
+	{my_pleasure, Result, Ref} -> Result
+    after
+	Timeout -> {error,do_timeout}
+    end.
+	    
+%%%----------------
+%%% Start a new connection
+%%% Precondition:  deamon exists
+
+ssh_open_connection_pre(S) -> S#state.servers /= [].
+    
+ssh_open_connection_args(S) -> [oneof(S#state.servers), S#state.data_dir].
+    
+ssh_open_connection(#srvr{address=Ip, port=Port}, DataDir) ->
+    ok(ssh:connect(ensure_string(Ip), Port, 
+		   [
+		    {silently_accept_hosts, true},
+		    {user_dir, user_dir(DataDir)},
+		    {user_interaction, false}
+		   ])).
+
+ssh_open_connection_post(_S, _Args, Result) -> is_ok(Result).
+
+ssh_open_connection_next(S, ConnRef, [#srvr{ref=SrvrRef},_]) -> 
+    S#state{connections=[#conn{ref=ConnRef, srvr_ref=SrvrRef}|S#state.connections]}.
+
+%%%----------------
+%%% Stop a new connection
+%%% Precondition:  connection exists
+
+ssh_close_connection_pre(S) -> S#state.connections /= [].
+
+ssh_close_connection_args(S) -> [oneof(S#state.connections)].
+    
+ssh_close_connection(#conn{ref=ConnectionRef}) -> ssh:close(ConnectionRef).
+
+ssh_close_connection_next(S, _, [Conn=#conn{ref=ConnRef}]) ->
+	S#state{connections = S#state.connections--[Conn],
+		channels = [C || C <- S#state.channels,
+				 C#chan.conn_ref /= ConnRef]
+	       }.
+
+%%%----------------
+%%% Start a new channel without a sub system
+%%% Precondition:  connection exists
+
+ssh_open_channel_pre(S) -> S#state.connections /= [].
+
+ssh_open_channel_args(S) -> [oneof(S#state.connections)].
+
+%%% For re-arrangement in parallel tests. 
+ssh_open_channel_pre(S,[C]) -> lists:member(C,S#state.connections).
+
+ssh_open_channel(#conn{ref=ConnectionRef}) -> 
+    ok(ssh_connection:session_channel(ConnectionRef, 20?sec)).
+
+ssh_open_channel_post(_S, _Args, Result) -> is_ok(Result).
+
+ssh_open_channel_next(S, ChannelRef, [#conn{ref=ConnRef}]) ->  
+    S#state{channels=[#chan{ref=ChannelRef,
+			    conn_ref=ConnRef}
+		      | S#state.channels]}.
+
+%%%----------------
+%%% Stop a channel
+%%% Precondition: a channel exists, with or without a subsystem
+
+ssh_close_channel_pre(S) -> S#state.channels /= [].
+
+ssh_close_channel_args(S) -> [oneof(S#state.channels)].
+
+ssh_close_channel(#chan{ref=ChannelRef, conn_ref=ConnectionRef}) -> 
+    ssh_connection:close(ConnectionRef, ChannelRef).
+
+ssh_close_channel_next(S, _, [C]) -> 
+    S#state{channels = [Ci || Ci <- S#state.channels,
+			      sig(C) /= sig(Ci)]}.
+
+			      
+sig(C) -> {C#chan.ref, C#chan.conn_ref}.
+    
+
+%%%----------------
+%%% Start a sub system on a channel
+%%% Precondition:  A channel without subsystem exists
+
+ssh_start_subsyst_pre(S) -> lists:any(fun no_subsyst/1, S#state.channels) andalso
+				S#state.clients /= [].
+
+ssh_start_subsyst_args(S) -> [oneof(lists:filter(fun no_subsyst/1, S#state.channels)),
+			      oneof(?SUBSYSTEMS),
+			      oneof(S#state.clients)
+			     ].
+
+%% For re-arrangement in parallel tests. 
+ssh_start_subsyst_pre(S, [C|_]) -> lists:member(C,S#state.channels) 
+				       andalso no_subsyst(C).
+
+ssh_start_subsyst(#chan{ref=ChannelRef, conn_ref=ConnectionRef}, SubSystem, Pid) -> 
+    do(Pid, fun()->ssh_connection:subsystem(ConnectionRef, ChannelRef, SubSystem, 120?sec) end).
+
+ssh_start_subsyst_post(_S, _Args, Result) -> Result==success.
+
+ssh_start_subsyst_next(S, _Result, [C,SS,Pid|_]) ->
+    S#state{channels = [C#chan{subsystem=SS,
+			       client_pid=Pid}|(S#state.channels--[C])] }.
+
+%%%----------------
+%%% Send a message on a channel
+%%% Precondition: a channel exists with a subsystem connected
+
+ssh_send_pre(S) -> lists:any(fun has_subsyst/1, S#state.channels).
+
+ssh_send_args(S) -> [oneof(lists:filter(fun has_subsyst/1, S#state.channels)),
+		     choose(0,1),
+		     message()].
+
+%% For re-arrangement in parallel tests. 
+ssh_send_pre(S, [C|_]) -> lists:member(C, S#state.channels).
+
+ssh_send(C=#chan{conn_ref=ConnectionRef, ref=ChannelRef, client_pid=Pid}, Type, Msg) ->
+    do(Pid, 
+       fun() -> 
+	       case ssh_connection:send(ConnectionRef, ChannelRef, Type, modify_msg(C,Msg), 10?sec) of
+		   ok ->
+		       receive
+			   {ssh_cm,ConnectionRef,{data,ChannelRef,Type,Answer}} -> Answer
+		       after 15?sec -> 
+			       %% receive
+			       %% 	   Other -> {error,{unexpected,Other}}
+			       %% after 0 ->
+				       {error,receive_timeout}
+			       %% end
+		       end;
+		   Other ->
+		       Other
+	       end
+       end).
+
+ssh_send_blocking(_S, _Args) ->
+    true.
+
+ssh_send_post(_S, [C,_,Msg], Response) when is_binary(Response) ->
+    Expected = ssh_eqc_subsys:response(modify_msg(C,Msg), C#chan.subsystem),
+    case Response of
+	Expected -> true;
+	_ -> {send_failed, size(Response), size(Expected)}
+    end;
+	    
+ssh_send_post(_S, _Args, Response) ->
+    {error,Response}.
+    
+
+modify_msg(_, <<>>) -> <<>>;
+modify_msg(#chan{subsystem=SS}, Msg) -> <<(list_to_binary(SS))/binary,Msg/binary>>.
+
+%%%================================================================
+%%% Misc functions
+
+message() -> 
+    resize(500, binary()).
+
+    %% binary().
+
+    %% oneof([binary(),
+    %% 	   ?LET(Size, choose(0,10000), binary(Size))
+    %% 	  ]).
+
+has_subsyst(C) -> C#chan.subsystem /= undefined.
+
+no_subsyst(C) -> not has_subsyst(C).
+
+
+ok({ok,X}) -> X;
+ok({error,Err}) -> {error,Err}.
+
+is_ok({error,_}) -> false;
+is_ok(_) -> true.
+
+ensure_string({A,B,C,D}) -> lists:flatten(io_lib:format("~w.~w.~w.~w",[A,B,C,D]));
+ensure_string(X) -> X.
+
+%%%----------------------------------------------------------------
+present_result(_Module, Cmds, _Triple, true) -> 
+    aggregate(with_title("Distribution sequential/parallel"), sequential_parallel(Cmds),
+    aggregate(with_title("Function calls"), cmnd_names(Cmds),
+    aggregate(with_title("Message sizes"), empty_msgs(Cmds),
+    aggregate(print_frequencies(), message_sizes(Cmds),
+    aggregate(title("Length of command sequences",print_frequencies()), num_calls(Cmds),
+	      true)))));
+
+present_result(Module, Cmds, Triple, false) -> 
+    pretty_commands(Module, Cmds, Triple, [{show_states,true}], false).
+
+
+
+cmnd_names(Cs) -> traverse_commands(fun cmnd_name/1, Cs).
+cmnd_name(L) ->  [F || {set,_Var,{call,_Mod,F,_As}} <- L].
+    
+empty_msgs(Cs) -> traverse_commands(fun empty_msg/1, Cs).
+empty_msg(L) -> [empty || {set,_,{call,_,ssh_send,[_,_,Msg]}} <- L,
+			  size(Msg)==0].
+    
+message_sizes(Cs) -> traverse_commands(fun message_size/1, Cs).
+message_size(L) -> [size(Msg) || {set,_,{call,_,ssh_send,[_,_,Msg]}} <- L].
+    
+num_calls(Cs) -> traverse_commands(fun num_call/1, Cs).
+num_call(L) -> [length(L)].
+    
+sequential_parallel(Cs) ->
+    traverse_commands(fun(L) -> dup_module(L, sequential) end,
+		      fun(L) -> [dup_module(L1, mkmod("parallel",num(L1,L))) || L1<-L] end,
+		      Cs).
+dup_module(L, ModName) -> lists:duplicate(length(L), ModName).
+mkmod(PfxStr,N) -> list_to_atom(PfxStr++"_"++integer_to_list(N)).
+    
+%% Meta functions for the aggregate functions
+traverse_commands(Fun, L) when is_list(L) -> Fun(L);
+traverse_commands(Fun, {Seq, ParLs}) -> Fun(lists:append([Seq|ParLs])).
+    
+traverse_commands(Fseq, _Fpar, L) when is_list(L) -> Fseq(L);
+traverse_commands(Fseq, Fpar, {Seq, ParLs}) -> lists:append([Fseq(Seq)|Fpar(ParLs)]).
+    
+%%%----------------
+%% PrintMethod([{term(), int()}]) -> any().
+print_frequencies() -> print_frequencies(10).
+
+print_frequencies(Ngroups) -> fun([]) -> io:format('Empty list!~n',[]);
+                                 (L ) -> print_frequencies(L,Ngroups,0,element(1,lists:last(L)))
+                              end.
+
+print_frequencies(Ngroups, MaxValue) -> fun(L) -> print_frequencies(L,Ngroups,0,MaxValue) end.
+
+print_frequencies(L, N, Min, Max) when N>Max -> print_frequencies(L++[{N,0}], N, Min, N);
+print_frequencies(L, N, Min, Max) ->
+%%io:format('L=~p~n',[L]),
+    try
+	IntervalUpperLimits = 
+	    lists:reverse(
+	      [Max | tl(lists:reverse(lists:seq(Min,Max,round((Max-Min)/N))))]
+	     ),
+	{Acc0,_} = lists:mapfoldl(fun(Upper,Lower) -> 
+					  {{{Lower,Upper},0}, Upper+1}
+				  end, hd(IntervalUpperLimits), tl(IntervalUpperLimits)),
+	Fs0 = get_frequencies(L, Acc0),
+	SumVal = lists:sum([V||{_,V}<-Fs0]),
+	Fs = with_percentage(Fs0, SumVal),
+	Mean = mean(L),
+	Median = median(L),
+	Npos_value = num_digits(SumVal),
+	Npos_range = num_digits(Max),
+	io:format("Range~*s: ~s~n",[2*Npos_range-2,"", "Number in range"]),
+	io:format("~*c:~*c~n",[2*Npos_range+3,$-, max(16,Npos_value+10),$- ]),
+	[begin
+	     io:format("~*w - ~*w:  ~*w  ~5.1f%",[Npos_range,Rlow,
+						  Npos_range,Rhigh,
+						  Npos_value,Val,
+						  Percent]),
+	     [io:format(" <-- mean=~.1f",[Mean]) || in_interval(Mean, Interval)],
+	     [io:format(" <-- median=" ++
+			    if 
+				is_float(Median) -> "~.1f";
+				true -> "~p"
+			    end, [Median]) || in_interval(Median, Interval)],
+	     io:nl()
+	 end
+	 || {Interval={Rlow,Rhigh},Val,Percent} <- Fs],
+	io:format('~*c    ~*c~n',[2*Npos_range,32,Npos_value+2,$-]),
+	io:format('~*c      ~*w~n',[2*Npos_range,32,Npos_value,SumVal])
+        %%,io:format('L=~p~n',[L])
+    catch
+	C:E ->
+	    io:format('*** Faild printing (~p:~p) for~n~p~n',[C,E,L])
+    end.
+
+get_frequencies([{I,Num}|T], [{{Lower,Upper},Cnt}|Acc]) when Lower=<I,I=<Upper ->
+    get_frequencies(T,  [{{Lower,Upper},Cnt+Num}|Acc]);
+get_frequencies(L=[{I,_Num}|_], [Ah={{_Lower,Upper},_Cnt}|Acc]) when I>Upper ->
+    [Ah | get_frequencies(L,Acc)];
+get_frequencies([], Acc) -> 
+    Acc.
+
+with_percentage(Fs, Sum) ->
+    [{Rng,Val,100*Val/Sum} || {Rng,Val} <- Fs].
+    
+
+title(Str, Fun) ->
+    fun(L) ->
+	    io:format('~s~n',[Str]),
+	    Fun(L)
+    end.
+
+num_digits(I) -> 1+trunc(math:log(I)/math:log(10)).
+
+num(Elem, List) -> length(lists:takewhile(fun(E) -> E /= Elem end, List)) + 1.
+
+%%%---- Just for naming an operation for readability
+is_odd(I) -> (I rem 2) == 1.
+
+in_interval(Value, {Rlow,Rhigh}) -> 
+    try 
+	Rlow=<round(Value) andalso round(Value)=<Rhigh
+    catch 
+	_:_ -> false
+    end.
+
+%%%================================================================
+%%% Statistical functions
+
+%%%---- Mean value
+mean(L = [X|_]) when is_number(X) -> 
+    lists:sum(L) / length(L);
+mean(L = [{_Value,_Weight}|_]) -> 
+    SumOfWeights = lists:sum([W||{_,W}<-L]),
+    WeightedSum = lists:sum([W*V||{V,W}<-L]),
+    WeightedSum / SumOfWeights;
+mean(_) -> 
+    undefined.
+    
+%%%---- Median
+median(L = [X|_]) when is_number(X) -> 
+    case is_odd(length(L)) of
+	true ->
+	    hd(lists:nthtail(length(L) div 2, L));
+	false -> 
+	    %%  1) L has at least on element (the when test).
+	    %%  2) Length is even.
+	    %%     => Length >= 2
+	    [M1,M2|_] = lists:nthtail((length(L) div 2)-1, L),
+	    (M1+M2) / 2
+    end;
+%% integer Weights...
+median(L = [{_Value,_Weight}|_]) ->
+    median( lists:append([lists:duplicate(W,V) || {V,W} <- L]) );
+median(_) ->
+    undefined.
+
+%%%================================================================
+%%% The rest is taken and modified from ssh_test_lib.erl
+inet_port(IpAddress)->
+    {ok, Socket} = gen_tcp:listen(0, [{ip,IpAddress},{reuseaddr,true}]),
+    {ok, Port} = inet:port(Socket),
+    gen_tcp:close(Socket),
+    Port.
+
+setup_rsa(Dir) ->
+    erase_dir(system_dir(Dir)),
+    erase_dir(user_dir(Dir)),
+    file:make_dir(system_dir(Dir)),
+    file:make_dir(user_dir(Dir)),
+
+    file:copy(data_dir(Dir,"id_rsa"),           user_dir(Dir,"id_rsa")),
+    file:copy(data_dir(Dir,"ssh_host_rsa_key"), system_dir(Dir,"ssh_host_rsa_key")),
+    file:copy(data_dir(Dir,"ssh_host_rsa_key"), system_dir(Dir,"ssh_host_rsa_key.pub")),
+    ssh_test_lib:setup_rsa_known_host(data_dir(Dir), user_dir(Dir)),
+    ssh_test_lib:setup_rsa_auth_keys(data_dir(Dir),  user_dir(Dir)).
+
+data_dir(Dir, File) ->   filename:join(Dir, File).
+system_dir(Dir, File) -> filename:join([Dir, "system", File]).
+user_dir(Dir, File) ->   filename:join([Dir, "user", File]).
+
+data_dir(Dir) -> Dir.
+system_dir(Dir) -> system_dir(Dir,"").
+user_dir(Dir) -> user_dir(Dir,"").
+    
+erase_dir(Dir) ->
+    case file:list_dir(Dir) of
+	{ok,Files} -> lists:foreach(fun(F) -> file:delete(filename:join(Dir,F)) end,
+				    Files);
+	_ -> ok
+    end,
+    file:del_dir(Dir).
+
+-endif.
diff --git a/lib/ssh/test/property_test/ssh_eqc_client_server_dirs/id_dsa b/lib/ssh/test/property_test/ssh_eqc_client_server_dirs/id_dsa
new file mode 100644
index 0000000000..d306f8b26e
--- /dev/null
+++ b/lib/ssh/test/property_test/ssh_eqc_client_server_dirs/id_dsa
@@ -0,0 +1,13 @@
+-----BEGIN DSA PRIVATE KEY-----
+MIIBvAIBAAKBgQDfi2flSTZZofwT4yQT0NikX/LGNT7UPeB/XEWe/xovEYCElfaQ
+APFixXvEgXwoojmZ5kiQRKzLM39wBP0jPERLbnZXfOOD0PDnw0haMh7dD7XKVMod
+/EigVgHf/qBdM2M8yz1s/rRF7n1UpLSypziKjkzCm7JoSQ2zbWIPdmBIXwIVAMgP
+kpr7Sq3O7sHdb8D601DRjoExAoGAMOQxDfB2Fd8ouz6G96f/UOzRMI/Kdv8kYYKW
+JIGY+pRYrLPyYzUeJznwZreOJgrczAX+luHnKFWJ2Dnk5CyeXk67Wsr7pJ/4MBMD
+OKeIS0S8qoSBN8+Krp79fgA+yS3IfqbkJLtLu4EBaCX4mKQIX4++k44d4U5lc8pt
++9hlEI8CgYEAznKxx9kyC6bVo7LUYKaGhofRFt0SYFc5PVmT2VUGRs1R6+6DPD+e
+uEO6IhFct7JFSRbP9p0JD4Uk+3zlZF+XX6b2PsZkeV8f/02xlNGUSmEzCSiNg1AX
+Cy/WusYhul0MncWCHMcOZB5rIvU/aP5EJJtn3xrRaz6u0SThF6AnT34CFQC63czE
+ZU8w8Q+H7z0j+a+70x2iAw==
+-----END DSA PRIVATE KEY-----
+
diff --git a/lib/ssh/test/property_test/ssh_eqc_client_server_dirs/id_rsa b/lib/ssh/test/property_test/ssh_eqc_client_server_dirs/id_rsa
new file mode 100644
index 0000000000..9d7e0dd5fb
--- /dev/null
+++ b/lib/ssh/test/property_test/ssh_eqc_client_server_dirs/id_rsa
@@ -0,0 +1,15 @@
+-----BEGIN RSA PRIVATE KEY-----
+MIICXAIBAAKBgQD1OET+3O/Bvj/dtjxDTXmj1oiJt4sIph5kGy0RfjoPrZfaS+CU
+DhakCmS6t2ivxWFgtpKWaoGMZMJqWj6F6ZsumyFl3FPBtujwY/35cgifrI9Ns4Tl
+zR1uuengNBmV+WRQ5cd9F2qS6Z8aDQihzt0r8JUqLcK+VQbrmNzboCCQQwIDAQAB
+AoGAPQEyqPTt8JUT7mRXuaacjFXiweAXhp9NEDpyi9eLOjtFe9lElZCrsUOkq47V
+TGUeRKEm9qSodfTbKPoqc8YaBJGJPhUaTAcha+7QcDdfHBvIsgxvU7ePVnlpXRp3
+CCUEMPhlnx6xBoTYP+fRU0e3+xJIPVyVCqX1jAdUMkzfRoECQQD6ux7B1QJAIWyK
+SGkbDUbBilNmzCFNgIpOP6PA+bwfi5d16diTpra5AX09keQABAo/KaP1PdV8Vg0p
+z4P3A7G3AkEA+l+AKG6m0kQTTBMJDqOdVPYwe+5GxunMaqmhokpEbuGsrZBl5Dvd
+WpcBjR7jmenrhKZRIuA+Fz5HPo/UQJPl1QJBAKxstDkeED8j/S2XoFhPKAJ+6t39
+sUVICVTIZQeXdmzHJXCcUSkw8+WEhakqw/3SyW0oaK2FSWQJFWJUZ+8eJj8CQEh3
+xeduB5kKnS9CvzdeghZqX6QvVosSdtlUmfUYW/BgH5PpHKTP8wTaeld3XldZTpMJ
+dKiMkUw2+XYROVUrubUCQD+Na1LhULlpn4ISEtIEfqpdlUhxDgO15Wg8USmsng+x
+ICliVOSQtwaZjm8kwaFt0W7XnpnDxbRs37vIEbIMWak=
+-----END RSA PRIVATE KEY-----
diff --git a/lib/ssh/test/property_test/ssh_eqc_client_server_dirs/ssh_host_dsa_key b/lib/ssh/test/property_test/ssh_eqc_client_server_dirs/ssh_host_dsa_key
new file mode 100644
index 0000000000..51ab6fbd88
--- /dev/null
+++ b/lib/ssh/test/property_test/ssh_eqc_client_server_dirs/ssh_host_dsa_key
@@ -0,0 +1,13 @@
+-----BEGIN DSA PRIVATE KEY-----
+MIIBuwIBAAKBgQCClaHzE2ul0gKSUxah5W0W8UiJLy4hXngKEqpaUq9SSdVdY2LK
+wVfKH1gt5iuaf1FfzOhsIC9G/GLnjYttXZc92cv/Gfe3gR+s0ni2++MX+T++mE/Q
+diltXv/Hp27PybS67SmiFW7I+RWnT2OKlMPtw2oUuKeztCe5UWjaj/y5FQIVAPLA
+l9RpiU30Z87NRAHY3NTRaqtrAoGANMRxw8UfdtNVR0CrQj3AgPaXOGE4d+G4Gp4X
+skvnCHycSVAjtYxebUkzUzt5Q6f/IabuLUdge3gXrc8BetvrcKbp+XZgM0/Vj2CF
+Ymmy3in6kzGZq7Fw1sZaku6AOU8vLa5woBT2vAcHLLT1bLAzj7viL048T6MfjrOP
+ef8nHvACgYBhDWFQJ1mf99sg92LalVq1dHLmVXb3PTJDfCO/Gz5NFmj9EZbAtdah
+/XcF3DeRF+eEoz48wQF/ExVxSMIhLdL+o+ElpVhlM7Yii+T7dPhkQfEul6zZXu+U
+ykSTXYUbtsfTNRFQGBW2/GfnEc0mnIxfn9v10NEWMzlq5z9wT9P0CgIVAN4wtL5W
+Lv62jKcdskxNyz2NQoBx
+-----END DSA PRIVATE KEY-----
+
diff --git a/lib/ssh/test/property_test/ssh_eqc_client_server_dirs/ssh_host_dsa_key.pub b/lib/ssh/test/property_test/ssh_eqc_client_server_dirs/ssh_host_dsa_key.pub
new file mode 100644
index 0000000000..4dbb1305b0
--- /dev/null
+++ b/lib/ssh/test/property_test/ssh_eqc_client_server_dirs/ssh_host_dsa_key.pub
@@ -0,0 +1,11 @@
+---- BEGIN SSH2 PUBLIC KEY ----
+AAAAB3NzaC1kc3MAAACBAIKVofMTa6XSApJTFqHlbRbxSIkvLiFeeAoSqlpSr1JJ1V1j
+YsrBV8ofWC3mK5p/UV/M6GwgL0b8YueNi21dlz3Zy/8Z97eBH6zSeLb74xf5P76YT9B2
+KW1e/8enbs/JtLrtKaIVbsj5FadPY4qUw+3DahS4p7O0J7lRaNqP/LkVAAAAFQDywJfU
+aYlN9GfOzUQB2NzU0WqrawAAAIA0xHHDxR9201VHQKtCPcCA9pc4YTh34bganheyS+cI
+fJxJUCO1jF5tSTNTO3lDp/8hpu4tR2B7eBetzwF62+twpun5dmAzT9WPYIViabLeKfqT
+MZmrsXDWxlqS7oA5Ty8trnCgFPa8BwcstPVssDOPu+IvTjxPox+Os495/yce8AAAAIBh
+DWFQJ1mf99sg92LalVq1dHLmVXb3PTJDfCO/Gz5NFmj9EZbAtdah/XcF3DeRF+eEoz48
+wQF/ExVxSMIhLdL+o+ElpVhlM7Yii+T7dPhkQfEul6zZXu+UykSTXYUbtsfTNRFQGBW2
+/GfnEc0mnIxfn9v10NEWMzlq5z9wT9P0Cg==
+---- END SSH2 PUBLIC KEY ----
diff --git a/lib/ssh/test/property_test/ssh_eqc_client_server_dirs/ssh_host_rsa_key b/lib/ssh/test/property_test/ssh_eqc_client_server_dirs/ssh_host_rsa_key
new file mode 100644
index 0000000000..79968bdd7d
--- /dev/null
+++ b/lib/ssh/test/property_test/ssh_eqc_client_server_dirs/ssh_host_rsa_key
@@ -0,0 +1,16 @@
+-----BEGIN RSA PRIVATE KEY-----
+MIICXQIBAAKBgQDCZX+4FBDwZIh9y/Uxee1VJnEXlowpz2yDKwj8semM4q843337
+zbNfxHmladB1lpz2NqyxI175xMIJuDxogyZdsOxGnFAzAnthR4dqL/RWRWzjaxSB
+6IAO9SPYVVlrpZ+1hsjLW79fwXK/yc8VdhRuWTeQiRgYY2ek8+OKbOqz4QIDAQAB
+AoGANmvJzJO5hkLuvyDZHKfAnGTtpifcR1wtSa9DjdKUyn8vhKF0mIimnbnYQEmW
+NUUb3gXCZLi9PvkpRSVRrASDOZwcjoU/Kvww163vBUVb2cOZfFhyn6o2Sk88Tt++
+udH3hdjpf9i7jTtUkUe+QYPsia+wgvvrmn4QrahLAH86+kECQQDx5gFeXTME3cnW
+WMpFz3PPumduzjqgqMMWEccX4FtQkMX/gyGa5UC7OHFyh0N/gSWvPbRHa8A6YgIt
+n8DO+fh5AkEAzbqX4DOn8NY6xJIi42q7l/2jIA0RkB6P7YugW5NblhqBZ0XDnpA5
+sMt+rz+K07u9XZtxgh1xi7mNfwY6lEAMqQJBAJBEauCKmRj35Z6OyeQku59SPsnY
++SJEREVvSNw2lH9SOKQQ4wPsYlTGbvKtNVZgAcen91L5MmYfeckYE/fdIZECQQCt
+64zxsTnM1I8iFxj/gP/OYlJBikrKt8udWmjaghzvLMEw+T2DExJyb9ZNeT53+UMB
+m6O+B/4xzU/djvp+0hbhAkAemIt+rA5kTmYlFndhpvzkSSM8a2EXsO4XIPgGWCTT
+tQKS/tTly0ADMjN/TVy11+9d6zcqadNVuHXHGtR4W0GR
+-----END RSA PRIVATE KEY-----
+
diff --git a/lib/ssh/test/property_test/ssh_eqc_client_server_dirs/ssh_host_rsa_key.pub b/lib/ssh/test/property_test/ssh_eqc_client_server_dirs/ssh_host_rsa_key.pub
new file mode 100644
index 0000000000..75d2025c71
--- /dev/null
+++ b/lib/ssh/test/property_test/ssh_eqc_client_server_dirs/ssh_host_rsa_key.pub
@@ -0,0 +1,5 @@
+---- BEGIN SSH2 PUBLIC KEY ----
+AAAAB3NzaC1yc2EAAAADAQABAAAAgQDCZX+4FBDwZIh9y/Uxee1VJnEXlowpz2yDKwj8
+semM4q843337zbNfxHmladB1lpz2NqyxI175xMIJuDxogyZdsOxGnFAzAnthR4dqL/RW
+RWzjaxSB6IAO9SPYVVlrpZ+1hsjLW79fwXK/yc8VdhRuWTeQiRgYY2ek8+OKbOqz4Q==
+---- END SSH2 PUBLIC KEY ----
diff --git a/lib/ssh/test/property_test/ssh_eqc_encode_decode.erl b/lib/ssh/test/property_test/ssh_eqc_encode_decode.erl
new file mode 100644
index 0000000000..6ddf2c9972
--- /dev/null
+++ b/lib/ssh/test/property_test/ssh_eqc_encode_decode.erl
@@ -0,0 +1,381 @@
+%%
+%% %CopyrightBegin%
+%% 
+%% Copyright Ericsson AB 2004-2014. All Rights Reserved.
+%% 
+%% The contents of this file are subject to the Erlang Public License,
+%% Version 1.1, (the "License"); you may not use this file except in
+%% compliance with the License. You should have received a copy of the
+%% Erlang Public License along with this software. If not, it can be
+%% retrieved online at http://www.erlang.org/.
+%% 
+%% Software distributed under the License is distributed on an "AS IS"
+%% basis, WITHOUT WARRANTY OF ANY KIND, either express or implied. See
+%% the License for the specific language governing rights and limitations
+%% under the License.
+%% 
+%% %CopyrightEnd%
+%%
+%%
+
+-module(ssh_eqc_encode_decode).
+
+-compile(export_all).
+
+-ifndef(EQC).
+-ifndef(PROPER).
+-define(EQC,true).
+%%-define(PROPER,true).
+-endif.
+-endif.
+
+-ifdef(EQC).
+-include_lib("eqc/include/eqc.hrl").
+-define(MOD_eqc,eqc).
+-else.
+-ifdef(PROPER).
+-include_lib("proper/include/proper.hrl").
+-define(MOD_eqc,proper).
+-endif.
+-endif.
+
+
+%%% Properties:
+
+prop_ssh_decode() ->
+    ?FORALL(Msg, ssh_msg(),
+	    try ssh_message:decode(Msg)
+	    of
+		_ -> true
+	    catch
+		C:E -> io:format('~p:~p~n',[C,E]),
+		       false
+	    end
+	   ).
+
+
+%%% This fails because ssh_message is not symmetric in encode and decode regarding data types
+prop_ssh_decode_encode() ->
+    ?FORALL(Msg, ssh_msg(),
+	    Msg == ssh_message:encode(ssh_message:decode(Msg))
+	   ).
+
+
+%%%================================================================
+%%%
+%%% Scripts to generate message generators
+%%%
+
+%% awk '/^( |\t)+byte( |\t)+SSH/,/^( |\t)*$/{print}' rfc425?.txt | sed 's/^\( \|\\t\)*//' > msgs.txt
+
+%% awk '/^byte( |\t)+SSH/{print $2","}' < msgs.txt
+
+%% awk 'BEGIN{print "%%%---- BEGIN GENERATED";prev=0} END{print "    >>.\n%%%---- END GENERATED"}  /^byte( |\t)+SSH/{if (prev==1) print "    >>.\n"; prev=1; printf "%c%s%c",39,$2,39; print "()->\n   <<?"$2;next}  /^string( |\t)+\"/{print "    ,"$2;next} /^string( |\t)+.*address/{print "    ,(ssh_string_address())/binary %%",$2,$3,$4,$5,$6;next}/^string( |\t)+.*US-ASCII/{print "    ,(ssh_string_US_ASCII())/binary %%",$2,$3,$4,$5,$6;next} /^string( |\t)+.*UTF-8/{print "    ,(ssh_string_UTF_8())/binary %% ",$2,$3,$4,$5,$6;next}    /^[a-z0-9]+( |\t)/{print "    ,(ssh_"$1"())/binary %%",$2,$3,$4,$5,$6;next}  /^byte\[16\]( |\t)+/{print"    ,(ssh_byte_16())/binary %%",$2,$3,$4,$5,$6;next} /^name-list( |\t)+/{print"    ,(ssh_name_list())/binary %%",$2,$3,$4,$5,$6;next} /./{print "?? %%",$0}' < msgs.txt > gen.txt
+
+%%%================================================================
+%%%
+%%% Generators
+%%% 
+
+ssh_msg() -> ?LET(M,oneof(
+[[msg_code('SSH_MSG_CHANNEL_CLOSE'),gen_uint32()],
+    [msg_code('SSH_MSG_CHANNEL_DATA'),gen_uint32(),gen_string( )],
+    [msg_code('SSH_MSG_CHANNEL_EOF'),gen_uint32()],
+    [msg_code('SSH_MSG_CHANNEL_EXTENDED_DATA'),gen_uint32(),gen_uint32(),gen_string( )],
+    [msg_code('SSH_MSG_CHANNEL_FAILURE'),gen_uint32()],
+    [msg_code('SSH_MSG_CHANNEL_OPEN'),gen_string("direct-tcpip"),gen_uint32(),gen_uint32(),gen_uint32(),gen_string( ),gen_uint32(),gen_string( ),gen_uint32()],
+    [msg_code('SSH_MSG_CHANNEL_OPEN'),gen_string("forwarded-tcpip"),gen_uint32(),gen_uint32(),gen_uint32(),gen_string( ),gen_uint32(),gen_string( ),gen_uint32()],
+    [msg_code('SSH_MSG_CHANNEL_OPEN'),gen_string("session"),gen_uint32(),gen_uint32(),gen_uint32()],
+    [msg_code('SSH_MSG_CHANNEL_OPEN'),gen_string("x11"),gen_uint32(),gen_uint32(),gen_uint32(),gen_string( ),gen_uint32()],
+    [msg_code('SSH_MSG_CHANNEL_OPEN'),gen_string( ),gen_uint32(),gen_uint32(),gen_uint32()],
+    [msg_code('SSH_MSG_CHANNEL_OPEN_CONFIRMATION'),gen_uint32(),gen_uint32(),gen_uint32(),gen_uint32()],
+    [msg_code('SSH_MSG_CHANNEL_OPEN_FAILURE'),gen_uint32(),gen_uint32(),gen_string( ),gen_string( )],
+    [msg_code('SSH_MSG_CHANNEL_REQUEST'),gen_uint32(),gen_string("env"),gen_boolean(),gen_string( ),gen_string( )],
+    [msg_code('SSH_MSG_CHANNEL_REQUEST'),gen_uint32(),gen_string("exec"),gen_boolean(),gen_string( )],
+    [msg_code('SSH_MSG_CHANNEL_REQUEST'),gen_uint32(),gen_string("exit-signal"),0,gen_string( ),gen_boolean(),gen_string( ),gen_string( )],
+    [msg_code('SSH_MSG_CHANNEL_REQUEST'),gen_uint32(),gen_string("exit-status"),0,gen_uint32()],
+    [msg_code('SSH_MSG_CHANNEL_REQUEST'),gen_uint32(),gen_string("pty-req"),gen_boolean(),gen_string( ),gen_uint32(),gen_uint32(),gen_uint32(),gen_uint32(),gen_string( )],
+    [msg_code('SSH_MSG_CHANNEL_REQUEST'),gen_uint32(),gen_string("shell"),gen_boolean()],
+    [msg_code('SSH_MSG_CHANNEL_REQUEST'),gen_uint32(),gen_string("signal"),0,gen_string( )],
+    [msg_code('SSH_MSG_CHANNEL_REQUEST'),gen_uint32(),gen_string("subsystem"),gen_boolean(),gen_string( )],
+    [msg_code('SSH_MSG_CHANNEL_REQUEST'),gen_uint32(),gen_string("window-change"),0,gen_uint32(),gen_uint32(),gen_uint32(),gen_uint32()],
+    [msg_code('SSH_MSG_CHANNEL_REQUEST'),gen_uint32(),gen_string("x11-req"),gen_boolean(),gen_boolean(),gen_string( ),gen_string( ),gen_uint32()],
+    [msg_code('SSH_MSG_CHANNEL_REQUEST'),gen_uint32(),gen_string("xon-xoff"),0,gen_boolean()],
+    [msg_code('SSH_MSG_CHANNEL_REQUEST'),gen_uint32(),gen_string( ),gen_boolean()],
+    [msg_code('SSH_MSG_CHANNEL_SUCCESS'),gen_uint32()],
+    [msg_code('SSH_MSG_CHANNEL_WINDOW_ADJUST'),gen_uint32(),gen_uint32()],
+%%Assym    [msg_code('SSH_MSG_DEBUG'),gen_boolean(),gen_string( ),gen_string( )],
+    [msg_code('SSH_MSG_DISCONNECT'),gen_uint32(),gen_string( ),gen_string( )],
+%%Assym    [msg_code('SSH_MSG_GLOBAL_REQUEST'),gen_string("cancel-tcpip-forward"),gen_boolean(),gen_string( ),gen_uint32()],
+%%Assym    [msg_code('SSH_MSG_GLOBAL_REQUEST'),gen_string("tcpip-forward"),gen_boolean(),gen_string( ),gen_uint32()],
+%%Assym    [msg_code('SSH_MSG_GLOBAL_REQUEST'),gen_string( ),gen_boolean()],
+    [msg_code('SSH_MSG_IGNORE'),gen_string( )],
+    %% [msg_code('SSH_MSG_KEXDH_INIT'),gen_mpint()],
+    %% [msg_code('SSH_MSG_KEXDH_REPLY'),gen_string( ),gen_mpint(),gen_string( )],
+    %% [msg_code('SSH_MSG_KEXINIT'),gen_byte(16),gen_name_list(),gen_name_list(),gen_name_list(),gen_name_list(),gen_name_list(),gen_name_list(),gen_name_list(),gen_name_list(),gen_name_list(),gen_name_list(),gen_boolean(),gen_uint32()],
+    [msg_code('SSH_MSG_KEX_DH_GEX_GROUP'),gen_mpint(),gen_mpint()],
+    [msg_code('SSH_MSG_NEWKEYS')],
+    [msg_code('SSH_MSG_REQUEST_FAILURE')],
+    [msg_code('SSH_MSG_REQUEST_SUCCESS')],
+    [msg_code('SSH_MSG_REQUEST_SUCCESS'),gen_uint32()],
+    [msg_code('SSH_MSG_SERVICE_ACCEPT'),gen_string( )],
+    [msg_code('SSH_MSG_SERVICE_REQUEST'),gen_string( )],
+    [msg_code('SSH_MSG_UNIMPLEMENTED'),gen_uint32()],
+    [msg_code('SSH_MSG_USERAUTH_BANNER'),gen_string( ),gen_string( )],
+    [msg_code('SSH_MSG_USERAUTH_FAILURE'),gen_name_list(),gen_boolean()],
+    [msg_code('SSH_MSG_USERAUTH_PASSWD_CHANGEREQ'),gen_string( ),gen_string( )],
+    [msg_code('SSH_MSG_USERAUTH_PK_OK'),gen_string( ),gen_string( )],
+    [msg_code('SSH_MSG_USERAUTH_SUCCESS')]
+]
+
+), list_to_binary(M)).
+
+
+%%%================================================================
+%%%
+%%% Generator
+%%% 
+
+do() -> 
+    io_lib:format('[~s~n]',
+		  [write_gen(
+		     files(["rfc4254.txt", 
+			    "rfc4253.txt", 
+			    "rfc4419.txt",
+			    "rfc4252.txt",
+			    "rfc4256.txt"]))]).
+    
+
+write_gen(L) when is_list(L) -> 
+    string:join(lists:map(fun write_gen/1, L), ",\n    ");
+write_gen({MsgName,Args}) -> 
+    lists:flatten(["[",generate_args([MsgName|Args]),"]"]).
+     
+generate_args(As) -> string:join([generate_arg(A) || A <- As], ",").
+
+generate_arg({<<"string">>, <<"\"",B/binary>>}) -> 
+    S = get_string($",B),
+    ["gen_string(\"",S,"\")"];
+generate_arg({<<"string">>, _}) -> "gen_string( )";
+generate_arg({<<"byte[",B/binary>>, _}) -> 
+    io_lib:format("gen_byte(~p)",[list_to_integer(get_string($],B))]);
+generate_arg({<<"byte">>  ,_}) ->    "gen_byte()";
+generate_arg({<<"uint16">>,_}) ->    "gen_uint16()";
+generate_arg({<<"uint32">>,_}) ->    "gen_uint32()";
+generate_arg({<<"uint64">>,_}) ->    "gen_uint64()";
+generate_arg({<<"mpint">>,_}) ->     "gen_mpint()";
+generate_arg({<<"name-list">>,_}) -> "gen_name_list()";
+generate_arg({<<"boolean">>,<<"FALSE">>}) -> "0";
+generate_arg({<<"boolean">>,<<"TRUE">>}) ->  "1";
+generate_arg({<<"boolean">>,_}) -> "gen_boolean()";
+generate_arg({<<"....">>,_}) -> "";  %% FIXME
+generate_arg(Name) when is_binary(Name) -> 
+    lists:flatten(["msg_code('",binary_to_list(Name),"')"]).
+
+
+gen_boolean() -> choose(0,1).
+
+gen_byte() -> choose(0,255).
+
+gen_uint16() -> gen_byte(2).
+
+gen_uint32() -> gen_byte(4).
+
+gen_uint64() -> gen_byte(8).
+
+gen_byte(N) when N>0 -> [gen_byte() || _ <- lists:seq(1,N)].
+    
+gen_char() -> choose($a,$z).
+
+gen_mpint() -> ?LET(Size, choose(1,20), 
+	       ?LET(Str, vector(Size, gen_byte()),
+		    gen_string( strip_0s(Str) )
+		   )).
+
+strip_0s([0|T]) -> strip_0s(T);
+strip_0s(X) -> X.
+    
+
+gen_string() -> 
+    ?LET(Size, choose(0,10), 
+	 ?LET(Vector,vector(Size, gen_char()),
+	      gen_string(Vector) 
+	     )).
+
+gen_string(S) when is_binary(S) -> gen_string(binary_to_list(S));
+gen_string(S) when is_list(S) -> uint32_to_list(length(S)) ++ S.
+    
+gen_name_list() ->
+    ?LET(NumNames, choose(0,10),
+	 ?LET(L, [gen_name() || _ <- lists:seq(1,NumNames)],
+	      gen_string( string:join(L,"," ) )
+	)).
+
+gen_name() -> gen_string().
+
+uint32_to_list(I) ->  binary_to_list(<<I:32/unsigned-big-integer>>).
+    
+%%%----
+get_string(Delim, B) -> 
+    binary_to_list( element(1, split_binary(B, count_string_chars(Delim,B,0))) ).
+
+count_string_chars(Delim, <<Delim,_/binary>>, Acc) -> Acc;
+count_string_chars(Delim, <<_,B/binary>>, Acc) -> count_string_chars(Delim, B, Acc+1).
+
+
+-define(MSG_CODE(Name,Num),
+msg_code(Name) -> Num;
+msg_code(Num) -> Name
+).
+
+?MSG_CODE('SSH_MSG_USERAUTH_REQUEST',   50);
+?MSG_CODE('SSH_MSG_USERAUTH_FAILURE',   51);
+?MSG_CODE('SSH_MSG_USERAUTH_SUCCESS',   52);
+?MSG_CODE('SSH_MSG_USERAUTH_BANNER',   53);
+?MSG_CODE('SSH_MSG_USERAUTH_PK_OK',   60);
+?MSG_CODE('SSH_MSG_USERAUTH_PASSWD_CHANGEREQ',   60);
+?MSG_CODE('SSH_MSG_DISCONNECT',   1);
+?MSG_CODE('SSH_MSG_IGNORE',   2);
+?MSG_CODE('SSH_MSG_UNIMPLEMENTED',   3);
+?MSG_CODE('SSH_MSG_DEBUG',   4);
+?MSG_CODE('SSH_MSG_SERVICE_REQUEST',   5);
+?MSG_CODE('SSH_MSG_SERVICE_ACCEPT',   6);
+?MSG_CODE('SSH_MSG_KEXINIT',   20);
+?MSG_CODE('SSH_MSG_NEWKEYS',   21);
+?MSG_CODE('SSH_MSG_GLOBAL_REQUEST',   80);
+?MSG_CODE('SSH_MSG_REQUEST_SUCCESS',   81);
+?MSG_CODE('SSH_MSG_REQUEST_FAILURE',   82);
+?MSG_CODE('SSH_MSG_CHANNEL_OPEN',   90);
+?MSG_CODE('SSH_MSG_CHANNEL_OPEN_CONFIRMATION',   91);
+?MSG_CODE('SSH_MSG_CHANNEL_OPEN_FAILURE',   92);
+?MSG_CODE('SSH_MSG_CHANNEL_WINDOW_ADJUST',   93);
+?MSG_CODE('SSH_MSG_CHANNEL_DATA',   94);
+?MSG_CODE('SSH_MSG_CHANNEL_EXTENDED_DATA',   95);
+?MSG_CODE('SSH_MSG_CHANNEL_EOF',   96);
+?MSG_CODE('SSH_MSG_CHANNEL_CLOSE',   97);
+?MSG_CODE('SSH_MSG_CHANNEL_REQUEST',   98);
+?MSG_CODE('SSH_MSG_CHANNEL_SUCCESS',   99);
+?MSG_CODE('SSH_MSG_CHANNEL_FAILURE',   100);
+?MSG_CODE('SSH_MSG_USERAUTH_INFO_REQUEST',   60);
+?MSG_CODE('SSH_MSG_USERAUTH_INFO_RESPONSE',   61);
+?MSG_CODE('SSH_MSG_KEX_DH_GEX_REQUEST_OLD',   30);
+?MSG_CODE('SSH_MSG_KEX_DH_GEX_REQUEST',   34);
+?MSG_CODE('SSH_MSG_KEX_DH_GEX_GROUP',   31);
+?MSG_CODE('SSH_MSG_KEX_DH_GEX_INIT',   32);
+?MSG_CODE('SSH_MSG_KEX_DH_GEX_REPLY', 33).
+
+%%%=============================================================================
+%%%=============================================================================
+%%%=============================================================================
+
+files(Fs) ->
+    Defs = lists:usort(lists:flatten(lists:map(fun file/1, Fs))),
+    DefinedIDs = lists:usort([binary_to_list(element(1,D)) || D <- Defs]),
+    WantedIDs = lists:usort(wanted_messages()),
+    Missing = WantedIDs -- DefinedIDs,
+    case Missing of
+	[] -> ok;
+	_ -> io:format('%% Warning: missing ~p~n', [Missing])
+    end,
+    Defs.
+	    
+
+file(F) ->
+    {ok,B} = file:read_file(F),
+    hunt_msg_def(B).
+
+
+hunt_msg_def(<<"\n",B/binary>>) -> some_hope(skip_blanks(B));
+hunt_msg_def(<<_, B/binary>>) -> hunt_msg_def(B);
+hunt_msg_def(<<>>) -> [].
+    
+some_hope(<<"byte ", B/binary>>) -> try_message(skip_blanks(B));
+some_hope(B) -> hunt_msg_def(B).
+    
+try_message(B = <<"SSH_MSG_",_/binary>>) ->
+    {ID,Rest} = get_id(B),
+    case lists:member(binary_to_list(ID), wanted_messages()) of
+	true ->
+	    {Lines,More} = get_def_lines(skip_blanks(Rest), []),
+	    [{ID,lists:reverse(Lines)} | hunt_msg_def(More)];
+	false ->
+	    hunt_msg_def(Rest)
+    end;
+try_message(B) -> hunt_msg_def(B).
+    
+
+skip_blanks(<<32, B/binary>>) -> skip_blanks(B);
+skip_blanks(<< 9, B/binary>>) -> skip_blanks(B);
+skip_blanks(B) -> B.
+
+get_def_lines(B0 = <<"\n",B/binary>>, Acc) ->
+    {ID,Rest} = get_id(skip_blanks(B)),
+    case {size(ID), skip_blanks(Rest)} of
+	{0,<<"....",More/binary>>} ->
+	    {Text,LineEnd} = get_to_eol(skip_blanks(More)),
+	    get_def_lines(LineEnd, [{<<"....">>,Text}|Acc]);
+	{0,_} ->
+	    {Acc,B0};
+	{_,Rest1} -> 
+	    {Text,LineEnd} = get_to_eol(Rest1),
+	    get_def_lines(LineEnd, [{ID,Text}|Acc])
+    end;
+get_def_lines(B, Acc) -> 
+    {Acc,B}.
+    
+
+get_to_eol(B) -> split_binary(B, count_to_eol(B,0)).
+
+count_to_eol(<<"\n",_/binary>>, Acc) -> Acc;
+count_to_eol(<<>>, Acc) -> Acc;
+count_to_eol(<<_,B/binary>>, Acc) -> count_to_eol(B,Acc+1).
+    
+
+get_id(B) -> split_binary(B, count_id_chars(B,0)).
+    
+count_id_chars(<<C,B/binary>>, Acc) when $A=<C,C=<$Z -> count_id_chars(B,Acc+1);
+count_id_chars(<<C,B/binary>>, Acc) when $a=<C,C=<$z -> count_id_chars(B,Acc+1);
+count_id_chars(<<C,B/binary>>, Acc) when $0=<C,C=<$9 -> count_id_chars(B,Acc+1);
+count_id_chars(<<"_",B/binary>>, Acc)  ->  count_id_chars(B,Acc+1);
+count_id_chars(<<"-",B/binary>>, Acc)  ->  count_id_chars(B,Acc+1); %% e.g name-list
+count_id_chars(<<"[",B/binary>>, Acc)  ->  count_id_chars(B,Acc+1); %% e.g byte[16]
+count_id_chars(<<"]",B/binary>>, Acc)  ->  count_id_chars(B,Acc+1); %% e.g byte[16]
+count_id_chars(_, Acc) -> Acc.
+
+wanted_messages() ->
+    ["SSH_MSG_CHANNEL_CLOSE",
+     "SSH_MSG_CHANNEL_DATA",
+     "SSH_MSG_CHANNEL_EOF",
+     "SSH_MSG_CHANNEL_EXTENDED_DATA",
+     "SSH_MSG_CHANNEL_FAILURE",
+     "SSH_MSG_CHANNEL_OPEN",
+     "SSH_MSG_CHANNEL_OPEN_CONFIRMATION",
+     "SSH_MSG_CHANNEL_OPEN_FAILURE",
+     "SSH_MSG_CHANNEL_REQUEST",
+     "SSH_MSG_CHANNEL_SUCCESS",
+     "SSH_MSG_CHANNEL_WINDOW_ADJUST",
+     "SSH_MSG_DEBUG",
+     "SSH_MSG_DISCONNECT",
+     "SSH_MSG_GLOBAL_REQUEST",
+     "SSH_MSG_IGNORE",
+     "SSH_MSG_KEXDH_INIT",
+     "SSH_MSG_KEXDH_REPLY",
+     "SSH_MSG_KEXINIT",
+     "SSH_MSG_KEX_DH_GEX_GROUP",
+     "SSH_MSG_KEX_DH_GEX_REQUEST",
+     "SSH_MSG_KEX_DH_GEX_REQUEST_OLD",
+     "SSH_MSG_NEWKEYS",
+     "SSH_MSG_REQUEST_FAILURE",
+     "SSH_MSG_REQUEST_SUCCESS",
+     "SSH_MSG_SERVICE_ACCEPT",
+     "SSH_MSG_SERVICE_REQUEST",
+     "SSH_MSG_UNIMPLEMENTED",
+     "SSH_MSG_USERAUTH_BANNER",
+     "SSH_MSG_USERAUTH_FAILURE",
+%% hard args    "SSH_MSG_USERAUTH_INFO_REQUEST",
+%%     "SSH_MSG_USERAUTH_INFO_RESPONSE",
+     "SSH_MSG_USERAUTH_PASSWD_CHANGEREQ",
+     "SSH_MSG_USERAUTH_PK_OK",
+%%rfc4252 p12 error      "SSH_MSG_USERAUTH_REQUEST",
+     "SSH_MSG_USERAUTH_SUCCESS"].
+
diff --git a/lib/ssh/test/property_test/ssh_eqc_subsys.erl b/lib/ssh/test/property_test/ssh_eqc_subsys.erl
new file mode 100644
index 0000000000..e4b6af166f
--- /dev/null
+++ b/lib/ssh/test/property_test/ssh_eqc_subsys.erl
@@ -0,0 +1,63 @@
+%%
+%% %CopyrightBegin%
+%% 
+%% Copyright Ericsson AB 2004-2014. All Rights Reserved.
+%% 
+%% The contents of this file are subject to the Erlang Public License,
+%% Version 1.1, (the "License"); you may not use this file except in
+%% compliance with the License. You should have received a copy of the
+%% Erlang Public License along with this software. If not, it can be
+%% retrieved online at http://www.erlang.org/.
+%% 
+%% Software distributed under the License is distributed on an "AS IS"
+%% basis, WITHOUT WARRANTY OF ANY KIND, either express or implied. See
+%% the License for the specific language governing rights and limitations
+%% under the License.
+%% 
+%% %CopyrightEnd%
+%%
+%%
+
+-module(ssh_eqc_subsys).
+
+-behaviour(ssh_daemon_channel).
+
+-export([init/1, handle_msg/2, handle_ssh_msg/2, terminate/2]).
+
+-export([response/2]).
+
+-record(state, {id, 
+		cm,
+		subsyst
+	       }).
+
+init([SS]) ->
+    {ok, #state{subsyst=SS}}.
+
+handle_msg({ssh_channel_up, ChannelId, ConnectionManager}, State) ->
+    {ok, State#state{id = ChannelId,
+		     cm = ConnectionManager}}.
+
+handle_ssh_msg({ssh_cm, CM, {data, ChannelId, Type, Data}}, S) ->
+    ssh_connection:send(CM, ChannelId, Type, response(Data,S)),
+    {ok, S};
+
+handle_ssh_msg({ssh_cm, _ConnectionManager, {eof, _ChannelId}}, State) ->
+    {ok, State};
+
+handle_ssh_msg({ssh_cm, _, {signal, _, _}}, State) ->
+    %% Ignore signals according to RFC 4254 section 6.9.
+    {ok, State};
+
+handle_ssh_msg({ssh_cm, _, {exit_signal, ChannelId, _, _Error, _}}, State) ->
+    {stop, ChannelId,  State};
+
+handle_ssh_msg({ssh_cm, _, {exit_status, ChannelId, _Status}}, State) ->
+    {stop, ChannelId, State}.
+
+terminate(_Reason, _State) ->
+    ok.
+
+
+response(Msg, #state{subsyst=SS}) -> response(Msg, SS);
+response(Msg, SS) -> <<"Resp: ",Msg/binary,(list_to_binary(SS))/binary>>.
diff --git a/lib/ssh/test/ssh_property_test_SUITE.erl b/lib/ssh/test/ssh_property_test_SUITE.erl
new file mode 100644
index 0000000000..c6c63d7367
--- /dev/null
+++ b/lib/ssh/test/ssh_property_test_SUITE.erl
@@ -0,0 +1,109 @@
+%%
+%% %CopyrightBegin%
+%% 
+%% Copyright Ericsson AB 2004-2014. All Rights Reserved.
+%% 
+%% The contents of this file are subject to the Erlang Public License,
+%% Version 1.1, (the "License"); you may not use this file except in
+%% compliance with the License. You should have received a copy of the
+%% Erlang Public License along with this software. If not, it can be
+%% retrieved online at http://www.erlang.org/.
+%% 
+%% Software distributed under the License is distributed on an "AS IS"
+%% basis, WITHOUT WARRANTY OF ANY KIND, either express or implied. See
+%% the License for the specific language governing rights and limitations
+%% under the License.
+%% 
+%% %CopyrightEnd%
+%%
+%%
+
+%%% Run like this:
+%%%  ct:run_test([{suite,"ssh_property_test_SUITE"}, {logdir,"/ldisk/OTP/LOG"}]).
+
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+%%%                                                             %%%
+%%%                       WARNING                               %%%
+%%%                                                             %%%
+%%% This is experimental code which may be changed or removed   %%%
+%%%               anytime without any warning.                  %%%
+%%%                                                             %%%
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+
+-module(ssh_property_test_SUITE).
+
+-compile(export_all).
+
+-include_lib("common_test/include/ct.hrl").
+
+all() -> [{group, messages},
+	  {group, client_server}
+	 ].
+
+groups() ->
+    [{messages, [], [decode,
+		     decode_encode]},
+     {client_server, [], [client_server_sequential,
+			  client_server_parallel,
+			  client_server_parallel_multi]}
+    ].
+
+
+%%% First prepare Config and compile the property tests for the found tool:
+init_per_suite(Config) ->
+    ct_property_test:init_per_suite(Config).
+
+%%% One group in this suite happens to support only QuickCheck, so skip it
+%%% if we run proper.
+init_per_group(client_server, Config) ->
+    case ?config(property_test_tool,Config) of
+	proper ->
+	    {skip, "PropEr is not supported"};
+	eqc ->
+	    Config
+    end;
+init_per_group(_, Config) ->
+    Config.
+
+end_per_group(_, Config) ->
+    Config.
+
+%%% Always skip the testcase that is not quite in phase with the
+%%% ssh_message.erl code
+init_per_testcase(decode_encode, _) -> {skip, "Fails - testcase is not ok"};
+init_per_testcase(_TestCase, Config) -> Config.
+    
+end_per_testcase(_TestCase, Config) -> Config.
+
+%%%================================================================
+%%% Test suites
+%%%
+decode(Config) ->
+    ct_property_test:quickcheck(
+      ssh_eqc_encode_decode:prop_ssh_decode(),
+      Config
+     ).
+
+decode_encode(Config) ->
+    ct_property_test:quickcheck(
+      ssh_eqc_encode_decode:prop_ssh_decode_encode(),
+      Config
+     ).
+
+client_server_sequential(Config) ->
+    ct_property_test:quickcheck(
+      ssh_eqc_client_server:prop_seq(Config),
+      Config
+     ).
+
+client_server_parallel(Config) ->
+    ct_property_test:quickcheck(
+      ssh_eqc_client_server:prop_parallel(Config),
+      Config
+     ).
+
+client_server_parallel_multi(Config) ->
+    ct_property_test:quickcheck(
+      ssh_eqc_client_server:prop_parallel_multi(Config),
+      Config
+     ).