Rewrite inet* for address family 'local'

16 files changed, 582 insertions, 299 deletions

diff --git a/lib/kernel/src/Makefile b/lib/kernel/src/Makefile
index 57dacebde3..2b72f78dcf 100644
--- a/lib/kernel/src/Makefile
+++ b/lib/kernel/src/Makefile
@@ -1,7 +1,7 @@
 #
 # %CopyrightBegin%
 #
-# Copyright Ericsson AB 1996-2013. All Rights Reserved.
+# Copyright Ericsson AB 1996-2016. All Rights Reserved.
 #
 # Licensed under the Apache License, Version 2.0 (the "License");
 # you may not use this file except in compliance with the License.
@@ -104,6 +104,8 @@ MODULES = \
 	inet_sctp \
 	kernel \
 	kernel_config \
+	local_udp \
+	local_tcp \
 	net \
 	net_adm \
 	net_kernel \
@@ -244,6 +246,8 @@ $(EBIN)/inet_tcp.beam: inet_int.hrl
 $(EBIN)/inet_udp_dist.beam: ../include/net_address.hrl ../include/dist.hrl ../include/dist_util.hrl
 $(EBIN)/inet_udp.beam: inet_int.hrl
 $(EBIN)/inet_sctp.beam: inet_int.hrl ../include/inet_sctp.hrl
+$(EBIN)/local_udp.beam: inet_int.hrl
+$(EBIN)/local_tcp.beam: inet_int.hrl
 $(EBIN)/net_kernel.beam: ../include/net_address.hrl
 $(EBIN)/os.beam: ../include/file.hrl
 $(EBIN)/ram_file.beam: ../include/file.hrl
diff --git a/lib/kernel/src/gen_sctp.erl b/lib/kernel/src/gen_sctp.erl
index a47535b2f8..b133e6fed4 100644
--- a/lib/kernel/src/gen_sctp.erl
+++ b/lib/kernel/src/gen_sctp.erl
@@ -1,7 +1,7 @@
 %%
 %% %CopyrightBegin%
 %%
-%% Copyright Ericsson AB 2007-2013. All Rights Reserved.
+%% Copyright Ericsson AB 2007-2016. All Rights Reserved.
 %%
 %% Licensed under the Apache License, Version 2.0 (the "License");
 %% you may not use this file except in compliance with the License.
@@ -124,8 +124,8 @@ open() ->
 	      SockType :: seqpacket | stream,
               Socket :: sctp_socket().
 
-open(Opts) when is_list(Opts) ->
-    Mod = mod(Opts, undefined),
+open(Opts0) when is_list(Opts0) ->
+    {Mod, Opts} = inet:sctp_module(Opts0),
     case Mod:open(Opts) of
 	{error,badarg} ->
 	    erlang:error(badarg, [Opts]);
@@ -445,32 +445,3 @@ controlling_process(S, Pid) when is_port(S), is_pid(Pid) ->
     inet:udp_controlling_process(S, Pid);
 controlling_process(S, Pid) ->
     erlang:error(badarg, [S,Pid]).
-
-%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
-%% Utilites
-%%
-
-%% Get the SCTP module, but IPv6 address overrides default IPv4
-mod(Address) ->
-    case inet_db:sctp_module() of
-	inet_sctp when tuple_size(Address) =:= 8 ->
-	    inet6_sctp;
-	Mod ->
-	    Mod
-    end.
-
-%% Get the SCTP module, but option sctp_module|inet|inet6 overrides
-mod([{sctp_module,Mod}|_], _Address) ->
-    Mod;
-mod([inet|_], _Address) ->
-    inet_sctp;
-mod([inet6|_], _Address) ->
-    inet6_sctp;
-mod([{ip, Address}|Opts], _) ->
-    mod(Opts, Address);
-mod([{ifaddr, Address}|Opts], _) ->
-    mod(Opts, Address);
-mod([_|Opts], Address) ->
-    mod(Opts, Address);
-mod([], Address) ->
-    mod(Address).
diff --git a/lib/kernel/src/gen_tcp.erl b/lib/kernel/src/gen_tcp.erl
index d7dba4ac80..f1a787ae1a 100644
--- a/lib/kernel/src/gen_tcp.erl
+++ b/lib/kernel/src/gen_tcp.erl
@@ -1,7 +1,7 @@
 %%
 %% %CopyrightBegin%
 %% 
-%% Copyright Ericsson AB 1997-2013. All Rights Reserved.
+%% Copyright Ericsson AB 1997-2016. All Rights Reserved.
 %% 
 %% Licensed under the Apache License, Version 2.0 (the "License");
 %% you may not use this file except in compliance with the License.
@@ -150,8 +150,8 @@ connect(Address, Port, Opts, Time) ->
 	Error -> Error
     end.
 
-connect1(Address,Port,Opts,Timer) ->
-    Mod = mod(Opts, Address),
+connect1(Address, Port, Opts0, Timer) ->
+    {Mod, Opts} = inet:tcp_module(Opts0, Address),
     case Mod:getaddrs(Address,Timer) of
 	{ok,IPs} ->
 	    case Mod:getserv(Port) of
@@ -184,8 +184,8 @@ try_connect([], _Port, _Opts, _Timer, _Mod, Err) ->
       ListenSocket :: socket(),
       Reason :: system_limit | inet:posix().
 
-listen(Port, Opts) ->
-    Mod = mod(Opts, undefined),
+listen(Port, Opts0) ->
+    {Mod, Opts} = inet:tcp_module(Opts0),
     case Mod:getserv(Port) of
 	{ok,TP} ->
 	    Mod:listen(TP, Opts);
@@ -334,32 +334,6 @@ controlling_process(S, NewOwner) ->
 %%
 %% Create a port/socket from a file descriptor 
 %%
-fdopen(Fd, Opts) ->
-    Mod = mod(Opts, undefined),
+fdopen(Fd, Opts0) ->
+    {Mod, Opts} = inet:tcp_module(Opts0),
     Mod:fdopen(Fd, Opts).
-
-%% Get the tcp_module, but IPv6 address overrides default IPv4
-mod(Address) ->
-    case inet_db:tcp_module() of
-	inet_tcp when tuple_size(Address) =:= 8 ->
-	    inet6_tcp;
-	Mod ->
-	    Mod
-    end.
-
-%% Get the tcp_module, but option tcp_module|inet|inet6 overrides
-mod([{tcp_module,Mod}|_], _Address) ->
-    Mod;
-mod([inet|_], _Address) ->
-    inet_tcp;
-mod([inet6|_], _Address) ->
-    inet6_tcp;
-mod([{ip, Address}|Opts], _) ->
-    mod(Opts, Address);
-mod([{ifaddr, Address}|Opts], _) ->
-    mod(Opts, Address);
-mod([_|Opts], Address) ->
-    mod(Opts, Address);
-mod([], Address) ->
-    mod(Address).
-
diff --git a/lib/kernel/src/gen_udp.erl b/lib/kernel/src/gen_udp.erl
index 6698d5f0fa..2227bb3562 100644
--- a/lib/kernel/src/gen_udp.erl
+++ b/lib/kernel/src/gen_udp.erl
@@ -1,7 +1,7 @@
 %%
 %% %CopyrightBegin%
 %% 
-%% Copyright Ericsson AB 1997-2013. All Rights Reserved.
+%% Copyright Ericsson AB 1997-2016. All Rights Reserved.
 %% 
 %% Licensed under the Apache License, Version 2.0 (the "License");
 %% you may not use this file except in compliance with the License.
@@ -101,9 +101,9 @@ open(Port) ->
       Socket :: socket(),
       Reason :: inet:posix().
 
-open(Port, Opts) ->
-    Mod = mod(Opts, undefined),
-    {ok,UP} = Mod:getserv(Port),
+open(Port, Opts0) ->
+    {Mod, Opts} = inet:udp_module(Opts0),
+    {ok, UP} = Mod:getserv(Port),
     Mod:open(UP, Opts).
 
 -spec close(Socket) -> ok when
@@ -203,32 +203,6 @@ controlling_process(S, NewOwner) ->
 %%
 %% Create a port/socket from a file descriptor 
 %%
-fdopen(Fd, Opts) ->
-    Mod = mod(Opts, undefined),
+fdopen(Fd, Opts0) ->
+    {Mod,Opts} = inet:udp_module(Opts0),
     Mod:fdopen(Fd, Opts).
