Move bit syntax test cases from compilation_SUITE to bs_match_SUITE

We used to put code that would crash the compiler into
compilation_SUITE_data. That way we would have a failing test case to
remind us to fix a bug.

Nowadays, we generally fix the bug and write the test case at the same
time. Therefore it makes more sense to put the test code directly into
a test suite.

Move out bin_syntax_1 through bin_syntax_5 test cases. Scrap
bin_syntax_6 because it does not longer seems to be relevant.

While we are it, rename the fun_shadow/1 test to size_shadow/1. Also
make sure that the code produces the correct result.

7 files changed, 81 insertions, 230 deletions

diff --git a/lib/compiler/test/bs_match_SUITE.erl b/lib/compiler/test/bs_match_SUITE.erl
index c2d146a0b1..224abf6c29 100644
--- a/lib/compiler/test/bs_match_SUITE.erl
+++ b/lib/compiler/test/bs_match_SUITE.erl
@@ -24,11 +24,11 @@
 -export([all/0, suite/0,groups/0,init_per_suite/1, end_per_suite/1, 
 	 init_per_group/2,end_per_group/2,
 	 init_per_testcase/2,end_per_testcase/2,
-	 fun_shadow/1,int_float/1,otp_5269/1,null_fields/1,wiger/1,
+	 size_shadow/1,int_float/1,otp_5269/1,null_fields/1,wiger/1,
 	 bin_tail/1,save_restore/1,
 	 partitioned_bs_match/1,function_clause/1,
 	 unit/1,shared_sub_bins/1,bin_and_float/1,
-	 dec_subidentifiers/1,skip_optional_tag/1,
+	 dec_subidentifiers/1,skip_optional_tag/1,decode_integer/1,
 	 wfbm/1,degenerated_match/1,bs_sum/1,coverage/1,
 	 multiple_uses/1,zero_label/1,followed_by_catch/1,
 	 matching_meets_construction/1,simon/1,matching_and_andalso/1,
@@ -38,7 +38,7 @@
 	 no_partition/1,calling_a_binary/1,binary_in_map/1,
 	 match_string_opt/1,select_on_integer/1,
 	 map_and_binary/1,unsafe_branch_caching/1,
-	 bad_literals/1,good_literals/1]).
+	 bad_literals/1,good_literals/1,constant_propagation/1]).
 
 -export([coverage_id/1,coverage_external_ignore/2]).
 
@@ -56,11 +56,11 @@ all() ->
 
 groups() -> 
     [{p,[parallel],
-      [fun_shadow,int_float,otp_5269,null_fields,wiger,
+      [size_shadow,int_float,otp_5269,null_fields,wiger,
        bin_tail,save_restore,
        partitioned_bs_match,function_clause,unit,
        shared_sub_bins,bin_and_float,dec_subidentifiers,
-       skip_optional_tag,wfbm,degenerated_match,bs_sum,
+       skip_optional_tag,decode_integer,wfbm,degenerated_match,bs_sum,
        coverage,multiple_uses,zero_label,followed_by_catch,
        matching_meets_construction,simon,
        matching_and_andalso,otp_7188,otp_7233,otp_7240,
@@ -69,7 +69,7 @@ groups() ->
        no_partition,calling_a_binary,binary_in_map,
        match_string_opt,select_on_integer,
        map_and_binary,unsafe_branch_caching,
-       bad_literals,good_literals]}].
+       bad_literals,good_literals,constant_propagation]}].
 
 
 init_per_suite(Config) ->
@@ -91,33 +91,54 @@ init_per_testcase(Case, Config) when is_atom(Case), is_list(Config) ->
 end_per_testcase(Case, Config) when is_atom(Case), is_list(Config) ->
     ok.
 
-fun_shadow(Config) when is_list(Config) ->
-    %% OTP-5270
-    7 = fun_shadow_1(),
-    7 = fun_shadow_2(8),
-    7 = fun_shadow_3(),
-    no = fun_shadow_4(8),
+size_shadow(Config) when is_list(Config) ->
+    %% Originally OTP-5270.
+    7 = size_shadow_1(),
+    7 = size_shadow_2(8),
+    7 = size_shadow_3(),
+    no = size_shadow_4(8),
+    Any = {any,term,goes},
+    {2577,Any,-175,whatever} =
+	(size_shadow_5(Any, 12))(<<2577:12>>, -175, whatever),
+    {7777,Any,42,whatever} =
+	(size_shadow_6(Any, 13))(42, <<7777:13>>, whatever),
+    {<<45>>,<<>>} = size_shadow_7({int,1}, <<1:16,45>>),
+    {'EXIT',{function_clause,_}} =
+	(catch size_shadow_7({int,42}, <<1:16,45>>)),
     ok.
 
