Fix problems with timetrap handling in common_test:

1. ct:timetrap(infinity) not supported.
2. Previous set timetrap for a test case is not cancelled by new one.

5 files changed, 126 insertions, 20 deletions

diff --git a/lib/common_test/src/ct.erl b/lib/common_test/src/ct.erl
index dfec2b7a67..66da3ef742 100644
--- a/lib/common_test/src/ct.erl
+++ b/lib/common_test/src/ct.erl
@@ -861,6 +861,7 @@ remove_config(Callback, Config) ->
 %%%
 %%% @doc <p>Use this function to set a new timetrap for the running test case.</p>
 timetrap(Time) ->
+    test_server:timetrap_cancel(),
     test_server:timetrap(Time).
 
 %%%-----------------------------------------------------------------
diff --git a/lib/common_test/test/ct_error_SUITE.erl b/lib/common_test/test/ct_error_SUITE.erl
index c4ad2934ae..813467aabe 100644
--- a/lib/common_test/test/ct_error_SUITE.erl
+++ b/lib/common_test/test/ct_error_SUITE.erl
@@ -210,6 +210,23 @@ timetrap_extended(Config) when is_list(Config) ->
     ok = ct_test_support:verify_events(TestEvents, Events, Config).
 
 %%%-----------------------------------------------------------------
+%%%
+timetrap_parallel(Config) when is_list(Config) ->
+    DataDir = ?config(data_dir, Config),
+    Join = fun(D, S) -> filename:join(D, "error/test/"++S) end,
+    Suite = Join(DataDir, "timetrap_3_SUITE"),
+    {Opts,ERPid} = setup([{suite,Suite}], Config),
+    ok = ct_test_support:run(Opts, Config),
+    Events = ct_test_support:get_events(ERPid, Config),
+
+    ct_test_support:log_events(timetrap_parallel,
+			       reformat(Events, ?eh),
+			       ?config(priv_dir, Config)),
+
+    TestEvents = events_to_check(timetrap_parallel),
+    ok = ct_test_support:verify_events(TestEvents, Events, Config).
+
+%%%-----------------------------------------------------------------
 %%% HELP FUNCTIONS
 %%%-----------------------------------------------------------------
 
