Add some more binary syntax construction tests

Some more cases (taken from the BEAM bs_construct suite) that used to
show different behaviour than BEAM when compiled to native code were
included in the appropriate test file of the HiPE test suite.

1 files changed, 115 insertions, 0 deletions

diff --git a/lib/hipe/test/bs_SUITE_data/bs_construct.erl b/lib/hipe/test/bs_SUITE_data/bs_construct.erl
index 37a54c1981..7d59482662 100644
--- a/lib/hipe/test/bs_SUITE_data/bs_construct.erl
+++ b/lib/hipe/test/bs_SUITE_data/bs_construct.erl
@@ -14,6 +14,9 @@ test() ->
   16#10000008 = bit_size(large_bin(1, 2, 3, 4)),
   ok = bad_ones(),
   ok = zero_width(),
+  ok = not_used(),
+  ok = bad_append(),
+  ok = system_limit(),
   ok.
 
 %%--------------------------------------------------------------------
@@ -142,3 +145,115 @@ zero_width() ->
   ok.
 
 id(X) -> X.
+
+%%--------------------------------------------------------------------
+%% Taken from bs_construct_SUITE. The test checks that constructed
+%% binaries that are not used would still give a `badarg' exception.
+%% Problem was that in native code one of them gave `badarith'.
+
+not_used() ->
+    ok = not_used1(3, <<"dum">>),
+    {'EXIT',{badarg,_}} = (catch not_used1(42, "dum_string")),
+    {'EXIT',{badarg,_}} = (catch not_used2(666, -2)),
+    {'EXIT',{badarg,_}} = (catch not_used2(666, "bad_size")), % this one
+    {'EXIT',{badarg,_}} = (catch not_used3(666)),
+    ok.
+
+not_used1(I, BinString) ->
+    <<I:32,BinString/binary>>,
+    ok.
+
+not_used2(I, Sz) ->
+    <<I:Sz>>,
+    ok.
+
+not_used3(I) ->
+    <<I:(-8)>>,
+    ok.
+
+%%--------------------------------------------------------------------
+%% Taken from bs_construct_SUITE.
+
+bad_append() ->
+    do_bad_append(<<127:1>>, fun append_unit_3/1),
+    do_bad_append(<<127:2>>, fun append_unit_3/1),
+    do_bad_append(<<127:17>>, fun append_unit_3/1),
+
+    do_bad_append(<<127:3>>, fun append_unit_4/1),
+    do_bad_append(<<127:5>>, fun append_unit_4/1),
+    do_bad_append(<<127:7>>, fun append_unit_4/1),
+    do_bad_append(<<127:199>>, fun append_unit_4/1),
+
+    do_bad_append(<<127:7>>, fun append_unit_8/1),
+    do_bad_append(<<127:9>>, fun append_unit_8/1),
+
+    do_bad_append(<<0:8>>, fun append_unit_16/1),
+    do_bad_append(<<0:15>>, fun append_unit_16/1),
+    do_bad_append(<<0:17>>, fun append_unit_16/1),
+    ok.
+
+do_bad_append(Bin0, Appender) ->
+    {'EXIT',{badarg,_}} = (catch Appender(Bin0)),
+
+    Bin1 = id(<<0:3,Bin0/bitstring>>),
+    <<_:3,Bin2/bitstring>> = Bin1,
+    {'EXIT',{badarg,_}} = (catch Appender(Bin2)),
+
+    %% Create a writable binary.
+    Empty = id(<<>>),
+    Bin3 = <<Empty/bitstring,Bin0/bitstring>>,
+    {'EXIT',{badarg,_}} = (catch Appender(Bin3)),
+    ok.
+
+append_unit_3(Bin) ->
+    <<Bin/binary-unit:3,0:1>>.
+
+append_unit_4(Bin) ->
+    <<Bin/binary-unit:4,0:1>>.
+
+append_unit_8(Bin) ->
+    <<Bin/binary,0:1>>.
+
+append_unit_16(Bin) ->
+    <<Bin/binary-unit:16,0:1>>.
+
+%%--------------------------------------------------------------------
+%% Taken from bs_construct_SUITE.
+
+system_limit() ->
+    WordSize = erlang:system_info(wordsize),
+    BitsPerWord = WordSize * 8,
+    {'EXIT',{system_limit,_}} =
+	(catch <<0:(id(0)),42:(id(1 bsl BitsPerWord))>>),
+    {'EXIT',{system_limit,_}} =
+	(catch <<42:(id(1 bsl BitsPerWord)),0:(id(0))>>),
+    {'EXIT',{system_limit,_}} =
+	(catch <<(id(<<>>))/binary,0:(id(1 bsl 100))>>),
+
+    %% Would fail to load.
+    {'EXIT',{system_limit,_}} = (catch <<0:(1 bsl 67)>>),
+    {'EXIT',{system_limit,_}} = (catch <<0:((1 bsl 64)+1)>>),
+    case WordSize of
+	4 ->
+	    system_limit_32();
+	8 ->
+	    ok
+    end.
+
+system_limit_32() ->
+    {'EXIT',{badarg,_}} = (catch <<42:(-1)>>),
+    {'EXIT',{badarg,_}} = (catch <<42:(id(-1))>>),
+    {'EXIT',{badarg,_}} = (catch <<42:(id(-389739873536870912))/unit:8>>),
+    {'EXIT',{system_limit,_}} = (catch <<42:536870912/unit:8>>),
+    {'EXIT',{system_limit,_}} = (catch <<42:(id(536870912))/unit:8>>),
+    {'EXIT',{system_limit,_}} = (catch <<0:(id(8)),42:536870912/unit:8>>),
+    {'EXIT',{system_limit,_}} =	(catch <<0:(id(8)),42:(id(536870912))/unit:8>>),
+
+    %% The size would be silently truncated, resulting in a crash.
+    {'EXIT',{system_limit,_}} = (catch <<0:(1 bsl 35)>>),
+    {'EXIT',{system_limit,_}} = (catch <<0:((1 bsl 32)+1)>>),
+
+    %% Would fail to load.
+    {'EXIT',{system_limit,_}} = (catch <<0:(1 bsl 43)>>),
+    {'EXIT',{system_limit,_}} = (catch <<0:((1 bsl 40)+1)>>),
+    ok.