-fun_shadow_1() ->
+size_shadow_1() ->
     L = 8,
     F = fun(<<L:L,B:L>>) -> B end,
     F(<<16:8, 7:16>>).
 
-fun_shadow_2(L) ->
+size_shadow_2(L) ->
     F = fun(<<L:L,B:L>>) -> B end,
     F(<<16:8, 7:16>>).
 
-fun_shadow_3() ->
+size_shadow_3() ->
     L = 8,
     F = fun(<<L:L,B:L,L:L>>) -> B end,
     F(<<16:8, 7:16,16:16>>).
 
-fun_shadow_4(L) ->
+size_shadow_4(L) ->
     F = fun(<<L:L,B:L,L:L>>) -> B;
 	   (_) -> no end,
     F(<<16:8, 7:16,15:16>>).
 
+size_shadow_5(X, Y) ->
+    fun (<< A:Y >>, Y, B) -> fum(A, X, Y, B) end.
+
+size_shadow_6(X, Y) ->
+    fun (Y, << A:Y >>, B) -> fum(A, X, Y, B) end.
+
+fum(A, B, C, D) ->
+    {A,B,C,D}.
+
+size_shadow_7({int,N}, <<N:16,B:N/binary,T/binary>>) ->
+    {B,T}.
+
+
 int_float(Config) when is_list(Config) ->
     %% OTP-5323
     <<103133.0:64/float>> = <<103133:64/float>>,
@@ -504,6 +525,23 @@ skip_optional_tag(<<Tag,RestTag/binary>>, <<Tag,Rest/binary>>) ->
     skip_optional_tag(RestTag, Rest);
 skip_optional_tag(_, _) -> missing.
 
+decode_integer(_Config) ->
+    {10795,<<43>>,whatever} = decode_integer(1, <<42,43>>, whatever),
+    {-28909,<<19>>,whatever} = decode_integer(1, <<143,19>>, whatever),
+    ok.
+
+decode_integer(Len, <<B1:1,B2:7,Bs/binary>>, RemovedBytes) when B1 == 0 ->
+    Bin = <<_Skip:Len/unit:8, Buffer2/binary>> = <<B1:1,B2:7,Bs/binary>>,
+    Size = byte_size(Bin),
+    <<Int:Size/unit:8>> = Bin,
+    {Int,Buffer2,RemovedBytes};
+decode_integer(Len, <<B1:1,B2:7,Bs/binary>>, RemovedBytes)  ->
+    Bin = <<_Skip:Len/unit:8,Buffer2/binary>> = <<B1:1,B2:7,Bs/binary>>,
+    Size = byte_size(Bin),
+    <<N:Size/unit:8>> = <<B2,Bs/binary>>,
+    Int = N - (1 bsl (8 * size(Bin) -1)),
+    {Int,Buffer2,RemovedBytes}.
+
 -define(DATELEN, 16).
 
 wfbm(Config) when is_list(Config) ->
@@ -1387,6 +1425,32 @@ good_literals(_Config) ->
     <<16#cafebeef:4/unit:8>> = id(<<16#cafebeef:32>>),
     ok.
 
+constant_propagation(_Config) ->
+    <<5>> = constant_propagation_a(a, <<5>>),
+    {'EXIT',{{case_clause,b},_}} = (catch constant_propagation_a(b, <<5>>)),
+    258 = constant_propagation_b(<<1,2>>),
+    F = constant_propagation_c(),
+    259 = F(<<1,3>>),
+    ok.
+
+constant_propagation_a(X, Y) ->
+    case X of
+	a -> Y2 = 8
+    end,
+    <<5:Y2>> = Y.
+
+constant_propagation_b(B) ->
+    Sz = 16,
+    <<X:Sz/integer>> = B,
+    X.
+
+constant_propagation_c() ->
+    Size = 16,
+    fun(Bin) ->
+	    <<X:Size/integer>> = Bin,
+	    X
+    end.
+
 
 check(F, R) ->
     R = F().
diff --git a/lib/compiler/test/compilation_SUITE.erl b/lib/compiler/test/compilation_SUITE.erl
index 1f64da96ff..6a29016337 100644
--- a/lib/compiler/test/compilation_SUITE.erl
+++ b/lib/compiler/test/compilation_SUITE.erl
@@ -44,9 +44,7 @@ groups() ->
        beam_compiler_11,beam_compiler_12,
        nested_tuples_in_case_expr,otp_2330,guards,
        {group,vsn},otp_2380,otp_2173,otp_4790,
-       const_list_256,bin_syntax_1,bin_syntax_2,
-       bin_syntax_3,bin_syntax_4,bin_syntax_5,bin_syntax_6,
-       live_var,convopts,
+       const_list_256,live_var,convopts,
        catch_in_catch,redundant_case,long_string,otp_5076,
        complex_guard,otp_5092,otp_5151,otp_5235,otp_5244,
        trycatch_4,opt_crash,otp_5404,otp_5436,otp_5481,
