1 files changed, 85 insertions, 0 deletions
diff --git a/lib/hipe/rtl/hipe_rtl_cleanup_const.erl b/lib/hipe/rtl/hipe_rtl_cleanup_const.erl
new file mode 100644
index 0000000000..d3e71a56c1
--- /dev/null
+++ b/lib/hipe/rtl/hipe_rtl_cleanup_const.erl
@@ -0,0 +1,85 @@
+%%% -*- erlang-indent-level: 2 -*-
+%%%
+%%% %CopyrightBegin%
+%%% 
+%%% Copyright Ericsson AB 2004-2009. All Rights Reserved.
+%%% 
+%%% The contents of this file are subject to the Erlang Public License,
+%%% Version 1.1, (the "License"); you may not use this file except in
+%%% compliance with the License. You should have received a copy of the
+%%% Erlang Public License along with this software. If not, it can be
+%%% retrieved online at http://www.erlang.org/.
+%%% 
+%%% Software distributed under the License is distributed on an "AS IS"
+%%% basis, WITHOUT WARRANTY OF ANY KIND, either express or implied. See
+%%% the License for the specific language governing rights and limitations
+%%% under the License.
+%%% 
+%%% %CopyrightEnd%
+%%%
+%%%-------------------------------------------------------------------
+%%% File    : hipe_rtl_cleanup_const.erl
+%%% Author  : Tobias Lindahl <[email protected]>
+%%% Description : 
+%%%
+%%% Created :  5 Mar 2004 by Tobias Lindahl <[email protected]>
+%%%-------------------------------------------------------------------
+
+%% Big constants (floats, bignums) can be used as arguments to
+%% arbitrary instructions in RTL. Since these are located in the
+%% constants area and the only instruction that currently can access
+%% them is load_address, the constants have to be moved out of the
+%% instruction and loaded into temporary variables before the
+%% instruction.
+%%
+%% Some backends can make use of the information that the arguments
+%% are really constants. Here is the place to add new backend-specific
+%% behaviour depending on this.
+
+%%--------------------------------------------------------------------
+
+-module(hipe_rtl_cleanup_const).
+
+-export([cleanup/1]).
+
+-include("hipe_rtl.hrl").
+
+%%--------------------------------------------------------------------
+
+%%-spec cleanup(#rtl{}) -> #rtl{}.
+
+cleanup(Rtl) ->
+  Code = cleanup(hipe_rtl:rtl_code(Rtl), []),
+  hipe_rtl:rtl_code_update(Rtl, Code).
+
+cleanup([I|Left], Acc) ->
+  Args = hipe_rtl:args(I),
+  case [X || X <- Args, hipe_rtl:is_const_label(X)] of
+    [] ->
+      cleanup(Left, [I|Acc]);
+    ConstArgs ->
+      NewIns = cleanup_instr(ConstArgs, I),
+      cleanup(Left, NewIns ++ Acc)
+  end;
+cleanup([], Acc) ->
+  lists:reverse(Acc).
+
+cleanup_instr(Consts, I) ->
+  cleanup_instr(ordsets:from_list(Consts), I, []).
+
+cleanup_instr([Const|Left], I, Acc) ->
+  Dst = hipe_rtl:mk_new_var(),
+  ConstLabel = hipe_rtl:const_label_label(Const),
+  Load = hipe_rtl:mk_load_address(Dst, ConstLabel, constant),
+  case I of
+    X when is_record(X, fp_unop) orelse is_record(X, fp) ->
+      Fdst = hipe_rtl:mk_new_fpreg(),
+      Fconv = hipe_tagscheme:unsafe_untag_float(Fdst, Dst),		  
+      NewI = hipe_rtl:subst_uses([{Const, Fdst}], I),
+      cleanup_instr(Left, NewI, Fconv ++ [Load|Acc]);
+    _ ->
+      NewI = hipe_rtl:subst_uses([{Const, Dst}], I),
+      cleanup_instr(Left, NewI, [Load|Acc])
+  end;
+cleanup_instr([], I, Acc) ->
+  [I|Acc].