-
-
-%% Get the udp_module, but IPv6 address overrides default IPv4
-mod(Address) ->
-    case inet_db:udp_module() of
-	inet_udp when tuple_size(Address) =:= 8 ->
-	    inet6_udp;
-	Mod ->
-	    Mod
-    end.
-
-%% Get the udp_module, but option udp_module|inet|inet6 overrides
-mod([{udp_module,Mod}|_], _Address) ->
-    Mod;
-mod([inet|_], _Address) ->
-    inet_udp;
-mod([inet6|_], _Address) ->
-    inet6_udp;
-mod([{ip, Address}|Opts], _) ->
-    mod(Opts, Address);
-mod([{ifaddr, Address}|Opts], _) ->
-    mod(Opts, Address);
-mod([_|Opts], Address) ->
-    mod(Opts, Address);
-mod([], Address) ->
-    mod(Address).
diff --git a/lib/kernel/src/inet.erl b/lib/kernel/src/inet.erl
index 8840f05fa1..1520f31a6f 100644
--- a/lib/kernel/src/inet.erl
+++ b/lib/kernel/src/inet.erl
@@ -1,7 +1,7 @@
 %%
 %% %CopyrightBegin%
 %%
-%% Copyright Ericsson AB 1997-2015. All Rights Reserved.
+%% Copyright Ericsson AB 1997-2016. All Rights Reserved.
 %%
 %% Licensed under the Apache License, Version 2.0 (the "License");
 %% you may not use this file except in compliance with the License.
@@ -37,10 +37,11 @@
 	 parse_ipv6strict_address/1, parse_address/1, parse_strict_address/1, ntoa/1]).
 
 -export([connect_options/2, listen_options/2, udp_options/2, sctp_options/2]).
+-export([udp_module/1, tcp_module/1, tcp_module/2, sctp_module/1]).
 
 -export([i/0, i/1, i/2]).
 
--export([getll/1, getfd/1, open/8, fdopen/6, getfamily/1]).
+-export([getll/1, getfd/1, open/8, fdopen/6]).
 
 -export([tcp_controlling_process/2, udp_controlling_process/2,
 	 tcp_close/1, udp_close/1]).
@@ -136,6 +137,8 @@
 -type address_family() :: 'inet' | 'inet6' | 'local'.
 -type socket_protocol() :: 'tcp' | 'udp' | 'sctp'.
 -type socket_type() :: 'stream' | 'dgram' | 'seqpacket'.
+-type socket_address() ::
+	ip_address() | {address_family(), any()} | 'any' | 'loopback'.
 -type stat_option() :: 
 	'recv_cnt' | 'recv_max' | 'recv_avg' | 'recv_oct' | 'recv_dvi' |
 	'send_cnt' | 'send_max' | 'send_avg' | 'send_oct' | 'send_pend'.
@@ -676,7 +679,7 @@ connect_options() ->
      low_msgq_watermark, send_timeout, send_timeout_close, delay_send, raw,
      show_econnreset].
     
-connect_options(Opts, Family) ->
+connect_options(Opts, Mod) ->
     BaseOpts = 
 	case application:get_env(kernel, inet_default_connect_options) of
 	    {ok,List} when is_list(List) ->
