Add synchronous stop functions to gen_server and gen_fsm

The functions utilize proc_lib:stop, which in turn utilizes
sys:terminate.

7 files changed, 367 insertions, 56 deletions

diff --git a/lib/stdlib/doc/src/gen_fsm.xml b/lib/stdlib/doc/src/gen_fsm.xml
index 1713367bd8..24468b0e8e 100644
--- a/lib/stdlib/doc/src/gen_fsm.xml
+++ b/lib/stdlib/doc/src/gen_fsm.xml
@@ -4,7 +4,7 @@
 <erlref>
   <header>
     <copyright>
-      <year>1996</year><year>2013</year>
+      <year>1996</year><year>2014</year>
       <holder>Ericsson AB. All Rights Reserved.</holder>
     </copyright>
     <legalnotice>
@@ -43,8 +43,11 @@
     <pre>
 gen_fsm module                    Callback module
 --------------                    ---------------
+gen_fsm:start
 gen_fsm:start_link                -----> Module:init/1
 
+gen_fsm:stop                      -----> Module:terminate/3
+
 gen_fsm:send_event                -----> Module:StateName/2
 
 gen_fsm:send_all_state_event      -----> Module:handle_event/3
@@ -187,6 +190,39 @@ gen_fsm:sync_send_all_state_event -----> Module:handle_sync_event/4
       </desc>
     </func>
     <func>
+      <name>stop(FsmRef) -> ok</name>
+      <name>stop(FsmRef, Reason, Timeout) -> ok</name>
+      <fsummary>Synchronously stop a generic FSM.</fsummary>
+      <type>
+        <v>FsmRef = Name | {Name,Node} | {global,GlobalName}
+	| {via,Module,ViaName} | pid()</v>
+        <v>&nbsp;Node = atom()</v>
+        <v>&nbsp;GlobalName = ViaName = term()</v>
+        <v>Reason = term()</v>
+        <v>Timeout = int()>0 | infinity</v>
+      </type>
+      <desc>
+	<p>Orders a generic FSM to exit with the given <c>Reason</c>
+	  and waits for it to terminate. The gen_fsm will call
+          <seealso marker="#Module:terminate/3">Module:terminate/3</seealso>
+	  before exiting.</p>
+	<p>The function returns <c>ok</c> if the generic FSM terminates
+	  with the expected reason. Any other reason than <c>normal</c>,
+          <c>shutdown</c>, or <c>{shutdown,Term}</c> will cause an
+          error report to be issued using
+          <seealso marker="kernel:error_logger#format/2">error_logger:format/2</seealso>.
+	  The default <c>Reason</c> is <c>normal</c>.</p>
+	<p><c>Timeout</c> is an integer greater than zero which
+          specifies how many milliseconds to wait for the generic FSM
+          to terminate, or the atom <c>infinity</c> to wait
+          indefinitely. The default value is <c>infinity</c>. If the
+          generic FSM has not terminated within the specified time, a
+	  <c>timeout</c> exception is raised.</p>
+	<p>If the process does not exist, a <c>noproc</c> exception
+	  is raised.</p>
+      </desc>
+    </func>
+    <func>
       <name>send_event(FsmRef, Event) -> ok</name>
       <fsummary>Send an event asynchronously to a generic FSM.</fsummary>
       <type>
diff --git a/lib/stdlib/doc/src/gen_server.xml b/lib/stdlib/doc/src/gen_server.xml
index 4c83fde237..4bef50245d 100644
--- a/lib/stdlib/doc/src/gen_server.xml
+++ b/lib/stdlib/doc/src/gen_server.xml
@@ -4,7 +4,7 @@
 <erlref>
   <header>
     <copyright>
-      <year>1996</year><year>2013</year>
+      <year>1996</year><year>2014</year>
       <holder>Ericsson AB. All Rights Reserved.</holder>
     </copyright>
     <legalnotice>
@@ -43,8 +43,11 @@
     <pre>
 gen_server module            Callback module
 -----------------            ---------------
+gen_server:start
 gen_server:start_link -----> Module:init/1
 
