Fix a race bug affecting dets_SUITE:open_file/2

The Dets server pretends the file is open before internal_open()
has been called, which means that unless the internal_open
message is applied first, other processes can find the pid by
calling dets_server:get_pid() and do things before Head has been
initialized properly.

2 files changed, 60 insertions, 3 deletions

diff --git a/lib/stdlib/src/dets.erl b/lib/stdlib/src/dets.erl
index 7036316242..6887bda67c 100644
--- a/lib/stdlib/src/dets.erl
+++ b/lib/stdlib/src/dets.erl
@@ -1291,7 +1291,15 @@ init(Parent, Server) ->
     open_file_loop(#head{parent = Parent, server = Server}).
 
 open_file_loop(Head) ->
-    open_file_loop(Head, 0).
+    %% The Dets server pretends the file is open before
+    %% internal_open() has been called, which means that unless the
+    %% internal_open message is applied first, other processes can
+    %% find the pid by calling dets_server:get_pid() and do things
+    %% before Head has been initialized properly.
+    receive
+        ?DETS_CALL(From, {internal_open, _Ref, _Args}=Op) ->
+            do_apply_op(Op, From, Head, 0)
+    end.
 
 open_file_loop(Head, N) when element(1, Head#head.update_mode) =:= error ->
     open_file_loop2(Head, N);
diff --git a/lib/stdlib/test/dets_SUITE.erl b/lib/stdlib/test/dets_SUITE.erl
index e061e16e4c..b101054229 100644
--- a/lib/stdlib/test/dets_SUITE.erl
+++ b/lib/stdlib/test/dets_SUITE.erl
@@ -53,7 +53,8 @@
          simultaneous_open/1, insert_new/1, repair_continuation/1,
          otp_5487/1, otp_6206/1, otp_6359/1, otp_4738/1, otp_7146/1,
          otp_8070/1, otp_8856/1, otp_8898/1, otp_8899/1, otp_8903/1,
-         otp_8923/1, otp_9282/1, otp_11245/1, otp_11709/1, otp_13229/1]).
+         otp_8923/1, otp_9282/1, otp_11245/1, otp_11709/1, otp_13229/1,
+         otp_13260/1]).
 
 -export([dets_dirty_loop/0]).
 
@@ -111,7 +112,7 @@ all() ->
 	insert_new, repair_continuation, otp_5487, otp_6206,
 	otp_6359, otp_4738, otp_7146, otp_8070, otp_8856, otp_8898,
 	otp_8899, otp_8903, otp_8923, otp_9282, otp_11245, otp_11709,
-        otp_13229
+        otp_13229, otp_13260
     ].
 
 groups() -> 
@@ -4001,6 +4002,54 @@ otp_13229(_Config) ->
             ok
     end.
 
+otp_13260(doc) ->
+    ["OTP-13260. Race when opening a table."];
+otp_13260(Config) ->
+    [ok] = lists:usort([otp_13260_1(Config) || _ <- lists:seq(1, 3)]),
+    ok.
+
+otp_13260_1(Config) ->
+    Tab = otp_13260,
+    File = filename(Tab, Config),
+    N = 20,
+    P = self(),
+    Pids = [spawn_link(fun() -> counter(P, Tab, File) end) ||
+               _ <- lists:seq(1, N)],
+    Rs = rec(Pids),
+    true = lists:all(fun(R) -> is_integer(R) end, Rs),
+    wait_for_close(Tab).
+
+rec([]) ->
+    [];
+rec([Pid | Pids]) ->
+    receive {Pid, R} ->
+            [R | rec(Pids)]
+    end.
+
+%% One may have to run the test several times to trigger the bug.
+counter(P, Tab, File) ->
+    Key = key,
+    N = case catch dets:update_counter(Tab, Key, 1) of
+            {'EXIT', _} ->
+                {ok, Tab} = dets:open_file(Tab, [{file, File}]),
+                ok = dets:insert(Tab, {Key, 1}),
+                dets:update_counter(Tab, Key, 1);
+            N1 when is_integer(N1) ->
+                N1;
+            DetsBug ->
+                DetsBug
+        end,
+    P ! {self(), N}.
+
+wait_for_close(Tab) ->
+    case dets:info(Tab, owner) of
+        undefined ->
+            ok;
+        _ ->
+            timer:sleep(100),
+            wait_for_close(Tab)
+    end.
+
 %%
 %% Parts common to several test cases
 %%