[ct_netconfc] Add optional parameters to edit-config

Earlier there was no way to add optional parameters like
default-operation to an edit-config request sent with
ct_netconfc:edit_config/3,4, you had to use
ct_netconfc:send_rpc/2,3. For simplicity and completion, a new
optional argument, OptParams, is now added to the edit_config
function.

3 files changed, 65 insertions, 9 deletions

diff --git a/lib/common_test/src/ct_netconfc.erl b/lib/common_test/src/ct_netconfc.erl
index a3861dc745..47fa43f561 100644
--- a/lib/common_test/src/ct_netconfc.erl
+++ b/lib/common_test/src/ct_netconfc.erl
@@ -190,6 +190,7 @@
 	 get_config/4,
 	 edit_config/3,
 	 edit_config/4,
+	 edit_config/5,
 	 delete_config/2,
 	 delete_config/3,
 	 copy_config/3,
@@ -678,15 +679,39 @@ get_config(Client, Source, Filter, Timeout) ->
 
 %%----------------------------------------------------------------------
 %% @spec edit_config(Client, Target, Config) -> Result
-%% @equiv edit_config(Client, Target, Config, infinity)
+%% @equiv edit_config(Client, Target, Config, [], infinity)
 edit_config(Client, Target, Config) ->
     edit_config(Client, Target, Config, ?DEFAULT_TIMEOUT).
 
 %%----------------------------------------------------------------------
--spec edit_config(Client, Target, Config, Timeout) -> Result when
+-spec edit_config(Client, Target, Config, OptParamsOrTimeout) -> Result when
       Client :: client(),
       Target :: netconf_db(),
       Config :: simple_xml(),
+      OptParamsOrTimeout :: [simple_xml()] | timeout(),
+      Result :: ok | {error,error_reason()}.
+%% @doc
+%%
+%% If `OptParamsOrTimeout' is a timeout value, then this is
+%% equivalent to {@link edit_config/5. edit_config(Client, Target,
+%% Config, [], Timeout)}.
+%%
+%% If `OptParamsOrTimeout' is a list of simple XML, then this is
+%% equivalent to {@link edit_config/5. edit_config(Client, Target,
+%% Config, OptParams, infinity)}.
+%%
+%% @end
+edit_config(Client, Target, Config, Timeout) when ?is_timeout(Timeout) ->
+    edit_config(Client, Target, Config, [], Timeout);
+edit_config(Client, Target, Config, OptParams) when is_list(OptParams) ->
+    edit_config(Client, Target, Config, OptParams, ?DEFAULT_TIMEOUT).
+
+%%----------------------------------------------------------------------
+-spec edit_config(Client, Target, Config, OptParams, Timeout) -> Result when
+      Client :: client(),
+      Target :: netconf_db(),
+      Config :: simple_xml(),
+      OptParams :: [simple_xml()],
       Timeout :: timeout(),
       Result :: ok | {error,error_reason()}.
 %% @doc Edit configuration data.
@@ -695,10 +720,20 @@ edit_config(Client, Target, Config) ->
 %% include `:candidate' or `:startup' in its list of
 %% capabilities.
 %%