+gen_server:stop       -----> Module:terminate/2
+
 gen_server:call
 gen_server:multi_call -----> Module:handle_call/3
 
@@ -184,6 +187,40 @@ gen_server:abcast     -----> Module:handle_cast/2
       </desc>
     </func>
     <func>
+      <name>stop(ServerRef) -> ok</name>
+      <name>stop(ServerRef, Reason, Timeout) -> ok</name>
+      <fsummary>Synchronously stop a generic server.</fsummary>
+      <type>
+        <v>ServerRef = Name | {Name,Node} | {global,GlobalName}
+	| {via,Module,ViaName} | pid()</v>
+        <v>&nbsp;Node = atom()</v>
+        <v>&nbsp;GlobalName = ViaName = term()</v>
+        <v>Reason = term()</v>
+        <v>Timeout = int()>0 | infinity</v>
+      </type>
+      <desc>
+	<p>Orders a generic server to exit with the
+	  given <c>Reason</c> and waits for it to terminate. The
+	  gen_server will call
+          <seealso marker="#Module:terminate/2">Module:terminate/2</seealso>
+	  before exiting.</p>
+	<p>The function returns <c>ok</c> if the server terminates
+	  with the expected reason. Any other reason than <c>normal</c>,
+          <c>shutdown</c>, or <c>{shutdown,Term}</c> will cause an
+          error report to be issued using
+          <seealso marker="kernel:error_logger#format/2">error_logger:format/2</seealso>.
+	  The default <c>Reason</c> is <c>normal</c>.</p>
+	<p><c>Timeout</c> is an integer greater than zero which
+          specifies how many milliseconds to wait for the server to
+          terminate, or the atom <c>infinity</c> to wait
+          indefinitely. The default value is <c>infinity</c>. If the
+          server has not terminated within the specified time, a
+          <c>timeout</c> exception is raised.</p>
+	<p>If the process does not exist, a <c>noproc</c> exception
+	  is raised.</p>
+      </desc>
+    </func>
+    <func>
       <name>call(ServerRef, Request) -> Reply</name>
       <name>call(ServerRef, Request, Timeout) -> Reply</name>
       <fsummary>Make a synchronous call to a generic server.</fsummary>
diff --git a/lib/stdlib/src/gen.erl b/lib/stdlib/src/gen.erl
index 63116fa16e..6d7ca3d75c 100644
--- a/lib/stdlib/src/gen.erl
+++ b/lib/stdlib/src/gen.erl
@@ -26,7 +26,7 @@
 %%% The standard behaviour should export init_it/6.
 %%%-----------------------------------------------------------------
 -export([start/5, start/6, debug_options/1,
-	 call/3, call/4, reply/2]).
+	 call/3, call/4, reply/2, stop/1, stop/3]).
 
 -export([init_it/6, init_it/7]).
 
@@ -145,56 +145,10 @@ init_it2(GenMod, Starter, Parent, Name, Mod, Args, Options) ->
 call(Process, Label, Request) -> 
     call(Process, Label, Request, ?default_timeout).
 
-%% Local or remote by pid
-call(Pid, Label, Request, Timeout) 
-  when is_pid(Pid), Timeout =:= infinity;
-       is_pid(Pid), is_integer(Timeout), Timeout >= 0 ->
-    do_call(Pid, Label, Request, Timeout);
-%% Local by name
-call(Name, Label, Request, Timeout) 
-  when is_atom(Name), Timeout =:= infinity;
-       is_atom(Name), is_integer(Timeout), Timeout >= 0 ->
-    case whereis(Name) of
-	Pid when is_pid(Pid) ->
-	    do_call(Pid, Label, Request, Timeout);
-	undefined ->
-	    exit(noproc)
-    end;
-%% Global by name
 call(Process, Label, Request, Timeout)