@@ -107,13 +105,6 @@ end_per_group(_GroupName, Config) ->
 
 ?comp(const_list_256).
 
-?comp(bin_syntax_1).
-?comp(bin_syntax_2).
-?comp(bin_syntax_3).
-?comp(bin_syntax_4).
-
-?comp(bin_syntax_6).
-
 ?comp(otp_5076).
 
 ?comp(complex_guard).
@@ -121,27 +112,6 @@ end_per_group(_GroupName, Config) ->
 ?comp(otp_5092).
 ?comp(otp_5151).
 
-%%% By Per Gustafsson <[email protected]>
-
-bin_syntax_5(Config) when is_list(Config) ->
-    {<<45>>,<<>>} = split({int, 1}, <<1:16,45>>).   
-
-split({int, N}, <<N:16,B:N/binary,T/binary>>) ->
-    {B,T}.
-
-%% This program works with the old version of the compiler
-%% but, the core erlang that it produces have the same variable appearing
-%% looks like this:
-%%
-%% split({int, N}, <<_core1:16, B:N/binary, T/binary>>) when _core1==N
-%%
-%% with my change it will look like this:
-%%
-%% split({int, N}, <<_core1:16, B:_core1/binary, T/binary>>) when _core1==N
-%%
-%% This means that everything worked fine as long as the pattern
-%% matching order was left-to-right but on core erlang any order should be possible
-
 ?comp(live_var).
 
 ?comp(trycatch_4).
