[common_test] Added tests and corrected bugs in ct_snmp

OTP-10454
OTP-10434

Function register_users/2, register_agents/2 and register_usm_users/2,
and the corresponding unregister_*/1 functions were not
executable. These are corrected/rewritten.

Function update_usm_users/2 is removed, and an unregister function is
added instead. Update can now be done with unregister_usm_users and
then register_usm_users.

Functions unregister_*/2 are added, so specific users/agents/usm users
can be unregistered.

Function unload_mibs/1 is added.

Overriding configuration files did not work, since the files were
written in priv_dir instead of in the configuration dir
(priv_dir/conf). This has been corrected.

Minor updates to documentation.

13 files changed, 658 insertions, 287 deletions

diff --git a/lib/common_test/src/ct_snmp.erl b/lib/common_test/src/ct_snmp.erl
index 02f849201d..71038bd4f4 100644
--- a/lib/common_test/src/ct_snmp.erl
+++ b/lib/common_test/src/ct_snmp.erl
@@ -39,7 +39,7 @@
 %%%        %%% Manager config
 %%%        [{start_manager, boolean()}    % Optional - default is true
 %%%        {users, [{user_name(), [call_back_module(), user_data()]}]}, %% Optional 
-%%%        {usm_users, [{usm_user_name(), usm_config()}]},%% Optional - snmp v3 only
+%%%        {usm_users, [{usm_user_name(), [usm_config()]}]},%% Optional - snmp v3 only
 %%%        % managed_agents is optional 
 %%%        {managed_agents,[{agent_name(), [user_name(), agent_ip(), agent_port(), [agent_config()]]}]},   
 %%%        {max_msg_size, integer()},     % Optional - default is 484
@@ -130,7 +130,7 @@
 %%% @type agent_config() = {Item, Value} 
 %%% @type user_name() = atom() 
 %%% @type usm_user_name() = string() 
-%%% @type usm_config() = string()  
+%%% @type usm_config() = {Item, Value}
 %%% @type call_back_module() = atom()
 %%% @type user_data() = term() 
 %%% @type oids() = [oid()]
@@ -157,8 +157,9 @@
 %%% API
 -export([start/2, start/3, stop/1, get_values/3, get_next_values/3, set_values/4, 
 	 set_info/1, register_users/2, register_agents/2, register_usm_users/2,
-	 unregister_users/1, unregister_agents/1, update_usm_users/2, 
-	 load_mibs/1]).
+	 unregister_users/1, unregister_users/2, unregister_agents/1,
+	 unregister_agents/2, unregister_usm_users/1, unregister_usm_users/2,
+	 load_mibs/1, unload_mibs/1]).
 
 %% Manager values
 -define(CT_SNMP_LOG_FILE, "ct_snmp_set.log").
@@ -322,12 +323,23 @@ set_info(Config) ->
 %%%      Reason = term()    
 %%%
 %%% @doc Register the manager entity (=user) responsible for specific agent(s).
-%%% Corresponds to making an entry in users.conf
+%%% Corresponds to making an entry in users.conf.
+%%%
+%%% This function will try to register the given users, without
+%%% checking if any of them already exist. In order to change an
+%%% already registered user, the user must first be unregistered.
 register_users(MgrAgentConfName, Users) ->
-    {snmp, SnmpVals} = ct:get_config(MgrAgentConfName),
-    NewSnmpVals = lists:keyreplace(users, 1, SnmpVals, {users, Users}),
-    ct_config:update_config(MgrAgentConfName, {snmp, NewSnmpVals}),
-    setup_users(Users).
+    case setup_users(Users) of
+	ok ->
+	    SnmpVals = ct:get_config(MgrAgentConfName),
+	    OldUsers = ct:get_config({MgrAgentConfName,users},[]),
+	    NewSnmpVals = lists:keystore(users, 1, SnmpVals,
+					 {users, Users ++ OldUsers}),
+	    ct_config:update_config(MgrAgentConfName, NewSnmpVals),
+	    ok;
+	Error ->
+	    Error
+    end.
 
 %%% @spec register_agents(MgrAgentConfName, ManagedAgents) -> ok | {error, Reason}
 %%%
@@ -337,12 +349,24 @@ register_users(MgrAgentConfName, Users) ->
 %%%
 %%% @doc Explicitly instruct the manager to handle this agent.
 %%% Corresponds to making an entry in agents.conf 
+%%%
+%%% This function will try to register the given managed agents,
+%%% without checking if any of them already exist. In order to change
+%%% an already registered managed agent, the agent must first be
+%%% unregistered.
 register_agents(MgrAgentConfName, ManagedAgents) ->
-    {snmp, SnmpVals} = ct:get_config(MgrAgentConfName),
-    NewSnmpVals = lists:keyreplace(managed_agents, 1, SnmpVals,
-				   {managed_agents, ManagedAgents}),
-    ct_config:update_config(MgrAgentConfName, {snmp, NewSnmpVals}),
-    setup_managed_agents(MgrAgentConfName,ManagedAgents).
+    case setup_managed_agents(MgrAgentConfName,ManagedAgents) of
+	ok ->
+	    SnmpVals = ct:get_config(MgrAgentConfName),
+	    OldAgents = ct:get_config({MgrAgentConfName,managed_agents},[]),
+	    NewSnmpVals = lists:keystore(managed_agents, 1, SnmpVals,
+					 {managed_agents,
+					  ManagedAgents ++ OldAgents}),
+	    ct_config:update_config(MgrAgentConfName, NewSnmpVals),
+	    ok;
+	Error ->
+	    Error
+    end.
 
 %%% @spec register_usm_users(MgrAgentConfName, UsmUsers) ->  ok | {error, Reason}
 %%%
@@ -352,60 +376,115 @@ register_agents(MgrAgentConfName, ManagedAgents) ->
 %%%
 %%% @doc Explicitly instruct the manager to handle this USM user.
 %%% Corresponds to making an entry in usm.conf 
+%%%
+%%% This function will try to register the given users, without
+%%% checking if any of them already exist. In order to change an
+%%% already registered user, the user must first be unregistered.
 register_usm_users(MgrAgentConfName, UsmUsers) ->
-    {snmp, SnmpVals} = ct:get_config(MgrAgentConfName),
-    NewSnmpVals = lists:keyreplace(users, 1, SnmpVals, {usm_users, UsmUsers}),
-    ct_config:update_config(MgrAgentConfName, {snmp, NewSnmpVals}),
     EngineID = ct:get_config({MgrAgentConfName, engine_id}, ?ENGINE_ID),
-    setup_usm_users(UsmUsers, EngineID).
+    case setup_usm_users(UsmUsers, EngineID) of
+	ok ->
+	    SnmpVals = ct:get_config(MgrAgentConfName),
+	    OldUsmUsers = ct:get_config({MgrAgentConfName,usm_users},[]),
+	    NewSnmpVals = lists:keystore(usm_users, 1, SnmpVals,
+					 {usm_users, UsmUsers ++ OldUsmUsers}),
+	    ct_config:update_config(MgrAgentConfName, NewSnmpVals),
+	    ok;
+	Error ->
+	    Error
+    end.
 
-%%% @spec unregister_users(MgrAgentConfName) ->  ok | {error, Reason}
+%%% @spec unregister_users(MgrAgentConfName) ->  ok
 %%%
 %%%      MgrAgentConfName = atom()
 %%%      Reason = term()
 %%%