-  when ((tuple_size(Process) == 2 andalso element(1, Process) == global)
-	orelse
-	  (tuple_size(Process) == 3 andalso element(1, Process) == via))
-       andalso
-       (Timeout =:= infinity orelse (is_integer(Timeout) andalso Timeout >= 0)) ->
-    case where(Process) of
-	Pid when is_pid(Pid) ->
-	    Node = node(Pid),
- 	    try do_call(Pid, Label, Request, Timeout)
- 	    catch
- 		exit:{nodedown, Node} ->
- 		    %% A nodedown not yet detected by global,
- 		    %% pretend that it was.
- 		    exit(noproc)
-	    end;
-	undefined ->
-	    exit(noproc)
-    end;
-%% Local by name in disguise
-call({Name, Node}, Label, Request, Timeout)
-  when Node =:= node(), Timeout =:= infinity;
-       Node =:= node(), is_integer(Timeout), Timeout >= 0 ->
-    call(Name, Label, Request, Timeout);
-%% Remote by name
-call({_Name, Node}=Process, Label, Request, Timeout)
-  when is_atom(Node), Timeout =:= infinity;
-       is_atom(Node), is_integer(Timeout), Timeout >= 0 ->
-    if
- 	node() =:= nonode@nohost ->
- 	    exit({nodedown, Node});
- 	true ->
- 	    do_call(Process, Label, Request, Timeout)
-    end.
+  when Timeout =:= infinity; is_integer(Timeout), Timeout >= 0 ->
+    Fun = fun(Pid) -> do_call(Pid, Label, Request, Timeout) end,
+    do_for_proc(Process, Fun).
 
 do_call(Process, Label, Request, Timeout) ->
     try erlang:monitor(process, Process) of
@@ -276,6 +230,65 @@ reply({To, Tag}, Reply) ->
     Msg = {Tag, Reply},
     try To ! Msg catch _:_ -> Msg end.
 
+%%-----------------------------------------------------------------
+%% Syncronously stop a generic process
+%%-----------------------------------------------------------------
+stop(Process) ->
+    stop(Process, normal, infinity).
+
+stop(Process, Reason, Timeout)
+  when Timeout =:= infinity; is_integer(Timeout), Timeout >= 0 ->
+    Fun = fun(Pid) -> proc_lib:stop(Pid, Reason, Timeout) end,
+    do_for_proc(Process, Fun).
+
+%%-----------------------------------------------------------------
+%% Map different specifications of a process to either Pid or
+%% {Name,Node}. Execute the given Fun with the process as only
+%% argument.
+%% -----------------------------------------------------------------
+
+%% Local or remote by pid
+do_for_proc(Pid, Fun) when is_pid(Pid) ->
+    Fun(Pid);
+%% Local by name
+do_for_proc(Name, Fun) when is_atom(Name) ->
+    case whereis(Name) of
+	Pid when is_pid(Pid) ->
+	    Fun(Pid);
+	undefined ->
+	    exit(noproc)
+    end;
+%% Global by name
+do_for_proc(Process, Fun)
+  when ((tuple_size(Process) == 2 andalso element(1, Process) == global)
+	orelse
+	  (tuple_size(Process) == 3 andalso element(1, Process) == via)) ->
+    case where(Process) of
+	Pid when is_pid(Pid) ->
+	    Node = node(Pid),
+	    try Fun(Pid)
+	    catch
+		exit:{nodedown, Node} ->
+		    %% A nodedown not yet detected by global,
+		    %% pretend that it was.
+		    exit(noproc)
+	    end;
+	undefined ->
+	    exit(noproc)
+    end;
+%% Local by name in disguise
+do_for_proc({Name, Node}, Fun) when Node =:= node() ->
+    do_for_proc(Name, Fun);
+%% Remote by name
+do_for_proc({_Name, Node} = Process, Fun) when is_atom(Node) ->
+    if
+	node() =:= nonode@nohost ->
+	    exit({nodedown, Node});
+	true ->
+	    Fun(Process)
+    end.
+
+
 %%%-----------------------------------------------------------------
 %%%  Misc. functions.
 %%%-----------------------------------------------------------------