diff --git a/lib/compiler/test/compilation_SUITE_data/bin_syntax_1.erl b/lib/compiler/test/compilation_SUITE_data/bin_syntax_1.erl
deleted file mode 100644
index 72f6a0cee6..0000000000
--- a/lib/compiler/test/compilation_SUITE_data/bin_syntax_1.erl
+++ /dev/null
@@ -1,32 +0,0 @@
-%%
-%% %CopyrightBegin%
-%% 
-%% Copyright Ericsson AB 2000-2016. All Rights Reserved.
-%% 
-%% Licensed under the Apache License, Version 2.0 (the "License");
-%% you may not use this file except in compliance with the License.
-%% You may obtain a copy of the License at
-%%
-%%     http://www.apache.org/licenses/LICENSE-2.0
-%%
-%% Unless required by applicable law or agreed to in writing, software
-%% distributed under the License is distributed on an "AS IS" BASIS,
-%% WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
-%% See the License for the specific language governing permissions and
-%% limitations under the License.
-%% 
-%% %CopyrightEnd%
-%%
--module(bin_syntax_1).
-
--export([f/2,?MODULE/0]).
-
-?MODULE() ->
-    ok.
-
-f(X, Y) ->
-    case X of
-	a ->
-	    Y2 = 8
-    end,
-    <<5:Y2>> = Y.
diff --git a/lib/compiler/test/compilation_SUITE_data/bin_syntax_2.erl b/lib/compiler/test/compilation_SUITE_data/bin_syntax_2.erl
deleted file mode 100644
index cd0c2a4b0e..0000000000
--- a/lib/compiler/test/compilation_SUITE_data/bin_syntax_2.erl
+++ /dev/null
@@ -1,42 +0,0 @@
-%%
-%% %CopyrightBegin%
-%% 
-%% Copyright Ericsson AB 2000-2016. All Rights Reserved.
-%% 
-%% Licensed under the Apache License, Version 2.0 (the "License");
-%% you may not use this file except in compliance with the License.
-%% You may obtain a copy of the License at
-%%
-%%     http://www.apache.org/licenses/LICENSE-2.0
-%%
-%% Unless required by applicable law or agreed to in writing, software
-%% distributed under the License is distributed on an "AS IS" BASIS,
-%% WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
-%% See the License for the specific language governing permissions and
-%% limitations under the License.
-%% 
-%% %CopyrightEnd%
-%%
--module(bin_syntax_2).
-
--export([?MODULE/0]).
-
-%% This module tests that constant propagation is done properly.
-
-?MODULE() ->
-    258 = b(<<1,2>>),
-    F = c(),
-    259 = F(<<1,3>>),
-    ok.
-
-b(B) ->
-    Sz = 16,
-    <<X:Sz/integer>> = B,
-    X.
-
-c() ->
-    Size = 16,
-    fun(Bin) ->
-	    <<X:Size/integer>> = Bin,
-	    X
-    end.
diff --git a/lib/compiler/test/compilation_SUITE_data/bin_syntax_3.erl b/lib/compiler/test/compilation_SUITE_data/bin_syntax_3.erl
deleted file mode 100644
index b3118e0adc..0000000000
--- a/lib/compiler/test/compilation_SUITE_data/bin_syntax_3.erl
+++ /dev/null
@@ -1,36 +0,0 @@
-%%
-%% %CopyrightBegin%
-%% 
-%% Copyright Ericsson AB 2000-2016. All Rights Reserved.
-%% 
-%% Licensed under the Apache License, Version 2.0 (the "License");
-%% you may not use this file except in compliance with the License.
-%% You may obtain a copy of the License at
-%%
-%%     http://www.apache.org/licenses/LICENSE-2.0
-%%
-%% Unless required by applicable law or agreed to in writing, software
-%% distributed under the License is distributed on an "AS IS" BASIS,
-%% WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
-%% See the License for the specific language governing permissions and
-%% limitations under the License.
-%% 
-%% %CopyrightEnd%
-%%
--module(bin_syntax_3).
--export([?MODULE/0,decode_integer/3]).
-
-?MODULE() ->
-    ok.
-
-decode_integer(Len, <<B1:1,B2:7,Bs/binary>>, RemovedBytes) when B1 == 0 ->
-     Bin = <<Skip:Len/unit:8, Buffer2/binary>> = <<B1:1,B2:7,Bs/binary>>,
-     Size = size(Bin),
-     <<Int:Size/unit:8>> = Bin,
-     {Int,Buffer2,RemovedBytes};
-decode_integer(Len,<<B1:1,B2:7,Bs/binary>>,RemovedBytes)  ->
-      Bin = <<Skip:Len/unit:8,Buffer2/binary>> = <<B1:1,B2:7,Bs/binary>>,
-      Size = size(Bin),
-      <<N:Size/unit:8>> = <<B2,Bs/binary>>,
-      Int = N - (1 bsl (8 * size(Bin) -1)),
-     {Int,Buffer2,RemovedBytes}.
diff --git a/lib/compiler/test/compilation_SUITE_data/bin_syntax_4.erl b/lib/compiler/test/compilation_SUITE_data/bin_syntax_4.erl
deleted file mode 100644
index 185d6ec3b0..0000000000
--- a/lib/compiler/test/compilation_SUITE_data/bin_syntax_4.erl
+++ /dev/null
@@ -1,33 +0,0 @@
-%%
-%% %CopyrightBegin%
-%% 
-%% Copyright Ericsson AB 2000-2016. All Rights Reserved.
-%% 
-%% Licensed under the Apache License, Version 2.0 (the "License");
-%% you may not use this file except in compliance with the License.
-%% You may obtain a copy of the License at
-%%
-%%     http://www.apache.org/licenses/LICENSE-2.0
-%%
-%% Unless required by applicable law or agreed to in writing, software
-%% distributed under the License is distributed on an "AS IS" BASIS,
-%% WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
-%% See the License for the specific language governing permissions and
-%% limitations under the License.
-%% 
-%% %CopyrightEnd%
-%%
--module(bin_syntax_4).
--export([?MODULE/0,f4b/2,f4c/2]).
-
-?MODULE() ->
-    ok.
-
-f4b(X, Y) ->
-    fun (<< A:Y >>, Y, B) -> fum(A, X, Y, B) end.
-
-f4c(X, Y) ->
-    fun (Y, << A:Y >>, B) -> fum(A, X, Y, B) end.
-
-fum(A, B, C, D) ->
-    {A,B,C,D}.
diff --git a/lib/compiler/test/compilation_SUITE_data/bin_syntax_6.erl b/lib/compiler/test/compilation_SUITE_data/bin_syntax_6.erl
deleted file mode 100644
index 1841a2ee0a..0000000000
--- a/lib/compiler/test/compilation_SUITE_data/bin_syntax_6.erl
+++ /dev/null
@@ -1,40 +0,0 @@
-%%
-%% %CopyrightBegin%
-%% 
-%% Copyright Ericsson AB 2005-2016. All Rights Reserved.
-%% 
-%% Licensed under the Apache License, Version 2.0 (the "License");
-%% you may not use this file except in compliance with the License.
-%% You may obtain a copy of the License at
-%%
-%%     http://www.apache.org/licenses/LICENSE-2.0
-%%
-%% Unless required by applicable law or agreed to in writing, software
-%% distributed under the License is distributed on an "AS IS" BASIS,
-%% WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
-%% See the License for the specific language governing permissions and
-%% limitations under the License.
-%% 
-%% %CopyrightEnd%
-%%
--module(bin_syntax_6).
--export([?MODULE/0,x/1,y/1]).
-
-?MODULE() ->
-    ok.
-
-x(X) ->
-    blurf(),
-    B = {X,"OK",<<>>},
-    catch b({a,B}).
-
-y(X) ->
-    blurf(),
-    B = {X,"OK",<<42>>},
-    catch b({a,B}).
-
-blurf() ->
-    ok.
-
-b(_) ->
-    ok.