-%%% @doc Removes information added when calling register_users/2. 
+%%% @doc Unregister all users.
 unregister_users(MgrAgentConfName) ->
-    Users = lists:map(fun({UserName, _}) -> UserName end,
-		      ct:get_config({MgrAgentConfName, users})),
-    {snmp, SnmpVals} = ct:get_config(MgrAgentConfName),
-    NewSnmpVals = lists:keyreplace(users, 1, SnmpVals, {users, []}),
-    ct_config:update_config(MgrAgentConfName, {snmp, NewSnmpVals}),
-    takedown_users(Users).
+    Users = [Id || {Id,_} <- ct:get_config({MgrAgentConfName, users},[])],
+    unregister_users(MgrAgentConfName,Users).
 
-%%% @spec unregister_agents(MgrAgentConfName) ->  ok | {error, Reason}
+%%% @spec unregister_users(MgrAgentConfName,Users) ->  ok
 %%%
 %%%      MgrAgentConfName = atom()
+%%%      Users = [user_name()]
 %%%      Reason = term()
 %%%
-%%% @doc  Removes information added when calling register_agents/2. 
+%%% @doc Unregister the given users.
+unregister_users(MgrAgentConfName,Users) ->
+    takedown_users(Users),
+    SnmpVals = ct:get_config(MgrAgentConfName),
+    AllUsers = ct:get_config({MgrAgentConfName, users},[]),
+    RemainingUsers = lists:filter(fun({Id,_}) ->
+					  not lists:member(Id,Users)
+				  end,
+				  AllUsers),
+    NewSnmpVals = lists:keyreplace(users, 1, SnmpVals, {users,RemainingUsers}),
+    ct_config:update_config(MgrAgentConfName, NewSnmpVals),
+    ok.
+
+%%% @spec unregister_agents(MgrAgentConfName) ->  ok
+%%%
+%%%      MgrAgentConfName = atom()
+%%%      Reason = term()
+%%%
+%%% @doc  Unregister all managed agents.
 unregister_agents(MgrAgentConfName) ->    
-    ManagedAgents = lists:map(fun({_, [Uid, AgentIP, AgentPort, _]}) -> 
-				      {Uid, AgentIP, AgentPort} 
-			      end,
-			      ct:get_config({MgrAgentConfName, managed_agents})),
-    {snmp, SnmpVals} = ct:get_config(MgrAgentConfName),
-    NewSnmpVals = lists:keyreplace(managed_agents, 1, SnmpVals, 
-				   {managed_agents, []}),
-    ct_config:update_config(MgrAgentConfName, {snmp, NewSnmpVals}),
-    takedown_managed_agents(ManagedAgents).
+    ManagedAgents =  [AgentName ||
+			 {AgentName, _} <-
+			     ct:get_config({MgrAgentConfName,managed_agents},[])],
+    unregister_agents(MgrAgentConfName,ManagedAgents).
 
+%%% @spec unregister_agents(MgrAgentConfName,ManagedAgents) ->  ok
+%%%
+%%%      MgrAgentConfName = atom()
+%%%      ManagedAgents = [agent_name()]
+%%%      Reason = term()
+%%%
+%%% @doc  Unregister the given managed agents.
+unregister_agents(MgrAgentConfName,ManagedAgents) ->
+    takedown_managed_agents(MgrAgentConfName, ManagedAgents),
+    SnmpVals = ct:get_config(MgrAgentConfName),
+    AllAgents = ct:get_config({MgrAgentConfName,managed_agents},[]),
+    RemainingAgents = lists:filter(fun({Name,_}) ->
+					  not lists:member(Name,ManagedAgents)
+				   end,
+				   AllAgents),
+    NewSnmpVals = lists:keyreplace(managed_agents, 1, SnmpVals,
+				   {managed_agents,RemainingAgents}),
+    ct_config:update_config(MgrAgentConfName, NewSnmpVals),
+    ok.
 
-%%% @spec update_usm_users(MgrAgentConfName, UsmUsers) -> ok | {error, Reason}
+%%% @spec unregister_usm_users(MgrAgentConfName) ->  ok
 %%%
 %%%      MgrAgentConfName = atom()
-%%%      UsmUsers = usm_users()
 %%%      Reason = term()
 %%%
-%%% @doc  Alters information added when calling register_usm_users/2. 
-update_usm_users(MgrAgentConfName, UsmUsers) ->    
-   
-    {snmp, SnmpVals} = ct:get_config(MgrAgentConfName),
-    NewSnmpVals = lists:keyreplace(usm_users, 1, SnmpVals, 
-				   {usm_users, UsmUsers}),
-    ct_config:update_config(MgrAgentConfName, {snmp, NewSnmpVals}),
+%%% @doc Unregister all usm users.
+unregister_usm_users(MgrAgentConfName) ->
+    UsmUsers = [Id || {Id,_} <- ct:get_config({MgrAgentConfName, usm_users},[])],
+    unregister_usm_users(MgrAgentConfName,UsmUsers).
+
+%%% @spec unregister_usm_users(MgrAgentConfName,UsmUsers) ->  ok
+%%%
+%%%      MgrAgentConfName = atom()
+%%%      UsmUsers = [usm_user_name()]
+%%%      Reason = term()
+%%%
+%%% @doc Unregister the given usm users.
+unregister_usm_users(MgrAgentConfName,UsmUsers) ->
     EngineID = ct:get_config({MgrAgentConfName, engine_id}, ?ENGINE_ID),
-    do_update_usm_users(UsmUsers, EngineID). 
+    takedown_usm_users(UsmUsers,EngineID),
+    SnmpVals = ct:get_config(MgrAgentConfName),
+    AllUsmUsers = ct:get_config({MgrAgentConfName, usm_users},[]),
+    RemainingUsmUsers = lists:filter(fun({Id,_}) ->
+					     not lists:member(Id,UsmUsers)
+				     end,
+				     AllUsmUsers),
+    NewSnmpVals = lists:keyreplace(usm_users, 1, SnmpVals,
+				   {usm_users,RemainingUsmUsers}),
+    ct_config:update_config(MgrAgentConfName, NewSnmpVals),
+    ok.
 
 %%% @spec load_mibs(Mibs) -> ok | {error, Reason}
 %%%
@@ -417,6 +496,15 @@ update_usm_users(MgrAgentConfName, UsmUsers) ->
 load_mibs(Mibs) ->       
     snmpa:load_mibs(snmp_master_agent, Mibs).
  
+%%% @spec unload_mibs(Mibs) -> ok | {error, Reason}
+%%%
+%%%      Mibs = [MibName]
+%%%      MibName = string()
+%%%      Reason = term()
+%%%
+%%% @doc Unload the mibs from the agent 'snmp_master_agent'.
+unload_mibs(Mibs) ->
+    snmpa:unload_mibs(snmp_master_agent, Mibs).
 
 %%%========================================================================
 %%% Internal functions
@@ -533,69 +621,57 @@ manager_register(true, MgrAgentConfName) ->
 
 %%%---------------------------------------------------------------------------
 setup_users(Users) ->
