Merge branch 'bjorn/cleanup'

* bjorn/cleanup:
  epp: Only flatten the original filename
  epp: Modernize the internal data structures
  epp: Eliminate the Type argument from expand_macros/5
  epp: Refactor user_predef/2 to share more code
  epp: Refactor scan_define()
  epp: Remove vestigial support for packages
  epp_SUITE: Improve coverage of epp
  epp_SUITE: Extend smoke and cover test of format_error/1
  epp_SUITE: Add test of -extends()

2 files changed, 193 insertions, 189 deletions

diff --git a/lib/stdlib/src/epp.erl b/lib/stdlib/src/epp.erl
index c8bba579cc..45f616bb02 100644
--- a/lib/stdlib/src/epp.erl
+++ b/lib/stdlib/src/epp.erl
@@ -40,7 +40,7 @@
 
 -type ifdef() :: 'ifdef' | 'ifndef' | 'else'.
 
--type name() :: {'atom', atom()}.
+-type name() :: atom().
 -type argspec() :: 'none'                       %No arguments
                  | non_neg_integer().           %Number of arguments
 -type tokens() :: [erl_scan:token()].
@@ -58,21 +58,14 @@
               istk=[] :: [ifdef()],             %Ifdef stack
               sstk=[] :: [#epp{}],              %State stack
               path=[] :: [file:name()],         %Include-path
-              macs = dict:new()                 %Macros (don't care locations)
-                  :: dict:dict(name(), {argspec(), tokens()}),
-              uses = dict:new()                 %Macro use structure
-                  :: dict:dict(name(), [{argspec(), [used()]}]),
+              macs = #{}		        %Macros (don't care locations)
+	            :: #{name() => {argspec(), tokens()}},
+              uses = #{}			%Macro use structure
+	            :: #{name() => [{argspec(), [used()]}]},
               default_encoding = ?DEFAULT_ENCODING :: source_encoding(),
 	      pre_opened = false :: boolean()
 	     }).
 
-%%% Note on representation: as tokens, both {var, Location, Name} and
-%%% {atom, Location, Name} can occur as macro identifiers. However, keeping
-%%% this distinction here is done for historical reasons only: previously,
-%%% ?FOO and ?'FOO' were not the same, but now they are. Removing the
-%%% distinction in the internal representation would simplify the code
-%%% a little.
-
 %% open(Options)
 %% open(FileName, IncludePath)
 %% open(FileName, IncludePath, PreDefMacros)
@@ -550,7 +543,8 @@ init_server(Pid, Name, Options, St0) ->
 			 default_encoding=DefEncoding},
             From = wait_request(St),
             Anno = erl_anno:new(AtLocation),
-            enter_file_reply(From, Name, Anno, AtLocation, code),
+            enter_file_reply(From, file_name(Name), Anno,
+			     AtLocation, code),
             wait_req_scan(St);
 	{error,E} ->
 	    epp_reply(Pid, {error,E})
@@ -561,18 +555,18 @@ init_server(Pid, Name, Options, St0) ->
 %%  FILE, LINE, MODULE as undefined, MACHINE and MACHINE value.
 
 predef_macros(File) ->
-     Machine = list_to_atom(erlang:system_info(machine)),
-     Anno = line1(),
-     dict:from_list([
-	{{atom,'FILE'}, 	      {none,[{string,Anno,File}]}},
-	{{atom,'LINE'},		      {none,[{integer,Anno,1}]}},
-	{{atom,'MODULE'},	      undefined},
-	{{atom,'MODULE_STRING'},      undefined},
-	{{atom,'BASE_MODULE'},	      undefined},
-	{{atom,'BASE_MODULE_STRING'}, undefined},
-	{{atom,'MACHINE'},	      {none,[{atom,Anno,Machine}]}},
-	{{atom,Machine},	      {none,[{atom,Anno,true}]}}
-     ]).
+    Machine = list_to_atom(erlang:system_info(machine)),
+    Anno = line1(),
+    Defs = [{'FILE', 	           {none,[{string,Anno,File}]}},
+	    {'LINE',		   {none,[{integer,Anno,1}]}},
+	    {'MODULE',	           undefined},
+	    {'MODULE_STRING',      undefined},
+	    {'BASE_MODULE',	   undefined},
+	    {'BASE_MODULE_STRING', undefined},
+	    {'MACHINE',	           {none,[{atom,Anno,Machine}]}},
+	    {Machine,	           {none,[{atom,Anno,true}]}}
+	   ],
+    maps:from_list(Defs).
 
 %% user_predef(PreDefMacros, Macros) ->
 %%	{ok,MacroDict} | {error,E}
