Anonymous cipher suites

For testing purposes ssl now also support some anonymous cipher suites
when explicitly configured to do so.

Also moved session cache tests to its own suite, so that timeout
of end_per_testcase when the mnesia is used as session cache will
not affect other test cases.

1 files changed, 305 insertions, 0 deletions

diff --git a/lib/ssl/test/ssl_session_cache_SUITE.erl b/lib/ssl/test/ssl_session_cache_SUITE.erl
new file mode 100644
index 0000000000..7a441e4599
--- /dev/null
+++ b/lib/ssl/test/ssl_session_cache_SUITE.erl
@@ -0,0 +1,305 @@
+%%
+%% %CopyrightBegin%
+%%
+%% Copyright Ericsson AB 2010-2010. All Rights Reserved.
+%%
+%% The contents of this file are subject to the Erlang Public License,
+%% Version 1.1, (the "License"); you may not use this file except in
+%% compliance with the License. You should have received a copy of the
+%% Erlang Public License along with this software. If not, it can be
+%% retrieved online at http://www.erlang.org/.2
+%%
+%% Software distributed under the License is distributed on an "AS IS"
+%% basis, WITHOUT WARRANTY OF ANY KIND, either express or implied. See
+%% the License for the specific language governing rights and limitations
+%% under the License.
+%%
+%% %CopyrightEnd%
+%%
+
+%%
+
+-module(ssl_session_cache_SUITE).
+
+%% Note: This directive should only be used in test suites.
+-compile(export_all).
+
+-include("test_server.hrl").
+
+-define(SLEEP, 500).
+-define(TIMEOUT, 60000).
+-behaviour(ssl_session_cache_api).
+
+%% For the session cache tests
+-export([init/1, terminate/1, lookup/2, update/3,
+	 delete/2, foldl/3, select_session/2]).
+
+%% Test server callback functions
+%%--------------------------------------------------------------------
+%% Function: init_per_suite(Config) -> Config
+%% Config - [tuple()]
+%%   A list of key/value pairs, holding the test case configuration.
+%% Description: Initialization before the whole suite
+%%
+%% Note: This function is free to add any key/value pairs to the Config
+%% variable, but should NOT alter/remove any existing entries.
+%%--------------------------------------------------------------------
+init_per_suite(Config0) ->
+    Dog = ssl_test_lib:timetrap(?TIMEOUT *2),
+    crypto:start(),
+    application:start(public_key),
+    ssl:start(),
+
+    %% make rsa certs using oppenssl
+    Result =
+	(catch make_certs:all(?config(data_dir, Config0),
+			      ?config(priv_dir, Config0))),
+    test_server:format("Make certs  ~p~n", [Result]),
+
+    Config1 = ssl_test_lib:make_dsa_cert(Config0),
+    Config = ssl_test_lib:cert_options(Config1),
+    [{watchdog, Dog} | Config].
+
+%%--------------------------------------------------------------------
+%% Function: end_per_suite(Config) -> _
+%% Config - [tuple()]
+%%   A list of key/value pairs, holding the test case configuration.
+%% Description: Cleanup after the whole suite
+%%--------------------------------------------------------------------
+end_per_suite(_Config) ->
+    ssl:stop(),
+    crypto:stop().
+
+%%--------------------------------------------------------------------
+%% Function: init_per_testcase(TestCase, Config) -> Config
+%% Case - atom()
+%%   Name of the test case that is about to be run.
+%% Config - [tuple()]
+%%   A list of key/value pairs, holding the test case configuration.
+%%
+%% Description: Initialization before each test case
+%%
+%% Note: This function is free to add any key/value pairs to the Config
+%% variable, but should NOT alter/remove any existing entries.
+%% Description: Initialization before each test case
+%%--------------------------------------------------------------------
+init_per_testcase(session_cache_process_list, Config) ->
+    init_customized_session_cache(list, Config);
+
+init_per_testcase(session_cache_process_mnesia, Config) ->
+    mnesia:start(),
+    init_customized_session_cache(mnesia, Config);
+
+init_per_testcase(_TestCase, Config0) ->
+    Config = lists:keydelete(watchdog, 1, Config0),
+    Dog = test_server:timetrap(?TIMEOUT),
+   [{watchdog, Dog} | Config].
+
+init_customized_session_cache(Type, Config0) ->
+    Config = lists:keydelete(watchdog, 1, Config0),
+    Dog = test_server:timetrap(?TIMEOUT),
+    ssl:stop(),
+    application:load(ssl),
+    application:set_env(ssl, session_cb, ?MODULE),
+    application:set_env(ssl, session_cb_init_args, [Type]),
+    ssl:start(),
+    [{watchdog, Dog} | Config].
+
+%%--------------------------------------------------------------------
+%% Function: end_per_testcase(TestCase, Config) -> _
+%% Case - atom()
+%%   Name of the test case that is about to be run.
+%% Config - [tuple()]
+%%   A list of key/value pairs, holding the test case configuration.
+%% Description: Cleanup after each test case
+%%--------------------------------------------------------------------
+end_per_testcase(session_cache_process_list, Config) ->
+    application:unset_env(ssl, session_cb),
+    end_per_testcase(default_action, Config);
+end_per_testcase(session_cache_process_mnesia, Config) ->
+    application:unset_env(ssl, session_cb),
+    application:unset_env(ssl, session_cb_init_args),
+    mnesia:stop(),
+    ssl:stop(),
+    ssl:start(),
+    end_per_testcase(default_action, Config);
+end_per_testcase(_TestCase, Config) ->
+    Dog = ?config(watchdog, Config),
+    case Dog of
+	undefined ->
+	    ok;
+	_ ->
+	    test_server:timetrap_cancel(Dog)
+    end.
+
+%%--------------------------------------------------------------------
+%% Function: all(Clause) -> TestCases
+%% Clause - atom() - suite | doc
+%% TestCases - [Case]
+%% Case - atom()
+%%   Name of a test case.
+%% Description: Returns a list of all test cases in this test suite
+%%--------------------------------------------------------------------
+all(doc) ->
+    ["Test session cach API"];
+
+all(suite) ->
+    [
+     session_cache_process_list, session_cache_process_mnesia
+    ].
+
+session_cache_process_list(doc) ->
+    ["Test reuse of sessions (short handshake)"];
+
+session_cache_process_list(suite) ->
+    [];
+session_cache_process_list(Config) when is_list(Config) ->
+    session_cache_process(list,Config).
+%%--------------------------------------------------------------------
+session_cache_process_mnesia(doc) ->
+    ["Test reuse of sessions (short handshake)"];
+
+session_cache_process_mnesia(suite) ->
+    [];
+session_cache_process_mnesia(Config) when is_list(Config) ->
+    session_cache_process(mnesia,Config).
+
+
+%%--------------------------------------------------------------------
+%%% Session cache API callbacks
+%%--------------------------------------------------------------------
+
+init([Type]) ->
+    ets:new(ssl_test, [named_table, public, set]),
+    ets:insert(ssl_test, {type, Type}),
+    case Type of
+	list ->
+	    spawn(fun() -> session_loop([]) end);
+	mnesia ->
+	    mnesia:start(),
+	    {atomic,ok} = mnesia:create_table(sess_cache, []),
+	    sess_cache
+    end.
+
+session_cb() ->
+    [{type, Type}] = ets:lookup(ssl_test, type),
+    Type.
+
+terminate(Cache) ->
+    case session_cb() of
+	list ->
+	    Cache ! terminate;
+	mnesia ->
+	    catch {atomic,ok} =
+		mnesia:delete_table(sess_cache)
+    end.
+
+lookup(Cache, Key) ->
+    case session_cb() of
+	list ->
+	    Cache ! {self(), lookup, Key},
+	    receive {Cache, Res} -> Res end;
+	mnesia ->
+	    case mnesia:transaction(fun() ->
+					    mnesia:read(sess_cache,
+							Key, read)
+				    end) of
+		{atomic, [{sess_cache, Key, Value}]} ->
+		    Value;
+		_ ->
+		    undefined
+	    end
+	end.
+
+update(Cache, Key, Value) ->
+    case session_cb() of
+	list ->
+	    Cache ! {update, Key, Value};
+	mnesia ->
+	    {atomic, ok} =
+		mnesia:transaction(fun() ->
+					   mnesia:write(sess_cache,
+							{sess_cache, Key, Value}, write)
+				   end)
+    end.
+
+delete(Cache, Key) ->
+    case session_cb() of
+	list ->
+	    Cache ! {delete, Key};
+	mnesia ->
+	    {atomic, ok} =
+		mnesia:transaction(fun() ->
+					   mnesia:delete(sess_cache, Key)
+				   end)
+    end.
+
+foldl(Fun, Acc, Cache) ->
+    case session_cb() of
+	list ->
+	    Cache ! {self(),foldl,Fun,Acc},
+	    receive {Cache, Res} -> Res end;
+	mnesia ->
+	    Foldl = fun() ->
+			    mnesia:foldl(Fun, Acc, sess_cache)
+		    end,
+	    {atomic, Res} = mnesia:transaction(Foldl),
+	    Res
+    end.
+
+select_session(Cache, PartialKey) ->
+    case session_cb() of
+	list ->
+	    Cache ! {self(),select_session, PartialKey},
+	    receive
+		{Cache, Res} ->
+		    Res
+	    end;
+	mnesia ->
+	    Sel = fun() ->
+			  mnesia:select(Cache,
+					[{{sess_cache,{PartialKey,'$1'}, '$2'},
+					  [],['$$']}])
+		  end,
+	    {atomic, Res} = mnesia:transaction(Sel),
+	    Res
+    end.
+
+session_loop(Sess) ->
+    receive
+	terminate ->
+	    ok;
+	{Pid, lookup, Key} ->
+	    case lists:keysearch(Key,1,Sess) of
+		{value, {Key,Value}} ->
+		    Pid ! {self(), Value};
+		_ ->
+		    Pid ! {self(), undefined}
+	    end,
+	    session_loop(Sess);
+	{update, Key, Value} ->
+	    NewSess = [{Key,Value}| lists:keydelete(Key,1,Sess)],
+	    session_loop(NewSess);
+	{delete, Key} ->
+	    session_loop(lists:keydelete(Key,1,Sess));
+	{Pid,foldl,Fun,Acc} ->
+	    Res = lists:foldl(Fun, Acc,Sess),
+	    Pid ! {self(), Res},
+	    session_loop(Sess);
+	{Pid,select_session,PKey} ->
+	    Sel = fun({{PKey0, Id},Session}, Acc) when PKey == PKey0 ->
+			  [[Id, Session]|Acc];
+		     (_,Acc) ->
+			  Acc
+		  end,
+	    Sessions = lists:foldl(Sel, [], Sess),
+	    Pid ! {self(), Sessions},
+	    session_loop(Sess)
+    end.
+
+%%--------------------------------------------------------------------
+%%% Internal functions
+%%--------------------------------------------------------------------
+
+session_cache_process(_Type,Config) when is_list(Config) ->
+    ssl_basic_SUITE:reuse_session(Config).