@@ -693,7 +696,7 @@ connect_options(Opts, Family) ->
 	{ok, R} ->
 	    {ok, R#connect_opts {
 		   opts = lists:reverse(R#connect_opts.opts),
-		   ifaddr = translate_ip(R#connect_opts.ifaddr, Family)
+		   ifaddr = Mod:translate_ip(R#connect_opts.ifaddr)
 		  }};
 	Error -> Error	    
     end.
@@ -708,10 +711,6 @@ con_opt([Opt | Opts], #connect_opts{} = R, As) ->
 	{fd,Fd}     -> con_opt(Opts, R#connect_opts { fd = Fd }, As);
 	binary      -> con_add(mode, binary, R, Opts, As);
 	list        -> con_add(mode, list, R, Opts, As);
-	{tcp_module,_}  -> con_opt(Opts, R, As);
-	inet        -> con_opt(Opts, R, As);
-	inet6       -> con_opt(Opts, R, As);
-	local       -> con_opt(Opts, R#connect_opts { family = local }, As);
 	{netns,NS} ->
 	    BinNS = filename2binary(NS),
 	    case prim_inet:is_sockopt_val(netns, BinNS) of
@@ -748,7 +747,7 @@ listen_options() ->
      low_msgq_watermark, send_timeout, send_timeout_close, delay_send,
      packet_size, raw, show_econnreset].
 
-listen_options(Opts, Family) ->
+listen_options(Opts, Mod) ->
     BaseOpts = 
 	case application:get_env(kernel, inet_default_listen_options) of
 	    {ok,List} when is_list(List) ->
@@ -765,7 +764,7 @@ listen_options(Opts, Family) ->
 	{ok, R} ->
 	    {ok, R#listen_opts {
 		   opts = lists:reverse(R#listen_opts.opts),
-		   ifaddr = translate_ip(R#listen_opts.ifaddr, Family)
+		   ifaddr = Mod:translate_ip(R#listen_opts.ifaddr)
 		  }};
 	Error -> Error
     end.
@@ -781,10 +780,6 @@ list_opt([Opt | Opts], #listen_opts{} = R, As) ->
 	{backlog,BL} ->  list_opt(Opts, R#listen_opts { backlog = BL }, As);
 	binary       ->  list_add(mode, binary, R, Opts, As);
 	list         ->  list_add(mode, list, R, Opts, As);
-	{tcp_module,_}  -> list_opt(Opts, R, As);
-	inet         -> list_opt(Opts, R, As);
-	inet6        -> list_opt(Opts, R, As);
-	local        -> list_opt(Opts, R#listen_opts { family = local }, As);
 	{netns,NS} ->
 	    BinNS = filename2binary(NS),
 	    case prim_inet:is_sockopt_val(netns, BinNS) of
@@ -809,6 +804,19 @@ list_add(Name, Val, #listen_opts{} = R, Opts, As) ->
 	Error -> Error
     end.
 
+tcp_module(Opts) ->
+    tcp_module_1(Opts, undefined).
+
+tcp_module(Opts, Addr) ->
+    Address = {undefined,Addr},
+    %% Address has to be a 2-tuple but the first element is ignored
+    tcp_module_1(Opts, Address).
+
+tcp_module_1(Opts, Address) ->
+    mod(
+      Opts, tcp_module, Address,
+      #{inet => inet_tcp, inet6 => inet6_tcp, local => local_tcp}).
+
 %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 %% Available options for udp:open
 %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
@@ -820,12 +828,12 @@ udp_options() ->
      high_msgq_watermark, low_msgq_watermark].
 
 
-udp_options(Opts, Family) ->
+udp_options(Opts, Mod) ->
     case udp_opt(Opts, #udp_opts { }, udp_options()) of
 	{ok, R} ->
 	    {ok, R#udp_opts {
 		   opts = lists:reverse(R#udp_opts.opts),
-		   ifaddr = translate_ip(R#udp_opts.ifaddr, Family)
+		   ifaddr = Mod:translate_ip(R#udp_opts.ifaddr)
 		  }};
 	Error -> Error
     end.
@@ -840,10 +848,6 @@ udp_opt([Opt | Opts], #udp_opts{} = R, As) ->
 	{fd,Fd}     ->  udp_opt(Opts, R#udp_opts { fd = Fd }, As);
 	binary      ->  udp_add(mode, binary, R, Opts, As);
 	list        ->  udp_add(mode, list, R, Opts, As);
-	{udp_module,_} -> udp_opt(Opts, R, As);
-	inet        ->  udp_opt(Opts, R, As);
-	inet6       ->  udp_opt(Opts, R, As);
-	local       ->  udp_opt(Opts, R#udp_opts { family = local }, As);
 	{netns,NS} ->
 	    BinNS = filename2binary(NS),
 	    case prim_inet:is_sockopt_val(netns, BinNS) of
@@ -868,6 +872,11 @@ udp_add(Name, Val, #udp_opts{} = R, Opts, As) ->
 	Error -> Error
     end.
 
+udp_module(Opts) ->
+    mod(
+      Opts, udp_module, undefined,
+      #{inet => inet_udp, inet6 => inet6_udp, local => local_udp}).
+
 %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 %% Available options for sctp:open
 %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
@@ -924,9 +933,6 @@ sctp_opt([Opt|Opts], Mod, #sctp_opts{} = R, As) ->
 	    sctp_opt(Opts, Mod, R#sctp_opts{type=Type}, As);
 	binary		-> sctp_opt (Opts, Mod, R, As, mode, binary);
 	list		-> sctp_opt (Opts, Mod, R, As, mode, list);
-	{sctp_module,_}	-> sctp_opt (Opts, Mod, R, As); % Done with
-	inet		-> sctp_opt (Opts, Mod, R, As); % Done with
-	inet6		-> sctp_opt (Opts, Mod, R, As); % Done with
 	{netns,NS} ->
 	    BinNS = filename2binary(NS),
 	    case prim_inet:is_sockopt_val(netns, BinNS) of
@@ -968,6 +974,11 @@ sctp_opt_ifaddr(Opts, Mod, #sctp_opts{ifaddr=IfAddr}=R, As, Addr) ->
 			  _                      -> [IP,IfAddr]
 		      end}, As).
 
+sctp_module(Opts) ->
+    mod(
+      Opts, sctp_module, undefined,
+      #{inet => inet_sctp, inet6 => inet6_sctp}).
+
 %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 %% Util to check and insert option in option list
 %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
@@ -1026,6 +1037,53 @@ translate_ip(any,      inet6) -> {0,0,0,0,0,0,0,0};
 translate_ip(loopback, inet6) -> {0,0,0,0,0,0,0,1};
 translate_ip(IP, _) -> IP.
 
+mod(Opts, Tag, Address, Map) ->
+    mod(Opts, Tag, Address, Map, undefined, []).
+%%
+mod([{Tag, M}|Opts], Tag, Address, Map, Mod, Acc) ->
+    mod(Opts, Tag, Address, Map, Mod, Acc, M);
+mod([{T, _} = Opt|Opts], Tag, _Address, Map, Mod, Acc)
+  when T =:= ip; T =:= ifaddr->
+    mod(Opts, Tag, Opt, Map, Mod, [Opt|Acc]);
+mod([Family|Opts], Tag, Address, Map, Mod, Acc) when is_atom(Family) ->
+    case Map of
+	#{Family := M} ->
+	    mod(Opts, Tag, Address, Map, Mod, Acc, M);
+	#{} ->
+	    mod(Opts, Tag, Address, Map, Mod, [Family|Acc])
+    end;
+mod([Opt|Opts], Tag, Address, Map, Mod, Acc) ->
+    mod(Opts, Tag, Address, Map, Mod, [Opt|Acc]);
+mod([], Tag, Address, Map, undefined, Acc) ->
+    {case Address of
+	 {_, {local, _}} ->
+	     case Map of
+		 #{local := Mod} ->
+		     Mod;
+		 #{} ->
+		     inet_db:Tag()
+	     end;
+	 {_, IP} when tuple_size(IP) =:= 8 ->
+	     #{inet := IPv4Mod} = Map,
+	     %% Get the mod, but IPv6 address overrides default IPv4
+	     case inet_db:Tag() of
+		 IPv4Mod ->
+		     #{inet6 := IPv6Mod} = Map,
+		     IPv6Mod;
+		 Mod ->
+		     Mod
+	     end;
+	 _ ->
+	     inet_db:Tag()
+     end, lists:reverse(Acc)};
+mod([], _Tag, _Address, _Map, Mod, Acc) ->
+    {Mod, lists:reverse(Acc)}.
+%%
+mod(Opts, Tag, Address, Map, undefined, Acc, M) ->
+    mod(Opts, Tag, Address, Map, M, Acc);
+mod(Opts, Tag, Address, Map, Mod, Acc, _M) ->
+    mod(Opts, Tag, Address, Map, Mod, Acc).
+
 
 getaddrs_tm({A,B,C,D} = IP, Fam, _)  ->
     %% Only "syntactic" validation and check of family.
@@ -1233,7 +1291,7 @@ gethostbyaddr_tm_native(Addr, Timer, Opts) ->
     end.
 
 -spec open(Fd_or_OpenOpts :: integer() | list(),
-	   Addr :: ip_address(),
+	   Addr :: socket_address(),
 	   Port :: port_number(),
 	   Opts :: [socket_setopt()],
 	   Protocol :: socket_protocol(),
@@ -1321,7 +1379,7 @@ fdopen(Fd, Addr, Port, Opts, Protocol, Family, Type, Module) ->
     Bound = Port == 0 andalso IsAnyAddr,
     case prim_inet:fdopen(Protocol, Family, Type, Fd, Bound) of
 	{ok, S} ->
-	    case prim_inet:setopts(S, Opts -- [local]) of
+	    case prim_inet:setopts(S, Opts) of
 		ok ->
                     case if
                              Bound ->
@@ -1348,13 +1406,6 @@ fdopen(Fd, Addr, Port, Opts, Protocol, Family, Type, Module) ->
 	Error -> Error
     end.
 
--spec getfamily(list()) -> atom().
-getfamily(Options) when is_list(Options) ->
-    case lists:member(local, Options) of
-    true  -> local;
-    false -> inet
-    end.
-
 %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 %%  socket stat
 %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
diff --git a/lib/kernel/src/inet6_sctp.erl b/lib/kernel/src/inet6_sctp.erl
index 5934c269fa..a5503f6f54 100644
--- a/lib/kernel/src/inet6_sctp.erl
+++ b/lib/kernel/src/inet6_sctp.erl
@@ -1,8 +1,8 @@
 %%
 %% %CopyrightBegin%
-%% 
-%% Copyright Ericsson AB 2007-2011. All Rights Reserved.
-%% 
+%%
+%% Copyright Ericsson AB 2007-2016. All Rights Reserved.
+%%
 %% Licensed under the Apache License, Version 2.0 (the "License");
 %% you may not use this file except in compliance with the License.
 %% You may obtain a copy of the License at
@@ -14,13 +14,12 @@
 %% WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 %% See the License for the specific language governing permissions and
 %% limitations under the License.
-%% 
+%%
 %% %CopyrightEnd%
 %%
 %% SCTP protocol contribution by Leonid Timochouk and Serge Aleynikov.
 %% See also: $ERL_TOP/lib/kernel/AUTHORS
 %%
-%%
 -module(inet6_sctp).
 
 %% This module provides functions for communicating with
@@ -31,6 +30,7 @@
 -include("inet_sctp.hrl").
 -include("inet_int.hrl").
 
+-define(PROTO, sctp).
 -define(FAMILY, inet6).
 -export([getserv/1,getaddr/1,getaddr/2,translate_ip/1]).
 -export([open/1,close/1,listen/2,peeloff/2,connect/5]).
@@ -39,25 +39,19 @@
 
 
 getserv(Port) when is_integer(Port) -> {ok, Port};
-getserv(Name) when is_atom(Name) ->
-    inet:getservbyname(Name, sctp);
-getserv(_) ->
-    {error,einval}.
-
-getaddr(Address) ->
-    inet:getaddr(Address, ?FAMILY).
-getaddr(Address, Timer) ->
-    inet:getaddr_tm(Address, ?FAMILY, Timer).
+getserv(Name) when is_atom(Name) -> inet:getservbyname(Name, ?PROTO);
+getserv(_) -> {error,einval}.
 
-translate_ip(IP) ->
-    inet:translate_ip(IP, ?FAMILY).
+getaddr(Address) -> inet:getaddr(Address, ?FAMILY).
+getaddr(Address, Timer) -> inet:getaddr_tm(Address, ?FAMILY, Timer).
 
+translate_ip(IP) -> inet:translate_ip(IP, ?FAMILY).
 
     
 open(Opts) ->
     case inet:sctp_options(Opts, ?MODULE) of
 	{ok,#sctp_opts{fd=Fd,ifaddr=Addr,port=Port,type=Type,opts=SOs}} ->
-	    inet:open(Fd, Addr, Port, SOs, sctp, ?FAMILY, Type, ?MODULE);
+	    inet:open(Fd, Addr, Port, SOs, ?PROTO, ?FAMILY, Type, ?MODULE);
 	Error -> Error
     end.
 
diff --git a/lib/kernel/src/inet6_tcp.erl b/lib/kernel/src/inet6_tcp.erl
index 1978307b3c..a0d5d3df70 100644
--- a/lib/kernel/src/inet6_tcp.erl
+++ b/lib/kernel/src/inet6_tcp.erl
@@ -1,7 +1,7 @@
 %%
 %% %CopyrightBegin%
 %% 
-%% Copyright Ericsson AB 1997-2011. All Rights Reserved.
+%% Copyright Ericsson AB 1997-2016. All Rights Reserved.
 %% 
 %% Licensed under the Apache License, Version 2.0 (the "License");
 %% you may not use this file except in compliance with the License.
@@ -25,13 +25,18 @@
 -export([controlling_process/2]).
 -export([fdopen/2]).
 
--export([family/0, mask/2, parse_address/1]).
+-export([family/0, mask/2, parse_address/1]). % inet_tcp_dist
 -export([getserv/1, getaddr/1, getaddr/2, getaddrs/1, getaddrs/2]).
+-export([translate_ip/1]).
 
 -include("inet_int.hrl").
 
+-define(FAMILY, inet6).
+-define(PROTO, tcp).
+-define(TYPE, stream).
+
 %% my address family
-family() -> inet6.
+family() -> ?FAMILY.
 
 %% Apply netmask on address
 mask({M1,M2,M3,M4,M5,M6,M7,M8}, {IP1,IP2,IP3,IP4,IP5,IP6,IP7,IP8}) ->
@@ -50,15 +55,18 @@ parse_address(Host) ->
 
 %% inet_tcp port lookup
 getserv(Port) when is_integer(Port) -> {ok, Port};
-getserv(Name) when is_atom(Name)    -> inet:getservbyname(Name,tcp).
+getserv(Name) when is_atom(Name) -> inet:getservbyname(Name, ?PROTO).
 
 %% inet_tcp address lookup
-getaddr(Address) -> inet:getaddr(Address, inet6).
-getaddr(Address,Timer) -> inet:getaddr_tm(Address, inet6, Timer).
+getaddr(Address) -> inet:getaddr(Address, ?FAMILY).
+getaddr(Address, Timer) -> inet:getaddr_tm(Address, ?FAMILY, Timer).
 
 %% inet_tcp address lookup
-getaddrs(Address) -> inet:getaddrs(Address, inet6).
-getaddrs(Address,Timer) -> inet:getaddrs_tm(Address,inet6,Timer).
+getaddrs(Address) -> inet:getaddrs(Address, ?FAMILY).
+getaddrs(Address, Timer) -> inet:getaddrs_tm(Address, ?FAMILY, Timer).
+
+%% inet_udp special this side addresses
+translate_ip(IP) -> inet:translate_ip(IP, ?FAMILY).
 
 %%
 %% Send data on a socket
@@ -73,11 +81,6 @@ recv(Socket, Length) -> prim_inet:recv(Socket, Length).
 recv(Socket, Length, Timeout) -> prim_inet:recv(Socket, Length, Timeout).
 
 unrecv(Socket, Data) -> prim_inet:unrecv(Socket, Data).
-%%
-%% Close a socket (async)
-%%
-close(Socket) -> 
-    inet:tcp_close(Socket).
 
 %%
 %% Shutdown one end of a socket
@@ -86,6 +89,12 @@ shutdown(Socket, How) ->
     prim_inet:shutdown(Socket, How).
 
 %%
+%% Close a socket (async)
+%%
+close(Socket) ->
+    inet:tcp_close(Socket).
+
+%%
 %% Set controlling process
 %% FIXME: move messages to new owner!!!
 %%
@@ -100,24 +109,28 @@ connect(Address, Port, Opts) ->
 
 connect(Address, Port, Opts, infinity) ->
     do_connect(Address, Port, Opts, infinity);
-connect(Address, Port, Opts, Timeout) when is_integer(Timeout), 
-                                           Timeout >= 0 ->
+connect(Address, Port, Opts, Timeout)
+  when is_integer(Timeout), Timeout >= 0 ->
     do_connect(Address, Port, Opts, Timeout).
 
-do_connect(Addr = {A,B,C,D,E,F,G,H}, Port, Opts, Time) when 
-  ?ip6(A,B,C,D,E,F,G,H), ?port(Port) ->
-    case inet:connect_options(Opts, inet6) of
+do_connect(Addr = {A,B,C,D,E,F,G,H}, Port, Opts, Time)
+  when ?ip6(A,B,C,D,E,F,G,H), ?port(Port) ->
+    case inet:connect_options(Opts, ?MODULE) of
 	{error, Reason} -> exit(Reason);
-	{ok, #connect_opts{fd=Fd,
-			   ifaddr=BAddr={Ab,Bb,Cb,Db,Eb,Fb,Gb,Hb},
-			   port=BPort,
-			   opts=SockOpts}}
+	{ok,
+	 #connect_opts{
+	    fd = Fd,
+	    ifaddr = BAddr = {Ab,Bb,Cb,Db,Eb,Fb,Gb,Hb},
+	    port = BPort,
+	    opts = SockOpts}}
 	when ?ip6(Ab,Bb,Cb,Db,Eb,Fb,Gb,Hb), ?port(BPort) ->
-	    case inet:open(Fd,BAddr,BPort,SockOpts,tcp,inet6,stream,?MODULE) of
+	    case inet:open(
+		   Fd, BAddr, BPort, SockOpts,
+		   ?PROTO, ?FAMILY, ?TYPE, ?MODULE) of
 		{ok, S} ->
 		    case prim_inet:connect(S, Addr, Port, Time) of
-			ok    -> {ok,S};
-			Error ->  prim_inet:close(S), Error
+			ok -> {ok,S};
+			Error -> prim_inet:close(S), Error
 		    end;
 		Error -> Error
 	    end;
@@ -128,14 +141,18 @@ do_connect(Addr = {A,B,C,D,E,F,G,H}, Port, Opts, Time) when
 %% Listen
 %%
 listen(Port, Opts) ->
-    case inet:listen_options([{port,Port} | Opts], inet6) of
+    case inet:listen_options([{port,Port} | Opts], ?MODULE) of
 	{error, Reason} -> exit(Reason);
-	{ok, #listen_opts{fd=Fd,
-			  ifaddr=BAddr={A,B,C,D,E,F,G,H},
-			  port=BPort,
-			  opts=SockOpts}=R}
+	{ok,
+	 #listen_opts{
+	    fd = Fd,
+	    ifaddr = BAddr = {A,B,C,D,E,F,G,H},
+	    port = BPort,
+	    opts = SockOpts} = R}
 	when ?ip6(A,B,C,D,E,F,G,H), ?port(BPort) ->
-	    case inet:open(Fd,BAddr,BPort,SockOpts,tcp,inet6,stream,?MODULE) of
+	    case inet:open(
+		   Fd, BAddr, BPort, SockOpts,
+		   ?PROTO, ?FAMILY, ?TYPE, ?MODULE) of
 		{ok, S} ->
 		    case prim_inet:listen(S, R#listen_opts.backlog) of
 			ok -> {ok, S};
@@ -156,18 +173,17 @@ accept(L) ->
 	    {ok,S};
 	Error -> Error
     end.
-	    
-accept(L,Timeout) -> 
-    case prim_inet:accept(L,Timeout) of
+
+accept(L, Timeout) ->
+    case prim_inet:accept(L, Timeout) of
 	{ok, S} ->
 	    inet_db:register_socket(S, ?MODULE),
 	    {ok,S};
 	Error -> Error
     end.
-    
+
 %%
 %% Create a port/socket from a file descriptor 
 %%
 fdopen(Fd, Opts) ->
-    inet:fdopen(Fd, Opts, tcp, inet6, stream, ?MODULE).
-
+    inet:fdopen(Fd, Opts, ?PROTO, ?FAMILY, ?TYPE, ?MODULE).
diff --git a/lib/kernel/src/inet6_udp.erl b/lib/kernel/src/inet6_udp.erl
index 61c74bf14f..71db0357cd 100644
--- a/lib/kernel/src/inet6_udp.erl
+++ b/lib/kernel/src/inet6_udp.erl
@@ -1,7 +1,7 @@
 %%
 %% %CopyrightBegin%
 %% 
-%% Copyright Ericsson AB 1997-2011. All Rights Reserved.
+%% Copyright Ericsson AB 1997-2016. All Rights Reserved.
 %% 
 %% Licensed under the Apache License, Version 2.0 (the "License");
 %% you may not use this file except in compliance with the License.
@@ -24,29 +24,44 @@
 -export([controlling_process/2]).
 -export([fdopen/2]).
 
--export([getserv/1, getaddr/1, getaddr/2]).
+-export([getserv/1, getaddr/1, getaddr/2, translate_ip/1]).
 
 -include("inet_int.hrl").
 
+-define(FAMILY, inet6).
+-define(PROTO, udp).
+-define(TYPE, dgram).
+
+
 %% inet_udp port lookup
 getserv(Port) when is_integer(Port) -> {ok, Port};
-getserv(Name) when is_atom(Name)    -> inet:getservbyname(Name,udp).
+getserv(Name) when is_atom(Name) -> inet:getservbyname(Name, ?PROTO).
 
 %% inet_udp address lookup
-getaddr(Address) -> inet:getaddr(Address, inet6).
-getaddr(Address,Timer) -> inet:getaddr(Address, inet6, Timer).
+getaddr(Address) -> inet:getaddr(Address, ?FAMILY).
+getaddr(Address, Timer) -> inet:getaddr(Address, ?FAMILY, Timer).
+
+%% inet_udp special this side addresses
+translate_ip(IP) -> inet:translate_ip(IP, ?FAMILY).
 
+-spec open(_) -> {ok, inet:socket()} | {error, atom()}.
 open(Port) -> open(Port, []).
 
+-spec open(_, _) -> {ok, inet:socket()} | {error, atom()}.
 open(Port, Opts) ->
-    case inet:udp_options([{port,Port} | Opts], inet6) of
+    case inet:udp_options(
+	   [{port,Port} | Opts],
+	   ?MODULE) of
 	{error, Reason} -> exit(Reason);
-	{ok, #udp_opts{fd=Fd,
-		       ifaddr=BAddr={A,B,C,D,E,F,G,H},
-		       port=BPort,
-		       opts=SockOpts}}
+	{ok,
+	 #udp_opts{
+	    fd = Fd,
+	    ifaddr = BAddr = {A,B,C,D,E,F,G,H},
+	    port = BPort,
+	    opts = SockOpts}}
 	when ?ip6(A,B,C,D,E,F,G,H), ?port(BPort) ->
-	    inet:open(Fd,BAddr,BPort,SockOpts,udp,inet6,dgram,?MODULE);
+	    inet:open(
+	      Fd, BAddr, BPort, SockOpts, ?PROTO, ?FAMILY, ?TYPE, ?MODULE);
 	{ok, _} -> exit(badarg)
     end.
 
@@ -61,12 +76,13 @@ connect(S, Addr = {A,B,C,D,E,F,G,H}, P)
   when ?ip6(A,B,C,D,E,F,G,H), ?port(P) ->
     prim_inet:connect(S, Addr, P).
 
-recv(S,Len) ->
+recv(S, Len) ->
     prim_inet:recvfrom(S, Len).
 
-recv(S,Len,Time) ->
+recv(S, Len, Time) ->
     prim_inet:recvfrom(S, Len, Time).
 
+-spec close(inet:socket()) -> ok.
 close(S) ->
     inet:udp_close(S).
 
@@ -85,4 +101,4 @@ controlling_process(Socket, NewOwner) ->
 %% Create a port/socket from a file descriptor 
 %%
 fdopen(Fd, Opts) ->
-    inet:fdopen(Fd, Opts, udp, inet6, dgram, ?MODULE).
+    inet:fdopen(Fd, Opts, ?PROTO, ?FAMILY, ?TYPE, ?MODULE).
diff --git a/lib/kernel/src/inet_int.hrl b/lib/kernel/src/inet_int.hrl
index 6c9a23ff82..32d09fb63c 100644
--- a/lib/kernel/src/inet_int.hrl
+++ b/lib/kernel/src/inet_int.hrl
@@ -381,7 +381,6 @@
 	  ifaddr = any,     %% bind to interface address
 	  port   = 0,       %% bind to port (default is dynamic port)
 	  fd     = -1,      %% fd >= 0 => already bound
-	  family = inet,    %% address family
 	  opts   = []       %% [{active,true}] added in inet:connect_options
 	 }).
 
@@ -391,7 +390,6 @@
 	  port   = 0,                %% bind to port (default is dynamic port)
 	  backlog = ?LISTEN_BACKLOG, %% backlog
 	  fd      = -1,              %% %% fd >= 0 => already bound
-	  family = inet,             %% address family
 	  opts   = []                %% [{active,true}] added in 
 	                             %% inet:listen_options
 	 }).
@@ -401,7 +399,6 @@
 	  ifaddr = any,
 	  port   = 0,
 	  fd     = -1,
-	  family = inet,
 	  opts   = [{active,true}]
 	 }).
 
diff --git a/lib/kernel/src/inet_sctp.erl b/lib/kernel/src/inet_sctp.erl
index 88c8d24143..8569cacb29 100644
--- a/lib/kernel/src/inet_sctp.erl
+++ b/lib/kernel/src/inet_sctp.erl
@@ -1,7 +1,7 @@
 %%
 %% %CopyrightBegin%
 %%
-%% Copyright Ericsson AB 2007-2013. All Rights Reserved.
+%% Copyright Ericsson AB 2007-2016. All Rights Reserved.
 %%
 %% Licensed under the Apache License, Version 2.0 (the "License");
 %% you may not use this file except in compliance with the License.
@@ -30,6 +30,7 @@
 -include("inet_sctp.hrl").
 -include("inet_int.hrl").
 
+-define(PROTO, sctp).
 -define(FAMILY, inet).
 -export([getserv/1,getaddr/1,getaddr/2,translate_ip/1]).
 -export([open/1,close/1,listen/2,peeloff/2,connect/5]).
@@ -38,25 +39,19 @@
 
 
 getserv(Port) when is_integer(Port) -> {ok, Port};
-getserv(Name) when is_atom(Name) ->
-    inet:getservbyname(Name, sctp);
-getserv(_) ->
-    {error,einval}.
+getserv(Name) when is_atom(Name) -> inet:getservbyname(Name, ?PROTO);
+getserv(_) -> {error,einval}.
 
-getaddr(Address) ->
-    inet:getaddr(Address, ?FAMILY).
-getaddr(Address, Timer) ->
-    inet:getaddr_tm(Address, ?FAMILY, Timer).
-
-translate_ip(IP) ->
-    inet:translate_ip(IP, ?FAMILY).
+getaddr(Address) -> inet:getaddr(Address, ?FAMILY).
+getaddr(Address, Timer) -> inet:getaddr_tm(Address, ?FAMILY, Timer).
 
+translate_ip(IP) -> inet:translate_ip(IP, ?FAMILY).
 
     
 open(Opts) ->
     case inet:sctp_options(Opts, ?MODULE) of
 	{ok,#sctp_opts{fd=Fd,ifaddr=Addr,port=Port,type=Type,opts=SOs}} ->
-	    inet:open(Fd, Addr, Port, SOs, sctp, ?FAMILY, Type, ?MODULE);
+	    inet:open(Fd, Addr, Port, SOs, ?PROTO, ?FAMILY, Type, ?MODULE);
 	Error -> Error
     end.
 
diff --git a/lib/kernel/src/inet_tcp.erl b/lib/kernel/src/inet_tcp.erl
index ad0a6159fe..dac6b3119d 100644
--- a/lib/kernel/src/inet_tcp.erl
+++ b/lib/kernel/src/inet_tcp.erl
@@ -1,7 +1,7 @@
 %%
 %% %CopyrightBegin%
 %% 
-%% Copyright Ericsson AB 1997-2011. All Rights Reserved.
+%% Copyright Ericsson AB 1997-2016. All Rights Reserved.
 %% 
 %% Licensed under the Apache License, Version 2.0 (the "License");
 %% you may not use this file except in compliance with the License.
@@ -27,13 +27,18 @@
 -export([controlling_process/2]).
 -export([fdopen/2]).
 
--export([family/0, mask/2, parse_address/1]).
+-export([family/0, mask/2, parse_address/1]). % inet_tcp_dist
 -export([getserv/1, getaddr/1, getaddr/2, getaddrs/1, getaddrs/2]).
+-export([translate_ip/1]).
 
 -include("inet_int.hrl").
 
+-define(FAMILY, inet).
+-define(PROTO, tcp).
+-define(TYPE, stream).
+
 %% my address family
-family() -> inet.
+family() -> ?FAMILY.
 
 %% Apply netmask on address
 mask({M1,M2,M3,M4}, {IP1,IP2,IP3,IP4}) ->
@@ -48,16 +53,19 @@ parse_address(Host) ->
 
 %% inet_tcp port lookup
 getserv(Port) when is_integer(Port) -> {ok, Port};
-getserv(Name) when is_atom(Name)    -> inet:getservbyname(Name,tcp).
+getserv(Name) when is_atom(Name) -> inet:getservbyname(Name, ?PROTO).
 
 %% inet_tcp address lookup
-getaddr(Address) -> inet:getaddr(Address, inet).
-getaddr(Address,Timer) -> inet:getaddr_tm(Address, inet, Timer).
+getaddr(Address) -> inet:getaddr(Address, ?FAMILY).
+getaddr(Address, Timer) -> inet:getaddr_tm(Address, ?FAMILY, Timer).
 
 %% inet_tcp address lookup
-getaddrs(Address) -> inet:getaddrs(Address, inet).
-getaddrs(Address,Timer) -> inet:getaddrs_tm(Address,inet,Timer).
-    
+getaddrs(Address) -> inet:getaddrs(Address, ?FAMILY).
+getaddrs(Address, Timer) -> inet:getaddrs_tm(Address, ?FAMILY, Timer).
+
+%% inet_udp special this side addresses
+translate_ip(IP) -> inet:translate_ip(IP, ?FAMILY).
+
 %%
 %% Send data on a socket
 %%
@@ -77,7 +85,7 @@ unrecv(Socket, Data) -> prim_inet:unrecv(Socket, Data).
 %%
 shutdown(Socket, How) ->
     prim_inet:shutdown(Socket, How).
-    
+
 %%
 %% Close a socket (async)
 %%
@@ -88,7 +96,7 @@ close(Socket) ->
 %% Set controlling process
 %%
 controlling_process(Socket, NewOwner) ->
-    inet:tcp_controlling_process(Socket, NewOwner). 
+    inet:tcp_controlling_process(Socket, NewOwner).
 
 %%
 %% Connect
@@ -98,24 +106,28 @@ connect(Address, Port, Opts) ->
 
 connect(Address, Port, Opts, infinity) ->
     do_connect(Address, Port, Opts, infinity);
-connect(Address, Port, Opts, Timeout) when is_integer(Timeout), 
-                                           Timeout >= 0 ->
+connect(Address, Port, Opts, Timeout)
+  when is_integer(Timeout), Timeout >= 0 ->
     do_connect(Address, Port, Opts, Timeout).
 
-do_connect({A,B,C,D}, Port, Opts, Time) when ?ip(A,B,C,D), ?port(Port) ->
-    case inet:connect_options(Opts, inet) of
+do_connect(Addr = {A,B,C,D}, Port, Opts, Time)
+  when ?ip(A,B,C,D), ?port(Port) ->
+    case inet:connect_options(Opts, ?MODULE) of
 	{error, Reason} -> exit(Reason);
-	{ok, #connect_opts{fd=Fd,
-			   ifaddr=BAddr={Ab,Bb,Cb,Db},
-			   port=BPort,
-			   family=Family,
-			   opts=SockOpts}}
+	{ok,
+	 #connect_opts{
+	    fd = Fd,
+	    ifaddr = BAddr = {Ab,Bb,Cb,Db},
+	    port = BPort,
+	    opts = SockOpts}}
 	when ?ip(Ab,Bb,Cb,Db), ?port(BPort) ->
-	    case inet:open(Fd,BAddr,BPort,SockOpts,tcp,Family,stream,?MODULE) of
+	    case inet:open(
+		   Fd, BAddr, BPort, SockOpts,
+		   ?PROTO, ?FAMILY, ?TYPE, ?MODULE) of
 		{ok, S} ->
-		    case prim_inet:connect(S, {A,B,C,D}, Port, Time) of
-			ok    -> {ok,S};
-			Error ->  prim_inet:close(S), Error
+		    case prim_inet:connect(S, Addr, Port, Time) of
+			ok -> {ok,S};
+			Error -> prim_inet:close(S), Error
 		    end;
 		Error -> Error
 	    end;
@@ -126,15 +138,18 @@ do_connect({A,B,C,D}, Port, Opts, Time) when ?ip(A,B,C,D), ?port(Port) ->
 %% Listen
 %%
 listen(Port, Opts) ->
-    case inet:listen_options([{port,Port} | Opts], inet) of
-	{error,Reason} -> exit(Reason);
-	{ok, #listen_opts{fd=Fd,
-			  ifaddr=BAddr={A,B,C,D},
-			  port=BPort,
-			  family=Family,
-			  opts=SockOpts}=R}
+    case inet:listen_options([{port,Port} | Opts], ?MODULE) of
+	{error, Reason} -> exit(Reason);
+	{ok,
+	 #listen_opts{
+	    fd = Fd,
+	    ifaddr = BAddr = {A,B,C,D},
+	    port = BPort,
+	    opts = SockOpts} = R}
 	when ?ip(A,B,C,D), ?port(BPort) ->
-	    case inet:open(Fd,BAddr,BPort,SockOpts,tcp,Family,stream,?MODULE) of
+	    case inet:open(
+		   Fd, BAddr, BPort, SockOpts,
+		   ?PROTO, ?FAMILY, ?TYPE, ?MODULE) of
 		{ok, S} ->
 		    case prim_inet:listen(S, R#listen_opts.backlog) of
 			ok -> {ok, S};
@@ -148,26 +163,24 @@ listen(Port, Opts) ->
 %%
 %% Accept
 %%
-accept(L)         -> 
+accept(L) ->
     case prim_inet:accept(L) of
 	{ok, S} ->
 	    inet_db:register_socket(S, ?MODULE),
 	    {ok,S};
 	Error -> Error
     end.
-	    
-accept(L,Timeout) -> 
-    case prim_inet:accept(L,Timeout) of
+
+accept(L, Timeout) ->
+    case prim_inet:accept(L, Timeout) of
 	{ok, S} ->
 	    inet_db:register_socket(S, ?MODULE),
 	    {ok,S};
 	Error -> Error
     end.
+
 %%
 %% Create a port/socket from a file descriptor 
 %%
 fdopen(Fd, Opts) ->
-    fdopen(Fd, inet:getfamily(Opts), Opts).
-
-fdopen(Fd, Family, Opts) ->
-    inet:fdopen(Fd, Opts, tcp, Family, stream, ?MODULE).
+    inet:fdopen(Fd, Opts, ?PROTO, ?FAMILY, ?TYPE, ?MODULE).
diff --git a/lib/kernel/src/inet_udp.erl b/lib/kernel/src/inet_udp.erl
index 74b2874d5b..8a8aa8ecca 100644
--- a/lib/kernel/src/inet_udp.erl
+++ b/lib/kernel/src/inet_udp.erl
@@ -1,7 +1,7 @@
 %%
 %% %CopyrightBegin%
 %% 
-%% Copyright Ericsson AB 1997-2011. All Rights Reserved.
+%% Copyright Ericsson AB 1997-2016. All Rights Reserved.
 %% 
 %% Licensed under the Apache License, Version 2.0 (the "License");
 %% you may not use this file except in compliance with the License.
@@ -24,21 +24,26 @@
 -export([controlling_process/2]).
 -export([fdopen/2]).
 
--export([getserv/1, getaddr/1, getaddr/2]).
+-export([getserv/1, getaddr/1, getaddr/2, translate_ip/1]).
 
 -include("inet_int.hrl").
 
+-define(FAMILY, inet).
+-define(PROTO, udp).
+-define(TYPE, dgram).
 -define(RECBUF, (8*1024)).
 
 
-
 %% inet_udp port lookup
 getserv(Port) when is_integer(Port) -> {ok, Port};
-getserv(Name) when is_atom(Name)    -> inet:getservbyname(Name,udp).
+getserv(Name) when is_atom(Name) -> inet:getservbyname(Name, ?PROTO).
 
 %% inet_udp address lookup
-getaddr(Address) -> inet:getaddr(Address, inet).
-getaddr(Address,Timer) -> inet:getaddr_tm(Address, inet, Timer).
+getaddr(Address) -> inet:getaddr(Address, ?FAMILY).
+getaddr(Address, Timer) -> inet:getaddr(Address, ?FAMILY, Timer).
+
+%% inet_udp special this side addresses
+translate_ip(IP) -> inet:translate_ip(IP, ?FAMILY).
 
 -spec open(_) -> {ok, inet:socket()} | {error, atom()}.
 open(Port) -> open(Port, []).
@@ -47,34 +52,38 @@ open(Port) -> open(Port, []).
 open(Port, Opts) ->
     case inet:udp_options(
 	   [{port,Port}, {recbuf, ?RECBUF} | Opts], 
-	   inet) of
+	   ?MODULE) of
 	{error, Reason} -> exit(Reason);
-	{ok, #udp_opts{fd=Fd,
-		       ifaddr=BAddr={A,B,C,D},
-		       port=BPort,
-		       family=Family,
-		       opts=SockOpts}} when ?ip(A,B,C,D), ?port(BPort) ->
-	    inet:open(Fd,BAddr,BPort,SockOpts,udp,Family,dgram,?MODULE);
+	{ok,
+	 #udp_opts{
+	    fd = Fd,
+	    ifaddr = BAddr = {A,B,C,D},
+	    port = BPort,
+	    opts = SockOpts}}
+	  when ?ip(A,B,C,D), ?port(BPort) ->
+	    inet:open(
+	      Fd, BAddr, BPort, SockOpts, ?PROTO, ?FAMILY, ?TYPE, ?MODULE);
 	{ok, _} -> exit(badarg)
     end.
 
-send(S,{A,B,C,D},P,Data) when ?ip(A,B,C,D), ?port(P) ->
-    prim_inet:sendto(S, {A,B,C,D}, P, Data).
+send(S, {A,B,C,D} = Addr, P, Data)
+  when ?ip(A,B,C,D), ?port(P) ->
+    prim_inet:sendto(S, Addr, P, Data).
 
 send(S, Data) ->
     prim_inet:sendto(S, {0,0,0,0}, 0, Data).
     
-connect(S, {A,B,C,D}, P) when ?ip(A,B,C,D), ?port(P) ->
-    prim_inet:connect(S, {A,B,C,D}, P).
+connect(S, Addr = {A,B,C,D}, P)
+  when ?ip(A,B,C,D), ?port(P) ->
+    prim_inet:connect(S, Addr, P).
 
-recv(S,Len) ->
+recv(S, Len) ->
     prim_inet:recvfrom(S, Len).
 
-recv(S,Len,Time) ->
+recv(S, Len, Time) ->
     prim_inet:recvfrom(S, Len, Time).
 
 -spec close(inet:socket()) -> ok.
-
 close(S) ->
     inet:udp_close(S).
 
@@ -93,12 +102,9 @@ controlling_process(Socket, NewOwner) ->
 %% Create a port/socket from a file descriptor 
 %%
 fdopen(Fd, Opts) ->
-    fdopen(Fd, inet:getfamily(Opts), Opts).
-
-fdopen(Fd, Family, Opts) ->
-    inet:fdopen(Fd, 
-		optuniquify([{recbuf, ?RECBUF} | Opts]), 
-		udp, Family, dgram, ?MODULE).
+    inet:fdopen(
+      Fd, optuniquify([{recbuf, ?RECBUF} | Opts]),
+      ?PROTO, ?FAMILY, ?TYPE, ?MODULE).
 
 
 %% Remove all duplicate options from an option list.
diff --git a/lib/kernel/src/kernel.app.src b/lib/kernel/src/kernel.app.src
index b5555ca1a5..e23f5aaf1b 100644
--- a/lib/kernel/src/kernel.app.src
+++ b/lib/kernel/src/kernel.app.src
@@ -55,6 +55,8 @@
 	     inet_tcp_dist,
 	     kernel,
 	     kernel_config,
+	     local_tcp,
+	     local_udp,
 	     net,
 	     net_adm,
 	     net_kernel,
diff --git a/lib/kernel/src/local_tcp.erl b/lib/kernel/src/local_tcp.erl
new file mode 100644
index 0000000000..64085ec42e
--- /dev/null
+++ b/lib/kernel/src/local_tcp.erl
@@ -0,0 +1,172 @@
+%%
+%% %CopyrightBegin%
+%%
+%% Copyright Ericsson AB 1997-2016. All Rights Reserved.
+%%
+%% Licensed under the Apache License, Version 2.0 (the "License");
+%% you may not use this file except in compliance with the License.
+%% You may obtain a copy of the License at
+%%
+%%     http://www.apache.org/licenses/LICENSE-2.0
+%%
+%% Unless required by applicable law or agreed to in writing, software
+%% distributed under the License is distributed on an "AS IS" BASIS,
+%% WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+%% See the License for the specific language governing permissions and
+%% limitations under the License.
+%%
+%% %CopyrightEnd%
+%%
+-module(local_tcp).
+
+%% Socket server for TCP/IP
+
+-export([connect/3, connect/4, listen/2, accept/1, accept/2, close/1]).
+-export([send/2, send/3, recv/2, recv/3, unrecv/2]).
+-export([shutdown/2]).
+-export([controlling_process/2]).
+-export([fdopen/2]).
+
+-export([getserv/1, getaddr/1, getaddr/2, getaddrs/1, getaddrs/2]).
+-export([translate_ip/1]).
+
+-include("inet_int.hrl").
+
+-define(FAMILY, local).
+-define(PROTO, tcp).
+-define(TYPE, stream).
+
+%% port lookup
+getserv(0) -> {ok, 0}.
+
+%% no address lookup
+getaddr({?FAMILY, _} = Address) -> {ok, Address}.
+getaddr({?FAMILY, _} = Address, _Timer) -> {ok, Address}.
+
+%% no address lookup
+getaddrs({?FAMILY, _} = Address) -> {ok, [Address]}.
+getaddrs({?FAMILY, _} = Address, _Timer) -> {ok, [Address]}.
+
+%% special this side addresses
+translate_ip(IP) -> IP.
+
+%%
+%% Send data on a socket
+%%
+send(Socket, Packet, Opts) -> prim_inet:send(Socket, Packet, Opts).
+send(Socket, Packet) -> prim_inet:send(Socket, Packet, []).
+
+%%
+%% Receive data from a socket (inactive only)
+%%
+recv(Socket, Length) -> prim_inet:recv(Socket, Length).
+recv(Socket, Length, Timeout) -> prim_inet:recv(Socket, Length, Timeout).
+
+unrecv(Socket, Data) -> prim_inet:unrecv(Socket, Data).
+
+%%
+%% Shutdown one end of a socket
+%%
+shutdown(Socket, How) ->
+    prim_inet:shutdown(Socket, How).
+
+%%
+%% Close a socket (async)
+%%
+close(Socket) ->
+    inet:tcp_close(Socket).
+
+%%
+%% Set controlling process
+%% FIXME: move messages to new owner!!!
+%%
+controlling_process(Socket, NewOwner) ->
+    inet:tcp_controlling_process(Socket, NewOwner).
+
+%%
+%% Connect
+%%
+connect(Address, Port, Opts) ->
+    do_connect(Address, Port, Opts, infinity).
+%%
+connect(Address, Port, Opts, infinity) ->
+    do_connect(Address, Port, Opts, infinity);
+connect(Address, Port, Opts, Timeout)
+  when is_integer(Timeout), Timeout >= 0 ->
+    do_connect(Address, Port, Opts, Timeout).
+
+do_connect(Addr = {?FAMILY, _}, 0, Opts, Time) ->
+    case inet:connect_options(Opts, ?MODULE) of
+	{error, Reason} -> exit(Reason);
+	{ok,
+	 #connect_opts{
+	    fd = Fd,
+	    ifaddr = BAddr,
+	    port = 0,
+	    opts = SockOpts}}
+	when tuple_size(BAddr) =:= 2, element(1, BAddr) =:= ?FAMILY;
+	     BAddr =:= any ->
+	    case inet:open(
+		   Fd, BAddr, 0, SockOpts,
+		   ?PROTO, ?FAMILY, ?TYPE, ?MODULE) of
+		{ok, S} ->
+		    case prim_inet:connect(S, Addr, 0, Time) of
+			ok -> {ok,S};
+			Error -> prim_inet:close(S), Error
+		    end;
+		Error -> Error
+	    end;
+	{ok, _} -> exit(badarg)
+    end.
+
+%%
+%% Listen
+%%
+listen(0, Opts) ->
+    case inet:listen_options([{port,0} | Opts], ?MODULE) of
+	{error, Reason} -> exit(Reason);
+	{ok,
+	 #listen_opts{
+	    fd = Fd,
+	    ifaddr = BAddr,
+	    port = 0,
+	    opts = SockOpts} = R}
+	when tuple_size(BAddr) =:= 2, element(1, BAddr) =:= ?FAMILY;
+	     BAddr =:= any ->
+	    case inet:open(
+		   Fd, BAddr, 0, SockOpts,
+		   ?PROTO, ?FAMILY, ?TYPE, ?MODULE) of
+		{ok, S} ->
+		    case prim_inet:listen(S, R#listen_opts.backlog) of
+			ok -> {ok, S};
+			Error -> prim_inet:close(S), Error
+		    end;
+		Error -> Error
+	    end;
+	{ok, _} -> exit(badarg)
+    end.
+
+%%
+%% Accept
+%%
+accept(L) ->
+    case prim_inet:accept(L) of
+	{ok, S} ->
+	    inet_db:register_socket(S, ?MODULE),
+	    {ok,S};
+	Error -> Error
+    end.
+%%
+accept(L, Timeout) ->
+    case prim_inet:accept(L, Timeout) of
+	{ok, S} ->
+	    inet_db:register_socket(S, ?MODULE),
+	    {ok,S};
+	Error -> Error
+    end.
+
+%%
+%% Create a port/socket from a file descriptor
+%%
+fdopen(Fd, Opts) ->
+    inet:fdopen(Fd, Opts, ?PROTO, ?FAMILY, ?TYPE, ?MODULE).
diff --git a/lib/kernel/src/local_udp.erl b/lib/kernel/src/local_udp.erl
new file mode 100644
index 0000000000..ebb4d2b33f
--- /dev/null
+++ b/lib/kernel/src/local_udp.erl
@@ -0,0 +1,99 @@
+%%
+%% %CopyrightBegin%
+%%
+%% Copyright Ericsson AB 1997-2016. All Rights Reserved.
+%%
+%% Licensed under the Apache License, Version 2.0 (the "License");
+%% you may not use this file except in compliance with the License.
+%% You may obtain a copy of the License at
+%%
+%%     http://www.apache.org/licenses/LICENSE-2.0
+%%
+%% Unless required by applicable law or agreed to in writing, software
+%% distributed under the License is distributed on an "AS IS" BASIS,
+%% WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+%% See the License for the specific language governing permissions and
+%% limitations under the License.
+%%
+%% %CopyrightEnd%
+%%
+-module(local_udp).
+
+-export([open/1, open/2, close/1]).
+-export([send/2, send/4, recv/2, recv/3, connect/3]).
+-export([controlling_process/2]).
+-export([fdopen/2]).
+
+-export([getserv/1, getaddr/1, getaddr/2, translate_ip/1]).
+
+-include("inet_int.hrl").
+
+-define(FAMILY, local).
+-define(PROTO, udp).
+-define(TYPE, dgram).
+
+
+%% port lookup
+getserv(0) -> {ok, 0}.
+
+%% no address lookup
+getaddr({?FAMILY, _} = Address) -> {ok, Address}.
+getaddr({?FAMILY, _} = Address, _Timer) -> {ok, Address}.
+
+%% special this side addresses
+translate_ip(IP) -> IP.
+
+open(0) -> open(0, []).
+%%
+open(0, Opts) ->
+    case inet:udp_options(
+	   [{port,0} | Opts],
+	   ?MODULE) of
+	{error, Reason} -> exit(Reason);
+	{ok,
+	 #udp_opts{
+	    fd = Fd,
+	    ifaddr = BAddr,
+	    port = 0,
+	    opts = SockOpts}}
+	when tuple_size(BAddr) =:= 2, element(1, BAddr) =:= ?FAMILY;
+	     BAddr =:= any ->
+	    inet:open(
+	      Fd, BAddr, 0, SockOpts, ?PROTO, ?FAMILY, ?TYPE, ?MODULE);
+	{ok, _} -> exit(badarg)
+    end.
+
+send(S, Addr = {?FAMILY,_}, 0, Data) ->
+    prim_inet:sendto(S, Addr, 0, Data).
+%%
+send(S, Data) ->
+    prim_inet:sendto(S, {?FAMILY,<<>>}, 0, Data).
+
+connect(S, Addr = {?FAMILY,_}, 0) ->
+    prim_inet:connect(S, Addr, 0).
+
+recv(S, Len) ->
+    prim_inet:recvfrom(S, Len).
+%%
+recv(S, Len, Time) ->
+    prim_inet:recvfrom(S, Len, Time).
+
+close(S) ->
+    inet:udp_close(S).
+
+%%
+%% Set controlling process:
+%% 1) First sync socket into a known state
+%% 2) Move all messages onto the new owners message queue
+%% 3) Commit the owner
+%% 4) Wait for ack of new Owner (since socket does some link and unlink)
+%%
+
+controlling_process(Socket, NewOwner) ->
+    inet:udp_controlling_process(Socket, NewOwner).
+
+%%
+%% Create a port/socket from a file descriptor
+%%
+fdopen(Fd, Opts) ->
+    inet:fdopen(Fd, Opts, ?PROTO, ?FAMILY, ?TYPE, ?MODULE).
diff --git a/lib/kernel/test/inet_SUITE.erl b/lib/kernel/test/inet_SUITE.erl
index ccea6b2af4..f8d7aac8a6 100644
--- a/lib/kernel/test/inet_SUITE.erl
+++ b/lib/kernel/test/inet_SUITE.erl
@@ -1039,24 +1039,23 @@ getifaddrs(Config) when is_list (Config) ->
 check_addr({addr,Addr})
   when tuple_size(Addr) =:= 8,
        element(1, Addr) band 16#FFC0 =:= 16#FE80 ->