@@ -581,28 +575,21 @@ predef_macros(File) ->
 
 user_predef([{M,Val,redefine}|Pdm], Ms) when is_atom(M) ->
     Exp = erl_parse:tokens(erl_parse:abstract(Val)),
-    user_predef(Pdm, dict:store({atom,M}, {none,Exp}, Ms));
+    user_predef(Pdm, Ms#{M=>{none,Exp}});
 user_predef([{M,Val}|Pdm], Ms) when is_atom(M) ->
-    case dict:find({atom,M}, Ms) of
-	{ok,_Defs} when is_list(_Defs) -> %% User defined macros
+    case Ms of
+	#{M:=Defs} when is_list(Defs) ->
+	     %% User defined macros.
 	    {error,{redefine,M}};
-	{ok,_Def} -> %% Predefined macros
+	#{M:=_Defs} ->
+	    %% Predefined macros.
 	    {error,{redefine_predef,M}};
-	error ->
+	_ ->
 	    Exp = erl_parse:tokens(erl_parse:abstract(Val)),
-	    user_predef(Pdm, dict:store({atom,M}, [{none, {none,Exp}}], Ms))
+	    user_predef(Pdm, Ms#{M=>[{none,{none,Exp}}]})
     end;
 user_predef([M|Pdm], Ms) when is_atom(M) ->
-    case dict:find({atom,M}, Ms) of
-	{ok,_Defs} when is_list(_Defs) -> %% User defined macros
-	    {error,{redefine,M}};
-	{ok,_Def} -> %% Predefined macros
-	    {error,{redefine_predef,M}};
-	error ->
-            A = line1(),
-	    user_predef(Pdm,
-	                dict:store({atom,M}, [{none, {none,[{atom,A,true}]}}], Ms))
-    end;
+    user_predef([{M,true}|Pdm], Ms);
 user_predef([Md|_Pdm], _Ms) -> {error,{bad,Md}};
 user_predef([], Ms) -> {ok,Ms}.
 
@@ -616,7 +603,9 @@ wait_request(St) ->
     receive
 	{epp_request,From,scan_erl_form} -> From;
 	{epp_request,From,macro_defs} ->
-	    epp_reply(From, dict:to_list(St#epp.macs)),
+	    %% Return the old format to avoid any incompability issues.
+	    Defs = [{{atom,K},V} || {K,V} <- maps:to_list(St#epp.macs)],
+	    epp_reply(From, Defs),
 	    wait_request(St);
 	{epp_request,From,close} ->
 	    close_file(St),
@@ -668,7 +657,8 @@ enter_file(NewName, Inc, From, St) ->
 enter_file2(NewF, Pname, From, St0, AtLocation) ->
     Anno = erl_anno:new(AtLocation),
     enter_file_reply(From, Pname, Anno, AtLocation, code),
-    Ms = dict:store({atom,'FILE'}, {none,[{string,Anno,Pname}]}, St0#epp.macs),
+    Ms0 = St0#epp.macs,
+    Ms = Ms0#{'FILE':={none,[{string,Anno,Pname}]}},
     %% update the head of the include path to be the directory of the new
     %% source file, so that an included file can always include other files
     %% relative to its current location (this is also how C does it); note
@@ -689,7 +679,7 @@ enter_file_reply(From, Name, LocationAnno, AtLocation, Where) ->
                generated -> erl_anno:set_generated(true, Anno0)
            end,
     Rep = {ok, [{'-',Anno},{atom,Anno,file},{'(',Anno},
-		{string,Anno,file_name(Name)},{',',Anno},
+		{string,Anno,Name},{',',Anno},
 		{integer,Anno,get_line(LocationAnno)},{')',LocationAnno},
                 {dot,Anno}]},
     epp_reply(From, Rep).
@@ -720,9 +710,8 @@ leave_file(From, St) ->
                          name2=OldName2} = OldSt,
                     CurrLoc = add_line(OldLoc, Delta),
                     Anno = erl_anno:new(CurrLoc),
-		    Ms = dict:store({atom,'FILE'},
-				    {none,[{string,Anno,OldName2}]},
-				    St#epp.macs),
+		    Ms0 = St#epp.macs,
+		    Ms = Ms0#{'FILE':={none,[{string,Anno,OldName2}]}},
                     NextSt = OldSt#epp{sstk=Sts,macs=Ms,uses=St#epp.uses},
 		    enter_file_reply(From, OldName, Anno, CurrLoc, code),
                     case OldName2 =:= OldName of
@@ -797,91 +786,48 @@ scan_toks(Toks0, From, St) ->
     end.
 
 scan_module([{'-',_Lh},{atom,_Lm,module},{'(',_Ll}|Ts], Ms) ->
-    scan_module_1(Ts, [], Ms);
+    scan_module_1(Ts, Ms);
 scan_module([{'-',_Lh},{atom,_Lm,extends},{'(',_Ll}|Ts], Ms) ->
-    scan_extends(Ts, [], Ms);
+    scan_extends(Ts, Ms);
 scan_module(_Ts, Ms) -> Ms.
 
-scan_module_1([{atom,_,_}=A,{',',L}|Ts], As, Ms) ->
+scan_module_1([{atom,_,_}=A,{',',L}|Ts], Ms) ->
     %% Parameterized modules.
-    scan_module_1([A,{')',L}|Ts], As, Ms);
-scan_module_1([{atom,Ln,A},{')',_Lr}|_Ts], As, Ms0) ->
-    Mod = lists:concat(lists:reverse([A|As])),
-    Ms = dict:store({atom,'MODULE'},
-		     {none,[{atom,Ln,list_to_atom(Mod)}]}, Ms0),
-    dict:store({atom,'MODULE_STRING'}, {none,[{string,Ln,Mod}]}, Ms);
-scan_module_1([{atom,_Ln,A},{'.',_Lr}|Ts], As, Ms) ->
-    scan_module_1(Ts, [".",A|As], Ms);
-scan_module_1([{'.',_Lr}|Ts], As, Ms) ->
-    scan_module_1(Ts, As, Ms);
-scan_module_1(_Ts, _As, Ms) -> Ms.
-
-scan_extends([{atom,Ln,A},{')',_Lr}|_Ts], As, Ms0) ->
-    Mod = lists:concat(lists:reverse([A|As])),
-    Ms = dict:store({atom,'BASE_MODULE'},
-		     {none,[{atom,Ln,list_to_atom(Mod)}]}, Ms0),
-    dict:store({atom,'BASE_MODULE_STRING'}, {none,[{string,Ln,Mod}]}, Ms);
-scan_extends([{atom,_Ln,A},{'.',_Lr}|Ts], As, Ms) ->
-    scan_extends(Ts, [".",A|As], Ms);
-scan_extends([{'.',_Lr}|Ts], As, Ms) ->
-    scan_extends(Ts, As, Ms);
-scan_extends(_Ts, _As, Ms) -> Ms.
+    scan_module_1([A,{')',L}|Ts], Ms);
+scan_module_1([{atom,Ln,A}=ModAtom,{')',_Lr}|_Ts], Ms0) ->
+    ModString = atom_to_list(A),
+    Ms = Ms0#{'MODULE':={none,[ModAtom]}},
+    Ms#{'MODULE_STRING':={none,[{string,Ln,ModString}]}};
+scan_module_1(_Ts, Ms) -> Ms.
+
+scan_extends([{atom,Ln,A}=ModAtom,{')',_Lr}|_Ts], Ms0) ->
+    ModString = atom_to_list(A),
+    Ms = Ms0#{'BASE_MODULE':={none,[ModAtom]}},
+    Ms#{'BASE_MODULE_STRING':={none,[{string,Ln,ModString}]}};
+scan_extends(_Ts, Ms) -> Ms.
 
 %% scan_define(Tokens, DefineToken, From, EppState)
 
-scan_define([{'(',_Lp},{Type,_Lm,M}=Mac,{',',_}=Comma|Toks], _Def, From, St)
+scan_define([{'(',_Lp},{Type,_Lm,_}=Mac|Toks], Def, From, St)
   when Type =:= atom; Type =:= var ->
+    scan_define_1(Toks, Mac, Def, From, St);
+scan_define(_Toks, Def, From, St) ->
+    epp_reply(From, {error,{loc(Def),epp,{bad,define}}}),
+    wait_req_scan(St).
+
+scan_define_1([{',',_}=Comma|Toks], Mac,_Def, From, St) ->
     case catch macro_expansion(Toks, Comma) of
         Expansion when is_list(Expansion) ->
-            case dict:find({atom,M}, St#epp.macs) of
-                {ok, Defs} when is_list(Defs) ->
-                    %% User defined macros: can be overloaded
-                    case proplists:is_defined(none, Defs) of
-                        true ->
-                            epp_reply(From, {error,{loc(Mac),epp,{redefine,M}}}),
-                            wait_req_scan(St);
-                        false ->
-                            scan_define_cont(From, St,
-                                             {atom, M},
-                                             {none, {none,Expansion}})
-                    end;
-                {ok, _PreDef} ->
-                    %% Predefined macros: cannot be overloaded
-                    epp_reply(From, {error,{loc(Mac),epp,{redefine_predef,M}}}),
-                    wait_req_scan(St);
-                error ->
-                    scan_define_cont(From, St,
-                                     {atom, M},
-                                     {none, {none,Expansion}})
-            end;
+	    scan_define_2(none, {none,Expansion}, Mac, From, St);
         {error,ErrL,What} ->
             epp_reply(From, {error,{ErrL,epp,What}}),
             wait_req_scan(St)
     end;
-scan_define([{'(',_Lp},{Type,_Lm,M}=Mac,{'(',_Lc}|Toks], Def, From, St)
-  when Type =:= atom; Type =:= var ->
+scan_define_1([{'(',_Lc}|Toks], Mac, Def, From, St) ->
     case catch macro_pars(Toks, []) of
-        {ok, {As,Me}} ->
+        {ok,{As,_}=MacroDef} ->
             Len = length(As),
-            case dict:find({atom,M}, St#epp.macs) of
-                {ok, Defs} when is_list(Defs) ->
-                    %% User defined macros: can be overloaded
-                    case proplists:is_defined(Len, Defs) of
-                        true ->
-                            epp_reply(From,{error,{loc(Mac),epp,{redefine,M}}}),
-                            wait_req_scan(St);
-                        false ->
-                            scan_define_cont(From, St, {atom, M},
-                                             {Len, {As, Me}})
-                    end;
-                {ok, _PreDef} ->
-                    %% Predefined macros: cannot be overloaded
-                    %% (There are currently no predefined F(...) macros.)
-                    epp_reply(From, {error,{loc(Mac),epp,{redefine_predef,M}}}),
-                    wait_req_scan(St);
-                error ->
-                    scan_define_cont(From, St, {atom, M}, {Len, {As, Me}})
-            end;
+	    scan_define_2(Len, MacroDef, Mac, From, St);
 	{error,ErrL,What} ->
             epp_reply(From, {error,{ErrL,epp,What}}),
             wait_req_scan(St);
@@ -889,10 +835,29 @@ scan_define([{'(',_Lp},{Type,_Lm,M}=Mac,{'(',_Lc}|Toks], Def, From, St)
             epp_reply(From, {error,{loc(Def),epp,{bad,define}}}),
             wait_req_scan(St)
     end;
-scan_define(_Toks, Def, From, St) ->
+scan_define_1(_Toks, _Mac, Def, From, St) ->
     epp_reply(From, {error,{loc(Def),epp,{bad,define}}}),
     wait_req_scan(St).
 
+scan_define_2(Arity, Def, {_,_,Key}=Mac, From, #epp{macs=Ms}=St) ->
+    case Ms of
+	#{Key:=Defs} when is_list(Defs) ->
+	    %% User defined macros: can be overloaded
+	    case proplists:is_defined(Arity, Defs) of
+		true ->
+		    epp_reply(From, {error,{loc(Mac),epp,{redefine,Key}}}),
+		    wait_req_scan(St);
+		false ->
+		    scan_define_cont(From, St, Key, Defs, Arity, Def)
+	    end;
+	#{Key:=_} ->
+	    %% Predefined macros: cannot be overloaded
+	    epp_reply(From, {error,{loc(Mac),epp,{redefine_predef,Key}}}),
+	    wait_req_scan(St);
+	_ ->
+	    scan_define_cont(From, St, Key, [], Arity, Def)
+    end.
+
 %%% Detection of circular macro expansions (which would either keep
 %%% the compiler looping forever, or run out of memory):
 %%% When a macro is defined, we store the names of other macros it
@@ -902,11 +867,17 @@ scan_define(_Toks, Def, From, St) ->
 %%% the information from St#epp.uses is traversed, and if a circularity
 %%% is detected, an error message is thrown.
 
-scan_define_cont(F, St, M, {Arity, Def}) ->
-    Ms = dict:append_list(M, [{Arity, Def}], St#epp.macs),
-    try dict:append_list(M, [{Arity, macro_uses(Def)}], St#epp.uses) of
+scan_define_cont(F, #epp{macs=Ms0}=St, M, Defs, Arity, Def) ->
+    Ms = Ms0#{M=>[{Arity,Def}|Defs]},
+    try macro_uses(Def) of
         U ->
-            scan_toks(F, St#epp{uses=U, macs=Ms})
+	    Uses0 = St#epp.uses,
+	    Val = [{Arity,U}|case Uses0 of
+				 #{M:=UseList} -> UseList;
+				 _ -> []
+			     end],
+	    Uses = Uses0#{M=>Val},
+            scan_toks(F, St#epp{uses=Uses,macs=Ms})
     catch
         {error, Line, Reason} ->
             epp_reply(F, {error,{Line,epp,Reason}}),
@@ -924,23 +895,23 @@ macro_ref([{'?', _}, {'?', _} | Rest]) ->
 macro_ref([{'?', _}, {atom, _, A}=Atom | Rest]) ->
     Lm = loc(Atom),
     Arity = count_args(Rest, Lm, A),
-    [{{atom, A}, Arity} | macro_ref(Rest)];
+    [{A,Arity} | macro_ref(Rest)];
 macro_ref([{'?', _}, {var, _, A}=Var | Rest]) ->
     Lm = loc(Var),
     Arity = count_args(Rest, Lm, A),
-    [{{atom, A}, Arity} | macro_ref(Rest)];
+    [{A,Arity} | macro_ref(Rest)];
 macro_ref([_Token | Rest]) ->
     macro_ref(Rest).
 
 %% scan_undef(Tokens, UndefToken, From, EppState)
 
 scan_undef([{'(',_Llp},{atom,_Lm,M},{')',_Lrp},{dot,_Ld}], _Undef, From, St) ->
-    Macs = dict:erase({atom,M}, St#epp.macs),
-    Uses = dict:erase({atom,M}, St#epp.uses),
+    Macs = maps:remove(M, St#epp.macs),
+    Uses = maps:remove(M, St#epp.uses),
     scan_toks(From, St#epp{macs=Macs, uses=Uses});
 scan_undef([{'(',_Llp},{var,_Lm,M},{')',_Lrp},{dot,_Ld}], _Undef, From,St) ->
-    Macs = dict:erase({atom,M}, St#epp.macs),
-    Uses = dict:erase({atom,M}, St#epp.uses),
+    Macs = maps:remove(M, St#epp.macs),
+    Uses = maps:remove(M, St#epp.uses),
     scan_toks(From, St#epp{macs=Macs, uses=Uses});
 scan_undef(_Toks, Undef, From, St) ->
     epp_reply(From, {error,{loc(Undef),epp,{bad,undef}}}),
@@ -1007,17 +978,17 @@ scan_include_lib(_Toks, Inc, From, St) ->
 %%  Report a badly formed if[n]def test and then treat as undefined macro.
 
 scan_ifdef([{'(',_Llp},{atom,_Lm,M},{')',_Lrp},{dot,_Ld}], _IfD, From, St) ->
-    case dict:find({atom,M}, St#epp.macs) of
-	{ok,_Def} ->
+    case St#epp.macs of
+	#{M:=_Def} ->
 	    scan_toks(From, St#epp{istk=[ifdef|St#epp.istk]});
-	error ->
+	_ ->
 	    skip_toks(From, St, [ifdef])
     end;
 scan_ifdef([{'(',_Llp},{var,_Lm,M},{')',_Lrp},{dot,_Ld}], _IfD, From, St) ->
-    case dict:find({atom,M}, St#epp.macs) of
-	{ok,_Def} ->
+    case St#epp.macs of
+	#{M:=_Def} ->
 	    scan_toks(From, St#epp{istk=[ifdef|St#epp.istk]});
-	error ->
+	_ ->
 	    skip_toks(From, St, [ifdef])
     end;
 scan_ifdef(_Toks, IfDef, From, St) ->
@@ -1025,17 +996,17 @@ scan_ifdef(_Toks, IfDef, From, St) ->
     wait_req_skip(St, [ifdef]).
 
 scan_ifndef([{'(',_Llp},{atom,_Lm,M},{')',_Lrp},{dot,_Ld}], _IfnD, From, St) ->
-    case dict:find({atom,M}, St#epp.macs) of
-	{ok,_Def} ->
+    case St#epp.macs of
+	#{M:=_Def} ->
 	    skip_toks(From, St, [ifndef]);
-	error ->
+	_ ->
 	    scan_toks(From, St#epp{istk=[ifndef|St#epp.istk]})
     end;
 scan_ifndef([{'(',_Llp},{var,_Lm,M},{')',_Lrp},{dot,_Ld}], _IfnD, From, St) ->
-    case dict:find({atom,M}, St#epp.macs) of
-	{ok,_Def} ->
+    case St#epp.macs of
+	#{M:=_Def} ->
 	    skip_toks(From, St, [ifndef]);
-	error ->
+	_ ->
 	    scan_toks(From, St#epp{istk=[ifndef|St#epp.istk]})
     end;
 scan_ifndef(_Toks, IfnDef, From, St) ->
@@ -1103,7 +1074,8 @@ scan_file([{'(',_Llp},{string,_Ls,Name},{',',_Lc},{integer,_Li,Ln},{')',_Lrp},
            {dot,_Ld}], Tf, From, St) ->
     Anno = erl_anno:new(Ln),
     enter_file_reply(From, Name, Anno, loc(Tf), generated),
-    Ms = dict:store({atom,'FILE'}, {none,[{string,line1(),Name}]}, St#epp.macs),
+    Ms0 = St#epp.macs,
+    Ms = Ms0#{'FILE':={none,[{string,line1(),Name}]}},
     Locf = loc(Tf),
     NewLoc = new_location(Ln, St#epp.location, Locf),
     Delta = get_line(element(2, Tf))-Ln + St#epp.delta,
@@ -1191,40 +1163,42 @@ macro_expansion([], Anno0) -> throw({error,loc(Anno0),premature_end}).
 %%  Expand the macros in a list of tokens, making sure that an expansion
 %%  gets the same location as the macro call.
 
-expand_macros(Type, MacT, M, Toks, Ms0) ->
-    %% (Type will always be 'atom')
-    {Ms, U} = Ms0,
+expand_macros(MacT, M, Toks, Ms0) ->
+    {Ms,U} = Ms0,
     Lm = loc(MacT),
     Tinfo = element(2, MacT),
-    case expand_macro1(Type, Lm, M, Toks, Ms) of
+    case expand_macro1(Lm, M, Toks, Ms) of
 	{ok,{none,Exp}} ->
-	    check_uses([{{Type,M}, none}], [], U, Lm),
-	    Toks1 = expand_macros(expand_macro(Exp, Tinfo, [], dict:new()), Ms0),
+	    check_uses([{M,none}], [], U, Lm),
+	    Toks1 = expand_macros(expand_macro(Exp, Tinfo, [], #{}), Ms0),
 	    expand_macros(Toks1++Toks, Ms0);
 	{ok,{As,Exp}} ->
-	    check_uses([{{Type,M}, length(As)}], [], U, Lm),
-	    {Bs,Toks1} = bind_args(Toks, Lm, M, As, dict:new()),
+	    check_uses([{M,length(As)}], [], U, Lm),
+	    {Bs,Toks1} = bind_args(Toks, Lm, M, As, #{}),
 	    expand_macros(expand_macro(Exp, Tinfo, Toks1, Bs), Ms0)
     end.
 
-expand_macro1(Type, Lm, M, Toks, Ms) ->
+expand_macro1(Lm, M, Toks, Ms) ->
     Arity = count_args(Toks, Lm, M),
-    case dict:find({Type,M}, Ms) of
-        error -> %% macro not found
-            throw({error,Lm,{undefined,M,Arity}});
-        {ok, undefined} -> %% Predefined macro without definition
+    case Ms of
+	#{M:=undefined} ->
+	    %% Predefined macro without definition.
             throw({error,Lm,{undefined,M,Arity}});
-        {ok, [{none, Def}]} ->
-            {ok, Def};
-        {ok, Defs} when is_list(Defs) ->
-            case proplists:get_value(Arity, Defs) of
+	#{M:=[{none,Def}]} ->
+            {ok,Def};
+	#{M:=Defs} when is_list(Defs) ->
+	    case proplists:get_value(Arity, Defs) of
                 undefined ->
                     throw({error,Lm,{mismatch,M}});
                 Def ->
-                    {ok, Def}
+                    {ok,Def}
             end;
-        {ok, PreDef} -> %% Predefined macro
-            {ok, PreDef}
+        #{M:=PreDef} ->
+	    %% Predefined macro.
+            {ok,PreDef};
+        _ ->
+	    %% Macro not found.
+            throw({error,Lm,{undefined,M,Arity}})
     end.
 
 check_uses([], _Anc, _U, _Lm) ->
@@ -1232,7 +1206,7 @@ check_uses([], _Anc, _U, _Lm) ->
 check_uses([M|Rest], Anc, U, Lm) ->
     case lists:member(M, Anc) of
 	true ->
-	    {{_, Name},Arity} = M,
+	    {Name,Arity} = M,
 	    throw({error,Lm,{circular,Name,Arity}});
 	false ->
 	    L = get_macro_uses(M, U),
@@ -1241,23 +1215,23 @@ check_uses([M|Rest], Anc, U, Lm) ->
     end.
 
 get_macro_uses({M,Arity}, U) ->
-    case dict:find(M, U) of
-	error ->
-	    [];
-	{ok, L} ->
-	    proplists:get_value(Arity, L, proplists:get_value(none, L, []))
+    case U of
+	#{M:=L} ->
+	    proplists:get_value(Arity, L, proplists:get_value(none, L, []));
+	_ ->
+	    []
     end.
 
 %% Macro expansion
 %% Note: io:scan_erl_form() does not return comments or white spaces.
 expand_macros([{'?',_Lq},{atom,_Lm,M}=MacT|Toks], Ms) ->
-    expand_macros(atom, MacT, M, Toks, Ms);
+    expand_macros(MacT, M, Toks, Ms);
 %% Special macros
 expand_macros([{'?',_Lq},{var,Lm,'LINE'}=Tok|Toks], Ms) ->
     Line = erl_scan:line(Tok),
     [{integer,Lm,Line}|expand_macros(Toks, Ms)];
 expand_macros([{'?',_Lq},{var,_Lm,M}=MacT|Toks], Ms) ->
-    expand_macros(atom, MacT, M, Toks, Ms);
+    expand_macros(MacT, M, Toks, Ms);
 %% Illegal macros
 expand_macros([{'?',_Lq},Token|_Toks], _Ms) ->
     T = case erl_scan:text(Token) of
@@ -1296,7 +1270,7 @@ macro_args(_Toks, Lm, M, _As, _Bs) ->
 store_arg(L, M, _A, [], _Bs) ->
     throw({error,L,{mismatch,M}});
 store_arg(_L, _M, A, Arg, Bs) ->
-    dict:store(A, Arg, Bs).
+    Bs#{A=>Arg}.
 
 %% count_args(Tokens, MacroLine, MacroName)
 %%  Count the number of arguments in a macro call.
@@ -1369,19 +1343,17 @@ macro_arg([], _E, Arg) ->
 %%  and then the macro arguments, i.e. simulate textual expansion.
 
 expand_macro([{var,_Lv,V}|Ts], L, Rest, Bs) ->
-    case dict:find(V, Bs) of
-	{ok,Val} ->
-	    %% lists:append(Val, expand_macro(Ts, L, Rest, Bs));
+    case Bs of
+	#{V:=Val} ->
 	    expand_arg(Val, Ts, L, Rest, Bs);
-	error ->
+	_ ->
 	    [{var,L,V}|expand_macro(Ts, L, Rest, Bs)]
     end;
 expand_macro([{'?', _}, {'?', _}, {var,_Lv,V}|Ts], L, Rest, Bs) ->
-    case dict:find(V, Bs) of
-	{ok,Val} ->
-	    %% lists:append(Val, expand_macro(Ts, L, Rest, Bs));
+    case Bs of
+	#{V:=Val} ->
             expand_arg(stringify(Val, L), Ts, L, Rest, Bs);
-	error ->
+	_ ->
 	    [{var,L,V}|expand_macro(Ts, L, Rest, Bs)]
     end;
 expand_macro([T|Ts], L, Rest, Bs) ->
diff --git a/lib/stdlib/test/epp_SUITE.erl b/lib/stdlib/test/epp_SUITE.erl
index 199d2f193d..4c007e76ad 100644
--- a/lib/stdlib/test/epp_SUITE.erl
+++ b/lib/stdlib/test/epp_SUITE.erl
@@ -27,7 +27,7 @@
          pmod/1, not_circular/1, skip_header/1, otp_6277/1, otp_7702/1,
          otp_8130/1, overload_mac/1, otp_8388/1, otp_8470/1, otp_8503/1,
          otp_8562/1, otp_8665/1, otp_8911/1, otp_10302/1, otp_10820/1,
-         otp_11728/1, encoding/1]).
+         otp_11728/1, encoding/1, extends/1]).
 
 -export([epp_parse_erl_form/2]).
 
@@ -70,7 +70,7 @@ all() ->
      not_circular, skip_header, otp_6277, otp_7702, otp_8130,
      overload_mac, otp_8388, otp_8470, otp_8503, otp_8562,
      otp_8665, otp_8911, otp_10302, otp_10820, otp_11728,
-     encoding].
+     encoding, extends].
 
 groups() -> 
     [{upcase_mac, [], [upcase_mac_1, upcase_mac_2]},
@@ -621,6 +621,10 @@ otp_8130(Config) when is_list(Config) ->
              "                2 end,\n"
              "          7),\n"
              "   {2,7} =\n"
+             "      ?M1(begin 1 = fun _Name () -> 1 end(),\n"
+             "                2 end,\n"
+             "          7),\n"
+             "   {2,7} =\n"
              "      ?M1(begin 1 = fun t0/0(),\n"
              "                2 end,\n"
              "          7),\n"
@@ -645,6 +649,9 @@ otp_8130(Config) when is_list(Config) ->
              "      ?M1(begin yes = try 1 of 1 -> yes after foo end,\n"
              "                2 end,\n"
              "          7),\n"
+             "   {[42],7} =\n"
+             "      ?M1([42],\n"
+             "          7),\n"
              "ok.\n">>,
            ok},
 
@@ -728,11 +735,16 @@ otp_8130(Config) when is_list(Config) ->
            {errors,[{{2,2},epp,{include,lib,"$apa/foo.hrl"}}],[]}},
 
 
-          {otp_8130_c9,
+          {otp_8130_c9a,
            <<"-define(S, ?S).\n"
              "t() -> ?S.\n">>,
            {errors,[{{2,9},epp,{circular,'S', none}}],[]}},
 
+          {otp_8130_c9b,
+           <<"-define(S(), ?S()).\n"
+             "t() -> ?S().\n">>,
+           {errors,[{{2,9},epp,{circular,'S', 0}}],[]}},
+
           {otp_8130_c10,
            <<"\n-file.">>,
            {errors,[{{2,2},epp,{bad,file}}],[]}},
@@ -799,6 +811,10 @@ otp_8130(Config) when is_list(Config) ->
            <<"\n-include(\"no such file.erl\").\n">>,
            {errors,[{{2,2},epp,{include,file,"no such file.erl"}}],[]}},
 
+          {otp_8130_c25,
+           <<"\n-define(A.\n">>,
+           {errors,[{{2,2},epp,{bad,define}}],[]}},
+
           {otp_8130_7,
            <<"-record(b, {b}).\n"
              "-define(A, {{a,#b.b.\n"
@@ -1476,6 +1492,20 @@ encoding(Config) when is_list(Config) ->
 	epp_parse_file(ErlFile, [{default_encoding,utf8},extra]),
     ok.
 
+extends(Config) ->
+    Cs = [{extends_c1,
+	   <<"-extends(some.other.module).\n">>,
+	   {errors,[{1,erl_parse,["syntax error before: ","'.'"]}],[]}}],
+    [] = compile(Config, Cs),
+
+    Ts = [{extends_1,
+	   <<"-extends(some_other_module).\n"
+	     "t() -> {?BASE_MODULE,?BASE_MODULE_STRING}.\n">>,
+	   {some_other_module,"some_other_module"}}],
+
+    [] = run(Config, Ts),
+    ok.
+
 
 check(Config, Tests) ->
     eval_tests(Config, fun check_test/2, Tests).
@@ -1504,15 +1534,17 @@ eval_tests(Config, Fun, Tests) ->
 
 check_test(Config, Test) ->
     Filename = "epp_test.erl",
-    ?line PrivDir = ?config(priv_dir, Config),
-    ?line File = filename:join(PrivDir, Filename),
-    ?line ok = file:write_file(File, Test),
-    ?line case epp:parse_file(File, [PrivDir], []) of
-              {ok,Forms} ->
-                  [E || E={error,_} <- Forms];
-              {error,Error} ->
-                  Error
-          end.
+    PrivDir = ?config(priv_dir, Config),
+    File = filename:join(PrivDir, Filename),
+    ok = file:write_file(File, Test),
+    case epp:parse_file(File, [PrivDir], []) of
+	{ok,Forms} ->
+	    Errors = [E || E={error,_} <- Forms],
+	    call_format_error([E || {error,E} <- Errors]),
+	    Errors;
+	{error,Error} ->
+	    Error
+    end.
 
 compile_test(Config, Test0) ->
     Test = [<<"-module(epp_test). -compile(export_all). ">>, Test0],