+%% `OptParams' can be used for specifying optional parameters
+%% (`default-operation', `test-option' or `error-option') that will be
+%% added to the `edit-config' request. The value must be a list
+%% containing valid simple XML, for example
+%%
+%% ```
+%% [{'default-operation', ["none"]},
+%%  {'error-option', ["rollback-on-error"]}]
+%%'''
+%%
 %% @end
 %%----------------------------------------------------------------------
-edit_config(Client, Target, Config, Timeout) ->
-    call(Client, {send_rpc_op, edit_config, [Target,Config], Timeout}).
+edit_config(Client, Target, Config, OptParams, Timeout) ->
+    call(Client, {send_rpc_op, edit_config, [Target,Config,OptParams], Timeout}).
 
 
 %%----------------------------------------------------------------------
@@ -1234,8 +1269,8 @@ encode_rpc_operation(get,[Filter]) ->
     {get,filter(Filter)};
 encode_rpc_operation(get_config,[Source,Filter]) ->
     {'get-config',[{source,[Source]}] ++ filter(Filter)};
-encode_rpc_operation(edit_config,[Target,Config]) ->
-    {'edit-config',[{target,[Target]},{config,[Config]}]};
+encode_rpc_operation(edit_config,[Target,Config,OptParams]) ->
+    {'edit-config',[{target,[Target]}] ++ OptParams ++ [{config,[Config]}]};
 encode_rpc_operation(delete_config,[Target]) ->
     {'delete-config',[{target,[Target]}]};
 encode_rpc_operation(copy_config,[Target,Source]) ->
diff --git a/lib/common_test/test/ct_netconfc_SUITE_data/netconfc1_SUITE.erl b/lib/common_test/test/ct_netconfc_SUITE_data/netconfc1_SUITE.erl
index f2adeb9065..332e54d1a7 100644
--- a/lib/common_test/test/ct_netconfc_SUITE_data/netconfc1_SUITE.erl
+++ b/lib/common_test/test/ct_netconfc_SUITE_data/netconfc1_SUITE.erl
@@ -76,6 +76,7 @@ all() ->
 	     get_config,
 	     get_config_xpath,
 	     edit_config,
+	     edit_config_opt_params,
 	     copy_config,
 	     delete_config,
 	     lock,
@@ -400,6 +401,18 @@ edit_config(Config) ->
     ?ok = ct_netconfc:close_session(Client),
     ok.
 
+edit_config_opt_params(Config) ->
+    DataDir = ?config(data_dir,Config),
+    {ok,Client} = open_success(DataDir),
+    ?NS:expect_reply({'edit-config',{'default-operation',"none"}},ok),
+    ?ok = ct_netconfc:edit_config(Client,running,
+				  {server,[{xmlns,"myns"}],
+				   [{name,["myserver"]}]},
+				  [{'default-operation',["none"]}]),
+    ?NS:expect_do_reply('close-session',close,ok),
+    ?ok = ct_netconfc:close_session(Client),
+    ok.
+
 copy_config(Config) ->
     DataDir = ?config(data_dir,Config),
     {ok,Client} = open_success(DataDir),
diff --git a/lib/common_test/test/ct_netconfc_SUITE_data/ns.erl b/lib/common_test/test/ct_netconfc_SUITE_data/ns.erl
index fb0734d48e..f7c7b891bb 100644
--- a/lib/common_test/test/ct_netconfc_SUITE_data/ns.erl
+++ b/lib/common_test/test/ct_netconfc_SUITE_data/ns.erl
@@ -1,7 +1,7 @@
 %%--------------------------------------------------------------------
 %% %CopyrightBegin%
 %%
-%% Copyright Ericsson AB 2012-2013. All Rights Reserved.
+%% Copyright Ericsson AB 2012-2014. All Rights Reserved.
 %%
 %% The contents of this file are subject to the Erlang Public License,
 %% Version 1.1, (the "License"); you may not use this file except in
@@ -382,6 +382,7 @@ event({startElement,_,Name,_,Attrs},[ignore,{se,Name,As}|Match]) ->
 event({startPrefixMapping,_,Ns},[{ns,Ns}|Match]) -> Match;
 event({startPrefixMapping,_,Ns},[ignore,{ns,Ns}|Match]) -> Match;
 event({endPrefixMapping,_},Match) -> Match;
+event({characters,Chs},[{characters,Chs}|Match]) -> Match;
 event({endElement,_,Name,_},[{ee,Name}|Match]) -> Match;
 event({endElement,_,Name,_},[ignore,{ee,Name}|Match]) -> Match;
 event(endDocument,Match) when Match==[]; Match==[ignore] -> ok;
@@ -471,14 +472,17 @@ capabilities(no_caps) ->
 %%% expect_do_reply/3.
 %%%
 %%% match(term()) -> [Match].
-%%% Match = ignore | {se,Name} | {se,Name,Attrs} | {ee,Name} | {ns,Namespace}
+%%% Match = ignore | {se,Name} | {se,Name,Attrs} | {ee,Name} |
+%%%         {ns,Namespace} | {characters,Chs}
 %%% Name = string()
+%%% Chs = string()
 %%% Attrs = [{atom(),string()}]
 %%% Namespace = string()
 %%%
 %%% 'se' means start element, 'ee' means end element - i.e. to match
 %%% an XML element you need one 'se' entry and one 'ee' entry with the
-%%% same name in the match list.
+%%% same name in the match list. 'characters' can be used for matching
+%%% character data (cdata) inside an element.
 match(hello) ->
     [ignore,{se,"hello"},ignore,{ee,"hello"},ignore];
 match('close-session') ->
@@ -487,6 +491,10 @@ match('close-session') ->
 match('edit-config') ->
     [ignore,{se,"rpc"},{se,"edit-config"},{se,"target"},ignore,{ee,"target"},
      {se,"config"},ignore,{ee,"config"},{ee,"edit-config"},{ee,"rpc"},ignore];
+match({'edit-config',{'default-operation',DO}}) ->
+    [ignore,{se,"rpc"},{se,"edit-config"},{se,"target"},ignore,{ee,"target"},
+     {se,"default-operation"},{characters,DO},{ee,"default-operation"},
+     {se,"config"},ignore,{ee,"config"},{ee,"edit-config"},{ee,"rpc"},ignore];
 match('get') ->
     match({get,subtree});
 match({'get',FilterType}) ->