-    ?line ?t:format("Addr: ~p link local; SKIPPED!~n", [Addr]),
+    io:format("Addr: ~p link local; SKIPPED!~n", [Addr]),
     ok;
 check_addr({addr,Addr}) ->
-    ?line ?t:format("Addr: ~p.~n", [Addr]),
-    ?line Ping = "ping",
-    ?line Pong = "pong",
-    ?line {ok,L} = gen_tcp:listen(0, [{ip,Addr},{active,false}]),
-    ?line {ok,P} = inet:port(L),
-    ?line {ok,S1} = gen_tcp:connect(Addr, P, [{active,false}]),
-    ?line {ok,S2} = gen_tcp:accept(L),
-    ?line ok = gen_tcp:send(S2, Ping),
-    ?line {ok,Ping} = gen_tcp:recv(S1, length(Ping)),
-    ?line ok = gen_tcp:send(S1, Pong),
-    ?line ok = gen_tcp:close(S1),
-    ?line {ok,Pong} = gen_tcp:recv(S2, length(Pong)),
-    ?line ok = gen_tcp:close(S2),
-    ?line ok = gen_tcp:close(L),
-    ok.
+    io:format("Addr: ~p.~n", [Addr]),
+    Ping = "ping",
+    Pong = "pong",
+    {ok,L} = gen_tcp:listen(0, [{ip,Addr},{active,false}]),
+    {ok,P} = inet:port(L),
+    {ok,S1} = gen_tcp:connect(Addr, P, [{active,false}]),
+    {ok,S2} = gen_tcp:accept(L),
+    ok = gen_tcp:send(S2, Ping),
+    {ok,Ping} = gen_tcp:recv(S1, length(Ping)),
+    ok = gen_tcp:send(S1, Pong),
+    ok = gen_tcp:close(S1),
+    {ok,Pong} = gen_tcp:recv(S2, length(Pong)),
+    ok = gen_tcp:close(S2),
+    ok = gen_tcp:close(L).
 
 -record(ifopts, {name,flags,addrs=[],hwaddr}).
 