-    lists:foreach(fun({Id, [Module, Data]}) ->
-			  snmpm:register_user(Id, Module, Data)
-		  end, Users).
+    while_ok(fun({Id, [Module, Data]}) ->
+		     snmpm:register_user(Id, Module, Data)
+	     end, Users).
 %%%---------------------------------------------------------------------------   
-setup_managed_agents(_,[]) ->
-    ok;
-
-setup_managed_agents(AgentConfName,
-		     [{AgentName, [Uid, AgentIp, AgentUdpPort, AgentConf0]} |
-		      Rest]) ->
-    NewAgentIp = case AgentIp of
-		     IpTuple when is_tuple(IpTuple) ->
-			 IpTuple;
-		     HostName when is_list(HostName) ->
-			 {ok,Hostent} = inet:gethostbyname(HostName),
-			 [IpTuple|_] = Hostent#hostent.h_addr_list,
-			 IpTuple
-		 end,
-    AgentConf =
-	case lists:keymember(engine_id,1,AgentConf0) of
-	    true ->
-		AgentConf0;
-	    false ->
-		DefaultEngineID = ct:get_config({AgentConfName,agent_engine_id},
-						?AGENT_ENGINE_ID),
-		[{engine_id,DefaultEngineID}|AgentConf0]
+setup_managed_agents(AgentConfName,Agents) ->
+    Fun =
+	fun({AgentName, [Uid, AgentIp, AgentUdpPort, AgentConf0]}) ->
+		NewAgentIp = case AgentIp of
+				 IpTuple when is_tuple(IpTuple) ->
+				     IpTuple;
+				 HostName when is_list(HostName) ->
+				     {ok,Hostent} = inet:gethostbyname(HostName),
+				     [IpTuple|_] = Hostent#hostent.h_addr_list,
+				     IpTuple
+			     end,
+		AgentConf =
+		    case lists:keymember(engine_id,1,AgentConf0) of
+			true ->
+			    AgentConf0;
+			false ->
+			    DefaultEngineID =
+				ct:get_config({AgentConfName,agent_engine_id},
+					      ?AGENT_ENGINE_ID),
+			    [{engine_id,DefaultEngineID}|AgentConf0]
+		    end,
+		snmpm:register_agent(Uid, target_name(AgentName),
+				     [{address,NewAgentIp},{port,AgentUdpPort} |
+				      AgentConf])
 	end,
-    ok = snmpm:register_agent(Uid, target_name(AgentName),
-			      [{address,NewAgentIp},{port,AgentUdpPort} |
-			       AgentConf]),
-    setup_managed_agents(AgentConfName,Rest).
+    while_ok(Fun,Agents).
 %%%---------------------------------------------------------------------------
 setup_usm_users(UsmUsers, EngineID)->
-    lists:foreach(fun({UsmUser, Conf}) ->
-			  snmpm:register_usm_user(EngineID, UsmUser, Conf)
-		  end, UsmUsers).
+    while_ok(fun({UsmUser, Conf}) ->
+		     snmpm:register_usm_user(EngineID, UsmUser, Conf)
+	     end, UsmUsers).
 %%%---------------------------------------------------------------------------
 takedown_users(Users) ->
-     lists:foreach(fun({Id}) ->
+     lists:foreach(fun(Id) ->
 			  snmpm:unregister_user(Id)
 		   end, Users).
 %%%---------------------------------------------------------------------------
-takedown_managed_agents([{Uid, AgentIp, AgentUdpPort} |
-			 Rest]) ->
-    NewAgentIp = case AgentIp of
-		     IpTuple when is_tuple(IpTuple) ->
-			 IpTuple;
-		     HostName when is_list(HostName) ->
-			 {ok,Hostent} = inet:gethostbyname(HostName),
-			 [IpTuple|_] = Hostent#hostent.h_addr_list,
-			 IpTuple
-		 end,
-    ok = snmpm:unregister_agent(Uid, NewAgentIp, AgentUdpPort),   
-    takedown_managed_agents(Rest);
-
-takedown_managed_agents([]) ->
-    ok.
+takedown_managed_agents(MgrAgentConfName,ManagedAgents) ->
+    lists:foreach(fun(AgentName) ->
+			  [Uid | _] = agent_conf(AgentName, MgrAgentConfName),
+			  snmpm:unregister_agent(Uid, target_name(AgentName))
+		  end, ManagedAgents).
 %%%---------------------------------------------------------------------------
-do_update_usm_users(UsmUsers, EngineID) ->
-    lists:foreach(fun({UsmUser, {Item, Val}}) ->
-			  snmpm:update_usm_user_info(EngineID, UsmUser, 
-						     Item, Val)
-		  end, UsmUsers).
+takedown_usm_users(UsmUsers, EngineID) ->
+     lists:foreach(fun(Id) ->
+			  snmpm:unregister_usm_user(EngineID, Id)
+		   end, UsmUsers).
 %%%---------------------------------------------------------------------------  
 log(PrivDir, Agent, {_, _, Varbinds}, NewVarsAndVals) ->
 
@@ -659,7 +735,7 @@ override_contexts(Config, {data_dir_file, File}) ->
     override_contexts(Config, ContextInfo);
 
 override_contexts(Config, Contexts) ->
-    Dir = ?config(priv_dir, Config),    
+    Dir = filename:join(?config(priv_dir, Config),"conf"),
     File = filename:join(Dir,"context.conf"),
     file:delete(File),
     snmp_config:write_agent_context_config(Dir, "", Contexts).
@@ -675,7 +751,7 @@ override_sysinfo(Config, {data_dir_file, File}) ->
     override_sysinfo(Config, SysInfo);
 
 override_sysinfo(Config, SysInfo) ->   
-    Dir = ?config(priv_dir, Config),  
+    Dir = filename:join(?config(priv_dir, Config),"conf"),
     File = filename:join(Dir,"standard.conf"),
     file:delete(File),
     snmp_config:write_agent_standard_config(Dir, "", SysInfo).
@@ -690,7 +766,7 @@ override_target_address(Config, {data_dir_file, File}) ->
     override_target_address(Config, TargetAddressConf);
 
 override_target_address(Config, TargetAddressConf) ->
-    Dir = ?config(priv_dir, Config),  
+    Dir = filename:join(?config(priv_dir, Config),"conf"),
     File = filename:join(Dir,"target_addr.conf"),
     file:delete(File),
     snmp_config:write_agent_target_addr_config(Dir, "", TargetAddressConf).
@@ -706,7 +782,7 @@ override_target_params(Config, {data_dir_file, File}) ->
     override_target_params(Config, TargetParamsConf);
 
 override_target_params(Config, TargetParamsConf) ->
-    Dir = ?config(priv_dir, Config),  
+    Dir = filename:join(?config(priv_dir, Config),"conf"),
     File = filename:join(Dir,"target_params.conf"),
     file:delete(File),
     snmp_config:write_agent_target_params_config(Dir, "", TargetParamsConf). 
@@ -721,7 +797,7 @@ override_notify(Config, {data_dir_file, File}) ->
     override_notify(Config, NotifyConf);
 
 override_notify(Config, NotifyConf) ->
-    Dir = ?config(priv_dir, Config),  
+    Dir = filename:join(?config(priv_dir, Config),"conf"),
     File = filename:join(Dir,"notify.conf"),
     file:delete(File),
     snmp_config:write_agent_notify_config(Dir, "", NotifyConf).
@@ -736,7 +812,7 @@ override_usm(Config, {data_dir_file, File}) ->
     override_usm(Config, UsmConf);
 
 override_usm(Config, UsmConf) ->
-    Dir = ?config(priv_dir, Config),  
+    Dir = filename:join(?config(priv_dir, Config),"conf"),
     File = filename:join(Dir,"usm.conf"),
     file:delete(File),
     snmp_config:write_agent_usm_config(Dir, "", UsmConf).
@@ -751,7 +827,7 @@ override_community(Config, {data_dir_file, File}) ->
     override_community(Config, CommunityConf);
 
 override_community(Config, CommunityConf) ->
-    Dir = ?config(priv_dir, Config),  
+    Dir = filename:join(?config(priv_dir, Config),"conf"),
     File = filename:join(Dir,"community.conf"),
     file:delete(File),
     snmp_config:write_agent_community_config(Dir, "", CommunityConf).
@@ -767,8 +843,8 @@ override_vacm(Config, {data_dir_file, File}) ->
     override_vacm(Config, VacmConf);
 
 override_vacm(Config, VacmConf) ->
-    Dir = ?config(priv_dir, Config),  
-       File = filename:join(Dir,"vacm.conf"),
+    Dir = filename:join(?config(priv_dir, Config),"conf"),
+    File = filename:join(Dir,"vacm.conf"),
     file:delete(File),
     snmp_config:write_agent_vacm_config(Dir, "", VacmConf).
 
@@ -776,3 +852,11 @@ override_vacm(Config, VacmConf) ->
 
 target_name(Agent) ->
     atom_to_list(Agent).
+
+while_ok(Fun,[H|T]) ->
+    case Fun(H) of
+	ok -> while_ok(Fun,T);
+	Error -> Error
+    end;
+while_ok(_Fun,[]) ->
+    ok.
diff --git a/lib/common_test/test/ct_snmp_SUITE.erl b/lib/common_test/test/ct_snmp_SUITE.erl
index 848752b816..f8b4543770 100644
--- a/lib/common_test/test/ct_snmp_SUITE.erl
+++ b/lib/common_test/test/ct_snmp_SUITE.erl
@@ -70,7 +70,7 @@ all() ->
 %%%
 default(Config) when is_list(Config) ->
     DataDir = ?config(data_dir, Config),
-    Suite = filename:join(DataDir, "snmp1_SUITE"),
+    Suite = filename:join(DataDir, "snmp_SUITE"),
     CfgFile = filename:join(DataDir, "snmp.cfg"),
     {Opts,ERPid} = setup([{suite,Suite},{config,CfgFile},
 			  {label,default}], Config),
@@ -110,14 +110,14 @@ reformat(Events, EH) ->
 %%%-----------------------------------------------------------------
 events_to_check(_TestName,Config) ->
     {module,_} = code:load_abs(filename:join(?config(data_dir,Config),
-					     snmp1_SUITE)),
+					     snmp_SUITE)),
     TCs = get_tcs(),