diff --git a/lib/stdlib/src/gen_fsm.erl b/lib/stdlib/src/gen_fsm.erl
index 56137cde13..29b1d80088 100644
--- a/lib/stdlib/src/gen_fsm.erl
+++ b/lib/stdlib/src/gen_fsm.erl
@@ -106,6 +106,7 @@
 
 -export([start/3, start/4,
 	 start_link/3, start_link/4,
+	 stop/1, stop/3,
 	 send_event/2, sync_send_event/2, sync_send_event/3,
 	 send_all_state_event/2,
 	 sync_send_all_state_event/2, sync_send_all_state_event/3,
@@ -197,6 +198,11 @@ start_link(Mod, Args, Options) ->
 start_link(Name, Mod, Args, Options) ->
     gen:start(?MODULE, link, Name, Mod, Args, Options).
 
+stop(Name) ->
+    gen:stop(Name).
+
+stop(Name, Reason, Timeout) ->
+    gen:stop(Name, Reason, Timeout).
 
 send_event({global, Name}, Event) ->
     catch global:send(Name, {'$gen_event', Event}),
diff --git a/lib/stdlib/src/gen_server.erl b/lib/stdlib/src/gen_server.erl
index 22acdf10b7..9794c73cc2 100644
--- a/lib/stdlib/src/gen_server.erl
+++ b/lib/stdlib/src/gen_server.erl
@@ -88,6 +88,7 @@
 %% API
 -export([start/3, start/4,
 	 start_link/3, start_link/4,
+	 stop/1, stop/3,
 	 call/2, call/3,
 	 cast/2, reply/2,
 	 abcast/2, abcast/3,
@@ -177,6 +178,17 @@ start_link(Name, Mod, Args, Options) ->
 
 
 %% -----------------------------------------------------------------
+%% Stop a generic server and wait for it to terminate.
+%% If the server is located at another node, that node will
+%% be monitored.
+%% -----------------------------------------------------------------
+stop(Name) ->
+    gen:stop(Name).
+
+stop(Name, Reason, Timeout) ->
+    gen:stop(Name, Reason, Timeout).
+
+%% -----------------------------------------------------------------
 %% Make a call to a generic server.
 %% If the server is located at another node, that node will
 %% be monitored.
diff --git a/lib/stdlib/test/gen_fsm_SUITE.erl b/lib/stdlib/test/gen_fsm_SUITE.erl
index 8aeec07ae8..2e266198e9 100644
--- a/lib/stdlib/test/gen_fsm_SUITE.erl
+++ b/lib/stdlib/test/gen_fsm_SUITE.erl
@@ -1,7 +1,7 @@
 %%
 %% %CopyrightBegin%
 %%
-%% Copyright Ericsson AB 1996-2013. All Rights Reserved.
+%% Copyright Ericsson AB 1996-2014. All Rights Reserved.
 %%
 %% The contents of this file are subject to the Erlang Public License,
 %% Version 1.1, (the "License"); you may not use this file except in
@@ -27,6 +27,9 @@
 -export([start1/1, start2/1, start3/1, start4/1, start5/1, start6/1,
 	 start7/1, start8/1, start9/1, start10/1, start11/1, start12/1]).
 
+-export([stop1/1, stop2/1, stop3/1, stop4/1, stop5/1, stop6/1, stop7/1,
+	 stop8/1, stop9/1, stop10/1]).
+
 -export([ abnormal1/1, abnormal2/1]).
 
 -export([shutdown/1]).
@@ -64,6 +67,8 @@ groups() ->
     [{start, [],
       [start1, start2, start3, start4, start5, start6, start7,
        start8, start9, start10, start11, start12]},
+     {stop, [],
+      [stop1, stop2, stop3, stop4, stop5, stop6, stop7, stop8, stop9, stop10]},
      {abnormal, [], [abnormal1, abnormal2]},
      {sys, [],
       [sys1, call_format_status, error_format_status, get_state, replace_state]}].
@@ -278,6 +283,105 @@ start12(Config) when is_list(Config) ->
     ok.
 
 
+%% Anonymous, reason 'normal'
+stop1(_Config) ->
+    {ok, Pid} = gen_fsm:start(?MODULE, [], []),
+    ok = gen_fsm:stop(Pid),
+    false = erlang:is_process_alive(Pid),
+    {'EXIT',noproc} = (catch gen_fsm:stop(Pid)),
+    ok.
+
+%% Anonymous, other reason
+stop2(_Config) ->
+    {ok,Pid} = gen_fsm:start(?MODULE, [], []),
+    ok = gen_fsm:stop(Pid, other_reason, infinity),
+    false = erlang:is_process_alive(Pid),
+    ok.
+
+%% Anonymous, invalid timeout
+stop3(_Config) ->
+    {ok,Pid} = gen_fsm:start(?MODULE, [], []),
+    {'EXIT',_} = (catch gen_fsm:stop(Pid, other_reason, invalid_timeout)),
+    true = erlang:is_process_alive(Pid),
+    ok = gen_fsm:stop(Pid),
+    false = erlang:is_process_alive(Pid),
+    ok.
+
+%% Registered name
+stop4(_Config) ->
+    {ok,Pid} = gen_fsm:start({local,to_stop},?MODULE, [], []),
+    ok = gen_fsm:stop(to_stop),
+    false = erlang:is_process_alive(Pid),
+    {'EXIT',noproc} = (catch gen_fsm:stop(to_stop)),
+    ok.
+
+%% Registered name and local node
+stop5(_Config) ->
+    {ok,Pid} = gen_fsm:start({local,to_stop},?MODULE, [], []),
+    ok = gen_fsm:stop({to_stop,node()}),
+    false = erlang:is_process_alive(Pid),
+    {'EXIT',noproc} = (catch gen_fsm:stop({to_stop,node()})),
+    ok.
+
+%% Globally registered name
+stop6(_Config) ->
+    {ok, Pid} = gen_fsm:start({global, to_stop}, ?MODULE, [], []),
+    ok = gen_fsm:stop({global,to_stop}),
+    false = erlang:is_process_alive(Pid),
+    {'EXIT',noproc} = (catch gen_fsm:stop({global,to_stop})),
+    ok.
+
+%% 'via' registered name
+stop7(_Config) ->
+    dummy_via:reset(),
+    {ok, Pid} = gen_fsm:start({via, dummy_via, to_stop},
+				  ?MODULE, [], []),
+    ok = gen_fsm:stop({via, dummy_via, to_stop}),
+    false = erlang:is_process_alive(Pid),
+    {'EXIT',noproc} = (catch gen_fsm:stop({via, dummy_via, to_stop})),
+    ok.
+
+%% Anonymous on remote node
+stop8(_Config) ->
+    {ok,Node} = test_server:start_node(gen_fsm_SUITE_stop8,slave,[]),
+    Dir = filename:dirname(code:which(?MODULE)),
+    rpc:call(Node,code,add_path,[Dir]),
+    {ok, Pid} = rpc:call(Node,gen_fsm,start,[?MODULE,[],[]]),
+    ok = gen_fsm:stop(Pid),
+    false = rpc:call(Node,erlang,is_process_alive,[Pid]),
+    {'EXIT',noproc} = (catch gen_fsm:stop(Pid)),
+    true = test_server:stop_node(Node),
+    {'EXIT',{{nodedown,Node},_}} = (catch gen_fsm:stop(Pid)),
+    ok.
+
+%% Registered name on remote node
+stop9(_Config) ->
+    {ok,Node} = test_server:start_node(gen_fsm_SUITE_stop9,slave,[]),
+    Dir = filename:dirname(code:which(?MODULE)),
+    rpc:call(Node,code,add_path,[Dir]),
+    {ok, Pid} = rpc:call(Node,gen_fsm,start,[{local,to_stop},?MODULE,[],[]]),
+    ok = gen_fsm:stop({to_stop,Node}),
+    undefined = rpc:call(Node,erlang,whereis,[to_stop]),
+    false = rpc:call(Node,erlang,is_process_alive,[Pid]),
+    {'EXIT',noproc} = (catch gen_fsm:stop({to_stop,Node})),
+    true = test_server:stop_node(Node),
+    {'EXIT',{{nodedown,Node},_}} = (catch gen_fsm:stop({to_stop,Node})),
+    ok.
+
+%% Globally registered name on remote node
+stop10(_Config) ->
+    {ok,Node} = test_server:start_node(gen_fsm_SUITE_stop10,slave,[]),
+    Dir = filename:dirname(code:which(?MODULE)),
+    rpc:call(Node,code,add_path,[Dir]),
+    {ok, Pid} = rpc:call(Node,gen_fsm,start,[{global,to_stop},?MODULE,[],[]]),
+    global:sync(),
+    ok = gen_fsm:stop({global,to_stop}),
+    false = rpc:call(Node,erlang,is_process_alive,[Pid]),
+    {'EXIT',noproc} = (catch gen_fsm:stop({global,to_stop})),
+    true = test_server:stop_node(Node),
+    {'EXIT',noproc} = (catch gen_fsm:stop({global,to_stop})),
+    ok.
+
 %% Check that time outs in calls work
 abnormal1(suite) -> [];
 abnormal1(Config) when is_list(Config) ->
diff --git a/lib/stdlib/test/gen_server_SUITE.erl b/lib/stdlib/test/gen_server_SUITE.erl
index 960e7f60e7..c3ec4932b3 100644
--- a/lib/stdlib/test/gen_server_SUITE.erl
+++ b/lib/stdlib/test/gen_server_SUITE.erl
@@ -1,7 +1,7 @@
 %%
 %% %CopyrightBegin%
 %%
-%% Copyright Ericsson AB 1996-2013. All Rights Reserved.
+%% Copyright Ericsson AB 1996-2014. All Rights Reserved.
 %%
 %% The contents of this file are subject to the Erlang Public License,
 %% Version 1.1, (the "License"); you may not use this file except in
@@ -35,6 +35,9 @@
 	 error_format_status/1, get_state/1, replace_state/1, call_with_huge_message_queue/1
 	]).
 
+-export([stop1/1, stop2/1, stop3/1, stop4/1, stop5/1, stop6/1, stop7/1,
+	 stop8/1, stop9/1, stop10/1]).
+
 % spawn export
 -export([spec_init_local/2, spec_init_global/2, spec_init_via/2,
 	 spec_init_default_timeout/2, spec_init_global_default_timeout/2,
@@ -50,7 +53,7 @@
 suite() -> [{ct_hooks,[ts_install_cth]}].
 
 all() -> 
-    [start, crash, call, cast, cast_fast, info, abcast,
+    [start, {group,stop}, crash, call, cast, cast_fast, info, abcast,
      multicall, multicall_down, call_remote1, call_remote2,
      call_remote3, call_remote_n1, call_remote_n2,
      call_remote_n3, spec_init,
@@ -61,7 +64,8 @@ all() ->
      call_with_huge_message_queue].
 
 groups() -> 
-    [].
+    [{stop, [],
+      [stop1, stop2, stop3, stop4, stop5, stop6, stop7, stop8, stop9, stop10]}].
 
 init_per_suite(Config) ->
     Config.
@@ -235,6 +239,105 @@ start(Config) when is_list(Config) ->
     process_flag(trap_exit, OldFl),
     ok.
 
+%% Anonymous, reason 'normal'
+stop1(_Config) ->
+    {ok, Pid} = gen_server:start(?MODULE, [], []),
+    ok = gen_server:stop(Pid),
+    false = erlang:is_process_alive(Pid),
+    {'EXIT',noproc} = (catch gen_server:stop(Pid)),
+    ok.
+
+%% Anonymous, other reason
+stop2(_Config) ->
+    {ok,Pid} = gen_server:start(?MODULE, [], []),
+    ok = gen_server:stop(Pid, other_reason, infinity),
+    false = erlang:is_process_alive(Pid),
+    ok.
+
+%% Anonymous, invalid timeout
+stop3(_Config) ->
+    {ok,Pid} = gen_server:start(?MODULE, [], []),
+    {'EXIT',_} = (catch gen_server:stop(Pid, other_reason, invalid_timeout)),
+    true = erlang:is_process_alive(Pid),
+    ok = gen_server:stop(Pid),
+    false = erlang:is_process_alive(Pid),
+    ok.
+
+%% Registered name
+stop4(_Config) ->
+    {ok,Pid} = gen_server:start({local,to_stop},?MODULE, [], []),
+    ok = gen_server:stop(to_stop),
+    false = erlang:is_process_alive(Pid),
+    {'EXIT',noproc} = (catch gen_server:stop(to_stop)),
+    ok.
+
+%% Registered name and local node
+stop5(_Config) ->
+    {ok,Pid} = gen_server:start({local,to_stop},?MODULE, [], []),
+    ok = gen_server:stop({to_stop,node()}),
+    false = erlang:is_process_alive(Pid),
+    {'EXIT',noproc} = (catch gen_server:stop({to_stop,node()})),
+    ok.
+
+%% Globally registered name
+stop6(_Config) ->
+    {ok, Pid} = gen_server:start({global, to_stop}, ?MODULE, [], []),
+    ok = gen_server:stop({global,to_stop}),
+    false = erlang:is_process_alive(Pid),
+    {'EXIT',noproc} = (catch gen_server:stop({global,to_stop})),
+    ok.
+
+%% 'via' registered name
+stop7(_Config) ->
+    dummy_via:reset(),
+    {ok, Pid} = gen_server:start({via, dummy_via, to_stop},
+				  ?MODULE, [], []),
+    ok = gen_server:stop({via, dummy_via, to_stop}),
+    false = erlang:is_process_alive(Pid),
+    {'EXIT',noproc} = (catch gen_server:stop({via, dummy_via, to_stop})),
+    ok.
+
+%% Anonymous on remote node
+stop8(_Config) ->
+    {ok,Node} = test_server:start_node(gen_server_SUITE_stop8,slave,[]),
+    Dir = filename:dirname(code:which(?MODULE)),
+    rpc:call(Node,code,add_path,[Dir]),
+    {ok, Pid} = rpc:call(Node,gen_server,start,[?MODULE,[],[]]),
+    ok = gen_server:stop(Pid),
+    false = rpc:call(Node,erlang,is_process_alive,[Pid]),
+    {'EXIT',noproc} = (catch gen_server:stop(Pid)),
+    true = test_server:stop_node(Node),
+    {'EXIT',{{nodedown,Node},_}} = (catch gen_server:stop(Pid)),
+    ok.
+
+%% Registered name on remote node
+stop9(_Config) ->
+    {ok,Node} = test_server:start_node(gen_server_SUITE_stop9,slave,[]),
+    Dir = filename:dirname(code:which(?MODULE)),
+    rpc:call(Node,code,add_path,[Dir]),
+    {ok, Pid} = rpc:call(Node,gen_server,start,[{local,to_stop},?MODULE,[],[]]),
+    ok = gen_server:stop({to_stop,Node}),
+    undefined = rpc:call(Node,erlang,whereis,[to_stop]),
+    false = rpc:call(Node,erlang,is_process_alive,[Pid]),
+    {'EXIT',noproc} = (catch gen_server:stop({to_stop,Node})),
+    true = test_server:stop_node(Node),
+    {'EXIT',{{nodedown,Node},_}} = (catch gen_server:stop({to_stop,Node})),
+    ok.
+
+%% Globally registered name on remote node
+stop10(_Config) ->
+    {ok,Node} = test_server:start_node(gen_server_SUITE_stop10,slave,[]),
+    Dir = filename:dirname(code:which(?MODULE)),
+    rpc:call(Node,code,add_path,[Dir]),
+    {ok, Pid} = rpc:call(Node,gen_server,start,[{global,to_stop},?MODULE,[],[]]),
+    global:sync(),
+    ok = gen_server:stop({global,to_stop}),
+    false = rpc:call(Node,erlang,is_process_alive,[Pid]),
+    {'EXIT',noproc} = (catch gen_server:stop({global,to_stop})),
+    true = test_server:stop_node(Node),
+    {'EXIT',noproc} = (catch gen_server:stop({global,to_stop})),
+    ok.
+
 crash(Config) when is_list(Config) ->
     ?line error_logger_forwarder:register(),