@@ -1078,7 +1077,7 @@ ifaddrs([{If,Opts}|IOs]) ->
 check_ifopts([], #ifopts{flags=F,addrs=Raddrs}=Ifopts) ->
     Addrs = lists:reverse(Raddrs),
     R = Ifopts#ifopts{addrs=Addrs},
-    ?t:format("~p.~n", [R]),
+    io:format("~p.~n", [R]),
     %% See how we did...
     {flags,Flags} = F,
     case lists:member(broadcast, Flags) of
@@ -1111,7 +1110,7 @@ check_ifopts([{flags,_}=F|Opts], #ifopts{flags=Flags}=Ifopts) ->
 	Flags ->
 	    check_ifopts(Opts, Ifopts);
 	_ ->
-	    ?t:fail({multiple_flags,F,Ifopts})
+	    ct:fail({multiple_flags,F,Ifopts})
     end;
 check_ifopts(
   [{addr,_}=A,{netmask,_}=N,{dstaddr,_}=D|Opts],
@@ -1131,7 +1130,7 @@ check_ifopts([{hwaddr,Hwaddr}=H|Opts], #ifopts{hwaddr=undefined}=Ifopts)
   when is_list(Hwaddr) ->
     check_ifopts(Opts, Ifopts#ifopts{hwaddr=H});
 check_ifopts([{hwaddr,_}=H|_], #ifopts{}=Ifopts) ->
-    ?t:fail({multiple_hwaddrs,H,Ifopts}).
+    ct:fail({multiple_hwaddrs,H,Ifopts}).
 
 %% Works just like lists:member/2, except that any {127,_,_,_} tuple
 %% matches any other {127,_,_,_}. We do this to handle Linux systems