-    code:purge(snmp1_SUITE),
-    code:delete(snmp1_SUITE),
+    code:purge(snmp_SUITE),
+    code:delete(snmp_SUITE),
 
     OneTest =
 	[{?eh,start_logging,{'DEF','RUNDIR'}}] ++
-	[{?eh,tc_done,{snmp1_SUITE,TC,ok}} || TC <- TCs] ++
+	[{?eh,tc_done,{snmp_SUITE,TC,ok}} || TC <- TCs] ++
 	[{?eh,stop_logging,[]}],
 
     %% 2 tests (ct:run_test + script_start) is default
@@ -125,9 +125,9 @@ events_to_check(_TestName,Config) ->
 
 
 get_tcs() ->
-    All = snmp1_SUITE:all(),
+    All = snmp_SUITE:all(),
     Groups =
-	try snmp1_SUITE:groups()
+	try snmp_SUITE:groups()
 	catch error:undef -> []
 	end,
     flatten_tcs(All,Groups).
diff --git a/lib/common_test/test/ct_snmp_SUITE_data/snmp.cfg b/lib/common_test/test/ct_snmp_SUITE_data/snmp.cfg
index b0ac0e6a96..895e097de6 100644
--- a/lib/common_test/test/ct_snmp_SUITE_data/snmp.cfg
+++ b/lib/common_test/test/ct_snmp_SUITE_data/snmp.cfg
@@ -1,20 +1,44 @@
 %% -*- erlang -*-