@@ -735,7 +752,7 @@ test_events(timetrap_normal) ->
     [
      {?eh,start_logging,{'DEF','RUNDIR'}},
      {?eh,test_start,{'DEF',{'START_TIME','LOGDIR'}}},
-     {?eh,start_info,{1,1,3}},
+     {?eh,start_info,{1,1,4}},
      {?eh,tc_start,{timetrap_2_SUITE,init_per_suite}},
      {?eh,tc_done,{timetrap_2_SUITE,init_per_suite,ok}},
      {?eh,tc_start,{timetrap_2_SUITE,tc0}},
@@ -750,6 +767,9 @@ test_events(timetrap_normal) ->
      {?eh,tc_done,
       {timetrap_2_SUITE,tc2,{failed,{timetrap_timeout,500}}}},
      {?eh,test_stats,{0,3,{0,0}}},
+     {?eh,tc_start,{timetrap_2_SUITE,tc3}},
+     {?eh,tc_done,{timetrap_2_SUITE,tc3,ok}},
+     {?eh,test_stats,{1,3,{0,0}}},
      {?eh,tc_start,{timetrap_2_SUITE,end_per_suite}},
      {?eh,tc_done,{timetrap_2_SUITE,end_per_suite,ok}},
      {?eh,test_done,{'DEF','STOP_TIME'}},
@@ -760,7 +780,7 @@ test_events(timetrap_extended) ->
     [
      {?eh,start_logging,{'DEF','RUNDIR'}},
      {?eh,test_start,{'DEF',{'START_TIME','LOGDIR'}}},
-     {?eh,start_info,{1,1,3}},
+     {?eh,start_info,{1,1,4}},
      {?eh,tc_start,{timetrap_2_SUITE,init_per_suite}},
      {?eh,tc_done,{timetrap_2_SUITE,init_per_suite,ok}},
      {?eh,tc_start,{timetrap_2_SUITE,tc0}},
@@ -775,8 +795,52 @@ test_events(timetrap_extended) ->
      {?eh,tc_done,
       {timetrap_2_SUITE,tc2,{failed,{timetrap_timeout,1000}}}},
      {?eh,test_stats,{0,3,{0,0}}},
+     {?eh,tc_start,{timetrap_2_SUITE,tc3}},
+     {?eh,tc_done,{timetrap_2_SUITE,tc3,ok}},
+     {?eh,test_stats,{1,3,{0,0}}},
      {?eh,tc_start,{timetrap_2_SUITE,end_per_suite}},
      {?eh,tc_done,{timetrap_2_SUITE,end_per_suite,ok}},
      {?eh,test_done,{'DEF','STOP_TIME'}},
      {?eh,stop_logging,[]}
-    ].
+    ];
+
+test_events(timetrap_parallel) ->
+    [
+     {?eh,start_logging,{'DEF','RUNDIR'}},
+     {?eh,test_start,{'DEF',{'START_TIME','LOGDIR'}}},
+     {?eh,start_info,{1,1,7}},
+     {?eh,tc_done,{timetrap_3_SUITE,init_per_suite,ok}},
+     {parallel,
+      [{?eh,tc_start,
+	{timetrap_3_SUITE,{init_per_group,g1,[parallel]}}},
+       {?eh,tc_done,
+	{timetrap_3_SUITE,{init_per_group,g1,[parallel]},ok}},
+       {?eh,tc_start,{timetrap_3_SUITE,tc0}},
+       {?eh,tc_start,{timetrap_3_SUITE,tc1}},
+       {?eh,tc_start,{timetrap_3_SUITE,tc2}},
+       {?eh,tc_start,{timetrap_3_SUITE,tc3}},
+       {?eh,tc_start,{timetrap_3_SUITE,tc4}},
+       {?eh,tc_start,{timetrap_3_SUITE,tc6}},
+       {?eh,tc_start,{timetrap_3_SUITE,tc7}},
+       {?eh,tc_done,
+        {timetrap_3_SUITE,tc1,{failed,{timetrap_timeout,500}}}},
+       {?eh,tc_done,
+        {timetrap_3_SUITE,tc2,{failed,{timetrap_timeout,1000}}}},
+       {?eh,tc_done,
+        {timetrap_3_SUITE,tc6,{failed,{timetrap_timeout,1000}}}},
+       {?eh,tc_done,
+        {timetrap_3_SUITE,tc7,{failed,{timetrap_timeout,1500}}}},
+       {?eh,tc_done,
+        {timetrap_3_SUITE,tc0,{failed,{timetrap_timeout,2000}}}},
+       {?eh,tc_done,
+        {timetrap_3_SUITE,tc4,{failed,{timetrap_timeout,2000}}}},
+       {?eh,tc_done,
+        {timetrap_3_SUITE,tc3,{failed,{timetrap_timeout,3000}}}},
+       {?eh,test_stats,{0,7,{0,0}}},
+       {?eh,tc_start,
+	{timetrap_3_SUITE,{end_per_group,g1,[parallel]}}},
+       {?eh,tc_done,
+	{timetrap_3_SUITE,{end_per_group,g1,[parallel]},ok}}]},
+     {?eh,tc_done,{timetrap_3_SUITE,end_per_suite,ok}},
+     {?eh,test_done,{'DEF','STOP_TIME'}},
+     {?eh,stop_logging,[]}].
diff --git a/lib/common_test/test/ct_error_SUITE_data/error/test/timetrap_2_SUITE.erl b/lib/common_test/test/ct_error_SUITE_data/error/test/timetrap_2_SUITE.erl
index 99bb400137..7fcb631d06 100644
--- a/lib/common_test/test/ct_error_SUITE_data/error/test/timetrap_2_SUITE.erl
+++ b/lib/common_test/test/ct_error_SUITE_data/error/test/timetrap_2_SUITE.erl
@@ -77,8 +77,8 @@ init_per_testcase(tc1, Config) ->
     ct:timetrap({seconds,1}),
     Config;
 
