1 files changed, 120 insertions, 2 deletions

diff --git a/erts/test/otp_SUITE.erl b/erts/test/otp_SUITE.erl
index 2317b4f6a4..1fb452501f 100644
--- a/erts/test/otp_SUITE.erl
+++ b/erts/test/otp_SUITE.erl
@@ -23,7 +23,8 @@
 	 init_per_suite/1,end_per_suite/1]).
 -export([undefined_functions/1,deprecated_not_in_obsolete/1,
 	 obsolete_but_not_deprecated/1,call_to_deprecated/1,
-         call_to_size_1/1,strong_components/1]).
+         call_to_size_1/1,strong_components/1,
+	 erl_file_encoding/1,xml_file_encoding/1,runtime_dependencies/1]).
 
 -include_lib("test_server/include/test_server.hrl").
 
@@ -34,7 +35,9 @@ suite() -> [{ct_hooks,[ts_install_cth]}].
 all() -> 
     [undefined_functions, deprecated_not_in_obsolete,
      obsolete_but_not_deprecated, call_to_deprecated,
-     call_to_size_1, strong_components].
+     call_to_size_1, strong_components,
+     erl_file_encoding, xml_file_encoding,
+     runtime_dependencies].
 
 groups() -> 
     [].
@@ -320,6 +323,121 @@ strong_components(Config) when is_list(Config) ->
     io:format("\n\nStrong components:\n\n~p\n", [Cs]),
     ok.
 
+erl_file_encoding(_Config) ->
+    Root = code:root_dir(),
+    Wc = filename:join([Root,"**","*.erl"]),
+    ErlFiles = ordsets:subtract(ordsets:from_list(filelib:wildcard(Wc)),
+				release_files(Root, "*.erl")),
+    Fs = [F || F <- ErlFiles,
+	       case epp:read_encoding(F) of
+		   none -> false;
+		   _ -> true
+	       end],
+    case Fs of
+	[] ->
+	    ok;
+	[_|_] ->
+	    io:put_chars("Files with \"coding:\":\n"),
+	    [io:put_chars(F) || F <- Fs],
+	    ?t:fail()
+    end.
+
+xml_file_encoding(_Config) ->
+    XmlFiles = xml_files(),
+    Fs = [F || F <- XmlFiles, is_bad_encoding(F)],
+    case Fs of
+	[] ->
+	    ok;
+	[_|_] ->
+	    io:put_chars("Encoding should be \"utf-8\" or \"UTF-8\":\n"),
+	    [io:put_chars(F) || F <- Fs],
+	    ?t:fail()
+    end.
+
+xml_files() ->
+    Root = code:root_dir(),
+    AllWc = filename:join([Root,"**","*.xml"]),
+    AllXmlFiles = ordsets:from_list(filelib:wildcard(AllWc)),
+    TestsWc = filename:join([Root,"lib","*","test","**","*.xml"]),
+    TestXmlFiles = ordsets:from_list(filelib:wildcard(TestsWc)),
+    XmerlWc = filename:join([Root,"lib","xmerl","**","*.xml"]),
+    XmerlXmlFiles = ordsets:from_list(filelib:wildcard(XmerlWc)),
+    Ignore = ordsets:union([TestXmlFiles,XmerlXmlFiles,
+			    release_files(Root, "*.xml")]),
+    ordsets:subtract(AllXmlFiles, Ignore).
+
+release_files(Root, Ext) ->
+    Wc = filename:join([Root,"release","**",Ext]),
+    filelib:wildcard(Wc).
+
+is_bad_encoding(File) ->
+    {ok,Bin} = file:read_file(File),
+    case Bin of
+	<<"<?xml version=\"1.0\" encoding=\"utf-8\"",_/binary>> ->
+	    false;
+	<<"<?xml version=\"1.0\" encoding=\"UTF-8\"",_/binary>> ->
+	    false;
+	_ ->
+	    true
+    end.
+
+runtime_dependencies(Config) ->
+    %% Verify that (at least) OTP application runtime dependencies found
+    %% by xref are listed in the runtime_dependencies field of the .app file
+    %% of each application.
+    Server = ?config(xref_server, Config),
+    {ok, AE} = xref:q(Server, "AE"),
+    SAE = lists:keysort(1, AE),
+    {AppDep, AppDeps} = lists:foldl(fun ({App, App}, Acc) ->
+					    Acc;
+					({App, Dep}, {undefined, []}) ->
+					    {{App, [Dep]}, []};
+					({App, Dep}, {{App, Deps}, AppDeps}) ->
+					    {{App, [Dep|Deps]}, AppDeps};
+					({App, Dep}, {AppDep, AppDeps}) ->
+					    {{App, [Dep]}, [AppDep | AppDeps]}
+				    end,
+				    {undefined, []},
+				    SAE),
+    [] = check_apps_deps([AppDep|AppDeps]),
+    ok.
+
+have_rdep(_App, [], _Dep) ->
+    false;
+have_rdep(App, [RDep | RDeps], Dep) ->		    
+    [AppStr, _VsnStr] = string:tokens(RDep, "-"),
+    case Dep == list_to_atom(AppStr) of
+	true ->
+	    io:format("~p -> ~s~n", [App, RDep]),
+	    true;
+	false ->
+	    have_rdep(App, RDeps, Dep)
+    end.
+
+check_app_deps(_App, _AppFile, _AFDeps, []) ->
+    [];
+check_app_deps(App, AppFile, AFDeps, [XRDep | XRDeps]) ->
+    ResOtherDeps = check_app_deps(App, AppFile, AFDeps, XRDeps),
+    case have_rdep(App, AFDeps, XRDep) of
+	true ->
+	    ResOtherDeps;
+	false ->
+	    [{missing_runtime_dependency, AppFile, XRDep} | ResOtherDeps]
+    end.
+
+check_apps_deps([]) ->
+    [];
+check_apps_deps([{App, Deps}|AppDeps]) ->
+    ResOtherApps = check_apps_deps(AppDeps),
+    AppFile = code:where_is_file(atom_to_list(App) ++ ".app"),
+    {ok,[{application, App, Info}]} = file:consult(AppFile),
+    case lists:keyfind(runtime_dependencies, 1, Info) of
+	{runtime_dependencies, RDeps} ->
+	    check_app_deps(App, AppFile, RDeps, Deps) ++ ResOtherApps;
+	false ->
+	    [{missing_runtime_dependencies_key, AppFile} | ResOtherApps]
+    end.
+
 %%%
 %%% Common help functions.
 %%%