-{snmp, [{start_agent,true},
-	{users,[{user_name,[snmp1_SUITE,[]]}]},
-	{managed_agents,[{agent_name, [user_name, {127,0,0,1}, 4000,
-				       [{engine_id,"ct_snmp-test-engine"},
-					{version,v2}]]}]},
-	{engine_id,"ct_snmp-test-engine"},
-	{agent_vsns,[v2]}
-       ]}.
-{snmp_app,[{manager, [{config, [{verbosity, silence}]},
-		      {server,[{verbosity,silence}]},
-		      {net_if,[{verbosity,silence}]},
-		      {versions,[v2]}
-		     ]},
-	   {agent, [{config, [{verbosity, silence}]},
-		    {net_if,[{verbosity,silence}]},
-		    {mib_server,[{verbosity,silence}]},
-		    {local_db,[{verbosity,silence}]},
-		    {agent_verbosity,silence}
-		   ]}]}.
+{snmp1, [{start_agent,true},
+	 {users,[{user_name,[snmpm_user_default,[]]}]},
+	 {managed_agents,[{agent_name, [user_name, {127,0,0,1}, 4000,
+					[{engine_id,"ct_snmp-test-engine"},
+					 {version,v2}]]}]},
+	 {engine_id,"ct_snmp-test-engine"},
+	 {agent_vsns,[v2]}
+	]}.
+{snmp2, [{start_agent,true},
+	 {engine_id,"ct_snmp-test-engine"}
+	]}.
+{snmp3, [{start_agent,true},
+	 {engine_id,"ct_snmp-test-engine"},
+	 {agent_vsns,[v1,v2,v3]},
+	 {agent_contexts,{data_dir_file,"context.conf"}},
+	 {agent_usm,{data_dir_file,"usm.conf"}},
+	 {agent_community,{data_dir_file,"community.conf"}},
+	 {agent_notify_def,{data_dir_file,"notify.conf"}},
+	 {agent_sysinfo,{data_dir_file,"standard.conf"}},
+	 {agent_target_address_def,{data_dir_file,"target_addr.conf"}},
+	 {agent_target_param_def,{data_dir_file,"target_params.conf"}},
+	 {agent_vacm,{data_dir_file,"vacm.conf"}}]}.
+{snmp_app1,[{manager, [{config, [{verbosity, silence}]},
+		       {server,[{verbosity,silence}]},
+		       {net_if,[{verbosity,silence}]},
+		       {versions,[v2]}
+		      ]},
+	    {agent, [{config, [{verbosity, silence}]},
+		     {net_if,[{verbosity,silence}]},
+		     {mib_server,[{verbosity,silence}]},
+		     {local_db,[{verbosity,silence}]},
+		     {agent_verbosity,silence}
+		    ]}]}.
+{snmp_app2,[{manager, [{config, [{verbosity, silence}]},
+		       {server,[{verbosity,silence}]},
+		       {net_if,[{verbosity,silence}]}
+		      ]},
+	    {agent, [{config, [{verbosity, silence}]},
+		     {net_if,[{verbosity,silence}]},
+		     {mib_server,[{verbosity,silence}]},
+		     {local_db,[{verbosity,silence}]},
+		     {agent_verbosity,silence}
+		    ]}]}.
diff --git a/lib/common_test/test/ct_snmp_SUITE_data/snmp1_SUITE.erl b/lib/common_test/test/ct_snmp_SUITE_data/snmp1_SUITE.erl
deleted file mode 100644
index dcc5c5378b..0000000000
--- a/lib/common_test/test/ct_snmp_SUITE_data/snmp1_SUITE.erl
+++ /dev/null
@@ -1,152 +0,0 @@
-%%--------------------------------------------------------------------
-%% %CopyrightBegin%
-%%
-%% Copyright Ericsson AB 2012. All Rights Reserved.
-%%
-%% The contents of this file are subject to the Erlang Public License,
-%% Version 1.1, (the "License"); you may not use this file except in
-%% compliance with the License. You should have received a copy of the
-%% Erlang Public License along with this software. If not, it can be
-%% retrieved online at http://www.erlang.org/.
-%%
-%% Software distributed under the License is distributed on an "AS IS"
-%% basis, WITHOUT WARRANTY OF ANY KIND, either express or implied. See
-%% the License for the specific language governing rights and limitations
-%% under the License.
-%%
-%% %CopyrightEnd%
-%%
-%%----------------------------------------------------------------------
-%% File: ct_snmp_SUITE.erl
-%%
-%% Description:
-%%    This file contains the test cases for the ct_snmp API.
-%%
-%% @author Support
-%% @doc Test  of SNMP support in common_test
-%% @end
-%%----------------------------------------------------------------------
-%%----------------------------------------------------------------------
--module(snmp1_SUITE).
--include_lib("common_test/include/ct.hrl").
--include_lib("snmp/include/STANDARD-MIB.hrl").
--include_lib("snmp/include/snmp_types.hrl").
-
--compile(export_all).
-
-%% Default timetrap timeout (set in init_per_testcase).
--define(default_timeout, ?t:minutes(1)).
-
-%% SNMP user stuff
--behaviour(snmpm_user).
--export([handle_error/3,
-	 handle_agent/5,
-	 handle_pdu/4,
-	 handle_trap/3,
-	 handle_inform/3,
-	 handle_report/3]).
-
-
-suite() ->
-    [{require, snmp_mgr_agent, snmp},
-     {require, snmp_app_cfg, snmp_app}].
-
-all() ->
-    [start_stop,
-    {group,get_set}].
-
-
-groups() ->
-    [{get_set,[get_values,get_next_values,set_values]}].
-
-init_per_group(get_set, Config) ->
-    ok = ct_snmp:start(Config,snmp_mgr_agent,snmp_app_cfg),
-    Config.
-
-end_per_group(get_set, Config) ->
-    ok = ct_snmp:stop(Config),
-    Config.
-
-init_per_testcase(_Case, Config) ->
-    Dog = test_server:timetrap(?default_timeout),
-    [{watchdog, Dog}|Config].
-
-end_per_testcase(_Case, Config) ->
-    Dog=?config(watchdog, Config),
-    test_server:timetrap_cancel(Dog),
-    ok.
-
-init_per_suite(Config) ->
-    Config.
-
-end_per_suite(Config) ->
-    Config.
-
-break(_Config) ->
-    test_server:break(""),
-    ok.
-
-start_stop(Config) ->
-    ok = ct_snmp:start(Config,snmp_mgr_agent,snmp_app_cfg),
-    timer:sleep(1000),
-    {snmp,_,_} = lists:keyfind(snmp,1,application:which_applications()),
-    [_|_] = filelib:wildcard("*/*.conf",?config(priv_dir,Config)),
-
-    ok = ct_snmp:stop(Config),
-    timer:sleep(1000),
-    false = lists:keyfind(snmp,1,application:which_applications()),
-    [] = filelib:wildcard("*/*.conf",?config(priv_dir,Config)),
-    ok.
-
-get_values(_Config) ->
-    Oids1 = [?sysDescr_instance, ?sysName_instance],
-    {noError,_,V1} = ct_snmp:get_values(agent_name,Oids1,snmp_mgr_agent),
-    [#varbind{oid=?sysDescr_instance,value="Erlang SNMP agent"},
-     #varbind{oid=?sysName_instance,value="ct_test"}] = V1,
-    ok.
-
-get_next_values(_Config) ->
-    Oids2 = [?system],
-    {noError,_,V2} = ct_snmp:get_next_values(agent_name,Oids2,snmp_mgr_agent),
-    [#varbind{oid=?sysDescr_instance,value="Erlang SNMP agent"}] = V2,
-    ok.
-
-set_values(Config) ->
-    Oid3 = ?sysName_instance,
-    NewName = "ct_test changed by " ++ atom_to_list(?MODULE),
-    VarsAndVals = [{Oid3,s,NewName}],
-    {noError,_,_} =
-	ct_snmp:set_values(agent_name,VarsAndVals,snmp_mgr_agent,Config),
-
-    Oids4 = [?sysName_instance],
-    {noError,_,V4} = ct_snmp:get_values(agent_name,Oids4,snmp_mgr_agent),
-    [#varbind{oid=?sysName_instance,value=NewName}] = V4,
-
-    ok.
-
-
-%%%-----------------------------------------------------------------
-%%% SNMP Manager User callback
-handle_error(ReqId, Reason, UserData) ->
-    erlang:display({handle_error,ReqId, Reason, UserData}),
-    ignore.
-
-handle_agent(Addr, Port, Type, SnmpInfo, UserData) ->
-    erlang:display({handle_agent,Addr, Port, Type, SnmpInfo, UserData}),
-    ignore.
-
-handle_pdu(TargetName, ReqId, SnmpPduInfo, UserData) ->
-    erlang:display({handle_pdu,TargetName, ReqId, SnmpPduInfo, UserData}),
-    ignore.
-
-handle_trap(TargetName, SnmpTrapInfo, UserData) ->
-    erlang:display({handle_trap,TargetName, SnmpTrapInfo, UserData}),
-    ignore.
-
-handle_inform(TargetName, SnmpInformInfo, UserData) ->
-    erlang:display({handle_inform,TargetName, SnmpInformInfo, UserData}),
-    ignore.
-
-handle_report(TargetName, SnmpReportInfo, UserData) ->
-    erlang:display({handle_report,TargetName, SnmpReportInfo, UserData}),
-    ignore.
diff --git a/lib/common_test/test/ct_snmp_SUITE_data/snmp_SUITE.erl b/lib/common_test/test/ct_snmp_SUITE_data/snmp_SUITE.erl
new file mode 100644
index 0000000000..16b2b5690c
--- /dev/null
+++ b/lib/common_test/test/ct_snmp_SUITE_data/snmp_SUITE.erl
@@ -0,0 +1,395 @@
+%%--------------------------------------------------------------------
+%% %CopyrightBegin%
+%%
+%% Copyright Ericsson AB 2012. All Rights Reserved.
+%%
+%% The contents of this file are subject to the Erlang Public License,
+%% Version 1.1, (the "License"); you may not use this file except in
+%% compliance with the License. You should have received a copy of the
+%% Erlang Public License along with this software. If not, it can be
+%% retrieved online at http://www.erlang.org/.
+%%
+%% Software distributed under the License is distributed on an "AS IS"
+%% basis, WITHOUT WARRANTY OF ANY KIND, either express or implied. See
+%% the License for the specific language governing rights and limitations
+%% under the License.
+%%
+%% %CopyrightEnd%
+%%
+%%----------------------------------------------------------------------
+%% File: ct_snmp_SUITE.erl
+%%
+%% Description:
+%%    This file contains the test cases for the ct_snmp API.
+%%
+%% @author Support
+%% @doc Test  of SNMP support in common_test
+%% @end
+%%----------------------------------------------------------------------
+%%----------------------------------------------------------------------
+-module(snmp_SUITE).
+-include_lib("common_test/include/ct.hrl").
+-include_lib("snmp/include/STANDARD-MIB.hrl").
+-include_lib("snmp/include/SNMP-USER-BASED-SM-MIB.hrl").
+-include_lib("snmp/include/snmp_types.hrl").
+
+-compile(export_all).
+
+%% Default timetrap timeout (set in init_per_testcase).
+-define(default_timeout, ?t:minutes(1)).
+
+-define(AGENT_UDP, 4000).
+
+suite() ->
+    [
+     {require, snmp1, snmp1},
+     {require, snmp_app1, snmp_app1},
+     {require, snmp2, snmp2},
+     {require, snmp_app2, snmp_app2},
+     {require, snmp3, snmp3}
+    ].
+
+all() ->
+    [start_stop,
+     {group,get_set},
+     {group,register},
+     {group,override},
+     set_info].
+
+
+groups() ->
+    [{get_set,[get_values,
+	       get_next_values,
+	       set_values,
+	       load_mibs]},
+     {register,[register_users,
+		register_users_fail,
+		register_agents,
+		register_agents_fail,
+		register_usm_users,
+		register_usm_users_fail]},
+     {override,[override_usm,
+		override_standard,
+		override_context,
+		override_community,
+		override_notify,
+		override_target_addr,
+		override_target_params,
+		override_vacm]}].
+
+init_per_suite(Config) ->
+    Config.
+
+end_per_suite(Config) ->
+    Config.
+
+init_per_group(get_set, Config) ->
+    ok = ct_snmp:start(Config,snmp1,snmp_app1),
+    Config;
+init_per_group(register, Config) ->
+    ok = ct_snmp:start(Config,snmp2,snmp_app2),
+    Config;
+init_per_group(_, Config) ->
+    ok = ct_snmp:start(Config,snmp3,snmp_app2),
+    Config.
+
+end_per_group(_Group, Config) ->
+    catch ct_snmp:stop(Config),
+    Config.
+
+init_per_testcase(_Case, Config) ->
+    Dog = test_server:timetrap(?default_timeout),
+    [{watchdog, Dog}|Config].
+
+end_per_testcase(Case, Config) ->
+    try apply(?MODULE,Case,[cleanup,Config])
+    catch error:undef -> ok
+    end,
+    Dog=?config(watchdog, Config),
+    test_server:timetrap_cancel(Dog),
+    ok.
+
+%%%-----------------------------------------------------------------
+%%% Test cases
+break(_Config) ->
+    test_server:break(""),
+    ok.
+
+start_stop(Config) ->
+    ok = ct_snmp:start(Config,snmp1,snmp_app1),
+    timer:sleep(1000),
+    {snmp,_,_} = lists:keyfind(snmp,1,application:which_applications()),
+    [_|_] = filelib:wildcard("*/*.conf",?config(priv_dir,Config)),
+
+    ok = ct_snmp:stop(Config),
+    timer:sleep(1000),
+    false = lists:keyfind(snmp,1,application:which_applications()),
+    [] = filelib:wildcard("*/*.conf",?config(priv_dir,Config)),
+    ok.
+
+get_values(_Config) ->
+    Oids1 = [?sysDescr_instance, ?sysName_instance],
+    {noError,_,V1} = ct_snmp:get_values(agent_name,Oids1,snmp1),
+    [#varbind{oid=?sysDescr_instance,value="Erlang SNMP agent"},
+     #varbind{oid=?sysName_instance,value="ct_test"}] = V1,
+    ok.
+
+get_next_values(_Config) ->
+    Oids2 = [?system],
+    {noError,_,V2} = ct_snmp:get_next_values(agent_name,Oids2,snmp1),
+    [#varbind{oid=?sysDescr_instance,value="Erlang SNMP agent"}] = V2,
+    ok.
+
+set_values(Config) ->
+    Oid3 = ?sysName_instance,
+    NewName = "ct_test changed by " ++ atom_to_list(?MODULE),
+    VarsAndVals = [{Oid3,s,NewName}],
+    {noError,_,_} =
+	ct_snmp:set_values(agent_name,VarsAndVals,snmp1,Config),
+
+    Oids4 = [?sysName_instance],
+    {noError,_,V4} = ct_snmp:get_values(agent_name,Oids4,snmp1),
+    [#varbind{oid=?sysName_instance,value=NewName}] = V4,
+
+    ok.
+
+load_mibs(_Config) ->
+    [{'SNMPv2-MIB',_}=SnmpV2Mib] = snmpa:which_mibs(),
+    Mib = filename:join([code:priv_dir(snmp),"mibs","SNMP-USER-BASED-SM-MIB"]),
+    ok = ct_snmp:load_mibs([Mib]),
+    TwoMibs = [_,_] = snmpa:which_mibs(),
+    [{'SNMP-USER-BASED-SM-MIB',_}] = lists:delete(SnmpV2Mib,TwoMibs),
+    ok = ct_snmp:unload_mibs([Mib]),
+    [{'SNMPv2-MIB',_}] = snmpa:which_mibs(),
+    ok.
+
+
+register_users(_Config) ->
+    [] = snmpm:which_users(),
+    ok = ct_snmp:register_users(snmp2,[{reg_user1,[snmpm_user_default,[]]}]),
+    [_] = snmpm:which_users(),
+    [_] = ct:get_config({snmp2,users}),
+    ok = ct_snmp:register_users(snmp2,[{reg_user2,[snmpm_user_default,[]]}]),
+    [_,_] = snmpm:which_users(),
+    [_,_] = ct:get_config({snmp2,users}),
+    ok = ct_snmp:register_users(snmp2,[{reg_user3,[snmpm_user_default,[]]}]),
+    [_,_,_] = snmpm:which_users(),
+    [_,_,_] = ct:get_config({snmp2,users}),
+    ok = ct_snmp:unregister_users(snmp2,[reg_user3]),
+    [_,_] = snmpm:which_users(),
+    [_,_] = ct:get_config({snmp2,users}),
+    ok = ct_snmp:unregister_users(snmp2),
+    [] = snmpm:which_users(),
+    [] = ct:get_config({snmp2,users}),
+    ok.
+register_users(cleanup,_Config) ->
+    ct_snmp:unregister_users(snmp2).
+
+register_users_fail(_Config) ->
+    [] = snmpm:which_users(),
+    {error,_} = ct_snmp:register_users(snmp2,[{reg_user3,[unknown_module,[]]}]),
+    [] = snmpm:which_users(),
+    ok.
+register_users_fail(cleanup,_Config) ->
+    ct_snmp:unregister_users(snmp2).
+
+register_agents(_Config) ->
+    {ok, HostName} = inet:gethostname(),
+    {ok, Addr} = inet:getaddr(HostName, inet),
+
+    [] = snmpm:which_agents(),
+    ok = ct_snmp:register_users(snmp2,[{reg_user1,[snmpm_user_default,[]]}]),
+    ok = ct_snmp:register_agents(snmp2,[{reg_agent1,
+					 [reg_user1,Addr,?AGENT_UDP,[]]}]),
+    [_] = snmpm:which_agents(),
+    [_] = ct:get_config({snmp2,managed_agents}),
+    ok = ct_snmp:register_agents(snmp2,[{reg_agent2,
+					 [reg_user1,Addr,?AGENT_UDP,[]]}]),
+    [_,_] = snmpm:which_agents(),
+    [_,_] = ct:get_config({snmp2,managed_agents}),
+
+    ok = ct_snmp:register_agents(snmp2,[{reg_agent3,
+					 [reg_user1,Addr,?AGENT_UDP,[]]}]),
+    [_,_,_] = snmpm:which_agents(),
+    [_,_,_] = ct:get_config({snmp2,managed_agents}),
+
+    ok = ct_snmp:unregister_agents(snmp2,[reg_agent3]),
+    [_,_] = snmpm:which_agents(),
+    [_,_] = ct:get_config({snmp2,managed_agents}),
+
+    ok = ct_snmp:unregister_agents(snmp2),
+    ok = ct_snmp:unregister_users(snmp2),
+    [] = snmpm:which_agents(),
+    [] = ct:get_config({snmp2,managed_agents}),
+    ok.
+register_agents(cleanup,_Config) ->
+    ct_snmp:unregister_agents(snmp2),
+    ct_snmp:unregister_users(snmp2).
+
+register_agents_fail(_Config) ->
+    {ok, HostName} = inet:gethostname(),
+    {ok, Addr} = inet:getaddr(HostName, inet),
+
+    [] = snmpm:which_agents(),
+    {error,_}
+	= ct_snmp:register_agents(snmp2,[{reg_agent3,
+					  [unknown_user,Addr,?AGENT_UDP,[]]}]),
+    [] = snmpm:which_agents(),
+    ok.
+register_agents_fail(cleanup,_Config) ->
+    ct_snmp:unregister_agents(snmp2).
+
+register_usm_users(_Config) ->
+    [] = snmpm:which_usm_users(),
+    ok = ct_snmp:register_usm_users(snmp2,[{"reg_usm_user1",[]}]),
+    [_] = snmpm:which_usm_users(),
+    [_] = ct:get_config({snmp2,usm_users}),
+    ok = ct_snmp:register_usm_users(snmp2,[{"reg_usm_user2",[]}]),
+    [_,_] = snmpm:which_usm_users(),
+    [_,_] = ct:get_config({snmp2,usm_users}),
+    ok = ct_snmp:register_usm_users(snmp2,[{"reg_usm_user3",[]}]),
+    [_,_,_] = snmpm:which_usm_users(),
+    [_,_,_] = ct:get_config({snmp2,usm_users}),
+    ok = ct_snmp:unregister_usm_users(snmp2,["reg_usm_user3"]),
+    [_,_] = snmpm:which_usm_users(),
+    [_,_] = ct:get_config({snmp2,usm_users}),
+    ok = ct_snmp:unregister_usm_users(snmp2),
+    [] = snmpm:which_usm_users(),
+    [] = ct:get_config({snmp2,usm_users}),
+    ok.
+register_usm_users(cleanup,_Config) ->
+    ct_snmp:unregister_usm_users(snmp2).
+
+register_usm_users_fail(_Config) ->
+    [] = snmpm:which_usm_users(),
+    {error,_}
+	= ct_snmp:register_usm_users(snmp2,[{"reg_usm_user3",
+					     [{sec_name,invalid_data_type}]}]),
+    [] = snmpm:which_usm_users(),
+    ok.
+register_usm_users_fail(cleanup,_Config) ->
+    ct_snmp:unregister_usm_users(snmp2).
+
+%% Test that functionality for overriding default configuration file
+%% works - i.e. that the files are written and that the configuration
+%% is actually used.
+%%
+%% Note that the config files used in this test case do not
+%% necessarily make up a reasonable configuration for the snmp
+%% application...
+override_usm(Config) ->
+    DataDir = ?config(data_dir,Config),
+    PrivDir = ?config(priv_dir,Config),
+    ConfDir = filename:join(PrivDir,"conf"),
+
+    Mib = filename:join([code:priv_dir(snmp),"mibs","SNMP-USER-BASED-SM-MIB"]),
+    ok = ct_snmp:load_mibs([Mib]),
+
+    %% Check that usm.conf is overwritten
+    {ok,MyUsm} = snmpa_conf:read_usm_config(DataDir),
+    {ok,UsedUsm} = snmpa_conf:read_usm_config(ConfDir),
+    true = (MyUsm == UsedUsm),
+
+    %% Check that the usm user is actually configured...
+    [{Index,"secname"}] =
+	snmp_user_based_sm_mib:usmUserTable(get_next,?usmUserEntry,[3]),
+    true = lists:suffix("usm_user_name",Index),
+    ok.
+
+override_standard(Config) ->
+    DataDir = ?config(data_dir,Config),
+    PrivDir = ?config(priv_dir,Config),
+    ConfDir = filename:join(PrivDir,"conf"),
+
+    %% Check that standard.conf is overwritten
+    {ok,MyStandard} = snmpa_conf:read_standard_config(DataDir),
+    {ok,UsedStandard} = snmpa_conf:read_standard_config(ConfDir),
+    true = (MyStandard == UsedStandard),
+
+    %% Check that the values from standard.conf is actually configured...
+    {value,"name for override test"} = snmp_standard_mib:sysName(get),
+    {value,"agent for ct_snmp override test"} = snmp_standard_mib:sysDescr(get),
+    ok.
+
+override_context(Config) ->
+    DataDir = ?config(data_dir,Config),
+    PrivDir = ?config(priv_dir,Config),
+    ConfDir = filename:join(PrivDir,"conf"),
+
+    %% Check that context.conf is overwritten
+    {ok,MyContext} = snmpa_conf:read_context_config(DataDir),
+    {ok,UsedContext} = snmpa_conf:read_context_config(ConfDir),
+    true = (MyContext == UsedContext),
+    ok.
+
+override_community(Config) ->
+    DataDir = ?config(data_dir,Config),
+    PrivDir = ?config(priv_dir,Config),
+    ConfDir = filename:join(PrivDir,"conf"),
+
+    %% Check that community.conf is overwritten
+    {ok,MyCommunity} = snmpa_conf:read_community_config(DataDir),
+    {ok,UsedCommunity} = snmpa_conf:read_community_config(ConfDir),
+    true = (MyCommunity == UsedCommunity),
+    ok.
+
+override_notify(Config) ->
+    DataDir = ?config(data_dir,Config),
+    PrivDir = ?config(priv_dir,Config),
+    ConfDir = filename:join(PrivDir,"conf"),
+
+    %% Check that notify.conf is overwritten
+    {ok,MyNotify} = snmpa_conf:read_notify_config(DataDir),
+    {ok,UsedNotify} = snmpa_conf:read_notify_config(ConfDir),
+    true = (MyNotify == UsedNotify),
+    ok.
+
+override_target_addr(Config) ->
+    DataDir = ?config(data_dir,Config),
+    PrivDir = ?config(priv_dir,Config),
+    ConfDir = filename:join(PrivDir,"conf"),
+
+    %% Check that target_addr.conf is overwritten
+    {ok,MyTargetAddr} = snmpa_conf:read_target_addr_config(DataDir),
+    {ok,UsedTargetAddr} = snmpa_conf:read_target_addr_config(ConfDir),
+    true = (MyTargetAddr == UsedTargetAddr),
+    ok.
+
+override_target_params(Config) ->
+    DataDir = ?config(data_dir,Config),
+    PrivDir = ?config(priv_dir,Config),
+    ConfDir = filename:join(PrivDir,"conf"),
+
+    %% Check that target_params.conf is overwritten
+    {ok,MyTargetParams} = snmpa_conf:read_target_params_config(DataDir),
+    {ok,UsedTargetParams} = snmpa_conf:read_target_params_config(ConfDir),
+    true = (MyTargetParams == UsedTargetParams),
+    ok.
+
+override_vacm(Config) ->
+    DataDir = ?config(data_dir,Config),
+    PrivDir = ?config(priv_dir,Config),
+    ConfDir = filename:join(PrivDir,"conf"),
+
+    %% Check that vacm.conf is overwritten
+    {ok,MyVacm} = snmpa_conf:read_vacm_config(DataDir),
+    {ok,UsedVacm} = snmpa_conf:read_vacm_config(ConfDir),
+    true = (MyVacm == UsedVacm),
+    ok.
+
+
+
+
+%% NOTE!! This test must always be executed last in the suite, and
+%% should match all set requests performed in the suite. I.e. if you
+%% add a set request, you must add an entry in the return value of
+%% ct_snmp:set_info/1 below.
+set_info(Config) ->
+    %% From test case set_values/1:
+    Oid1 = ?sysName_instance,
+    NewValue1 = "ct_test changed by " ++ atom_to_list(?MODULE),
+
+    %% The test...
+    [{_AgentName,_,[{Oid1,_,NewValue1}]}]
+      = ct_snmp:set_info(Config),
+    ok.
diff --git a/lib/common_test/test/ct_snmp_SUITE_data/snmp_SUITE_data/community.conf b/lib/common_test/test/ct_snmp_SUITE_data/snmp_SUITE_data/community.conf
new file mode 100644
index 0000000000..5a64df6605
--- /dev/null
+++ b/lib/common_test/test/ct_snmp_SUITE_data/snmp_SUITE_data/community.conf
@@ -0,0 +1 @@
+{"public", "public", "initial", "", ""}.
diff --git a/lib/common_test/test/ct_snmp_SUITE_data/snmp_SUITE_data/context.conf b/lib/common_test/test/ct_snmp_SUITE_data/snmp_SUITE_data/context.conf
new file mode 100644
index 0000000000..feed5e1d11
--- /dev/null
+++ b/lib/common_test/test/ct_snmp_SUITE_data/snmp_SUITE_data/context.conf
@@ -0,0 +1 @@
+"testcontext".
diff --git a/lib/common_test/test/ct_snmp_SUITE_data/snmp_SUITE_data/notify.conf b/lib/common_test/test/ct_snmp_SUITE_data/snmp_SUITE_data/notify.conf
new file mode 100644
index 0000000000..367ba3aa4b
--- /dev/null
+++ b/lib/common_test/test/ct_snmp_SUITE_data/snmp_SUITE_data/notify.conf
@@ -0,0 +1 @@
+{"standard inform", "std_inform", inform}.
diff --git a/lib/common_test/test/ct_snmp_SUITE_data/snmp_SUITE_data/standard.conf b/lib/common_test/test/ct_snmp_SUITE_data/snmp_SUITE_data/standard.conf
new file mode 100644
index 0000000000..79908fb355
--- /dev/null
+++ b/lib/common_test/test/ct_snmp_SUITE_data/snmp_SUITE_data/standard.conf
@@ -0,0 +1,7 @@
+{sysDescr, "agent for ct_snmp override test"}.
+{sysObjectID, [1,2,3]}.
+{sysContact, "[email protected]"}.
+{sysLocation, "erlang"}.
+{sysServices, 72}.
+{snmpEnableAuthenTraps, enabled}.
+{sysName, "name for override test"}.
diff --git a/lib/common_test/test/ct_snmp_SUITE_data/snmp_SUITE_data/target_addr.conf b/lib/common_test/test/ct_snmp_SUITE_data/snmp_SUITE_data/target_addr.conf
new file mode 100644
index 0000000000..d02672a074
--- /dev/null
+++ b/lib/common_test/test/ct_snmp_SUITE_data/snmp_SUITE_data/target_addr.conf
@@ -0,0 +1,2 @@
+{"target1", snmpUDPDomain, [147,214,122,73], 5000, 1500, 3, "std_trap", "target_v3", "", [], 2048}.
+{"target2", snmpUDPDomain, [147,214,122,73], 5000, 1500, 3, "std_inform", "target_v3", "", [], 2048}.
diff --git a/lib/common_test/test/ct_snmp_SUITE_data/snmp_SUITE_data/target_params.conf b/lib/common_test/test/ct_snmp_SUITE_data/snmp_SUITE_data/target_params.conf
new file mode 100644
index 0000000000..5a9a619422
--- /dev/null
+++ b/lib/common_test/test/ct_snmp_SUITE_data/snmp_SUITE_data/target_params.conf
@@ -0,0 +1 @@
+{"target_v3", v3, usm, "initial", noAuthNoPriv}.
diff --git a/lib/common_test/test/ct_snmp_SUITE_data/snmp_SUITE_data/usm.conf b/lib/common_test/test/ct_snmp_SUITE_data/snmp_SUITE_data/usm.conf
new file mode 100644
index 0000000000..d6e245914e
--- /dev/null
+++ b/lib/common_test/test/ct_snmp_SUITE_data/snmp_SUITE_data/usm.conf
@@ -0,0 +1 @@
+{"ct_snmp-test-engine","usm_user_name","secname",zeroDotZero,usmNoAuthProtocol,"","",usmNoPrivProtocol,"","","","",""}.
diff --git a/lib/common_test/test/ct_snmp_SUITE_data/snmp_SUITE_data/vacm.conf b/lib/common_test/test/ct_snmp_SUITE_data/snmp_SUITE_data/vacm.conf
new file mode 100644
index 0000000000..158fe02e3b
--- /dev/null
+++ b/lib/common_test/test/ct_snmp_SUITE_data/snmp_SUITE_data/vacm.conf
@@ -0,0 +1,6 @@
+{vacmSecurityToGroup, usm, "initial", "initial"}.
+{vacmAccess, "initial", "", any, noAuthNoPriv, exact, "restricted", "", "restricted"}.
+{vacmAccess, "initial", "", usm, authNoPriv, exact, "internet", "internet", "internet"}.
+{vacmAccess, "initial", "", usm, authPriv, exact, "internet", "internet", "internet"}.
+{vacmViewTreeFamily, "restricted", [1,3,6,1], included, null}.
+{vacmViewTreeFamily, "internet", [1,3,6,1], included, null}.