-init_per_testcase(tc3, Config) ->
-    ct:timetrap({seconds,1}),
+init_per_testcase(tc2, Config) ->
+    ct:timetrap(250),
     Config;
 
 init_per_testcase(_TestCase, Config) ->
@@ -90,7 +90,7 @@ init_per_testcase(_TestCase, Config) ->
 %% TestCase = atom()
 %% Config0 = Config1 = [tuple()]
 %%--------------------------------------------------------------------
-end_per_testcase(_, Config) ->
+end_per_testcase(_, _Config) ->
     ok.
 
 %%--------------------------------------------------------------------
@@ -116,7 +116,7 @@ groups() ->
 %% Reason = term()
 %%--------------------------------------------------------------------
 all() ->
-    [tc0,tc1,tc2].
+    [tc0,tc1,tc2,tc3].
 
 tc0(_) ->
     N = list_to_integer(ct:get_config(multiply)),
@@ -131,8 +131,24 @@ tc1(_) ->
     ok.
 
 tc2(_) ->
+    ct:timetrap(500),
     N = list_to_integer(ct:get_config(multiply)),
     ct:comment(io_lib:format("TO after ~w sec", [0.5*N])),
-    ct:timetrap(500),
     ct:sleep(2000),
     ok.
+
+tc3() ->
+    [{timetrap,{seconds,2}}].
+
+tc3(_) ->
+    T0 = now(),
+    ct:timetrap(infinity),
+    N = list_to_integer(ct:get_config(multiply)),
+    ct:comment(io_lib:format("Sleeping for ~w sec...", [4*N])),
+    ct:sleep(4000),
+    Diff = timer:now_diff(now(), T0),
+    if ((Diff < (N*4000000)) or (Diff > (N*4500000))) ->
+	    exit(not_expected);
+       true ->
+	    ok
+    end.
diff --git a/lib/test_server/src/test_server.erl b/lib/test_server/src/test_server.erl
index 0a347ce995..591329b361 100644
--- a/lib/test_server/src/test_server.erl
+++ b/lib/test_server/src/test_server.erl
@@ -36,7 +36,7 @@
 -export([capture_start/0,capture_stop/0,capture_get/0]).
 -export([messages_get/0]).
 -export([hours/1,minutes/1,seconds/1,sleep/1,adjusted_sleep/1,timecall/3]).
--export([timetrap_scale_factor/0,timetrap/1,timetrap_cancel/1]).
+-export([timetrap_scale_factor/0,timetrap/1,timetrap_cancel/1,timetrap_cancel/0]).
 -export([m_out_of_n/3,do_times/4,do_times/2]).
 -export([call_crash/3,call_crash/4,call_crash/5]).
 -export([temp_name/1]).
@@ -1703,7 +1703,7 @@ fail() ->
 break(Comment) ->
     case erase(test_server_timetraps) of
 	undefined -> ok;
