1 files changed, 77 insertions, 0 deletions
diff --git a/lib/orber/COSS/CosNaming/cos_naming.idl b/lib/orber/COSS/CosNaming/cos_naming.idl
new file mode 100644
index 0000000000..3cd6c99c23
--- /dev/null
+++ b/lib/orber/COSS/CosNaming/cos_naming.idl
@@ -0,0 +1,77 @@
+// Naming Service v1.0 described in CORBAservices: 
+// Common Object Services Specification, chapter 3
+// OMG IDL for CosNaming Module, p 3-6
+
+#pragma prefix "omg.org"
+
+module CosNaming
+{
+  typedef string Istring;
+  struct NameComponent {
+    Istring id;
+    Istring kind;
+  };
+  
+  typedef sequence <NameComponent> Name;
+  
+  enum BindingType {nobject, ncontext};
+  
+  struct Binding {
+    Name    binding_name;
+    BindingType binding_type;
+  };
+  
+  typedef sequence <Binding> BindingList;
+   
+
+  interface BindingIterator;
+  interface NamingContext;
+  
+  interface NamingContext {
+    
+    enum NotFoundReason { missing_node, not_context, not_object};
+    
+    exception NotFound {
+      NotFoundReason why;
+      Name rest_of_name;
+    };
+    
+    exception CannotProceed {
+      NamingContext cxt;
+      Name rest_of_name;
+    };
+    
+    exception InvalidName{};
+    exception AlreadyBound {};
+    exception NotEmpty{};
+    
+    void bind(in Name n, in Object obj)
+      raises(NotFound, CannotProceed, InvalidName, AlreadyBound);
+    void rebind(in Name n, in Object obj)
+      raises(NotFound, CannotProceed, InvalidName);
+    void bind_context(in Name n, in NamingContext nc)
+      raises(NotFound, CannotProceed,InvalidName, AlreadyBound);
+    void rebind_context(in Name n, in NamingContext nc)
+      raises(NotFound, CannotProceed, InvalidName);
+    Object resolve (in Name n)
+      raises(NotFound, CannotProceed, InvalidName);
+    void unbind(in Name n)
+      raises(NotFound, CannotProceed, InvalidName);
+    NamingContext new_context();
+    NamingContext bind_new_context(in Name n)
+      raises(NotFound, AlreadyBound, CannotProceed, InvalidName);
+    void destroy( )
+      raises(NotEmpty);
+    void list (in unsigned long how_many,
+	       out BindingList bl,
+	       out BindingIterator bi);
+  };
+  
+  interface BindingIterator {
+    boolean next_one(out Binding b);
+    boolean next_n(in unsigned long how_many,
+		   out BindingList bl);
+    void destroy();
+  };
+};
+