-	List -> lists:foreach(fun(Ref) -> timetrap_cancel(Ref) end,List)
+	List -> lists:foreach(fun({Ref,_}) -> timetrap_cancel(Ref) end, List)
     end,
     io:format(user,
 	      "\n\n\n--- SEMIAUTOMATIC TESTING ---"
@@ -1784,14 +1784,16 @@ timetrap(Timeout0) ->
 	{undefined,false} -> timetrap1(Timeout, false);
 	{undefined,_} -> timetrap1(Timeout, true);
 	{infinity,_} -> infinity;
+	{_Int,_Scale} when Timeout == infinity -> infinity;
 	{Int,Scale} -> timetrap1(Timeout*Int, Scale)
     end.
 
 timetrap1(Timeout, Scale) ->
-    Ref = spawn_link(test_server_sup,timetrap,[Timeout,Scale,self()]),
+    TCPid = self(),
+    Ref = spawn_link(test_server_sup,timetrap,[Timeout,Scale,TCPid]),
     case get(test_server_timetraps) of
-	undefined -> put(test_server_timetraps,[Ref]);
-	List -> put(test_server_timetraps,[Ref|List])
+	undefined -> put(test_server_timetraps,[{Ref,TCPid}]);
+	List -> put(test_server_timetraps,[{Ref,TCPid}|List])
     end,
     Ref.
 
@@ -1804,14 +1806,16 @@ ensure_timetrap(Config) ->
 		undefined -> ok;
 		Garbage ->
 		    erase(test_server_default_timetrap),
-		    format("=== WARNING: garbage in test_server_default_timetrap: ~p~n",
+		    format("=== WARNING: garbage in "
+			   "test_server_default_timetrap: ~p~n",
 			   [Garbage])
 	    end,
 	    DTmo = case lists:keysearch(default_timeout,1,Config) of
 		       {value,{default_timeout,Tmo}} -> Tmo;
 		       _ -> ?DEFAULT_TIMETRAP_SECS
 		   end,
-	    format("=== test_server setting default timetrap of ~p seconds~n",
+	    format("=== test_server setting default "
+		   "timetrap of ~p seconds~n",
 		   [DTmo]),
 	    put(test_server_default_timetrap, timetrap(seconds(DTmo)))
     end.
@@ -1823,11 +1827,13 @@ cancel_default_timetrap() ->
 	TimeTrap when is_pid(TimeTrap) ->
 	    timetrap_cancel(TimeTrap),
 	    erase(test_server_default_timetrap),
-	    format("=== test_server canceled default timetrap since another timetrap was set~n"),
+	    format("=== test_server canceled default timetrap "
+		   "since another timetrap was set~n"),
 	    ok;
 	Garbage ->
 	    erase(test_server_default_timetrap),
-	    format("=== WARNING: garbage in test_server_default_timetrap: ~p~n",
+	    format("=== WARNING: garbage in "
+		   "test_server_default_timetrap: ~p~n",
 		   [Garbage]),
 	    error
     end.
@@ -1841,6 +1847,7 @@ time_ms({Other,_N}) ->
 	   "Should be seconds, minutes, or hours.~n", [Other]),
     exit({invalid_time_spec,Other});
 time_ms(Ms) when is_integer(Ms) -> Ms;
+time_ms(infinity) -> infinity;
 time_ms(Other) -> exit({invalid_time_spec,Other}).
 
 
@@ -1854,11 +1861,29 @@ timetrap_cancel(infinity) ->
 timetrap_cancel(Handle) ->
     case get(test_server_timetraps) of
 	undefined -> ok;
-	[Handle] -> erase(test_server_timetraps);
-	List -> put(test_server_timetraps,lists:delete(Handle,List))
+	[{Handle,_}] -> erase(test_server_timetraps);
+	Timers -> put(test_server_timetraps,
+		      lists:keydelete(Handle, 1, Timers))
     end,
     test_server_sup:timetrap_cancel(Handle).
 
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+%% timetrap_cancel() -> ok
+%%
+%% Cancels timetrap for current test case.
+timetrap_cancel() ->
+    case get(test_server_timetraps) of
+	undefined ->
+	    ok;
+	Timers ->
+	    case lists:keysearch(self(), 2, Timers) of
+		{value,{Handle,_}} ->
+		    timetrap_cancel(Handle);
+		_ ->
+		    ok
+	    end
+    end.
+
 %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 %% hours(N) -> Milliseconds
 %% minutes(N) -> Milliseconds
diff --git a/lib/test_server/src/test_server_sup.erl b/lib/test_server/src/test_server_sup.erl
index 1a614d74d5..53dfb45e3a 100644
--- a/lib/test_server/src/test_server_sup.erl
+++ b/lib/test_server/src/test_server_sup.erl
@@ -83,13 +83,13 @@ timetrap(Timeout0, Scale, Pid) ->
 %% Handle = term()
 %%
 %% Cancels a time trap.
-
 timetrap_cancel(Handle) ->
     unlink(Handle),
     MonRef = erlang:monitor(process, Handle),
     exit(Handle, kill),
     receive {'DOWN',MonRef,_,_,_} -> ok after 2000 -> ok end.
 
+
 capture_get(Msgs) ->
     receive
 	{captured,Msg} ->